qcsrc/server/mutators/mutator_buffs.qc

   1 #include "../../common/triggers/target/music.qh"
   2
   3 float buffs_BuffModel_Customize()
   4 {
   5         entity player, myowner;
   6         float same_team;
   7
   8         player = WaypointSprite_getviewentity(other);
   9         myowner = self.owner;
  10         same_team = (SAME_TEAM(player, myowner) || SAME_TEAM(player, myowner));
  11
  12         if(myowner.alpha <= 0.5 && !same_team && myowner.alpha != 0)
  13                 return false;
  14
  15         if(player == myowner || (IS_SPEC(other) && other.enemy == myowner))
  16         {
  17                 // somewhat hide the model, but keep the glow
  18                 self.effects = 0;
  19                 self.alpha = -1;
  20         }
  21         else
  22         {
  23                 self.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
  24                 self.alpha = 1;
  25         }
  26         return true;
  27 }
  28
  29 // buff item
  30 float buff_Waypoint_visible_for_player(entity plr)
  31 {
  32     if(!self.owner.buff_active && !self.owner.buff_activetime)
  33         return false;
  34
  35         if(plr.buffs)
  36         {
  37                 if(plr.cvar_cl_buffs_autoreplace)
  38                 {
  39                         if(plr.buffs == self.owner.buffs)
  40                                 return false;
  41                 }
  42                 else
  43                         return false;
  44         }
  45
  46     return WaypointSprite_visible_for_player(plr);
  47 }
  48
  49 void buff_Waypoint_Spawn(entity e)
  50 {
  51     WaypointSprite_Spawn(Buff_Sprite(e.buffs), 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, world, e.team, e, buff_waypoint, true, RADARICON_POWERUP, e.glowmod);
  52     WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_POWERUP, e.glowmod);
  53     e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
  54 }
  55
  56 void buff_SetCooldown(float cd)
  57 {
  58         cd = max(0, cd);
  59
  60         if(!self.buff_waypoint)
  61                 buff_Waypoint_Spawn(self);
  62
  63         WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + cd);
  64         self.buff_activetime = cd;
  65         self.buff_active = !cd;
  66 }
  67
  68 void buff_Respawn(entity ent)
  69 {
  70         if(gameover) { return; }
  71
  72         vector oldbufforigin = ent.origin;
  73
  74         if(!MoveToRandomMapLocation(ent, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
  75         {
  76                 entity spot = SelectSpawnPoint(true);
  77                 setorigin(ent, ((spot.origin + '0 0 200') + (randomvec() * 300)));
  78                 ent.angles = spot.angles;
  79         }
  80
  81         tracebox(ent.origin, ent.mins * 1.5, self.maxs * 1.5, ent.origin, MOVE_NOMONSTERS, ent);
  82
  83         setorigin(ent, trace_endpos); // attempt to unstick
  84
  85         ent.movetype = MOVETYPE_TOSS;
  86
  87         makevectors(ent.angles);
  88         ent.velocity = '0 0 200';
  89         ent.angles = '0 0 0';
  90         if(autocvar_g_buffs_random_lifetime > 0)
  91                 ent.lifetime = time + autocvar_g_buffs_random_lifetime;
  92
  93         pointparticles(particleeffectnum("electro_combo"), oldbufforigin + ((ent.mins + ent.maxs) * 0.5), '0 0 0', 1);
  94         pointparticles(particleeffectnum("electro_combo"), CENTER_OR_VIEWOFS(ent), '0 0 0', 1);
  95
  96         WaypointSprite_Ping(ent.buff_waypoint);
  97
  98         sound(ent, CH_TRIGGER, "keepaway/respawn.wav", VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
  99 }
 100
 101 void buff_Touch()
 102 {
 103         if(gameover) { return; }
 104
 105         if(ITEM_TOUCH_NEEDKILL())
 106         {
 107                 buff_Respawn(self);
 108                 return;
 109         }
 110
 111         if((self.team && DIFF_TEAM(other, self))
 112         || (other.frozen)
 113         || (other.vehicle)
 114         || (!IS_PLAYER(other))
 115         || (!self.buff_active)
 116         )
 117         {
 118                 // can't touch this
 119                 return;
 120         }
 121
 122         if(other.buffs)
 123         {
 124                 if(other.cvar_cl_buffs_autoreplace && other.buffs != self.buffs)
 125                 {
 126                         //Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_DROP, other.buffs);
 127                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ITEM_BUFF_LOST, other.netname, other.buffs);
 128
 129                         other.buffs = 0;
 130                         //sound(other, CH_TRIGGER, "relics/relic_effect.wav", VOL_BASE, ATTN_NORM);
 131                 }
 132                 else { return; } // do nothing
 133         }
 134
 135         self.owner = other;
 136         self.buff_active = false;
 137         self.lifetime = 0;
 138
 139         Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_GOT, self.buffs);
 140         Send_Notification(NOTIF_ALL_EXCEPT, other, MSG_INFO, INFO_ITEM_BUFF, other.netname, self.buffs);
 141
 142         pointparticles(particleeffectnum("item_pickup"), CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 143         sound(other, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);
 144         other.buffs |= (self.buffs);
 145 }
 146
 147 float buff_Available(float buffid)
 148 {
 149         if(buffid == BUFF_AMMO && ((start_items & IT_UNLIMITED_WEAPON_AMMO) || (start_items & IT_UNLIMITED_AMMO) || (cvar("g_melee_only"))))
 150                 return false;
 151
 152         if(buffid == BUFF_VAMPIRE && cvar("g_vampire"))
 153                 return false;
 154
 155         if(!cvar(strcat("g_buffs_", Buff_Name(buffid))))
 156                 return false;
 157
 158         return true;
 159 }
 160
 161 void buff_NewType(entity ent, float cb)
 162 {
 163         entity e;
 164         RandomSelection_Init();
 165         for(e = Buff_Type_first; e; e = e.enemy)
 166         if(buff_Available(e.items))
 167         {
 168                 RandomSelection_Add(world, e.items, string_null, 1, 1 / e.count); // if it's already been chosen, give it a lower priority
 169                 e.count += 1;
 170         }
 171         ent.buffs = RandomSelection_chosen_float;
 172 }
 173
 174 void buff_Think()
 175 {
 176         if(self.buffs != self.oldbuffs)
 177         {
 178                 self.color = Buff_Color(self.buffs);
 179                 self.glowmod = ((self.team) ? Team_ColorRGB(self.team) + '0.1 0.1 0.1' : self.color);
 180                 self.skin = Buff_Skin(self.buffs);
 181
 182                 setmodel(self, "models/relics/relic.md3");
 183
 184                 if(self.buff_waypoint)
 185                 {
 186                         //WaypointSprite_Disown(self.buff_waypoint, 1);
 187                         WaypointSprite_Kill(self.buff_waypoint);
 188                         buff_Waypoint_Spawn(self);
 189                         if(self.buff_activetime)
 190                                 WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + self.buff_activetime - frametime);
 191                 }
 192
 193                 self.oldbuffs = self.buffs;
 194         }
 195
 196         if(!gameover)
 197         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 198         if(!self.buff_activetime_updated)
 199         {
 200                 buff_SetCooldown(self.buff_activetime);
 201                 self.buff_activetime_updated = true;
 202     }
 203
 204         if(!self.buff_active && !self.buff_activetime)
 205         if(!self.owner || self.owner.frozen || self.owner.deadflag != DEAD_NO || !self.owner.iscreature || !(self.owner.buffs & self.buffs))
 206         {
 207                 buff_SetCooldown(autocvar_g_buffs_cooldown_respawn + frametime);
 208                 self.owner = world;
 209                 if(autocvar_g_buffs_randomize)
 210                         buff_NewType(self, self.buffs);
 211
 212                 if(autocvar_g_buffs_random_location || (self.spawnflags & 1))
 213                         buff_Respawn(self);
 214         }
 215
 216         if(self.buff_activetime)
 217         if(!gameover)
 218         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 219         {
 220                 self.buff_activetime = max(0, self.buff_activetime - frametime);
 221
 222                 if(!self.buff_activetime)
 223                 {
 224                         self.buff_active = true;
 225                         sound(self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);
 226                         pointparticles(particleeffectnum("item_respawn"), CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 227                 }
 228         }
 229
 230         if(!self.buff_active)
 231         {
 232                 self.alpha = 0.3;
 233                 self.effects &= ~(EF_FULLBRIGHT);
 234                 self.pflags = 0;
 235         }
 236         else
 237         {
 238                 self.alpha = 1;
 239                 self.effects |= EF_FULLBRIGHT;
 240                 self.light_lev = 220 + 36 * sin(time);
 241                 self.pflags = PFLAGS_FULLDYNAMIC;
 242
 243                 if(self.team && !self.buff_waypoint)
 244                         buff_Waypoint_Spawn(self);
 245
 246                 if(self.lifetime)
 247                 if(time >= self.lifetime)
 248                         buff_Respawn(self);
 249         }
 250
 251         self.nextthink = time;
 252         //self.angles_y = time * 110.1;
 253 }
 254
 255 void buff_Waypoint_Reset()
 256 {
 257         WaypointSprite_Kill(self.buff_waypoint);
 258
 259         if(self.buff_activetime) { buff_Waypoint_Spawn(self); }
 260 }
 261
 262 void buff_Reset()
 263 {
 264         if(autocvar_g_buffs_randomize)
 265                 buff_NewType(self, self.buffs);
 266         self.owner = world;
 267         buff_SetCooldown(autocvar_g_buffs_cooldown_activate);
 268         buff_Waypoint_Reset();
 269         self.buff_activetime_updated = false;
 270
 271         if(autocvar_g_buffs_random_location || (self.spawnflags & 1))
 272                 buff_Respawn(self);
 273 }
 274
 275 void buff_Init(entity ent)
 276 {
 277         if(!cvar("g_buffs")) { remove(self); return; }
 278
 279         if(!teamplay && self.team) { self.team = 0; }
 280
 281         entity oldself = self;
 282         self = ent;
 283         if(!self.buffs || buff_Available(self.buffs))
 284                 buff_NewType(self, 0);
 285
 286         self.classname = "item_buff";
 287         self.solid = SOLID_TRIGGER;
 288         self.flags = FL_ITEM;
 289         self.think = buff_Think;
 290         self.touch = buff_Touch;
 291         self.reset = buff_Reset;
 292         self.nextthink = time + 0.1;
 293         self.gravity = 1;
 294         self.movetype = MOVETYPE_TOSS;
 295         self.scale = 1;
 296         self.skin = Buff_Skin(self.buffs);
 297         self.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
 298         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 299         //self.gravity = 100;
 300         self.color = Buff_Color(self.buffs);
 301         self.glowmod = ((self.team) ? Team_ColorRGB(self.team) + '0.1 0.1 0.1' : self.color);
 302         buff_SetCooldown(autocvar_g_buffs_cooldown_activate + game_starttime);
 303         self.buff_active = !self.buff_activetime;
 304         self.pflags = PFLAGS_FULLDYNAMIC;
 305
 306         if(self.noalign)
 307                 self.movetype = MOVETYPE_NONE; // reset by random location
 308
 309         setmodel(self, "models/relics/relic.md3");
 310         setsize(self, BUFF_MIN, BUFF_MAX);
 311
 312         if(cvar("g_buffs_random_location") || (self.spawnflags & 1))
 313                 buff_Respawn(self);
 314
 315         self = oldself;
 316 }
 317
 318 void buff_Init_Compat(entity ent, float replacement)
 319 {
 320         if(ent.spawnflags & 2)
 321                 ent.team = NUM_TEAM_1;
 322         else if(ent.spawnflags & 4)
 323                 ent.team = NUM_TEAM_2;
 324
 325         ent.buffs = replacement;
 326
 327         buff_Init(ent);
 328 }
 329
 330 void buff_SpawnReplacement(entity ent, entity old)
 331 {
 332         setorigin(ent, old.origin);
 333         ent.angles = old.angles;
 334         ent.noalign = old.noalign;
 335
 336         buff_Init(ent);
 337 }
 338
 339 // mutator hooks
 340 MUTATOR_HOOKFUNCTION(buffs_PlayerDamage_SplitHealthArmor)
 341 {
 342         if(frag_deathtype == DEATH_BUFF_VENGEANCE) { return false; } // oh no you don't
 343
 344         if(frag_target.buffs & BUFF_RESISTANCE)
 345         {
 346                 vector v = healtharmor_applydamage(50, autocvar_g_buffs_resistance_blockpercent, frag_deathtype, frag_damage);
 347                 damage_take = v.x;
 348                 damage_save = v.y;
 349         }
 350
 351         return false;
 352 }
 353
 354 void buff_Vengeance_DelayedDamage()
 355 {
 356         if(self.enemy)
 357                 Damage(self.enemy, self.owner, self.owner, self.dmg, DEATH_BUFF_VENGEANCE, self.enemy.origin, '0 0 0');
 358
 359         remove(self);
 360         return;
 361 }
 362
 363 MUTATOR_HOOKFUNCTION(buffs_PlayerDamage_Calculate)
 364 {
 365         if(frag_deathtype == DEATH_BUFF_VENGEANCE) { return false; } // oh no you don't
 366
 367         if(frag_target.buffs & BUFF_SPEED)
 368         if(frag_target != frag_attacker)
 369                 frag_damage *= autocvar_g_buffs_speed_damage_take;
 370
 371         if(frag_target.buffs & BUFF_MEDIC)
 372         if((frag_target.health - frag_damage) <= 0)
 373         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 374         if(frag_attacker)
 375         if(random() <= autocvar_g_buffs_medic_survive_chance)
 376         if(frag_target.health - autocvar_g_buffs_medic_survive_health > 0) // not if the final result would be less than 0, medic must get health
 377                 frag_damage = frag_target.health - autocvar_g_buffs_medic_survive_health;
 378
 379         if(frag_target.buffs & BUFF_VENGEANCE)
 380         if(frag_attacker)
 381         if(frag_attacker != frag_target)
 382         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 383         {
 384                 entity dmgent = spawn();
 385
 386                 dmgent.dmg = frag_damage * autocvar_g_buffs_vengeance_damage_multiplier;
 387                 dmgent.enemy = frag_attacker;
 388                 dmgent.owner = frag_target;
 389                 dmgent.think = buff_Vengeance_DelayedDamage;
 390                 dmgent.nextthink = time + 0.1;
 391         }
 392
 393         if(frag_target.buffs & BUFF_BASH)
 394         if(frag_attacker != frag_target)
 395         if(vlen(frag_force))
 396                 frag_force = '0 0 0';
 397
 398         if(frag_attacker.buffs & BUFF_BASH)
 399         if(vlen(frag_force))
 400         if(frag_attacker == frag_target)
 401                 frag_force *= autocvar_g_buffs_bash_force_self;
 402         else
 403                 frag_force *= autocvar_g_buffs_bash_force;
 404
 405         if(frag_attacker.buffs & BUFF_DISABILITY)
 406         if(frag_target != frag_attacker)
 407                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_time;
 408
 409         if(frag_attacker.buffs & BUFF_MEDIC)
 410         if(SAME_TEAM(frag_attacker, frag_target))
 411         if(frag_attacker != frag_target)
 412         {
 413                 frag_target.health = min(g_pickup_healthmega_max, frag_target.health + frag_damage);
 414                 frag_damage = 0;
 415         }
 416
 417         // this... is ridiculous (TODO: fix!)
 418         if(frag_attacker.buffs & BUFF_VAMPIRE)
 419         if(!frag_target.vehicle)
 420         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 421         if(frag_target.deadflag == DEAD_NO)
 422         if(IS_PLAYER(frag_target) || (frag_target.flags & FL_MONSTER))
 423         if(frag_attacker != frag_target)
 424         if(!frag_target.frozen)
 425         if(frag_target.takedamage)
 426         if(DIFF_TEAM(frag_attacker, frag_target))
 427                 frag_attacker.health = bound(0, frag_attacker.health + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.health), g_pickup_healthsmall_max);
 428
 429         return false;
 430 }
 431
 432 MUTATOR_HOOKFUNCTION(buffs_PlayerSpawn)
 433 {
 434         self.buffs = 0;
 435         // reset timers here to prevent them continuing after re-spawn
 436         self.buff_disability_time = 0;
 437         self.buff_disability_effect_time = 0;
 438         return false;
 439 }
 440
 441 MUTATOR_HOOKFUNCTION(buffs_PlayerPhysics)
 442 {
 443         if(self.buffs & BUFF_SPEED)
 444         {
 445                 self.stat_sv_maxspeed *= autocvar_g_buffs_speed_speed;
 446                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_speed_speed;
 447         }
 448
 449         if(time < self.buff_disability_time)
 450         {
 451                 self.stat_sv_maxspeed *= autocvar_g_buffs_disability_speed;
 452                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_disability_speed;
 453         }
 454
 455         return false;
 456 }
 457
 458 MUTATOR_HOOKFUNCTION(buffs_PlayerJump)
 459 {
 460         if(self.buffs & BUFF_JUMP)
 461                 player_jumpheight = autocvar_g_buffs_jump_height;
 462         self.stat_jumpheight = player_jumpheight;
 463
 464         return false;
 465 }
 466
 467 MUTATOR_HOOKFUNCTION(buffs_MonsterMove)
 468 {
 469         if(time < self.buff_disability_time)
 470         {
 471                 monster_speed_walk *= autocvar_g_buffs_disability_speed;
 472                 monster_speed_run *= autocvar_g_buffs_disability_speed;
 473         }
 474
 475         return false;
 476 }
 477
 478 MUTATOR_HOOKFUNCTION(buffs_PlayerDies)
 479 {
 480         if(self.buffs)
 481         {
 482                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 483                 self.buffs = 0;
 484
 485                 if(self.buff_model)
 486                 {
 487                         remove(self.buff_model);
 488                         self.buff_model = world;
 489                 }
 490         }
 491         return false;
 492 }
 493
 494 MUTATOR_HOOKFUNCTION(buffs_PlayerUseKey)
 495 {
 496         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 497         if(self.buffs)
 498         {
 499                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, self.buffs);
 500                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 501
 502                 self.buffs = 0;
 503                 sound(self, CH_TRIGGER, "relics/relic_effect.wav", VOL_BASE, ATTN_NORM);
 504                 return true;
 505         }
 506         return false;
 507 }
 508
 509 MUTATOR_HOOKFUNCTION(buffs_RemovePlayer)
 510 {
 511         if(self.buff_model)
 512         {
 513                 remove(self.buff_model);
 514                 self.buff_model = world;
 515         }
 516
 517         // also reset timers here to prevent them continuing after spectating
 518         self.buff_disability_time = 0;
 519         self.buff_disability_effect_time = 0;
 520
 521         return false;
 522 }
 523
 524 MUTATOR_HOOKFUNCTION(buffs_CustomizeWaypoint)
 525 {
 526         entity e = WaypointSprite_getviewentity(other);
 527
 528         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 529         // but only apply this to real players, not to spectators
 530         if((self.owner.flags & FL_CLIENT) && (self.owner.buffs & BUFF_INVISIBLE) && (e == other))
 531         if(DIFF_TEAM(self.owner, e))
 532                 return true;
 533
 534         return false;
 535 }
 536
 537 MUTATOR_HOOKFUNCTION(buffs_OnEntityPreSpawn)
 538 {
 539         if(autocvar_g_buffs_replace_powerups)
 540         switch(self.classname)
 541         {
 542                 case "item_strength":
 543                 case "item_invincible":
 544                 {
 545                         entity e = spawn();
 546                         buff_SpawnReplacement(e, self);
 547                         return true;
 548                 }
 549         }
 550         return false;
 551 }
 552
 553 MUTATOR_HOOKFUNCTION(buffs_WeaponRate)
 554 {
 555         if(self.buffs & BUFF_SPEED)
 556                 weapon_rate *= autocvar_g_buffs_speed_rate;
 557
 558         if(time < self.buff_disability_time)
 559                 weapon_rate *= autocvar_g_buffs_disability_rate;
 560
 561         return false;
 562 }
 563
 564 MUTATOR_HOOKFUNCTION(buffs_PlayerThink)
 565 {
 566         if(gameover || self.deadflag != DEAD_NO) { return false; }
 567
 568         if(time < self.buff_disability_time)
 569         if(time >= self.buff_disability_effect_time)
 570         {
 571                 pointparticles(particleeffectnum("smoking"), self.origin + ((self.mins + self.maxs) * 0.5), '0 0 0', 1);
 572                 self.buff_disability_effect_time = time + 0.5;
 573         }
 574
 575         if(self.frozen)
 576         {
 577                 if(self.buffs)
 578                 {
 579                         Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 580                         self.buffs = 0;
 581                 }
 582         }
 583
 584         if((self.buffs & BUFF_INVISIBLE) && (self.oldbuffs & BUFF_INVISIBLE))
 585         if(self.alpha != autocvar_g_buffs_invisible_alpha)
 586                 self.alpha = autocvar_g_buffs_invisible_alpha;
 587
 588         if(self.buffs != self.oldbuffs)
 589         {
 590                 if(self.oldbuffs & BUFF_AMMO)
 591                 {
 592                         if(self.buff_ammo_prev_infitems)
 593                                 self.items |= IT_UNLIMITED_WEAPON_AMMO;
 594                         else
 595                                 self.items &= ~IT_UNLIMITED_WEAPON_AMMO;
 596                 }
 597                 else if(self.buffs & BUFF_AMMO)
 598                 {
 599                         self.buff_ammo_prev_infitems = (self.items & IT_UNLIMITED_WEAPON_AMMO);
 600                         self.items |= IT_UNLIMITED_WEAPON_AMMO;
 601                         if(!self.ammo_shells) { self.ammo_shells = 20; }
 602                         if(!self.ammo_cells) { self.ammo_cells = 20; }
 603                         if(!self.ammo_rockets) { self.ammo_rockets = 20; }
 604                         if(!self.ammo_nails) { self.ammo_nails = 20; }
 605                         if(!self.ammo_fuel) { self.ammo_fuel = 20; }
 606                 }
 607
 608                 if(self.oldbuffs & BUFF_INVISIBLE)
 609                 {
 610                         if(time < self.strength_finished && g_instagib)
 611                                 self.alpha = autocvar_g_instagib_invis_alpha;
 612                         else
 613                                 self.alpha = self.buff_invisible_prev_alpha;
 614                 }
 615                 else if(self.buffs & BUFF_INVISIBLE)
 616                 {
 617                         if(time < self.strength_finished && g_instagib)
 618                                 self.buff_invisible_prev_alpha = default_player_alpha;
 619                         else
 620                                 self.buff_invisible_prev_alpha = self.alpha;
 621                         self.alpha = autocvar_g_buffs_invisible_alpha;
 622                 }
 623
 624                 if(self.oldbuffs & BUFF_FLIGHT)
 625                         self.gravity = self.buff_flight_prev_gravity;
 626                 else if(self.buffs & BUFF_FLIGHT)
 627                 {
 628                         self.buff_flight_prev_gravity = self.gravity;
 629                         self.gravity = autocvar_g_buffs_flight_gravity;
 630                 }
 631
 632                 self.oldbuffs = self.buffs;
 633                 if(self.buffs)
 634                 {
 635                         if(!self.buff_model)
 636                         {
 637                                 self.buff_model = spawn();
 638                                 setmodel(self.buff_model, "models/relics/relic.md3");
 639                                 setsize(self.buff_model, '0 0 -40', '0 0 40');
 640                                 setattachment(self.buff_model, self, "");
 641                                 setorigin(self.buff_model, '0 0 1' * (self.buff_model.maxs.z * 1));
 642                                 self.buff_model.owner = self;
 643                                 self.buff_model.scale = 0.7;
 644                                 self.buff_model.pflags = PFLAGS_FULLDYNAMIC;
 645                                 self.buff_model.light_lev = 200;
 646                                 self.buff_model.customizeentityforclient = buffs_BuffModel_Customize;
 647                         }
 648                         self.buff_model.color = Buff_Color(self.buffs);
 649                         self.buff_model.glowmod = ((self.buff_model.team) ? Team_ColorRGB(self.buff_model.team) + '0.1 0.1 0.1' : self.buff_model.color);
 650                         self.buff_model.skin = Buff_Skin(self.buffs);
 651
 652                         self.effects |= EF_NOSHADOW;
 653                 }
 654                 else
 655                 {
 656                         remove(self.buff_model);
 657                         self.buff_model = world;
 658
 659                         self.effects &= ~(EF_NOSHADOW);
 660                 }
 661         }
 662
 663         if(self.buff_model)
 664         {
 665                 self.buff_model.effects = self.effects;
 666                 self.buff_model.effects |= EF_LOWPRECISION;
 667                 self.buff_model.effects = self.buff_model.effects & EFMASK_CHEAP; // eat performance
 668
 669                 self.buff_model.alpha = self.alpha;
 670         }
 671
 672         return false;
 673 }
 674
 675 MUTATOR_HOOKFUNCTION(buffs_SpectateCopy)
 676 {
 677         self.buffs = other.buffs;
 678         return false;
 679 }
 680
 681 MUTATOR_HOOKFUNCTION(buffs_VehicleEnter)
 682 {
 683         vh_vehicle.buffs = vh_player.buffs;
 684         vh_player.buffs = 0;
 685         return false;
 686 }
 687
 688 MUTATOR_HOOKFUNCTION(buffs_VehicleExit)
 689 {
 690         vh_player.buffs = vh_vehicle.buffs;
 691         vh_vehicle.buffs = 0;
 692         return false;
 693 }
 694
 695 MUTATOR_HOOKFUNCTION(buffs_PlayerRegen)
 696 {
 697         if(self.buffs & BUFF_MEDIC)
 698         {
 699                 regen_mod_rot = autocvar_g_buffs_medic_rot;
 700                 regen_mod_limit = regen_mod_max = autocvar_g_buffs_medic_max;
 701                 regen_mod_regen = autocvar_g_buffs_medic_regen;
 702         }
 703
 704         if(self.buffs & BUFF_SPEED)
 705                 regen_mod_regen = autocvar_g_buffs_speed_regen;
 706
 707         return false;
 708 }
 709
 710 MUTATOR_HOOKFUNCTION(buffs_GetCvars)
 711 {
 712         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_buffs_autoreplace, "cl_buffs_autoreplace");
 713         return false;
 714 }
 715
 716 MUTATOR_HOOKFUNCTION(buffs_BuildMutatorsString)
 717 {
 718         ret_string = strcat(ret_string, ":Buffs");
 719         return false;
 720 }
 721
 722 MUTATOR_HOOKFUNCTION(buffs_BuildMutatorsPrettyString)
 723 {
 724         ret_string = strcat(ret_string, ", Buffs");
 725         return false;
 726 }
 727
 728 void buffs_DelayedInit()
 729 {
 730         if(autocvar_g_buffs_spawn_count > 0)
 731         if(find(world, classname, "item_buff") == world)
 732         {
 733                 float i;
 734                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
 735                 {
 736                         entity e = spawn();
 737                         e.spawnflags |= 1; // always randomize
 738                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
 739                         buff_Init(e);
 740                 }
 741         }
 742 }
 743
 744 void buffs_Initialize()
 745 {
 746         precache_model("models/relics/relic.md3");
 747         precache_sound("misc/strength_respawn.wav");
 748         precache_sound("misc/shield_respawn.wav");
 749         precache_sound("relics/relic_effect.wav");
 750         precache_sound("weapons/rocket_impact.wav");
 751         precache_sound("keepaway/respawn.wav");
 752
 753         addstat(STAT_BUFFS, AS_INT, buffs);
 754         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_jumpheight);
 755
 756         InitializeEntity(world, buffs_DelayedInit, INITPRIO_FINDTARGET);
 757 }
 758
 759 MUTATOR_DEFINITION(mutator_buffs)
 760 {
 761         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, buffs_PlayerDamage_SplitHealthArmor, CBC_ORDER_ANY);
 762         MUTATOR_HOOK(PlayerDamage_Calculate, buffs_PlayerDamage_Calculate, CBC_ORDER_ANY);
 763         MUTATOR_HOOK(PlayerSpawn, buffs_PlayerSpawn, CBC_ORDER_ANY);
 764         MUTATOR_HOOK(PlayerPhysics, buffs_PlayerPhysics, CBC_ORDER_ANY);
 765         MUTATOR_HOOK(PlayerJump, buffs_PlayerJump, CBC_ORDER_ANY);
 766         MUTATOR_HOOK(MonsterMove, buffs_MonsterMove, CBC_ORDER_ANY);
 767         MUTATOR_HOOK(SpectateCopy, buffs_SpectateCopy, CBC_ORDER_ANY);
 768         MUTATOR_HOOK(VehicleEnter, buffs_VehicleEnter, CBC_ORDER_ANY);
 769         MUTATOR_HOOK(VehicleExit, buffs_VehicleExit, CBC_ORDER_ANY);
 770         MUTATOR_HOOK(PlayerRegen, buffs_PlayerRegen, CBC_ORDER_ANY);
 771         MUTATOR_HOOK(PlayerDies, buffs_PlayerDies, CBC_ORDER_ANY);
 772         MUTATOR_HOOK(PlayerUseKey, buffs_PlayerUseKey, CBC_ORDER_ANY);
 773         MUTATOR_HOOK(MakePlayerObserver, buffs_RemovePlayer, CBC_ORDER_ANY);
 774         MUTATOR_HOOK(ClientDisconnect, buffs_RemovePlayer, CBC_ORDER_ANY);
 775         MUTATOR_HOOK(OnEntityPreSpawn, buffs_OnEntityPreSpawn, CBC_ORDER_ANY);
 776         MUTATOR_HOOK(CustomizeWaypoint, buffs_CustomizeWaypoint, CBC_ORDER_ANY);
 777         MUTATOR_HOOK(WeaponRateFactor, buffs_WeaponRate, CBC_ORDER_ANY);
 778         MUTATOR_HOOK(PlayerPreThink, buffs_PlayerThink, CBC_ORDER_ANY);
 779         MUTATOR_HOOK(GetCvars, buffs_GetCvars, CBC_ORDER_ANY);
 780         MUTATOR_HOOK(BuildMutatorsString, buffs_BuildMutatorsString, CBC_ORDER_ANY);
 781         MUTATOR_HOOK(BuildMutatorsPrettyString, buffs_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 782
 783         MUTATOR_ONADD
 784         {
 785                 buffs_Initialize();
 786         }
 787
 788         return false;
 789 }