Update English weapon names
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / mutators / mutator_instagib.qc
1 void spawnfunc_item_minst_cells (void)
2 {
3         if (!g_instagib) { remove(self); return; }
4         if (!self.ammo_cells)
5                 self.ammo_cells = autocvar_g_instagib_ammo_drop;
6
7         StartItem ("models/items/a_cells.md3",
8                            "misc/itempickup.wav", 45, 0,
9                            "Vaporizer Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
10 }
11
12 void instagib_health_mega()
13 {
14         self.max_health = 1;
15         StartItem ("models/items/g_h100.md3",
16                            "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
17                            "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
18 }
19
20 .float instagib_nextthink;
21 .float instagib_needammo;
22 void instagib_stop_countdown(entity e)
23 {
24         if (!e.instagib_needammo)
25                 return;
26         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_INSTAGIB_FINDAMMO);
27         e.instagib_needammo = FALSE;
28 }
29 void instagib_ammocheck()
30 {
31         if(time < self.instagib_nextthink)
32                 return;
33         if(!IS_PLAYER(self))
34                 return; // not a player
35
36         if(self.deadflag || gameover)
37                 instagib_stop_countdown(self);
38         else if (self.ammo_cells > 0 || (self.items & IT_UNLIMITED_WEAPON_AMMO) || (self.flags & FL_GODMODE))
39                 instagib_stop_countdown(self);
40         else
41         {
42                 self.instagib_needammo = TRUE;
43                 if (self.health <= 5)
44                 {
45                         Damage(self, self, self, 5, DEATH_NOAMMO, self.origin, '0 0 0');
46                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_INSTAGIB_TERMINATED);
47                 }
48                 else if (self.health <= 10)
49                 {
50                         Damage(self, self, self, 5, DEATH_NOAMMO, self.origin, '0 0 0');
51                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_1);
52                 }
53                 else if (self.health <= 20)
54                 {
55                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
56                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_2);
57                 }
58                 else if (self.health <= 30)
59                 {
60                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
61                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_3);
62                 }
63                 else if (self.health <= 40)
64                 {
65                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
66                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_4);
67                 }
68                 else if (self.health <= 50)
69                 {
70                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
71                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_5);
72                 }
73                 else if (self.health <= 60)
74                 {
75                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
76                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_6);
77                 }
78                 else if (self.health <= 70)
79                 {
80                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
81                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_7);
82                 }
83                 else if (self.health <= 80)
84                 {
85                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
86                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_8);
87                 }
88                 else if (self.health <= 90)
89                 {
90                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_INSTAGIB_FINDAMMO);
91                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
92                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_9);
93                 }
94                 else
95                 {
96                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_MULTI, MULTI_INSTAGIB_FINDAMMO);
97                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
98                 }
99         }
100         self.instagib_nextthink = time + 1;
101 }
102
103 MUTATOR_HOOKFUNCTION(instagib_MatchEnd)
104 {
105         entity head;
106         FOR_EACH_PLAYER(head)
107                 instagib_stop_countdown(head);
108
109         return FALSE;
110 }
111
112 MUTATOR_HOOKFUNCTION(instagib_MonsterLoot)
113 {
114         other.monster_loot = spawnfunc_item_minst_cells;
115
116         return FALSE;
117 }
118
119 MUTATOR_HOOKFUNCTION(instagib_MonsterSpawn)
120 {
121         // always refill ammo
122         if(self.monsterid == MON_MAGE)
123                 self.skin = 1;
124         
125         return FALSE;
126 }
127
128 MUTATOR_HOOKFUNCTION(instagib_BotShouldAttack)
129 {
130         if(checkentity.items & IT_STRENGTH)
131                 return TRUE;
132
133         return FALSE;
134 }
135
136 MUTATOR_HOOKFUNCTION(instagib_MakePlayerObserver)
137 {
138         instagib_stop_countdown(self);
139         return FALSE;
140 }
141
142 MUTATOR_HOOKFUNCTION(instagib_PlayerSpawn)
143 {
144         self.effects |= EF_FULLBRIGHT;
145         return FALSE;
146 }
147
148 MUTATOR_HOOKFUNCTION(instagib_PlayerPreThink)
149 {
150         instagib_ammocheck();
151         return FALSE;
152 }
153
154 MUTATOR_HOOKFUNCTION(instagib_PlayerRegen)
155 {
156         // no regeneration in instagib
157         return TRUE;
158 }
159
160 MUTATOR_HOOKFUNCTION(instagib_PlayerPowerups)
161 {
162         if (!(self.effects & EF_FULLBRIGHT))
163                 self.effects |= EF_FULLBRIGHT;
164
165         if (self.items & IT_STRENGTH)
166         {
167                 play_countdown(self.strength_finished, "misc/poweroff.wav");
168                 if (time > self.strength_finished)
169                 {
170                         self.alpha = default_player_alpha;
171                         self.exteriorweaponentity.alpha = default_weapon_alpha;
172                         self.items &= ~IT_STRENGTH;
173                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
174                 }
175         }
176         else
177         {
178                 if (time < self.strength_finished)
179                 {
180                         self.alpha = autocvar_g_instagib_invis_alpha;
181                         self.exteriorweaponentity.alpha = autocvar_g_instagib_invis_alpha;
182                         self.items |= IT_STRENGTH;
183                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
184                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
185                 }
186         }
187
188         if (self.items & IT_INVINCIBLE)
189         {
190                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
191                 if (time > self.invincible_finished)
192                 {
193                         self.items &= ~IT_INVINCIBLE;
194                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
195                 }
196         }
197         else
198         {
199                 if (time < self.invincible_finished)
200                 {
201                         self.items |= IT_INVINCIBLE;
202                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
203                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
204                 }
205         }
206         return FALSE;
207 }
208
209 MUTATOR_HOOKFUNCTION(instagib_PlayerPhysics)
210 {
211         if(self.items & IT_INVINCIBLE)
212                 self.stat_sv_maxspeed = self.stat_sv_maxspeed * autocvar_g_instagib_speed_highspeed;
213
214         return FALSE;
215 }
216
217 MUTATOR_HOOKFUNCTION(instagib_SplitHealthArmor)
218 {
219         damage_save = 0;
220         damage_take = frag_damage;
221
222         return FALSE;
223 }
224
225 MUTATOR_HOOKFUNCTION(instagib_ForbidThrowing)
226 {
227         // weapon dropping on death handled by FilterItem
228
229         return TRUE;
230 }
231
232 MUTATOR_HOOKFUNCTION(instagib_PlayerDamage)
233 {
234         if(autocvar_g_friendlyfire == 0 && SAME_TEAM(frag_target, frag_attacker) && IS_PLAYER(frag_target) && IS_PLAYER(frag_attacker))
235                 frag_damage = 0;
236
237         if(IS_PLAYER(frag_target))
238         {
239                 if ((frag_deathtype == DEATH_FALL)  ||
240                         (frag_deathtype == DEATH_DROWN) ||
241                         (frag_deathtype == DEATH_SLIME) ||
242                         (frag_deathtype == DEATH_LAVA))
243                 {
244                         frag_damage = 0;
245                 }
246
247                 if(IS_PLAYER(frag_attacker))
248                 if(DEATH_ISWEAPON(frag_deathtype, WEP_VAPORIZER))
249                 {
250                         if(frag_deathtype & HITTYPE_SECONDARY)
251                         {
252                                 frag_damage = frag_mirrordamage = 0;
253                                 
254                                 if(frag_target != frag_attacker)
255                                 {
256                                         if(frag_target.health > 0) { Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_INSTAGIB_SECONDARY); }
257                                         frag_force = '0 0 0';
258                                 }
259                         }
260                         else if(frag_target.armorvalue)
261                         {
262                                 frag_target.armorvalue -= 1;
263                                 frag_damage = 0;
264                                 frag_target.damage_dealt += 1;
265                                 frag_attacker.damage_dealt += 1; // TODO: change this to a specific hitsound for armor hit
266                                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_INSTAGIB_LIVES_REMAINING, frag_target.armorvalue);
267                         }
268                 }
269         }
270
271         if(IS_PLAYER(frag_attacker))
272         if(frag_mirrordamage > 0)
273         {
274                 // just lose extra LIVES, don't kill the player for mirror damage
275                 if(frag_attacker.armorvalue > 0)
276                 {
277                         frag_attacker.armorvalue -= 1;
278                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_INSTAGIB_LIVES_REMAINING, frag_attacker.armorvalue);
279                         frag_attacker.damage_dealt += 1;
280                 }
281                 frag_mirrordamage = 0;
282         }
283
284         if(frag_target.items & IT_STRENGTH)
285                 yoda = 1;
286
287         return FALSE;
288 }
289
290 MUTATOR_HOOKFUNCTION(instagib_SetStartItems)
291 {
292         start_ammo_cells = cvar("g_instagib_ammo_start");
293
294         start_health = 100;
295         start_armorvalue = 0;
296         start_weapons = WEPSET_VAPORIZER;
297         warmup_start_weapons = WEPSET_VAPORIZER;
298         start_items |= IT_UNLIMITED_SUPERWEAPONS;
299
300         return FALSE;
301 }
302
303 MUTATOR_HOOKFUNCTION(instagib_FilterItem)
304 {
305         if(self.classname == "item_cells")
306                 return TRUE; // no normal cells?
307
308         if(self.weapon == WEP_VAPORIZER && self.classname == "droppedweapon")
309         {
310                 self.ammo_cells = autocvar_g_instagib_ammo_drop;
311                 return FALSE;
312         }
313
314         if(self.weapon == WEP_DEVASTATOR || self.weapon == WEP_VORTEX)
315         {
316                 entity e = spawn();
317                 setorigin(e, self.origin);
318                 entity oldself;
319                 oldself = self;
320                 self = e;
321                 spawnfunc_item_minst_cells();
322                 self = oldself;
323                 return TRUE;
324         }
325
326         if(self.flags & FL_POWERUP)
327                 return FALSE;
328
329         if(self.ammo_cells > autocvar_g_instagib_ammo_drop && self.classname != "item_minst_cells")
330                 self.ammo_cells = autocvar_g_instagib_ammo_drop;
331
332         if(self.ammo_cells && !self.weapon)
333                 return FALSE;
334
335         return TRUE;
336 }
337
338 MUTATOR_HOOKFUNCTION(instagib_CustomizeWaypoint)
339 {
340         entity e = WaypointSprite_getviewentity(other);
341
342         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
343         // but only apply this to real players, not to spectators
344         if((self.owner.flags & FL_CLIENT) && (self.owner.items & IT_STRENGTH) && (e == other))
345         if(DIFF_TEAM(self.owner, e))
346                 return TRUE;
347
348         return FALSE;
349 }
350
351 MUTATOR_HOOKFUNCTION(instagib_ItemCountdown)
352 {
353         switch(self.items)
354         {
355                 case IT_STRENGTH:   item_name = "item-invis"; item_color = '0 0 1'; break;
356                 case IT_NAILS:      item_name = "item-extralife"; item_color = '1 0 0'; break;
357                 case IT_INVINCIBLE: item_name = "item-speed"; item_color = '1 0 1'; break;
358         }
359         return FALSE;
360 }
361
362 MUTATOR_HOOKFUNCTION(instagib_ItemTouch)
363 {
364         if(self.ammo_cells)
365         {
366                 // play some cool sounds ;)
367                 if (IS_CLIENT(other))
368                 {
369                         if(other.health <= 5)
370                                 Send_Notification(NOTIF_ONE, other, MSG_ANNCE, ANNCE_INSTAGIB_LASTSECOND);
371                         else if(other.health < 50)
372                                 Send_Notification(NOTIF_ONE, other, MSG_ANNCE, ANNCE_INSTAGIB_NARROWLY);
373                 }
374
375                 if(other.health < 100)
376                         other.health = 100;
377
378                 return MUT_ITEMTOUCH_CONTINUE;
379         }
380
381         if(self.max_health)
382         {
383                 other.armorvalue = bound(other.armorvalue, 999, other.armorvalue + autocvar_g_instagib_extralives);
384                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
385                 return MUT_ITEMTOUCH_PICKUP;
386         }
387
388         return MUT_ITEMTOUCH_CONTINUE;
389 }
390
391 MUTATOR_HOOKFUNCTION(instagib_OnEntityPreSpawn)
392 {
393         if (!autocvar_g_powerups) { return FALSE; }
394         if (!(self.classname == "item_strength" || self.classname == "item_invincible" || self.classname == "item_health_mega"))
395                 return FALSE;
396
397         entity e = spawn();
398
399         if(random() < 0.3)
400                 e.think = spawnfunc_item_strength;
401         else if(random() < 0.6)
402                 e.think = instagib_health_mega;
403         else
404                 e.think = spawnfunc_item_invincible;
405
406         e.nextthink = time + 0.1;
407         e.spawnflags = self.spawnflags;
408         e.noalign = self.noalign;
409         setorigin(e, self.origin);
410
411         return TRUE;
412 }
413
414 MUTATOR_HOOKFUNCTION(instagib_BuildMutatorsString)
415 {
416         ret_string = strcat(ret_string, ":instagib");
417         return FALSE;
418 }
419
420 MUTATOR_HOOKFUNCTION(instagib_BuildMutatorsPrettyString)
421 {
422         ret_string = strcat(ret_string, ", instagib");
423         return FALSE;
424 }
425
426 MUTATOR_HOOKFUNCTION(instagib_SetModname)
427 {
428         modname = "instagib";
429         return TRUE;
430 }
431
432 MUTATOR_DEFINITION(mutator_instagib)
433 {
434         MUTATOR_HOOK(MatchEnd, instagib_MatchEnd, CBC_ORDER_ANY);
435         MUTATOR_HOOK(MonsterDropItem, instagib_MonsterLoot, CBC_ORDER_ANY);
436         MUTATOR_HOOK(MonsterSpawn, instagib_MonsterSpawn, CBC_ORDER_ANY);
437         MUTATOR_HOOK(BotShouldAttack, instagib_BotShouldAttack, CBC_ORDER_ANY);
438         MUTATOR_HOOK(PlayerPhysics, instagib_PlayerPhysics, CBC_ORDER_ANY);
439         MUTATOR_HOOK(PlayerSpawn, instagib_PlayerSpawn, CBC_ORDER_ANY);
440         MUTATOR_HOOK(PlayerDamage_Calculate, instagib_PlayerDamage, CBC_ORDER_ANY);
441         MUTATOR_HOOK(MakePlayerObserver, instagib_MakePlayerObserver, CBC_ORDER_ANY);
442         MUTATOR_HOOK(SetStartItems, instagib_SetStartItems, CBC_ORDER_ANY);
443         MUTATOR_HOOK(ItemTouch, instagib_ItemTouch, CBC_ORDER_ANY);
444         MUTATOR_HOOK(FilterItem, instagib_FilterItem, CBC_ORDER_ANY);
445         MUTATOR_HOOK(CustomizeWaypoint, instagib_CustomizeWaypoint, CBC_ORDER_ANY);
446         MUTATOR_HOOK(Item_RespawnCountdown, instagib_ItemCountdown, CBC_ORDER_ANY);
447         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, instagib_SplitHealthArmor, CBC_ORDER_ANY);
448         MUTATOR_HOOK(PlayerPowerups, instagib_PlayerPowerups, CBC_ORDER_ANY);
449         MUTATOR_HOOK(ForbidThrowCurrentWeapon, instagib_ForbidThrowing, CBC_ORDER_ANY);
450         MUTATOR_HOOK(PlayerPreThink, instagib_PlayerPreThink, CBC_ORDER_ANY);
451         MUTATOR_HOOK(PlayerRegen, instagib_PlayerRegen, CBC_ORDER_ANY);
452         MUTATOR_HOOK(OnEntityPreSpawn, instagib_OnEntityPreSpawn, CBC_ORDER_ANY);
453         MUTATOR_HOOK(BuildMutatorsString, instagib_BuildMutatorsString, CBC_ORDER_ANY);
454         MUTATOR_HOOK(BuildMutatorsPrettyString, instagib_BuildMutatorsPrettyString, CBC_ORDER_ANY);
455         MUTATOR_HOOK(SetModname, instagib_SetModname, CBC_ORDER_ANY);
456
457         return FALSE;
458 }