Merge branch 'master' into Mario/monsters
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / mutators / mutator_minstagib.qc
1 void spawnfunc_item_minst_cells (void) 
2 {
3         if not(g_minstagib) { remove(self); return; }
4         if not(self.ammo_cells)
5                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
6                 
7         StartItem ("models/items/a_cells.md3",
8                            "misc/itempickup.wav", 45, 0,
9                            "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
10 }
11
12 void minstagib_health_mega()
13 {
14         self.max_health = 1;
15         StartItem ("models/items/g_h100.md3",
16                            "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
17                            "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
18 }
19
20 .float minstagib_nextthink;
21 .float minstagib_needammo;
22 void minstagib_stop_countdown(entity e)
23 {
24         if (!e.minstagib_needammo)
25                 return;
26         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_MINSTA_FINDAMMO);
27         e.minstagib_needammo = FALSE;
28 }
29 void minstagib_ammocheck()
30 {
31         if not(IS_PLAYER(self))
32                 return; // not a player
33         if (time < self.minstagib_nextthink)
34                 return;
35
36         if (self.deadflag || gameover)
37                 minstagib_stop_countdown(self);
38         else if (self.ammo_cells > 0 || (self.items & IT_UNLIMITED_WEAPON_AMMO))
39                 minstagib_stop_countdown(self);
40         else
41         {
42                 self.minstagib_needammo = TRUE;
43                 if (self.health == 5)
44                 {
45                         Damage(self, self, self, 5, DEATH_NOAMMO, self.origin, '0 0 0');
46                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_MINSTAGIB_TERMINATED);
47                 }
48                 else if (self.health == 10)
49                 {
50                         Damage(self, self, self, 5, DEATH_NOAMMO, self.origin, '0 0 0');
51                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_1);
52                 }
53                 else if (self.health == 20)
54                 {
55                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
56                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_2);
57                 }
58                 else if (self.health == 30)
59                 {
60                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
61                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_3);
62                 }
63                 else if (self.health == 40)
64                 {
65                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
66                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_4);
67                 }
68                 else if (self.health == 50)
69                 {
70                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
71                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_5);
72                 }
73                 else if (self.health == 60)
74                 {
75                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
76                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_6);
77                 }
78                 else if (self.health == 70)
79                 {
80                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
81                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_7);
82                 }
83                 else if (self.health == 80)
84                 {
85                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
86                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_8);
87                 }
88                 else if (self.health == 90)
89                 {
90                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MINSTA_FINDAMMO);
91                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
92                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_9);
93                 }
94                 else if (self.health == 100)
95                 {
96                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_MULTI, MULTI_MINSTA_FINDAMMO);
97                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
98                 }
99         }
100         self.minstagib_nextthink = time + 1;
101 }
102
103 MUTATOR_HOOKFUNCTION(minstagib_MatchEnd)
104 {
105         entity head;
106         FOR_EACH_PLAYER(head)
107                 minstagib_stop_countdown(head);
108                 
109         return FALSE;
110 }
111
112 MUTATOR_HOOKFUNCTION(minstagib_MonsterLoot)
113 {
114         other.monster_loot = spawnfunc_item_minst_cells;
115
116         return FALSE;
117 }
118
119 MUTATOR_HOOKFUNCTION(minstagib_MonsterSpawn)
120 {
121         // always refill ammo
122         if(self.monsterid == MON_MAGE)
123                 self.skin = 1;
124         
125         return FALSE;
126 }
127
128 MUTATOR_HOOKFUNCTION(minstagib_BotShouldAttack)
129 {
130         if(checkentity.items & IT_STRENGTH)
131                 return TRUE;
132                 
133         return FALSE;
134 }
135
136 MUTATOR_HOOKFUNCTION(minstagib_MakePlayerObserver)
137 {
138         minstagib_stop_countdown(self);
139         return FALSE;
140 }
141
142 MUTATOR_HOOKFUNCTION(minstagib_PlayerSpawn)
143 {
144         self.effects |= EF_FULLBRIGHT;
145         return FALSE;
146 }
147
148 MUTATOR_HOOKFUNCTION(minstagib_PlayerPreThink)
149 {
150         minstagib_ammocheck();
151         return FALSE;
152 }
153
154 MUTATOR_HOOKFUNCTION(minstagib_PlayerPowerups)
155 {
156         if not(self.effects & EF_FULLBRIGHT)
157                 self.effects |= EF_FULLBRIGHT;
158
159         if (self.items & IT_STRENGTH)
160         {
161                 play_countdown(self.strength_finished, "misc/poweroff.wav");
162                 if (time > self.strength_finished)
163                 {
164                         self.alpha = default_player_alpha;
165                         self.exteriorweaponentity.alpha = default_weapon_alpha;
166                         self.items &= ~IT_STRENGTH;
167                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
168                 }
169         }
170         else
171         {
172                 if (time < self.strength_finished)
173                 {
174                         self.alpha = autocvar_g_minstagib_invis_alpha;
175                         self.exteriorweaponentity.alpha = autocvar_g_minstagib_invis_alpha;
176                         self.items |= IT_STRENGTH;
177                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
178                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
179                 }
180         }
181
182         if (self.items & IT_INVINCIBLE)
183         {
184                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
185                 if (time > self.invincible_finished)
186                 {
187                         self.items &= ~IT_INVINCIBLE;
188                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
189                 }
190         }
191         else
192         {
193                 if (time < self.invincible_finished)
194                 {
195                         self.items |= IT_INVINCIBLE;
196                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
197                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
198                 }
199         }
200         return FALSE;
201 }
202
203 MUTATOR_HOOKFUNCTION(minstagib_PlayerPhysics)
204 {
205         if(self.items & IT_INVINCIBLE)
206                 self.stat_sv_maxspeed = self.stat_sv_maxspeed * autocvar_g_minstagib_speed_highspeed;
207                 
208         return FALSE;
209 }
210
211 MUTATOR_HOOKFUNCTION(minstagib_SplitHealthArmor)
212 {
213         damage_save = 0;
214         damage_take = frag_damage;
215         
216         return FALSE;
217 }
218
219 MUTATOR_HOOKFUNCTION(minstagib_ForbidThrowing)
220 {
221         // weapon dropping on death handled by FilterItem
222         nades_CheckThrow();
223
224         return TRUE;
225 }
226
227 MUTATOR_HOOKFUNCTION(minstagib_PlayerDamage)
228 {
229         if(autocvar_g_friendlyfire == 0 && SAME_TEAM(frag_target, frag_attacker) && IS_PLAYER(frag_target) && IS_PLAYER(frag_attacker))
230                 frag_damage = 0;
231                 
232         if(IS_PLAYER(frag_target))
233         {
234                 if ((frag_deathtype == DEATH_FALL)  ||
235                         (frag_deathtype == DEATH_DROWN) ||
236                         (frag_deathtype == DEATH_SLIME) ||
237                         (frag_deathtype == DEATH_LAVA))
238                 {
239                         frag_damage = 0;
240                 }
241                 
242                 if(IS_PLAYER(frag_attacker))
243                 if(DEATH_ISWEAPON(frag_deathtype, WEP_MINSTANEX))
244                 if(frag_target.armorvalue)
245                 {
246                         frag_target.armorvalue -= 1;
247                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_MINSTA_LIVES_REMAINING, frag_target.armorvalue);
248                         frag_damage = 0;
249                         frag_target.hitsound += 1;
250                         frag_attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
251                 }
252                 
253                 if(IS_PLAYER(frag_attacker))
254                 if (DEATH_ISWEAPON(frag_deathtype, WEP_LASER))
255                 {
256                         frag_damage = 0;
257                         frag_mirrordamage = 0;
258                         if (frag_target != frag_attacker)
259                         {
260                                 if (frag_target.health >= 1)
261                                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_MINSTA_SECONDARY);
262                                 frag_force = '0 0 0';
263                                 // keep mirrorfrag_force
264                                 //frag_attacker = frag_target;
265                         }
266                 }
267         }
268         
269         if(IS_PLAYER(frag_attacker))
270         if(frag_mirrordamage > 0)
271         {
272                 // just lose extra LIVES, don't kill the player for mirror damage
273                 if(frag_attacker.armorvalue > 0)
274                 {
275                         frag_attacker.armorvalue -= 1;
276                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_MINSTA_LIVES_REMAINING, frag_attacker.armorvalue);
277                         frag_attacker.hitsound += 1;
278                 }
279                 frag_mirrordamage = 0;
280         }
281         
282         if(frag_target.items & IT_STRENGTH)
283                 yoda = 1;
284                 
285         return FALSE;
286 }
287
288 MUTATOR_HOOKFUNCTION(minstagib_SetStartItems)
289 {
290         start_ammo_cells = cvar("g_minstagib_ammo_start");
291         
292         start_health = 100;
293         start_armorvalue = 0;
294         start_weapons = WEPSET_MINSTANEX;
295         warmup_start_weapons = WEPSET_MINSTANEX;
296         start_items |= IT_UNLIMITED_SUPERWEAPONS;
297                 
298         return FALSE;
299 }
300
301 MUTATOR_HOOKFUNCTION(minstagib_FilterItem)
302 {
303         if(self.classname == "item_cells")
304                 return TRUE; // no normal cells?
305                 
306         if(self.weapon == WEP_MINSTANEX && self.classname == "droppedweapon")
307         {
308                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
309                 return FALSE;
310         }
311         
312         if(self.weapon == WEP_ROCKET_LAUNCHER || self.weapon == WEP_NEX)
313         {
314                 entity e = spawn();
315                 setorigin(e, self.origin);
316                 entity oldself;
317                 oldself = self;
318                 self = e;
319                 spawnfunc_item_minst_cells();
320                 self = oldself;
321                 return TRUE;
322         }
323                 
324         if(self.flags & FL_POWERUP)
325                 return FALSE;
326                 
327         if(self.ammo_cells > autocvar_g_minstagib_ammo_drop && self.classname != "item_minst_cells")
328                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
329                 
330         if(self.ammo_cells && !self.weapon)
331                 return FALSE;
332                 
333         return TRUE;
334 }
335
336 MUTATOR_HOOKFUNCTION(minstagib_CustomizeWaypoint)
337 {
338         entity e = WaypointSprite_getviewentity(other);
339         
340         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
341         // but only apply this to real players, not to spectators
342         if((self.owner.flags & FL_CLIENT) && (self.owner.items & IT_STRENGTH) && (e == other))
343         if(DIFF_TEAM(self.owner, e))
344                 return TRUE;
345         
346         return FALSE;
347 }
348
349 MUTATOR_HOOKFUNCTION(minstagib_ItemCountdown)
350 {
351         switch(self.items)
352         {
353                 case IT_STRENGTH:   item_name = "item-invis"; item_color = '0 0 1'; break;
354                 case IT_NAILS:      item_name = "item-extralife"; item_color = '1 0 0'; break;
355                 case IT_INVINCIBLE: item_name = "item-speed"; item_color = '1 0 1'; break;
356         }
357         return FALSE;
358 }
359
360 MUTATOR_HOOKFUNCTION(minstagib_ItemTouch)
361 {
362         if(self.ammo_cells)
363         {
364                 // play some cool sounds ;)
365                 if (IS_CLIENT(other))
366                 {
367                         if(other.health <= 5)
368                                 Send_Notification(NOTIF_ONE, other, MSG_ANNCE, ANNCE_MINSTAGIB_LASTSECOND);
369                         else if(other.health < 50)
370                                 Send_Notification(NOTIF_ONE, other, MSG_ANNCE, ANNCE_MINSTAGIB_NARROWLY);
371                 }
372
373                 if(other.health < 100)
374                         other.health = 100;
375
376                 return MUT_ITEMTOUCH_CONTINUE;
377         }
378         
379         if(self.max_health)
380         {
381                 other.armorvalue = bound(other.armorvalue, 999, other.armorvalue + autocvar_g_minstagib_extralives);
382                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
383                 return MUT_ITEMTOUCH_PICKUP;
384         }
385                 
386         return MUT_ITEMTOUCH_CONTINUE;
387 }
388
389 MUTATOR_HOOKFUNCTION(minstagib_OnEntityPreSpawn)
390 {
391         if not(autocvar_g_powerups) { return FALSE; }
392         if not(self.classname == "item_strength" || self.classname == "item_invincible" || self.classname == "item_health_mega")
393                 return FALSE;
394         
395         entity e = spawn();
396         
397         if(random() < 0.3)
398                 e.think = spawnfunc_item_strength;
399         else if(random() < 0.6)
400                 e.think = minstagib_health_mega;
401         else
402                 e.think = spawnfunc_item_invincible;
403                 
404         e.nextthink = time + 0.1;
405         e.spawnflags = self.spawnflags;
406         e.noalign = self.noalign;
407         setorigin(e, self.origin);
408         
409         return TRUE;
410 }
411
412 MUTATOR_HOOKFUNCTION(minstagib_BuildMutatorsString)
413 {
414         ret_string = strcat(ret_string, ":MinstaGib");
415         return FALSE;
416 }
417
418 MUTATOR_HOOKFUNCTION(minstagib_BuildMutatorsPrettyString)
419 {
420         ret_string = strcat(ret_string, ", MinstaGib");
421         return FALSE;
422 }
423
424 MUTATOR_DEFINITION(mutator_minstagib)
425 {
426         MUTATOR_HOOK(MatchEnd, minstagib_MatchEnd, CBC_ORDER_ANY);
427         MUTATOR_HOOK(MonsterDropItem, minstagib_MonsterLoot, CBC_ORDER_ANY);
428         MUTATOR_HOOK(MonsterSpawn, minstagib_MonsterSpawn, CBC_ORDER_ANY);
429         MUTATOR_HOOK(BotShouldAttack, minstagib_BotShouldAttack, CBC_ORDER_ANY);
430         MUTATOR_HOOK(PlayerPhysics, minstagib_PlayerPhysics, CBC_ORDER_ANY);
431         MUTATOR_HOOK(PlayerSpawn, minstagib_PlayerSpawn, CBC_ORDER_ANY);
432         MUTATOR_HOOK(PlayerDamage_Calculate, minstagib_PlayerDamage, CBC_ORDER_ANY);
433         MUTATOR_HOOK(MakePlayerObserver, minstagib_MakePlayerObserver, CBC_ORDER_ANY);
434         MUTATOR_HOOK(SetStartItems, minstagib_SetStartItems, CBC_ORDER_ANY);
435         MUTATOR_HOOK(ItemTouch, minstagib_ItemTouch, CBC_ORDER_ANY);
436         MUTATOR_HOOK(FilterItem, minstagib_FilterItem, CBC_ORDER_ANY);
437         MUTATOR_HOOK(CustomizeWaypoint, minstagib_CustomizeWaypoint, CBC_ORDER_ANY);
438         MUTATOR_HOOK(Item_RespawnCountdown, minstagib_ItemCountdown, CBC_ORDER_ANY);
439         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, minstagib_SplitHealthArmor, CBC_ORDER_ANY);
440         MUTATOR_HOOK(PlayerPowerups, minstagib_PlayerPowerups, CBC_ORDER_ANY);
441         MUTATOR_HOOK(ForbidThrowCurrentWeapon, minstagib_ForbidThrowing, CBC_ORDER_ANY);
442         MUTATOR_HOOK(PlayerPreThink, minstagib_PlayerPreThink, CBC_ORDER_ANY);
443         MUTATOR_HOOK(OnEntityPreSpawn, minstagib_OnEntityPreSpawn, CBC_ORDER_ANY);
444         MUTATOR_HOOK(BuildMutatorsString, minstagib_BuildMutatorsString, CBC_ORDER_ANY);
445         MUTATOR_HOOK(BuildMutatorsPrettyString, minstagib_BuildMutatorsPrettyString, CBC_ORDER_ANY);
446
447         return FALSE;
448 }