qcsrc/server/mutators/mutator/gamemode_race.qc

   1 #include "gamemode_race.qh"
   2
   3 #ifndef GAMEMODE_RACE_H
   4 #define GAMEMODE_RACE_H
   5
   6 void rc_SetLimits();
   7 void race_Initialize();
   8
   9 REGISTER_MUTATOR(rc, false)
  10 {
  11         MUTATOR_ONADD
  12         {
  13                 if (time > 1) // game loads at time 1
  14                         error("This is a game type and it cannot be added at runtime.");
  15
  16                 rc_SetLimits();
  17                 race_Initialize();
  18         }
  19
  20         MUTATOR_ONROLLBACK_OR_REMOVE
  21         {
  22                 // we actually cannot roll back race_Initialize here
  23                 // BUT: we don't need to! If this gets called, adding always
  24                 // succeeds.
  25         }
  26
  27         MUTATOR_ONREMOVE
  28         {
  29                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  30                 return -1;
  31         }
  32
  33         return 0;
  34 }
  35
  36 #endif
  37
  38 #ifdef IMPLEMENTATION
  39
  40 #include <server/race.qh>
  41
  42 #define autocvar_g_race_laps_limit cvar("g_race_laps_limit")
  43 float autocvar_g_race_qualifying_timelimit;
  44 float autocvar_g_race_qualifying_timelimit_override;
  45 int autocvar_g_race_teams;
  46
  47 // legacy bot roles
  48 .float race_checkpoint;
  49 void havocbot_role_race(entity this)
  50 {
  51         if(IS_DEAD(this))
  52                 return;
  53
  54         entity e;
  55         if (this.bot_strategytime < time)
  56         {
  57                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
  58                 navigation_goalrating_start(this);
  59
  60                 for(e = world; (e = find(e, classname, "trigger_race_checkpoint")) != world; )
  61                 {
  62                         if(e.cnt == this.race_checkpoint)
  63                         {
  64                                 navigation_routerating(this, e, 1000000, 5000);
  65                         }
  66                         else if(this.race_checkpoint == -1)
  67                         {
  68                                 navigation_routerating(this, e, 1000000, 5000);
  69                         }
  70                 }
  71
  72                 navigation_goalrating_end(this);
  73         }
  74 }
  75
  76 void race_ScoreRules()
  77 {
  78         ScoreRules_basics(race_teams, 0, 0, false);
  79         if(race_teams)
  80         {
  81                 ScoreInfo_SetLabel_TeamScore(  ST_RACE_LAPS,    "laps",      SFL_SORT_PRIO_PRIMARY);
  82                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_LAPS,    "laps",      SFL_SORT_PRIO_PRIMARY);
  83                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_TIME,    "time",      SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  84                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_FASTEST, "fastest",   SFL_LOWER_IS_BETTER | SFL_TIME);
  85         }
  86         else if(g_race_qualifying)
  87         {
  88                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_FASTEST, "fastest",   SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  89         }
  90         else
  91         {
  92                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_LAPS,    "laps",      SFL_SORT_PRIO_PRIMARY);
  93                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_TIME,    "time",      SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  94                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_FASTEST, "fastest",   SFL_LOWER_IS_BETTER | SFL_TIME);
  95         }
  96         ScoreRules_basics_end();
  97 }
  98
  99 void race_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
 100 {
 101         if(autocvar_sv_eventlog)
 102                 GameLogEcho(strcat(":race:", mode, ":", ((actor != world) ? (strcat(":", ftos(actor.playerid))) : "")));
 103 }
 104
 105 float WinningCondition_Race(float fraglimit)
 106 {
 107         float wc;
 108         float n, c;
 109
 110         n = 0;
 111         c = 0;
 112         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 113                 ++n;
 114                 if(it.race_completed)
 115                         ++c;
 116         ));
 117         if(n && (n == c))
 118                 return WINNING_YES;
 119         wc = WinningCondition_Scores(fraglimit, 0);
 120
 121         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
 122         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
 123         // do NOT support equality when the laps are all raced!
 124                 return WINNING_STARTSUDDENDEATHOVERTIME;
 125         else
 126                 return WINNING_NEVER;
 127 }
 128
 129 float WinningCondition_QualifyingThenRace(float limit)
 130 {
 131         float wc;
 132         wc = WinningCondition_Scores(limit, 0);
 133
 134         // NEVER initiate overtime
 135         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
 136         {
 137                 return WINNING_YES;
 138         }
 139
 140         return wc;
 141 }
 142
 143 MUTATOR_HOOKFUNCTION(rc, PlayerPhysics)
 144 {SELFPARAM();
 145         self.race_movetime_frac += PHYS_INPUT_TIMELENGTH;
 146         float f = floor(self.race_movetime_frac);
 147         self.race_movetime_frac -= f;
 148         self.race_movetime_count += f;
 149         self.race_movetime = self.race_movetime_frac + self.race_movetime_count;
 150
 151 #ifdef SVQC
 152         if(IS_PLAYER(self))
 153         {
 154                 if (self.race_penalty)
 155                         if (time > self.race_penalty)
 156                                 self.race_penalty = 0;
 157                 if(self.race_penalty)
 158                 {
 159                         self.velocity = '0 0 0';
 160                         self.movetype = MOVETYPE_NONE;
 161                         self.disableclientprediction = 2;
 162                 }
 163         }
 164 #endif
 165
 166         // force kbd movement for fairness
 167         float wishspeed;
 168         vector wishvel;
 169
 170         // if record times matter
 171         // ensure nothing EVIL is being done (i.e. div0_evade)
 172         // this hinders joystick users though
 173         // but it still gives SOME analog control
 174         wishvel.x = fabs(self.movement.x);
 175         wishvel.y = fabs(self.movement.y);
 176         if(wishvel.x != 0 && wishvel.y != 0 && wishvel.x != wishvel.y)
 177         {
 178                 wishvel.z = 0;
 179                 wishspeed = vlen(wishvel);
 180                 if(wishvel.x >= 2 * wishvel.y)
 181                 {
 182                         // pure X motion
 183                         if(self.movement.x > 0)
 184                                 self.movement_x = wishspeed;
 185                         else
 186                                 self.movement_x = -wishspeed;
 187                         self.movement_y = 0;
 188                 }
 189                 else if(wishvel.y >= 2 * wishvel.x)
 190                 {
 191                         // pure Y motion
 192                         self.movement_x = 0;
 193                         if(self.movement.y > 0)
 194                                 self.movement_y = wishspeed;
 195                         else
 196                                 self.movement_y = -wishspeed;
 197                 }
 198                 else
 199                 {
 200                         // diagonal
 201                         if(self.movement.x > 0)
 202                                 self.movement_x = M_SQRT1_2 * wishspeed;
 203                         else
 204                                 self.movement_x = -M_SQRT1_2 * wishspeed;
 205                         if(self.movement.y > 0)
 206                                 self.movement_y = M_SQRT1_2 * wishspeed;
 207                         else
 208                                 self.movement_y = -M_SQRT1_2 * wishspeed;
 209                 }
 210         }
 211
 212         return false;
 213 }
 214
 215 MUTATOR_HOOKFUNCTION(rc, reset_map_global)
 216 {
 217         float s;
 218
 219         Score_NicePrint(world);
 220
 221         race_ClearRecords();
 222         PlayerScore_Sort(race_place, 0, 1, 0);
 223
 224         FOREACH_CLIENT(true, LAMBDA(
 225                 if(it.race_place)
 226                 {
 227                         s = PlayerScore_Add(it, SP_RACE_FASTEST, 0);
 228                         if(!s)
 229                                 it.race_place = 0;
 230                 }
 231                 race_EventLog(ftos(it.race_place), it);
 232         ));
 233
 234         if(g_race_qualifying == 2)
 235         {
 236                 g_race_qualifying = 0;
 237                 independent_players = 0;
 238                 cvar_set("fraglimit", ftos(race_fraglimit));
 239                 cvar_set("leadlimit", ftos(race_leadlimit));
 240                 cvar_set("timelimit", ftos(race_timelimit));
 241                 race_ScoreRules();
 242         }
 243
 244         return false;
 245 }
 246
 247 MUTATOR_HOOKFUNCTION(rc, ClientConnect)
 248 {SELFPARAM();
 249         race_PreparePlayer();
 250         self.race_checkpoint = -1;
 251
 252         string rr = RACE_RECORD;
 253
 254         if(IS_REAL_CLIENT(self))
 255         {
 256                 msg_entity = self;
 257                 race_send_recordtime(MSG_ONE);
 258                 race_send_speedaward(MSG_ONE);
 259
 260                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
 261                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
 262                 race_send_speedaward_alltimebest(MSG_ONE);
 263
 264                 float i;
 265                 for (i = 1; i <= RANKINGS_CNT; ++i)
 266                 {
 267                         race_SendRankings(i, 0, 0, MSG_ONE);
 268                 }
 269         }
 270
 271         return false;
 272 }
 273
 274 MUTATOR_HOOKFUNCTION(rc, MakePlayerObserver)
 275 {SELFPARAM();
 276         if(g_race_qualifying)
 277         if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 278                 self.frags = FRAGS_LMS_LOSER;
 279         else
 280                 self.frags = FRAGS_SPECTATOR;
 281
 282         race_PreparePlayer();
 283         self.race_checkpoint = -1;
 284
 285         return false;
 286 }
 287
 288 MUTATOR_HOOKFUNCTION(rc, PlayerSpawn)
 289 {SELFPARAM();
 290         if(spawn_spot.target == "")
 291                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
 292                 race_PreparePlayer();
 293
 294         // if we need to respawn, do it right
 295         self.race_respawn_checkpoint = self.race_checkpoint;
 296         self.race_respawn_spotref = spawn_spot;
 297
 298         self.race_place = 0;
 299
 300         return false;
 301 }
 302
 303 MUTATOR_HOOKFUNCTION(rc, PutClientInServer)
 304 {SELFPARAM();
 305         if(IS_PLAYER(self))
 306         if(!gameover)
 307         {
 308                 if(self.killcount == FRAGS_SPECTATOR /* initial spawn */ || g_race_qualifying) // spawn
 309                         race_PreparePlayer();
 310                 else // respawn
 311                         race_RetractPlayer();
 312
 313                 race_AbandonRaceCheck(self);
 314         }
 315         return false;
 316 }
 317
 318 MUTATOR_HOOKFUNCTION(rc, PlayerDies)
 319 {
 320         frag_target.respawn_flags |= RESPAWN_FORCE;
 321         race_AbandonRaceCheck(frag_target);
 322         return false;
 323 }
 324
 325 MUTATOR_HOOKFUNCTION(rc, HavocBot_ChooseRole)
 326 {SELFPARAM();
 327         self.havocbot_role = havocbot_role_race;
 328         return true;
 329 }
 330
 331 MUTATOR_HOOKFUNCTION(rc, GetPressedKeys)
 332 {SELFPARAM();
 333         if(self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
 334         {
 335                 if (!self.stored_netname)
 336                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
 337                 if(self.stored_netname != self.netname)
 338                 {
 339                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
 340                         strunzone(self.stored_netname);
 341                         self.stored_netname = strzone(self.netname);
 342                 }
 343         }
 344
 345         if (!IS_OBSERVER(self))
 346         {
 347                 if (vlen(self.velocity - self.velocity_z * '0 0 1') > speedaward_speed)
 348                 {
 349                         speedaward_speed = vlen(self.velocity - self.velocity_z * '0 0 1');
 350                         speedaward_holder = self.netname;
 351                         speedaward_uid = self.crypto_idfp;
 352                         speedaward_lastupdate = time;
 353                 }
 354                 if (speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1)
 355                 {
 356                         string rr = RACE_RECORD;
 357                         race_send_speedaward(MSG_ALL);
 358                         speedaward_lastsent = speedaward_speed;
 359                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "")
 360                         {
 361                                 speedaward_alltimebest = speedaward_speed;
 362                                 speedaward_alltimebest_holder = speedaward_holder;
 363                                 speedaward_alltimebest_uid = speedaward_uid;
 364                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
 365                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
 366                                 race_send_speedaward_alltimebest(MSG_ALL);
 367                         }
 368                 }
 369         }
 370         return false;
 371 }
 372
 373 MUTATOR_HOOKFUNCTION(rc, ForbidPlayerScore_Clear)
 374 {
 375         if(g_race_qualifying)
 376                 return true; // in qualifying, you don't lose score by observing
 377
 378         return false;
 379 }
 380
 381 MUTATOR_HOOKFUNCTION(rc, GetTeamCount, CBC_ORDER_EXCLUSIVE)
 382 {
 383         ret_float = race_teams;
 384         return false;
 385 }
 386
 387 MUTATOR_HOOKFUNCTION(rc, Scores_CountFragsRemaining)
 388 {
 389         // announce remaining frags if not in qualifying mode
 390         if(!g_race_qualifying)
 391                 return true;
 392
 393         return false;
 394 }
 395
 396 MUTATOR_HOOKFUNCTION(rc, GetRecords)
 397 {
 398         for(int i = record_page * 200; i < MapInfo_count && i < record_page * 200 + 200; ++i)
 399         {
 400                 if(MapInfo_Get_ByID(i))
 401                 {
 402                         float r = race_readTime(MapInfo_Map_bspname, 1);
 403
 404                         if(!r)
 405                                 continue;
 406
 407                         string h = race_readName(MapInfo_Map_bspname, 1);
 408                         ret_string = strcat(ret_string, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
 409                 }
 410         }
 411
 412         return false;
 413 }
 414
 415 MUTATOR_HOOKFUNCTION(rc, FixClientCvars)
 416 {
 417         stuffcmd(fix_client, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 418         return false;
 419 }
 420
 421 MUTATOR_HOOKFUNCTION(rc, CheckRules_World)
 422 {
 423         if(checkrules_timelimit >= 0)
 424         {
 425                 if(!g_race_qualifying)
 426                 {
 427                         ret_float = WinningCondition_Race(checkrules_fraglimit);
 428                         return true;
 429                 }
 430                 else if(g_race_qualifying == 2)
 431                 {
 432                         ret_float = WinningCondition_QualifyingThenRace(checkrules_fraglimit);
 433                         return true;
 434                 }
 435         }
 436
 437         return false;
 438 }
 439
 440 MUTATOR_HOOKFUNCTION(rc, ReadLevelCvars)
 441 {
 442         if(g_race_qualifying == 2)
 443                 warmup_stage = 0;
 444         return false;
 445 }
 446
 447 void race_Initialize()
 448 {
 449         race_ScoreRules();
 450         if(g_race_qualifying == 2)
 451                 warmup_stage = 0;
 452 }
 453
 454 void rc_SetLimits()
 455 {
 456         int fraglimit_override, leadlimit_override;
 457         float timelimit_override, qualifying_override;
 458
 459         if(autocvar_g_race_teams)
 460         {
 461                 ActivateTeamplay();
 462                 race_teams = bound(2, autocvar_g_race_teams, 4);
 463                 have_team_spawns = -1; // request team spawns
 464         }
 465         else
 466                 race_teams = 0;
 467
 468         qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 469         fraglimit_override = autocvar_g_race_laps_limit;
 470         leadlimit_override = 0; // currently not supported by race
 471         timelimit_override = autocvar_timelimit_override;
 472
 473         float want_qualifying = ((qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit) > 0;
 474
 475         if(autocvar_g_campaign)
 476         {
 477                 g_race_qualifying = 1;
 478                 independent_players = 1;
 479         }
 480         else if(want_qualifying)
 481         {
 482                 g_race_qualifying = 2;
 483                 independent_players = 1;
 484                 race_fraglimit = (fraglimit_override >= 0) ? fraglimit_override : autocvar_fraglimit;
 485                 race_leadlimit = (leadlimit_override >= 0) ? leadlimit_override : autocvar_leadlimit;
 486                 race_timelimit = (timelimit_override >= 0) ? timelimit_override : autocvar_timelimit;
 487                 qualifying_override = (qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit;
 488                 fraglimit_override = 0;
 489                 leadlimit_override = 0;
 490                 timelimit_override = qualifying_override;
 491         }
 492         else
 493                 g_race_qualifying = 0;
 494         SetLimits(fraglimit_override, leadlimit_override, timelimit_override, qualifying_override);
 495 }
 496
 497 #endif