qcsrc/server/mutators/mutator/gamemode_race.qc

   1 #include "gamemode_race.qh"
   2
   3 #include <server/race.qh>
   4
   5 #define autocvar_g_race_laps_limit cvar("g_race_laps_limit")
   6 float autocvar_g_race_qualifying_timelimit;
   7 float autocvar_g_race_qualifying_timelimit_override;
   8 int autocvar_g_race_teams;
   9
  10 // legacy bot roles
  11 .float race_checkpoint;
  12 void havocbot_role_race(entity this)
  13 {
  14         if(IS_DEAD(this))
  15                 return;
  16
  17         if (this.bot_strategytime < time)
  18         {
  19                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
  20                 navigation_goalrating_start(this);
  21
  22                 IL_EACH(g_racecheckpoints, true,
  23                 {
  24                         if(it.cnt == this.race_checkpoint)
  25                         {
  26                                 navigation_routerating(this, it, 1000000, 5000);
  27                         }
  28                         else if(this.race_checkpoint == -1)
  29                         {
  30                                 navigation_routerating(this, it, 1000000, 5000);
  31                         }
  32                 });
  33
  34                 navigation_goalrating_end(this);
  35         }
  36 }
  37
  38 void race_ScoreRules()
  39 {
  40         ScoreRules_basics(race_teams, 0, 0, false);
  41         if(race_teams)
  42         {
  43                 ScoreInfo_SetLabel_TeamScore(  ST_RACE_LAPS,    "laps",       SFL_SORT_PRIO_PRIMARY);
  44                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_LAPS,    "laps",      SFL_SORT_PRIO_PRIMARY);
  45                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_TIME,    "time",      SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  46                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_FASTEST, "fastest",   SFL_LOWER_IS_BETTER | SFL_TIME);
  47         }
  48         else if(g_race_qualifying)
  49         {
  50                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_FASTEST, "fastest",   SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  51         }
  52         else
  53         {
  54                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_LAPS,    "laps",      SFL_SORT_PRIO_PRIMARY);
  55                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_TIME,    "time",      SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  56                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_FASTEST, "fastest",   SFL_LOWER_IS_BETTER | SFL_TIME);
  57         }
  58         ScoreRules_basics_end();
  59 }
  60
  61 void race_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  62 {
  63         if(autocvar_sv_eventlog)
  64                 GameLogEcho(strcat(":race:", mode, ":", ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  65 }
  66
  67 float WinningCondition_Race(float fraglimit)
  68 {
  69         float wc;
  70         float n, c;
  71
  72         n = 0;
  73         c = 0;
  74         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
  75                 ++n;
  76                 if(it.race_completed)
  77                         ++c;
  78         ));
  79         if(n && (n == c))
  80                 return WINNING_YES;
  81         wc = WinningCondition_Scores(fraglimit, 0);
  82
  83         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
  84         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
  85         // do NOT support equality when the laps are all raced!
  86                 return WINNING_STARTSUDDENDEATHOVERTIME;
  87         else
  88                 return WINNING_NEVER;
  89 }
  90
  91 float WinningCondition_QualifyingThenRace(float limit)
  92 {
  93         float wc;
  94         wc = WinningCondition_Scores(limit, 0);
  95
  96         // NEVER initiate overtime
  97         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
  98         {
  99                 return WINNING_YES;
 100         }
 101
 102         return wc;
 103 }
 104
 105 MUTATOR_HOOKFUNCTION(rc, ClientKill)
 106 {
 107         if(g_race_qualifying)
 108                 M_ARGV(1, float) = 0; // killtime
 109 }
 110
 111 MUTATOR_HOOKFUNCTION(rc, AbortSpeedrun)
 112 {
 113         entity player = M_ARGV(0, entity);
 114
 115         if(autocvar_g_allow_checkpoints)
 116                 race_PreparePlayer(player); // nice try
 117 }
 118
 119 MUTATOR_HOOKFUNCTION(rc, PlayerPhysics)
 120 {
 121         entity player = M_ARGV(0, entity);
 122         float dt = M_ARGV(1, float);
 123
 124         player.race_movetime_frac += dt;
 125         float f = floor(player.race_movetime_frac);
 126         player.race_movetime_frac -= f;
 127         player.race_movetime_count += f;
 128         player.race_movetime = player.race_movetime_frac + player.race_movetime_count;
 129
 130 #ifdef SVQC
 131         if(IS_PLAYER(player))
 132         {
 133                 if (player.race_penalty)
 134                         if (time > player.race_penalty)
 135                                 player.race_penalty = 0;
 136                 if(player.race_penalty)
 137                 {
 138                         player.velocity = '0 0 0';
 139                         set_movetype(player, MOVETYPE_NONE);
 140                         player.disableclientprediction = 2;
 141                 }
 142         }
 143 #endif
 144
 145         // force kbd movement for fairness
 146         float wishspeed;
 147         vector wishvel;
 148
 149         // if record times matter
 150         // ensure nothing EVIL is being done (i.e. div0_evade)
 151         // this hinders joystick users though
 152         // but it still gives SOME analog control
 153         wishvel.x = fabs(player.movement.x);
 154         wishvel.y = fabs(player.movement.y);
 155         if(wishvel.x != 0 && wishvel.y != 0 && wishvel.x != wishvel.y)
 156         {
 157                 wishvel.z = 0;
 158                 wishspeed = vlen(wishvel);
 159                 if(wishvel.x >= 2 * wishvel.y)
 160                 {
 161                         // pure X motion
 162                         if(player.movement.x > 0)
 163                                 player.movement_x = wishspeed;
 164                         else
 165                                 player.movement_x = -wishspeed;
 166                         player.movement_y = 0;
 167                 }
 168                 else if(wishvel.y >= 2 * wishvel.x)
 169                 {
 170                         // pure Y motion
 171                         player.movement_x = 0;
 172                         if(player.movement.y > 0)
 173                                 player.movement_y = wishspeed;
 174                         else
 175                                 player.movement_y = -wishspeed;
 176                 }
 177                 else
 178                 {
 179                         // diagonal
 180                         if(player.movement.x > 0)
 181                                 player.movement_x = M_SQRT1_2 * wishspeed;
 182                         else
 183                                 player.movement_x = -M_SQRT1_2 * wishspeed;
 184                         if(player.movement.y > 0)
 185                                 player.movement_y = M_SQRT1_2 * wishspeed;
 186                         else
 187                                 player.movement_y = -M_SQRT1_2 * wishspeed;
 188                 }
 189         }
 190 }
 191
 192 MUTATOR_HOOKFUNCTION(rc, reset_map_global)
 193 {
 194         float s;
 195
 196         Score_NicePrint(NULL);
 197
 198         race_ClearRecords();
 199         PlayerScore_Sort(race_place, 0, 1, 0);
 200
 201         FOREACH_CLIENT(true, LAMBDA(
 202                 if(it.race_place)
 203                 {
 204                         s = PlayerScore_Add(it, SP_RACE_FASTEST, 0);
 205                         if(!s)
 206                                 it.race_place = 0;
 207                 }
 208                 race_EventLog(ftos(it.race_place), it);
 209         ));
 210
 211         if(g_race_qualifying == 2)
 212         {
 213                 g_race_qualifying = 0;
 214                 independent_players = 0;
 215                 cvar_set("fraglimit", ftos(race_fraglimit));
 216                 cvar_set("leadlimit", ftos(race_leadlimit));
 217                 cvar_set("timelimit", ftos(race_timelimit));
 218                 race_ScoreRules();
 219         }
 220 }
 221
 222 MUTATOR_HOOKFUNCTION(rc, ClientConnect)
 223 {
 224         entity player = M_ARGV(0, entity);
 225
 226         race_PreparePlayer(player);
 227         player.race_checkpoint = -1;
 228
 229         string rr = RACE_RECORD;
 230
 231         if(IS_REAL_CLIENT(player))
 232         {
 233                 msg_entity = player;
 234                 race_send_recordtime(MSG_ONE);
 235                 race_send_speedaward(MSG_ONE);
 236
 237                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
 238                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
 239                 race_send_speedaward_alltimebest(MSG_ONE);
 240
 241                 float i;
 242                 for (i = 1; i <= RANKINGS_CNT; ++i)
 243                 {
 244                         race_SendRankings(i, 0, 0, MSG_ONE);
 245                 }
 246         }
 247 }
 248
 249 MUTATOR_HOOKFUNCTION(rc, MakePlayerObserver)
 250 {
 251         entity player = M_ARGV(0, entity);
 252
 253         if(g_race_qualifying)
 254         if(PlayerScore_Add(player, SP_RACE_FASTEST, 0))
 255                 player.frags = FRAGS_LMS_LOSER;
 256         else
 257                 player.frags = FRAGS_SPECTATOR;
 258
 259         race_PreparePlayer(player);
 260         player.race_checkpoint = -1;
 261 }
 262
 263 MUTATOR_HOOKFUNCTION(rc, PlayerSpawn)
 264 {
 265         entity player = M_ARGV(0, entity);
 266         entity spawn_spot = M_ARGV(1, entity);
 267
 268         if(spawn_spot.target == "")
 269                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
 270                 race_PreparePlayer(player);
 271
 272         // if we need to respawn, do it right
 273         player.race_respawn_checkpoint = player.race_checkpoint;
 274         player.race_respawn_spotref = spawn_spot;
 275
 276         player.race_place = 0;
 277 }
 278
 279 MUTATOR_HOOKFUNCTION(rc, PutClientInServer)
 280 {
 281         entity player = M_ARGV(0, entity);
 282
 283         if(IS_PLAYER(player))
 284         if(!game_stopped)
 285         {
 286                 if(player.killcount == FRAGS_SPECTATOR /* initial spawn */ || g_race_qualifying) // spawn
 287                         race_PreparePlayer(player);
 288                 else // respawn
 289                         race_RetractPlayer(player);
 290
 291                 race_AbandonRaceCheck(player);
 292         }
 293 }
 294
 295 MUTATOR_HOOKFUNCTION(rc, PlayerDies)
 296 {
 297         entity frag_target = M_ARGV(2, entity);
 298
 299         frag_target.respawn_flags |= RESPAWN_FORCE;
 300         race_AbandonRaceCheck(frag_target);
 301 }
 302
 303 MUTATOR_HOOKFUNCTION(rc, HavocBot_ChooseRole)
 304 {
 305         entity bot = M_ARGV(0, entity);
 306
 307         bot.havocbot_role = havocbot_role_race;
 308         return true;
 309 }
 310
 311 MUTATOR_HOOKFUNCTION(rc, GetPressedKeys)
 312 {
 313         entity player = M_ARGV(0, entity);
 314
 315         if(player.cvar_cl_allow_uidtracking == 1 && player.cvar_cl_allow_uid2name == 1)
 316         {
 317                 if (!player.stored_netname)
 318                         player.stored_netname = strzone(uid2name(player.crypto_idfp));
 319                 if(player.stored_netname != player.netname)
 320                 {
 321                         db_put(ServerProgsDB, strcat("/uid2name/", player.crypto_idfp), player.netname);
 322                         strunzone(player.stored_netname);
 323                         player.stored_netname = strzone(player.netname);
 324                 }
 325         }
 326
 327         if (!IS_OBSERVER(player))
 328         {
 329                 if(vdist(player.velocity - player.velocity_z * '0 0 1', >, speedaward_speed))
 330                 {
 331                         speedaward_speed = vlen(player.velocity - player.velocity_z * '0 0 1');
 332                         speedaward_holder = player.netname;
 333                         speedaward_uid = player.crypto_idfp;
 334                         speedaward_lastupdate = time;
 335                 }
 336                 if (speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1)
 337                 {
 338                         string rr = RACE_RECORD;
 339                         race_send_speedaward(MSG_ALL);
 340                         speedaward_lastsent = speedaward_speed;
 341                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "")
 342                         {
 343                                 speedaward_alltimebest = speedaward_speed;
 344                                 speedaward_alltimebest_holder = speedaward_holder;
 345                                 speedaward_alltimebest_uid = speedaward_uid;
 346                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
 347                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
 348                                 race_send_speedaward_alltimebest(MSG_ALL);
 349                         }
 350                 }
 351         }
 352 }
 353
 354 MUTATOR_HOOKFUNCTION(rc, ForbidPlayerScore_Clear)
 355 {
 356         if(g_race_qualifying)
 357                 return true; // in qualifying, you don't lose score by observing
 358 }
 359
 360 MUTATOR_HOOKFUNCTION(rc, CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
 361 {
 362         M_ARGV(0, float) = race_teams;
 363 }
 364
 365 MUTATOR_HOOKFUNCTION(rc, Scores_CountFragsRemaining)
 366 {
 367         // announce remaining frags if not in qualifying mode
 368         if(!g_race_qualifying)
 369                 return true;
 370 }
 371
 372 MUTATOR_HOOKFUNCTION(rc, GetRecords)
 373 {
 374         int record_page = M_ARGV(0, int);
 375         string ret_string = M_ARGV(1, string);
 376
 377         for(int i = record_page * 200; i < MapInfo_count && i < record_page * 200 + 200; ++i)
 378         {
 379                 if(MapInfo_Get_ByID(i))
 380                 {
 381                         float r = race_readTime(MapInfo_Map_bspname, 1);
 382
 383                         if(!r)
 384                                 continue;
 385
 386                         string h = race_readName(MapInfo_Map_bspname, 1);
 387                         ret_string = strcat(ret_string, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
 388                 }
 389         }
 390
 391         M_ARGV(1, string) = ret_string;
 392 }
 393
 394 MUTATOR_HOOKFUNCTION(rc, HideTeamNagger)
 395 {
 396         return true; // doesn't work so well
 397 }
 398
 399 MUTATOR_HOOKFUNCTION(rc, FixClientCvars)
 400 {
 401         entity player = M_ARGV(0, entity);
 402
 403         stuffcmd(player, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 404 }
 405
 406 MUTATOR_HOOKFUNCTION(rc, CheckRules_World)
 407 {
 408         float checkrules_timelimit = M_ARGV(1, float);
 409         float checkrules_fraglimit = M_ARGV(2, float);
 410
 411         if(checkrules_timelimit >= 0)
 412         {
 413                 if(!g_race_qualifying)
 414                 {
 415                         M_ARGV(0, float) = WinningCondition_Race(checkrules_fraglimit);
 416                         return true;
 417                 }
 418                 else if(g_race_qualifying == 2)
 419                 {
 420                         M_ARGV(0, float) = WinningCondition_QualifyingThenRace(checkrules_fraglimit);
 421                         return true;
 422                 }
 423         }
 424 }
 425
 426 MUTATOR_HOOKFUNCTION(rc, ReadLevelCvars)
 427 {
 428         if(g_race_qualifying == 2)
 429                 warmup_stage = 0;
 430 }
 431
 432 void race_Initialize()
 433 {
 434         race_ScoreRules();
 435         if(g_race_qualifying == 2)
 436                 warmup_stage = 0;
 437 }
 438
 439 void rc_SetLimits()
 440 {
 441         int fraglimit_override, leadlimit_override;
 442         float timelimit_override, qualifying_override;
 443
 444         if(autocvar_g_race_teams)
 445         {
 446                 ActivateTeamplay();
 447                 race_teams = bound(2, autocvar_g_race_teams, 4);
 448                 int teams = 0;
 449                 if(race_teams >= 1) teams |= BIT(0);
 450                 if(race_teams >= 2) teams |= BIT(1);
 451                 if(race_teams >= 3) teams |= BIT(2);
 452                 if(race_teams >= 4) teams |= BIT(3);
 453
 454                 race_teams = teams; // now set it?
 455
 456                 have_team_spawns = -1; // request team spawns
 457         }
 458         else
 459                 race_teams = 0;
 460
 461         qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 462         fraglimit_override = autocvar_g_race_laps_limit;
 463         leadlimit_override = 0; // currently not supported by race
 464         timelimit_override = autocvar_timelimit_override;
 465
 466         float want_qualifying = ((qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit) > 0;
 467
 468         if(autocvar_g_campaign)
 469         {
 470                 g_race_qualifying = 1;
 471                 independent_players = 1;
 472         }
 473         else if(want_qualifying)
 474         {
 475                 g_race_qualifying = 2;
 476                 independent_players = 1;
 477                 race_fraglimit = (fraglimit_override >= 0) ? fraglimit_override : autocvar_fraglimit;
 478                 race_leadlimit = (leadlimit_override >= 0) ? leadlimit_override : autocvar_leadlimit;
 479                 race_timelimit = (timelimit_override >= 0) ? timelimit_override : autocvar_timelimit;
 480                 qualifying_override = (qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit;
 481                 fraglimit_override = 0;
 482                 leadlimit_override = 0;
 483                 timelimit_override = qualifying_override;
 484         }
 485         else
 486                 g_race_qualifying = 0;
 487         SetLimits(fraglimit_override, leadlimit_override, timelimit_override, qualifying_override);
 488 }