qcsrc/server/mutators/mutator/gamemode_lms.qc

   1 #include "gamemode_lms.qh"
   2 #ifndef GAMEMODE_LMS_H
   3 #define GAMEMODE_LMS_H
   4
   5 #define autocvar_g_lms_lives_override cvar("g_lms_lives_override")
   6 void lms_Initialize();
   7
   8 REGISTER_MUTATOR(lms, false)
   9 {
  10         MUTATOR_ONADD
  11         {
  12                 if (time > 1) // game loads at time 1
  13                         error("This is a game type and it cannot be added at runtime.");
  14                 lms_Initialize();
  15
  16                 SetLimits(((!autocvar_g_lms_lives_override) ? -1 : autocvar_g_lms_lives_override), 0, autocvar_timelimit_override, -1);
  17         }
  18
  19         MUTATOR_ONROLLBACK_OR_REMOVE
  20         {
  21                 // we actually cannot roll back lms_Initialize here
  22                 // BUT: we don't need to! If this gets called, adding always
  23                 // succeeds.
  24         }
  25
  26         MUTATOR_ONREMOVE
  27         {
  28                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  29                 return -1;
  30         }
  31
  32         return 0;
  33 }
  34
  35 // scoreboard stuff
  36 const float SP_LMS_LIVES = 4;
  37 const float SP_LMS_RANK = 5;
  38
  39 // lives related defs
  40 float lms_lowest_lives;
  41 float lms_next_place;
  42 float LMS_NewPlayerLives();
  43
  44 #endif
  45
  46 #ifdef IMPLEMENTATION
  47
  48 #include <common/mutators/mutator/instagib/items.qc>
  49 #include <server/campaign.qh>
  50 #include <server/command/cmd.qh>
  51
  52 int autocvar_g_lms_extra_lives;
  53 bool autocvar_g_lms_join_anytime;
  54 int autocvar_g_lms_last_join;
  55 bool autocvar_g_lms_regenerate;
  56
  57 // main functions
  58 float LMS_NewPlayerLives()
  59 {
  60         float fl;
  61         fl = autocvar_fraglimit;
  62         if(fl == 0)
  63                 fl = 999;
  64
  65         // first player has left the game for dying too much? Nobody else can get in.
  66         if(lms_lowest_lives < 1)
  67                 return 0;
  68
  69         if(!autocvar_g_lms_join_anytime)
  70                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  71                         return 0;
  72
  73         return bound(1, lms_lowest_lives, fl);
  74 }
  75
  76 void ClearWinners();
  77
  78 // LMS winning condition: game terminates if and only if there's at most one
  79 // one player who's living lives. Top two scores being equal cancels the time
  80 // limit.
  81 int WinningCondition_LMS()
  82 {
  83         entity head, head2;
  84         bool have_player = false;
  85         bool have_players = false;
  86
  87         int l = LMS_NewPlayerLives();
  88
  89         head = find(world, classname, STR_PLAYER);
  90         if(head)
  91                 have_player = true;
  92         head2 = find(head, classname, STR_PLAYER);
  93         if(head2)
  94                 have_players = true;
  95
  96         if(have_player)
  97         {
  98                 // we have at least one player
  99                 if(have_players)
 100                 {
 101                         // two or more active players - continue with the game
 102                 }
 103                 else
 104                 {
 105                         // exactly one player?
 106
 107                         ClearWinners();
 108                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
 109
 110                         if(l)
 111                         {
 112                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
 113                                 return WINNING_NO;
 114                         }
 115                         else
 116                         {
 117                                 // a winner!
 118                                 // and assign him his first place
 119                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
 120                                 return WINNING_YES;
 121                         }
 122                 }
 123         }
 124         else
 125         {
 126                 // nobody is playing at all...
 127                 if(l)
 128                 {
 129                         // wait for players...
 130                 }
 131                 else
 132                 {
 133                         // SNAFU (maybe a draw game?)
 134                         ClearWinners();
 135                         LOG_TRACE("No players, ending game.\n");
 136                         return WINNING_YES;
 137                 }
 138         }
 139
 140         // When we get here, we have at least two players who are actually LIVING,
 141         // now check if the top two players have equal score.
 142         WinningConditionHelper();
 143
 144         ClearWinners();
 145         if(WinningConditionHelper_winner)
 146                 WinningConditionHelper_winner.winning = true;
 147         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
 148                 return WINNING_NEVER;
 149
 150         // Top two have different scores? Way to go for our beloved TIMELIMIT!
 151         return WINNING_NO;
 152 }
 153
 154 // mutator hooks
 155 MUTATOR_HOOKFUNCTION(lms, reset_map_global)
 156 {
 157         lms_lowest_lives = 999;
 158         lms_next_place = player_count;
 159
 160         return false;
 161 }
 162
 163 MUTATOR_HOOKFUNCTION(lms, reset_map_players)
 164 {
 165         if(restart_mapalreadyrestarted || (time < game_starttime))
 166         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(PlayerScore_Add(it, SP_LMS_LIVES, LMS_NewPlayerLives())));
 167         return false;
 168 }
 169
 170 MUTATOR_HOOKFUNCTION(lms, PutClientInServer)
 171 {
 172         entity player = M_ARGV(0, entity);
 173
 174         // player is dead and becomes observer
 175         // FIXME fix LMS scoring for new system
 176         if(PlayerScore_Add(player, SP_LMS_RANK, 0) > 0)
 177         {
 178                 TRANSMUTE(Observer, player);
 179                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_LMS_NOLIVES);
 180         }
 181 }
 182
 183 MUTATOR_HOOKFUNCTION(lms, PlayerDies)
 184 {
 185         frag_target.respawn_flags |= RESPAWN_FORCE;
 186         return false;
 187 }
 188
 189 void lms_RemovePlayer(entity player)
 190 {
 191         // Only if the player cannot play at all
 192         if(PlayerScore_Add(player, SP_LMS_RANK, 0) == 666)
 193                 player.frags = FRAGS_SPECTATOR;
 194         else
 195                 player.frags = FRAGS_LMS_LOSER;
 196
 197         if(player.killcount != FRAGS_SPECTATOR)
 198                 if(PlayerScore_Add(player, SP_LMS_RANK, 0) > 0 && player.lms_spectate_warning != 2)
 199                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, player.netname);
 200                 else
 201                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, player.netname);
 202 }
 203
 204 MUTATOR_HOOKFUNCTION(lms, ClientDisconnect)
 205 {SELFPARAM();
 206         lms_RemovePlayer(self);
 207         return false;
 208 }
 209
 210 MUTATOR_HOOKFUNCTION(lms, MakePlayerObserver)
 211 {
 212     SELFPARAM();
 213         lms_RemovePlayer(this);
 214         return true;  // prevent team reset
 215 }
 216
 217 MUTATOR_HOOKFUNCTION(lms, ClientConnect)
 218 {SELFPARAM();
 219         TRANSMUTE(Player, self);
 220         campaign_bots_may_start = true;
 221
 222         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
 223         {
 224                 PlayerScore_Add(self, SP_LMS_RANK, 666);
 225                 self.frags = FRAGS_SPECTATOR;
 226         }
 227
 228         return false;
 229 }
 230
 231 MUTATOR_HOOKFUNCTION(lms, PlayerPreThink)
 232 {SELFPARAM();
 233         if(this.deadflag == DEAD_DYING)
 234                 this.deadflag = DEAD_RESPAWNING;
 235
 236         return false;
 237 }
 238
 239 MUTATOR_HOOKFUNCTION(lms, PlayerRegen)
 240 {
 241         if(autocvar_g_lms_regenerate)
 242                 return false;
 243         return true;
 244 }
 245
 246 MUTATOR_HOOKFUNCTION(lms, ForbidThrowCurrentWeapon)
 247 {
 248         // forbode!
 249         return true;
 250 }
 251
 252 MUTATOR_HOOKFUNCTION(lms, GiveFragsForKill)
 253 {
 254         // remove a life
 255         float tl;
 256         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
 257         if(tl < lms_lowest_lives)
 258                 lms_lowest_lives = tl;
 259         if(tl <= 0)
 260         {
 261                 if(!lms_next_place)
 262                         lms_next_place = player_count;
 263                 else
 264                         lms_next_place = min(lms_next_place, player_count);
 265                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 266                 --lms_next_place;
 267         }
 268         frag_score = 0;
 269
 270         return true;
 271 }
 272
 273 MUTATOR_HOOKFUNCTION(lms, SetStartItems)
 274 {
 275         start_items &= ~IT_UNLIMITED_AMMO;
 276         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 277         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 278         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 279         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 280         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 281         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 282         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 283         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 284
 285         return false;
 286 }
 287
 288 MUTATOR_HOOKFUNCTION(lms, ForbidPlayerScore_Clear)
 289 {
 290         // don't clear player score
 291         return true;
 292 }
 293
 294 MUTATOR_HOOKFUNCTION(lms, FilterItem)
 295 {SELFPARAM();
 296         if(autocvar_g_lms_extra_lives)
 297         if(self.itemdef == ITEM_ExtraLife)
 298                 return false;
 299
 300         return true;
 301 }
 302
 303 void lms_extralife(entity this)
 304 {
 305         StartItem(this, ITEM_ExtraLife);
 306 }
 307
 308 MUTATOR_HOOKFUNCTION(lms, OnEntityPreSpawn)
 309 {SELFPARAM();
 310         if (!autocvar_g_powerups) return false;
 311         if (!autocvar_g_lms_extra_lives) return false;
 312
 313         // Can't use .itemdef here
 314         if (self.classname != "item_health_mega") return false;
 315
 316         entity e = spawn();
 317         setthink(e, lms_extralife);
 318
 319         e.nextthink = time + 0.1;
 320         e.spawnflags = self.spawnflags;
 321         e.noalign = self.noalign;
 322         setorigin(e, self.origin);
 323
 324         return true;
 325 }
 326
 327 MUTATOR_HOOKFUNCTION(lms, ItemTouch)
 328 {SELFPARAM();
 329         if(self.itemdef == ITEM_ExtraLife)
 330         {
 331                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 332                 PlayerScore_Add(other, SP_LMS_LIVES, autocvar_g_lms_extra_lives);
 333                 return MUT_ITEMTOUCH_PICKUP;
 334         }
 335
 336         return MUT_ITEMTOUCH_CONTINUE;
 337 }
 338
 339 MUTATOR_HOOKFUNCTION(lms, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 340 {
 341         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 342                 ++bot_activerealplayers;
 343                 ++bot_realplayers;
 344         ));
 345
 346         return true;
 347 }
 348
 349 MUTATOR_HOOKFUNCTION(lms, ClientCommand_Spectate)
 350 {
 351     SELFPARAM();
 352         if(self.lms_spectate_warning)
 353         {
 354                 // for the forfeit message...
 355                 self.lms_spectate_warning = 2;
 356                 // mark player as spectator
 357                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 358         }
 359         else
 360         {
 361                 self.lms_spectate_warning = 1;
 362                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 363                 return MUT_SPECCMD_RETURN;
 364         }
 365         return MUT_SPECCMD_CONTINUE;
 366 }
 367
 368 MUTATOR_HOOKFUNCTION(lms, CheckRules_World)
 369 {
 370         ret_float = WinningCondition_LMS();
 371         return true;
 372 }
 373
 374 MUTATOR_HOOKFUNCTION(lms, WantWeapon)
 375 {
 376         want_allguns = true;
 377         return false;
 378 }
 379
 380 MUTATOR_HOOKFUNCTION(lms, GetPlayerStatus)
 381 {
 382         return true;
 383 }
 384
 385 MUTATOR_HOOKFUNCTION(lms, AddPlayerScore)
 386 {
 387         if(gameover)
 388         if(score_field == SP_LMS_RANK)
 389                 return true; // allow writing to this field in intermission as it is needed for newly joining players
 390         return false;
 391 }
 392
 393 // scoreboard stuff
 394 void lms_ScoreRules()
 395 {
 396         ScoreRules_basics(0, 0, 0, false);
 397         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
 398         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
 399         ScoreRules_basics_end();
 400 }
 401
 402 void lms_Initialize()
 403 {
 404         lms_lowest_lives = 9999;
 405         lms_next_place = 0;
 406
 407         lms_ScoreRules();
 408 }
 409
 410
 411 #endif