qcsrc/server/mutators/mutator_buffs.qc

   1 #include "mutator_buffs.qh"
   2 #include "../_all.qh"
   3
   4 #include "mutator.qh"
   5
   6 #include "../../common/buffs.qh"
   7
   8 .float lifetime;
   9
  10 float buffs_BuffModel_Customize()
  11 {
  12         entity player, myowner;
  13         float same_team;
  14
  15         player = WaypointSprite_getviewentity(other);
  16         myowner = self.owner;
  17         same_team = (SAME_TEAM(player, myowner) || SAME_TEAM(player, myowner));
  18
  19         if(myowner.alpha <= 0.5 && !same_team && myowner.alpha != 0)
  20                 return false;
  21
  22         if(player == myowner || (IS_SPEC(other) && other.enemy == myowner))
  23         {
  24                 // somewhat hide the model, but keep the glow
  25                 self.effects = 0;
  26                 self.alpha = -1;
  27         }
  28         else
  29         {
  30                 self.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
  31                 self.alpha = 1;
  32         }
  33         return true;
  34 }
  35
  36 // buff item
  37 float buff_Waypoint_visible_for_player(entity plr)
  38 {
  39     if(!self.owner.buff_active && !self.owner.buff_activetime)
  40         return false;
  41
  42         if(plr.buffs)
  43         {
  44                 if(plr.cvar_cl_buffs_autoreplace)
  45                 {
  46                         if(plr.buffs == self.owner.buffs)
  47                                 return false;
  48                 }
  49                 else
  50                         return false;
  51         }
  52
  53     return WaypointSprite_visible_for_player(plr);
  54 }
  55
  56 void buff_Waypoint_Spawn(entity e)
  57 {
  58     WaypointSprite_Spawn(Buff_Sprite(e.buffs), 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, world, e.team, e, buff_waypoint, true, RADARICON_POWERUP, e.glowmod);
  59     WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_POWERUP, e.glowmod);
  60     e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
  61 }
  62
  63 void buff_SetCooldown(float cd)
  64 {
  65         cd = max(0, cd);
  66
  67         if(!self.buff_waypoint)
  68                 buff_Waypoint_Spawn(self);
  69
  70         WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + cd);
  71         self.buff_activetime = cd;
  72         self.buff_active = !cd;
  73 }
  74
  75 void buff_Respawn(entity ent)
  76 {
  77         if(gameover) { return; }
  78
  79         vector oldbufforigin = ent.origin;
  80
  81         if(!MoveToRandomMapLocation(ent, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
  82         {
  83                 entity spot = SelectSpawnPoint(true);
  84                 setorigin(ent, ((spot.origin + '0 0 200') + (randomvec() * 300)));
  85                 ent.angles = spot.angles;
  86         }
  87
  88         tracebox(ent.origin, ent.mins * 1.5, self.maxs * 1.5, ent.origin, MOVE_NOMONSTERS, ent);
  89
  90         setorigin(ent, trace_endpos); // attempt to unstick
  91
  92         ent.movetype = MOVETYPE_TOSS;
  93
  94         makevectors(ent.angles);
  95         ent.velocity = '0 0 200';
  96         ent.angles = '0 0 0';
  97         if(autocvar_g_buffs_random_lifetime > 0)
  98                 ent.lifetime = time + autocvar_g_buffs_random_lifetime;
  99
 100         pointparticles(particleeffectnum("electro_combo"), oldbufforigin + ((ent.mins + ent.maxs) * 0.5), '0 0 0', 1);
 101         pointparticles(particleeffectnum("electro_combo"), CENTER_OR_VIEWOFS(ent), '0 0 0', 1);
 102
 103         WaypointSprite_Ping(ent.buff_waypoint);
 104
 105         sound(ent, CH_TRIGGER, "keepaway/respawn.wav", VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 106 }
 107
 108 void buff_Touch()
 109 {
 110         if(gameover) { return; }
 111
 112         if(ITEM_TOUCH_NEEDKILL())
 113         {
 114                 buff_Respawn(self);
 115                 return;
 116         }
 117
 118         if((self.team && DIFF_TEAM(other, self))
 119         || (other.frozen)
 120         || (other.vehicle)
 121         || (!IS_PLAYER(other))
 122         || (!self.buff_active)
 123         )
 124         {
 125                 // can't touch this
 126                 return;
 127         }
 128
 129         if(other.buffs)
 130         {
 131                 if(other.cvar_cl_buffs_autoreplace && other.buffs != self.buffs)
 132                 {
 133                         //Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_DROP, other.buffs);
 134                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ITEM_BUFF_LOST, other.netname, other.buffs);
 135
 136                         other.buffs = 0;
 137                         //sound(other, CH_TRIGGER, "relics/relic_effect.wav", VOL_BASE, ATTN_NORM);
 138                 }
 139                 else { return; } // do nothing
 140         }
 141
 142         self.owner = other;
 143         self.buff_active = false;
 144         self.lifetime = 0;
 145
 146         Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_GOT, self.buffs);
 147         Send_Notification(NOTIF_ALL_EXCEPT, other, MSG_INFO, INFO_ITEM_BUFF, other.netname, self.buffs);
 148
 149         pointparticles(particleeffectnum("item_pickup"), CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 150         sound(other, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);
 151         other.buffs |= (self.buffs);
 152 }
 153
 154 float buff_Available(float buffid)
 155 {
 156         if(buffid == BUFF_AMMO && ((start_items & IT_UNLIMITED_WEAPON_AMMO) || (start_items & IT_UNLIMITED_AMMO) || (cvar("g_melee_only"))))
 157                 return false;
 158
 159         if(buffid == BUFF_VAMPIRE && cvar("g_vampire"))
 160                 return false;
 161
 162         if(!cvar(strcat("g_buffs_", Buff_Name(buffid))))
 163                 return false;
 164
 165         return true;
 166 }
 167
 168 void buff_NewType(entity ent, float cb)
 169 {
 170         entity e;
 171         RandomSelection_Init();
 172         for(e = Buff_Type_first; e; e = e.enemy)
 173         if(buff_Available(e.items))
 174         {
 175                 RandomSelection_Add(world, e.items, string_null, 1, 1 / e.count); // if it's already been chosen, give it a lower priority
 176                 e.count += 1;
 177         }
 178         ent.buffs = RandomSelection_chosen_float;
 179 }
 180
 181 void buff_Think()
 182 {
 183         if(self.buffs != self.oldbuffs)
 184         {
 185                 self.color = Buff_Color(self.buffs);
 186                 self.glowmod = ((self.team) ? Team_ColorRGB(self.team) + '0.1 0.1 0.1' : self.color);
 187                 self.skin = Buff_Skin(self.buffs);
 188
 189                 setmodel(self, "models/relics/relic.md3");
 190
 191                 if(self.buff_waypoint)
 192                 {
 193                         //WaypointSprite_Disown(self.buff_waypoint, 1);
 194                         WaypointSprite_Kill(self.buff_waypoint);
 195                         buff_Waypoint_Spawn(self);
 196                         if(self.buff_activetime)
 197                                 WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + self.buff_activetime - frametime);
 198                 }
 199
 200                 self.oldbuffs = self.buffs;
 201         }
 202
 203         if(!gameover)
 204         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 205         if(!self.buff_activetime_updated)
 206         {
 207                 buff_SetCooldown(self.buff_activetime);
 208                 self.buff_activetime_updated = true;
 209     }
 210
 211         if(!self.buff_active && !self.buff_activetime)
 212         if(!self.owner || self.owner.frozen || self.owner.deadflag != DEAD_NO || !self.owner.iscreature || !(self.owner.buffs & self.buffs))
 213         {
 214                 buff_SetCooldown(autocvar_g_buffs_cooldown_respawn + frametime);
 215                 self.owner = world;
 216                 if(autocvar_g_buffs_randomize)
 217                         buff_NewType(self, self.buffs);
 218
 219                 if(autocvar_g_buffs_random_location || (self.spawnflags & 1))
 220                         buff_Respawn(self);
 221         }
 222
 223         if(self.buff_activetime)
 224         if(!gameover)
 225         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 226         {
 227                 self.buff_activetime = max(0, self.buff_activetime - frametime);
 228
 229                 if(!self.buff_activetime)
 230                 {
 231                         self.buff_active = true;
 232                         sound(self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);
 233                         pointparticles(particleeffectnum("item_respawn"), CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 234                 }
 235         }
 236
 237         if(!self.buff_active)
 238         {
 239                 self.alpha = 0.3;
 240                 self.effects &= ~(EF_FULLBRIGHT);
 241                 self.pflags = 0;
 242         }
 243         else
 244         {
 245                 self.alpha = 1;
 246                 self.effects |= EF_FULLBRIGHT;
 247                 self.light_lev = 220 + 36 * sin(time);
 248                 self.pflags = PFLAGS_FULLDYNAMIC;
 249
 250                 if(self.team && !self.buff_waypoint)
 251                         buff_Waypoint_Spawn(self);
 252
 253                 if(self.lifetime)
 254                 if(time >= self.lifetime)
 255                         buff_Respawn(self);
 256         }
 257
 258         self.nextthink = time;
 259         //self.angles_y = time * 110.1;
 260 }
 261
 262 void buff_Waypoint_Reset()
 263 {
 264         WaypointSprite_Kill(self.buff_waypoint);
 265
 266         if(self.buff_activetime) { buff_Waypoint_Spawn(self); }
 267 }
 268
 269 void buff_Reset()
 270 {
 271         if(autocvar_g_buffs_randomize)
 272                 buff_NewType(self, self.buffs);
 273         self.owner = world;
 274         buff_SetCooldown(autocvar_g_buffs_cooldown_activate);
 275         buff_Waypoint_Reset();
 276         self.buff_activetime_updated = false;
 277
 278         if(autocvar_g_buffs_random_location || (self.spawnflags & 1))
 279                 buff_Respawn(self);
 280 }
 281
 282 void buff_Init(entity ent)
 283 {
 284         if(!cvar("g_buffs")) { remove(self); return; }
 285
 286         if(!teamplay && self.team) { self.team = 0; }
 287
 288         entity oldself = self;
 289         self = ent;
 290         if(!self.buffs || buff_Available(self.buffs))
 291                 buff_NewType(self, 0);
 292
 293         self.classname = "item_buff";
 294         self.solid = SOLID_TRIGGER;
 295         self.flags = FL_ITEM;
 296         self.think = buff_Think;
 297         self.touch = buff_Touch;
 298         self.reset = buff_Reset;
 299         self.nextthink = time + 0.1;
 300         self.gravity = 1;
 301         self.movetype = MOVETYPE_TOSS;
 302         self.scale = 1;
 303         self.skin = Buff_Skin(self.buffs);
 304         self.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
 305         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 306         //self.gravity = 100;
 307         self.color = Buff_Color(self.buffs);
 308         self.glowmod = ((self.team) ? Team_ColorRGB(self.team) + '0.1 0.1 0.1' : self.color);
 309         buff_SetCooldown(autocvar_g_buffs_cooldown_activate + game_starttime);
 310         self.buff_active = !self.buff_activetime;
 311         self.pflags = PFLAGS_FULLDYNAMIC;
 312
 313         if(self.noalign)
 314                 self.movetype = MOVETYPE_NONE; // reset by random location
 315
 316         setmodel(self, "models/relics/relic.md3");
 317         setsize(self, BUFF_MIN, BUFF_MAX);
 318
 319         if(cvar("g_buffs_random_location") || (self.spawnflags & 1))
 320                 buff_Respawn(self);
 321
 322         self = oldself;
 323 }
 324
 325 void buff_Init_Compat(entity ent, float replacement)
 326 {
 327         if(ent.spawnflags & 2)
 328                 ent.team = NUM_TEAM_1;
 329         else if(ent.spawnflags & 4)
 330                 ent.team = NUM_TEAM_2;
 331
 332         ent.buffs = replacement;
 333
 334         buff_Init(ent);
 335 }
 336
 337 void buff_SpawnReplacement(entity ent, entity old)
 338 {
 339         setorigin(ent, old.origin);
 340         ent.angles = old.angles;
 341         ent.noalign = old.noalign;
 342
 343         buff_Init(ent);
 344 }
 345
 346 // mutator hooks
 347 MUTATOR_HOOKFUNCTION(buffs_PlayerDamage_SplitHealthArmor)
 348 {
 349         if(frag_deathtype == DEATH_BUFF_VENGEANCE) { return false; } // oh no you don't
 350
 351         if(frag_target.buffs & BUFF_RESISTANCE)
 352         {
 353                 vector v = healtharmor_applydamage(50, autocvar_g_buffs_resistance_blockpercent, frag_deathtype, frag_damage);
 354                 damage_take = v.x;
 355                 damage_save = v.y;
 356         }
 357
 358         return false;
 359 }
 360
 361 void buff_Vengeance_DelayedDamage()
 362 {
 363         if(self.enemy)
 364                 Damage(self.enemy, self.owner, self.owner, self.dmg, DEATH_BUFF_VENGEANCE, self.enemy.origin, '0 0 0');
 365
 366         remove(self);
 367         return;
 368 }
 369
 370 MUTATOR_HOOKFUNCTION(buffs_PlayerDamage_Calculate)
 371 {
 372         if(frag_deathtype == DEATH_BUFF_VENGEANCE) { return false; } // oh no you don't
 373
 374         if(frag_target.buffs & BUFF_SPEED)
 375         if(frag_target != frag_attacker)
 376                 frag_damage *= autocvar_g_buffs_speed_damage_take;
 377
 378         if(frag_target.buffs & BUFF_MEDIC)
 379         if((frag_target.health - frag_damage) <= 0)
 380         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 381         if(frag_attacker)
 382         if(random() <= autocvar_g_buffs_medic_survive_chance)
 383         if(frag_target.health - autocvar_g_buffs_medic_survive_health > 0) // not if the final result would be less than 0, medic must get health
 384                 frag_damage = frag_target.health - autocvar_g_buffs_medic_survive_health;
 385
 386         if(frag_target.buffs & BUFF_VENGEANCE)
 387         if(frag_attacker)
 388         if(frag_attacker != frag_target)
 389         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 390         {
 391                 entity dmgent = spawn();
 392
 393                 dmgent.dmg = frag_damage * autocvar_g_buffs_vengeance_damage_multiplier;
 394                 dmgent.enemy = frag_attacker;
 395                 dmgent.owner = frag_target;
 396                 dmgent.think = buff_Vengeance_DelayedDamage;
 397                 dmgent.nextthink = time + 0.1;
 398         }
 399
 400         if(frag_target.buffs & BUFF_BASH)
 401         if(frag_attacker != frag_target)
 402         if(vlen(frag_force))
 403                 frag_force = '0 0 0';
 404
 405         if(frag_attacker.buffs & BUFF_BASH)
 406         if(vlen(frag_force))
 407         if(frag_attacker == frag_target)
 408                 frag_force *= autocvar_g_buffs_bash_force_self;
 409         else
 410                 frag_force *= autocvar_g_buffs_bash_force;
 411
 412         if(frag_attacker.buffs & BUFF_DISABILITY)
 413         if(frag_target != frag_attacker)
 414                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_time;
 415
 416         if(frag_attacker.buffs & BUFF_MEDIC)
 417         if(SAME_TEAM(frag_attacker, frag_target))
 418         if(frag_attacker != frag_target)
 419         {
 420                 frag_target.health = min(g_pickup_healthmega_max, frag_target.health + frag_damage);
 421                 frag_damage = 0;
 422         }
 423
 424         // this... is ridiculous (TODO: fix!)
 425         if(frag_attacker.buffs & BUFF_VAMPIRE)
 426         if(!frag_target.vehicle)
 427         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 428         if(frag_target.deadflag == DEAD_NO)
 429         if(IS_PLAYER(frag_target) || (frag_target.flags & FL_MONSTER))
 430         if(frag_attacker != frag_target)
 431         if(!frag_target.frozen)
 432         if(frag_target.takedamage)
 433         if(DIFF_TEAM(frag_attacker, frag_target))
 434                 frag_attacker.health = bound(0, frag_attacker.health + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.health), g_pickup_healthsmall_max);
 435
 436         return false;
 437 }
 438
 439 MUTATOR_HOOKFUNCTION(buffs_PlayerSpawn)
 440 {
 441         self.buffs = 0;
 442         // reset timers here to prevent them continuing after re-spawn
 443         self.buff_disability_time = 0;
 444         self.buff_disability_effect_time = 0;
 445         return false;
 446 }
 447
 448 MUTATOR_HOOKFUNCTION(buffs_PlayerPhysics)
 449 {
 450         if(self.buffs & BUFF_SPEED)
 451         {
 452                 self.stat_sv_maxspeed *= autocvar_g_buffs_speed_speed;
 453                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_speed_speed;
 454         }
 455
 456         if(time < self.buff_disability_time)
 457         {
 458                 self.stat_sv_maxspeed *= autocvar_g_buffs_disability_speed;
 459                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_disability_speed;
 460         }
 461
 462         return false;
 463 }
 464
 465 MUTATOR_HOOKFUNCTION(buffs_PlayerJump)
 466 {
 467         if(self.buffs & BUFF_JUMP)
 468                 player_jumpheight = autocvar_g_buffs_jump_height;
 469
 470         return false;
 471 }
 472
 473 MUTATOR_HOOKFUNCTION(buffs_MonsterMove)
 474 {
 475         if(time < self.buff_disability_time)
 476         {
 477                 monster_speed_walk *= autocvar_g_buffs_disability_speed;
 478                 monster_speed_run *= autocvar_g_buffs_disability_speed;
 479         }
 480
 481         return false;
 482 }
 483
 484 MUTATOR_HOOKFUNCTION(buffs_PlayerDies)
 485 {
 486         if(self.buffs)
 487         {
 488                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 489                 self.buffs = 0;
 490
 491                 if(self.buff_model)
 492                 {
 493                         remove(self.buff_model);
 494                         self.buff_model = world;
 495                 }
 496         }
 497         return false;
 498 }
 499
 500 MUTATOR_HOOKFUNCTION(buffs_PlayerUseKey)
 501 {
 502         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 503         if(self.buffs)
 504         {
 505                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, self.buffs);
 506                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 507
 508                 self.buffs = 0;
 509                 sound(self, CH_TRIGGER, "relics/relic_effect.wav", VOL_BASE, ATTN_NORM);
 510                 return true;
 511         }
 512         return false;
 513 }
 514
 515 MUTATOR_HOOKFUNCTION(buffs_RemovePlayer)
 516 {
 517         if(self.buff_model)
 518         {
 519                 remove(self.buff_model);
 520                 self.buff_model = world;
 521         }
 522
 523         // also reset timers here to prevent them continuing after spectating
 524         self.buff_disability_time = 0;
 525         self.buff_disability_effect_time = 0;
 526
 527         return false;
 528 }
 529
 530 MUTATOR_HOOKFUNCTION(buffs_CustomizeWaypoint)
 531 {
 532         entity e = WaypointSprite_getviewentity(other);
 533
 534         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 535         // but only apply this to real players, not to spectators
 536         if((self.owner.flags & FL_CLIENT) && (self.owner.buffs & BUFF_INVISIBLE) && (e == other))
 537         if(DIFF_TEAM(self.owner, e))
 538                 return true;
 539
 540         return false;
 541 }
 542
 543 MUTATOR_HOOKFUNCTION(buffs_OnEntityPreSpawn)
 544 {
 545         if(autocvar_g_buffs_replace_powerups)
 546         switch(self.classname)
 547         {
 548                 case "item_strength":
 549                 case "item_invincible":
 550                 {
 551                         entity e = spawn();
 552                         buff_SpawnReplacement(e, self);
 553                         return true;
 554                 }
 555         }
 556         return false;
 557 }
 558
 559 MUTATOR_HOOKFUNCTION(buffs_WeaponRate)
 560 {
 561         if(self.buffs & BUFF_SPEED)
 562                 weapon_rate *= autocvar_g_buffs_speed_rate;
 563
 564         if(time < self.buff_disability_time)
 565                 weapon_rate *= autocvar_g_buffs_disability_rate;
 566
 567         return false;
 568 }
 569
 570 MUTATOR_HOOKFUNCTION(buffs_PlayerThink)
 571 {
 572         if(gameover || self.deadflag != DEAD_NO) { return false; }
 573
 574         if(time < self.buff_disability_time)
 575         if(time >= self.buff_disability_effect_time)
 576         {
 577                 pointparticles(particleeffectnum("smoking"), self.origin + ((self.mins + self.maxs) * 0.5), '0 0 0', 1);
 578                 self.buff_disability_effect_time = time + 0.5;
 579         }
 580
 581         if(self.frozen)
 582         {
 583                 if(self.buffs)
 584                 {
 585                         Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 586                         self.buffs = 0;
 587                 }
 588         }
 589
 590         if((self.buffs & BUFF_INVISIBLE) && (self.oldbuffs & BUFF_INVISIBLE))
 591         if(self.alpha != autocvar_g_buffs_invisible_alpha)
 592                 self.alpha = autocvar_g_buffs_invisible_alpha;
 593
 594         if(self.buffs != self.oldbuffs)
 595         {
 596                 if(self.oldbuffs & BUFF_AMMO)
 597                 {
 598                         if(self.buff_ammo_prev_infitems)
 599                                 self.items |= IT_UNLIMITED_WEAPON_AMMO;
 600                         else
 601                                 self.items &= ~IT_UNLIMITED_WEAPON_AMMO;
 602                 }
 603                 else if(self.buffs & BUFF_AMMO)
 604                 {
 605                         self.buff_ammo_prev_infitems = (self.items & IT_UNLIMITED_WEAPON_AMMO);
 606                         self.items |= IT_UNLIMITED_WEAPON_AMMO;
 607                         if(!self.ammo_shells) { self.ammo_shells = 20; }
 608                         if(!self.ammo_cells) { self.ammo_cells = 20; }
 609                         if(!self.ammo_rockets) { self.ammo_rockets = 20; }
 610                         if(!self.ammo_nails) { self.ammo_nails = 20; }
 611                         if(!self.ammo_fuel) { self.ammo_fuel = 20; }
 612                 }
 613
 614                 if(self.oldbuffs & BUFF_INVISIBLE)
 615                 {
 616                         if(time < self.strength_finished && g_instagib)
 617                                 self.alpha = autocvar_g_instagib_invis_alpha;
 618                         else
 619                                 self.alpha = self.buff_invisible_prev_alpha;
 620                 }
 621                 else if(self.buffs & BUFF_INVISIBLE)
 622                 {
 623                         if(time < self.strength_finished && g_instagib)
 624                                 self.buff_invisible_prev_alpha = default_player_alpha;
 625                         else
 626                                 self.buff_invisible_prev_alpha = self.alpha;
 627                         self.alpha = autocvar_g_buffs_invisible_alpha;
 628                 }
 629
 630                 if(self.oldbuffs & BUFF_FLIGHT)
 631                         self.gravity = self.buff_flight_prev_gravity;
 632                 else if(self.buffs & BUFF_FLIGHT)
 633                 {
 634                         self.buff_flight_prev_gravity = self.gravity;
 635                         self.gravity = autocvar_g_buffs_flight_gravity;
 636                 }
 637
 638                 self.oldbuffs = self.buffs;
 639                 if(self.buffs)
 640                 {
 641                         if(!self.buff_model)
 642                         {
 643                                 self.buff_model = spawn();
 644                                 setmodel(self.buff_model, "models/relics/relic.md3");
 645                                 setsize(self.buff_model, '0 0 -40', '0 0 40');
 646                                 setattachment(self.buff_model, self, "");
 647                                 setorigin(self.buff_model, '0 0 1' * (self.buff_model.maxs.z * 1));
 648                                 self.buff_model.owner = self;
 649                                 self.buff_model.scale = 0.7;
 650                                 self.buff_model.pflags = PFLAGS_FULLDYNAMIC;
 651                                 self.buff_model.light_lev = 200;
 652                                 self.buff_model.customizeentityforclient = buffs_BuffModel_Customize;
 653                         }
 654                         self.buff_model.color = Buff_Color(self.buffs);
 655                         self.buff_model.glowmod = ((self.buff_model.team) ? Team_ColorRGB(self.buff_model.team) + '0.1 0.1 0.1' : self.buff_model.color);
 656                         self.buff_model.skin = Buff_Skin(self.buffs);
 657
 658                         self.effects |= EF_NOSHADOW;
 659                 }
 660                 else
 661                 {
 662                         remove(self.buff_model);
 663                         self.buff_model = world;
 664
 665                         self.effects &= ~(EF_NOSHADOW);
 666                 }
 667         }
 668
 669         if(self.buff_model)
 670         {
 671                 self.buff_model.effects = self.effects;
 672                 self.buff_model.effects |= EF_LOWPRECISION;
 673                 self.buff_model.effects = self.buff_model.effects & EFMASK_CHEAP; // eat performance
 674
 675                 self.buff_model.alpha = self.alpha;
 676         }
 677
 678         return false;
 679 }
 680
 681 MUTATOR_HOOKFUNCTION(buffs_SpectateCopy)
 682 {
 683         self.buffs = other.buffs;
 684         return false;
 685 }
 686
 687 MUTATOR_HOOKFUNCTION(buffs_VehicleEnter)
 688 {
 689         vh_vehicle.buffs = vh_player.buffs;
 690         vh_player.buffs = 0;
 691         return false;
 692 }
 693
 694 MUTATOR_HOOKFUNCTION(buffs_VehicleExit)
 695 {
 696         vh_player.buffs = vh_vehicle.buffs;
 697         vh_vehicle.buffs = 0;
 698         return false;
 699 }
 700
 701 MUTATOR_HOOKFUNCTION(buffs_PlayerRegen)
 702 {
 703         if(self.buffs & BUFF_MEDIC)
 704         {
 705                 regen_mod_rot = autocvar_g_buffs_medic_rot;
 706                 regen_mod_limit = regen_mod_max = autocvar_g_buffs_medic_max;
 707                 regen_mod_regen = autocvar_g_buffs_medic_regen;
 708         }
 709
 710         if(self.buffs & BUFF_SPEED)
 711                 regen_mod_regen = autocvar_g_buffs_speed_regen;
 712
 713         return false;
 714 }
 715
 716 MUTATOR_HOOKFUNCTION(buffs_GetCvars)
 717 {
 718         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_buffs_autoreplace, "cl_buffs_autoreplace");
 719         return false;
 720 }
 721
 722 MUTATOR_HOOKFUNCTION(buffs_BuildMutatorsString)
 723 {
 724         ret_string = strcat(ret_string, ":Buffs");
 725         return false;
 726 }
 727
 728 MUTATOR_HOOKFUNCTION(buffs_BuildMutatorsPrettyString)
 729 {
 730         ret_string = strcat(ret_string, ", Buffs");
 731         return false;
 732 }
 733
 734 void buffs_DelayedInit()
 735 {
 736         if(autocvar_g_buffs_spawn_count > 0)
 737         if(find(world, classname, "item_buff") == world)
 738         {
 739                 float i;
 740                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
 741                 {
 742                         entity e = spawn();
 743                         e.spawnflags |= 1; // always randomize
 744                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
 745                         buff_Init(e);
 746                 }
 747         }
 748 }
 749
 750 void buffs_Initialize()
 751 {
 752         precache_model("models/relics/relic.md3");
 753         precache_sound("misc/strength_respawn.wav");
 754         precache_sound("misc/shield_respawn.wav");
 755         precache_sound("relics/relic_effect.wav");
 756         precache_sound("weapons/rocket_impact.wav");
 757         precache_sound("keepaway/respawn.wav");
 758
 759         addstat(STAT_BUFFS, AS_INT, buffs);
 760
 761         InitializeEntity(world, buffs_DelayedInit, INITPRIO_FINDTARGET);
 762 }
 763
 764 MUTATOR_DEFINITION(mutator_buffs)
 765 {
 766         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, buffs_PlayerDamage_SplitHealthArmor, CBC_ORDER_ANY);
 767         MUTATOR_HOOK(PlayerDamage_Calculate, buffs_PlayerDamage_Calculate, CBC_ORDER_ANY);
 768         MUTATOR_HOOK(PlayerSpawn, buffs_PlayerSpawn, CBC_ORDER_ANY);
 769         MUTATOR_HOOK(PlayerPhysics, buffs_PlayerPhysics, CBC_ORDER_ANY);
 770         MUTATOR_HOOK(PlayerJump, buffs_PlayerJump, CBC_ORDER_ANY);
 771         MUTATOR_HOOK(MonsterMove, buffs_MonsterMove, CBC_ORDER_ANY);
 772         MUTATOR_HOOK(SpectateCopy, buffs_SpectateCopy, CBC_ORDER_ANY);
 773         MUTATOR_HOOK(VehicleEnter, buffs_VehicleEnter, CBC_ORDER_ANY);
 774         MUTATOR_HOOK(VehicleExit, buffs_VehicleExit, CBC_ORDER_ANY);
 775         MUTATOR_HOOK(PlayerRegen, buffs_PlayerRegen, CBC_ORDER_ANY);
 776         MUTATOR_HOOK(PlayerDies, buffs_PlayerDies, CBC_ORDER_ANY);
 777         MUTATOR_HOOK(PlayerUseKey, buffs_PlayerUseKey, CBC_ORDER_ANY);
 778         MUTATOR_HOOK(MakePlayerObserver, buffs_RemovePlayer, CBC_ORDER_ANY);
 779         MUTATOR_HOOK(ClientDisconnect, buffs_RemovePlayer, CBC_ORDER_ANY);
 780         MUTATOR_HOOK(OnEntityPreSpawn, buffs_OnEntityPreSpawn, CBC_ORDER_ANY);
 781         MUTATOR_HOOK(CustomizeWaypoint, buffs_CustomizeWaypoint, CBC_ORDER_ANY);
 782         MUTATOR_HOOK(WeaponRateFactor, buffs_WeaponRate, CBC_ORDER_ANY);
 783         MUTATOR_HOOK(PlayerPreThink, buffs_PlayerThink, CBC_ORDER_ANY);
 784         MUTATOR_HOOK(GetCvars, buffs_GetCvars, CBC_ORDER_ANY);
 785         MUTATOR_HOOK(BuildMutatorsString, buffs_BuildMutatorsString, CBC_ORDER_ANY);
 786         MUTATOR_HOOK(BuildMutatorsPrettyString, buffs_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 787
 788         MUTATOR_ONADD
 789         {
 790                 buffs_Initialize();
 791         }
 792
 793         return false;
 794 }