qcsrc/server/mutators/mutator_minstagib.qc

   1 void spawnfunc_item_minst_cells (void)
   2 {
   3         if not(g_minstagib) { remove(self); return; }
   4         if not(self.ammo_cells)
   5                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
   6
   7         StartItem ("models/items/a_cells.md3",
   8                            "misc/itempickup.wav", 45, 0,
   9                            "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
  10 }
  11
  12 void minstagib_health_mega()
  13 {
  14         self.max_health = 1;
  15         StartItem ("models/items/g_h100.md3",
  16                            "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
  17                            "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
  18 }
  19
  20 .float minstagib_nextthink;
  21 .float minstagib_needammo;
  22 void minstagib_stop_countdown(entity e)
  23 {
  24         if (!e.minstagib_needammo)
  25                 return;
  26         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_MINSTA_FINDAMMO);
  27         e.minstagib_needammo = FALSE;
  28 }
  29 void minstagib_ammocheck()
  30 {
  31         if not(IS_PLAYER(self))
  32                 return; // not a player
  33         if (time < self.minstagib_nextthink)
  34                 return;
  35
  36         if (self.deadflag || gameover)
  37                 minstagib_stop_countdown(self);
  38         else if (self.ammo_cells > 0 || (self.items & IT_UNLIMITED_WEAPON_AMMO))
  39                 minstagib_stop_countdown(self);
  40         else
  41         {
  42                 self.minstagib_needammo = TRUE;
  43                 if (self.health == 5)
  44                 {
  45                         Damage(self, self, self, 5, DEATH_NOAMMO, self.origin, '0 0 0');
  46                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_MINSTAGIB_TERMINATED);
  47                 }
  48                 else if (self.health == 10)
  49                 {
  50                         Damage(self, self, self, 5, DEATH_NOAMMO, self.origin, '0 0 0');
  51                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_1);
  52                 }
  53                 else if (self.health == 20)
  54                 {
  55                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  56                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_2);
  57                 }
  58                 else if (self.health == 30)
  59                 {
  60                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  61                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_3);
  62                 }
  63                 else if (self.health == 40)
  64                 {
  65                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  66                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_4);
  67                 }
  68                 else if (self.health == 50)
  69                 {
  70                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  71                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_5);
  72                 }
  73                 else if (self.health == 60)
  74                 {
  75                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  76                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_6);
  77                 }
  78                 else if (self.health == 70)
  79                 {
  80                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  81                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_7);
  82                 }
  83                 else if (self.health == 80)
  84                 {
  85                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  86                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_8);
  87                 }
  88                 else if (self.health == 90)
  89                 {
  90                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MINSTA_FINDAMMO);
  91                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  92                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_9);
  93                 }
  94                 else if (self.health == 100)
  95                 {
  96                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_MULTI, MULTI_MINSTA_FINDAMMO);
  97                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
  98                 }
  99         }
 100         self.minstagib_nextthink = time + 1;
 101 }
 102
 103 MUTATOR_HOOKFUNCTION(minstagib_MatchEnd)
 104 {
 105         entity head;
 106         FOR_EACH_PLAYER(head)
 107                 minstagib_stop_countdown(head);
 108
 109         return FALSE;
 110 }
 111
 112 MUTATOR_HOOKFUNCTION(minstagib_BotShouldAttack)
 113 {
 114         if(checkentity.items & IT_STRENGTH)
 115                 return TRUE;
 116
 117         return FALSE;
 118 }
 119
 120 MUTATOR_HOOKFUNCTION(minstagib_MakePlayerObserver)
 121 {
 122         minstagib_stop_countdown(self);
 123         return FALSE;
 124 }
 125
 126 MUTATOR_HOOKFUNCTION(minstagib_PlayerSpawn)
 127 {
 128         self.effects |= EF_FULLBRIGHT;
 129         return FALSE;
 130 }
 131
 132 MUTATOR_HOOKFUNCTION(minstagib_PlayerPreThink)
 133 {
 134         minstagib_ammocheck();
 135         return FALSE;
 136 }
 137
 138 MUTATOR_HOOKFUNCTION(minstagib_PlayerPowerups)
 139 {
 140         if not(self.effects & EF_FULLBRIGHT)
 141                 self.effects |= EF_FULLBRIGHT;
 142
 143         if (self.items & IT_STRENGTH)
 144         {
 145                 play_countdown(self.strength_finished, "misc/poweroff.wav");
 146                 if (time > self.strength_finished)
 147                 {
 148                         self.alpha = default_player_alpha;
 149                         self.exteriorweaponentity.alpha = default_weapon_alpha;
 150                         self.items &~= IT_STRENGTH;
 151                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
 152                 }
 153         }
 154         else
 155         {
 156                 if (time < self.strength_finished)
 157                 {
 158                         self.alpha = autocvar_g_minstagib_invis_alpha;
 159                         self.exteriorweaponentity.alpha = autocvar_g_minstagib_invis_alpha;
 160                         self.items |= IT_STRENGTH;
 161                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
 162                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
 163                 }
 164         }
 165
 166         if (self.items & IT_INVINCIBLE)
 167         {
 168                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
 169                 if (time > self.invincible_finished)
 170                 {
 171                         self.items &~= IT_INVINCIBLE;
 172                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
 173                 }
 174         }
 175         else
 176         {
 177                 if (time < self.invincible_finished)
 178                 {
 179                         self.items |= IT_INVINCIBLE;
 180                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
 181                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
 182                 }
 183         }
 184         return FALSE;
 185 }
 186
 187 MUTATOR_HOOKFUNCTION(minstagib_PlayerPhysics)
 188 {
 189         if(self.items & IT_INVINCIBLE)
 190                 self.stat_sv_maxspeed = self.stat_sv_maxspeed * autocvar_g_minstagib_speed_highspeed;
 191
 192         return FALSE;
 193 }
 194
 195 MUTATOR_HOOKFUNCTION(minstagib_SplitHealthArmor)
 196 {
 197         damage_save = 0;
 198         damage_take = frag_damage;
 199
 200         return FALSE;
 201 }
 202
 203 MUTATOR_HOOKFUNCTION(minstagib_ForbidThrowing)
 204 {
 205         // weapon dropping on death handled by FilterItem
 206
 207         return TRUE;
 208 }
 209
 210 MUTATOR_HOOKFUNCTION(minstagib_PlayerDamage)
 211 {
 212         if(autocvar_g_friendlyfire == 0 && !IsDifferentTeam(frag_target, frag_attacker) && IS_PLAYER(frag_target) && IS_PLAYER(frag_attacker))
 213                 frag_damage = 0;
 214
 215         if(IS_PLAYER(frag_target))
 216         {
 217                 if ((frag_deathtype == DEATH_FALL)  ||
 218                         (frag_deathtype == DEATH_DROWN) ||
 219                         (frag_deathtype == DEATH_SLIME) ||
 220                         (frag_deathtype == DEATH_LAVA))
 221                 {
 222                         frag_damage = 0;
 223                 }
 224
 225                 if(IS_PLAYER(frag_attacker))
 226                 if(DEATH_ISWEAPON(frag_deathtype, WEP_MINSTANEX))
 227                 if(frag_target.armorvalue)
 228                 {
 229                         frag_target.armorvalue -= 1;
 230                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_MINSTA_LIVES_REMAINING, frag_target.armorvalue);
 231                         frag_damage = 0;
 232                         frag_target.hitsound += 1;
 233                         frag_attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 234                 }
 235
 236                 if(IS_PLAYER(frag_attacker))
 237                 if (DEATH_ISWEAPON(frag_deathtype, WEP_LASER))
 238                 {
 239                         frag_damage = 0;
 240                         frag_mirrordamage = 0;
 241                         if (frag_target != frag_attacker)
 242                         {
 243                                 if (frag_target.health >= 1)
 244                                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_MINSTA_SECONDARY);
 245                                 frag_force = '0 0 0';
 246                                 // keep mirrorfrag_force
 247                                 //frag_attacker = frag_target;
 248                         }
 249                 }
 250         }
 251
 252         if(IS_PLAYER(frag_attacker))
 253         if(frag_mirrordamage > 0)
 254         {
 255                 // just lose extra LIVES, don't kill the player for mirror damage
 256                 if(frag_attacker.armorvalue > 0)
 257                 {
 258                         frag_attacker.armorvalue -= 1;
 259                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_MINSTA_LIVES_REMAINING, frag_attacker.armorvalue);
 260                         frag_attacker.hitsound += 1;
 261                 }
 262                 frag_mirrordamage = 0;
 263         }
 264
 265         if(frag_target.items & IT_STRENGTH)
 266                 yoda = 1;
 267
 268         return FALSE;
 269 }
 270
 271 MUTATOR_HOOKFUNCTION(minstagib_SetStartItems)
 272 {
 273         start_ammo_cells = cvar("g_minstagib_ammo_start");
 274
 275         start_health = 100;
 276         start_armorvalue = 0;
 277         WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
 278         start_items |= IT_UNLIMITED_SUPERWEAPONS;
 279
 280         return FALSE;
 281 }
 282
 283 MUTATOR_HOOKFUNCTION(minstagib_FilterItem)
 284 {
 285         if(self.classname == "item_cells")
 286                 return TRUE; // no normal cells?
 287
 288         if(self.weapon == WEP_MINSTANEX && self.classname == "droppedweapon")
 289         {
 290                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 291                 return FALSE;
 292         }
 293
 294         if(self.weapon == WEP_ROCKET_LAUNCHER || self.weapon == WEP_NEX)
 295         {
 296                 entity e = spawn();
 297                 setorigin(e, self.origin);
 298                 entity oldself;
 299                 oldself = self;
 300                 self = e;
 301                 spawnfunc_item_minst_cells();
 302                 self = oldself;
 303                 return TRUE;
 304         }
 305
 306         if(self.flags & FL_POWERUP)
 307                 return FALSE;
 308
 309         if(self.ammo_cells > autocvar_g_minstagib_ammo_drop && self.classname != "item_minst_cells")
 310                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 311
 312         if(self.ammo_cells && !self.weapon)
 313                 return FALSE;
 314
 315         return TRUE;
 316 }
 317
 318 MUTATOR_HOOKFUNCTION(minstagib_CustomizeWaypoint)
 319 {
 320         entity e = WaypointSprite_getviewentity(other);
 321
 322         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 323         // but only apply this to real players, not to spectators
 324         if((self.owner.flags & FL_CLIENT) && (self.owner.items & IT_STRENGTH) && (e == other))
 325         if(IsDifferentTeam(self.owner, e))
 326                 return TRUE;
 327
 328         return FALSE;
 329 }
 330
 331 MUTATOR_HOOKFUNCTION(minstagib_ItemCountdown)
 332 {
 333         switch(self.items)
 334         {
 335                 case IT_STRENGTH:   item_name = "item-invis"; item_color = '0 0 1'; break;
 336                 case IT_NAILS:      item_name = "item-extralife"; item_color = '1 0 0'; break;
 337                 case IT_INVINCIBLE: item_name = "item-speed"; item_color = '1 0 1'; break;
 338         }
 339         return FALSE;
 340 }
 341
 342 MUTATOR_HOOKFUNCTION(minstagib_ItemTouch)
 343 {
 344         if(self.ammo_cells)
 345         {
 346                 // play some cool sounds ;)
 347                 if (IS_CLIENT(other))
 348                 {
 349                         if(other.health <= 5)
 350                                 Send_Notification(NOTIF_ONE, other, MSG_ANNCE, ANNCE_MINSTAGIB_LASTSECOND);
 351                         else if(other.health < 50)
 352                                 Send_Notification(NOTIF_ONE, other, MSG_ANNCE, ANNCE_MINSTAGIB_NARROWLY);
 353                 }
 354
 355                 if(other.health < 100)
 356                         other.health = 100;
 357
 358                 return MUT_ITEMTOUCH_CONTINUE;
 359         }
 360
 361         if(self.max_health)
 362         {
 363                 other.armorvalue = bound(other.armorvalue, 999, other.armorvalue + autocvar_g_minstagib_extralives);
 364                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 365                 return MUT_ITEMTOUCH_PICKUP;
 366         }
 367
 368         return MUT_ITEMTOUCH_CONTINUE;
 369 }
 370
 371 MUTATOR_HOOKFUNCTION(minstagib_OnEntityPreSpawn)
 372 {
 373         if not(autocvar_g_powerups) { return FALSE; }
 374         if not(self.classname == "item_strength" || self.classname == "item_invincible" || self.classname == "item_health_mega")
 375                 return FALSE;
 376
 377         entity e = spawn();
 378
 379         if(random() < 0.3)
 380                 e.think = spawnfunc_item_strength;
 381         else if(random() < 0.6)
 382                 e.think = minstagib_health_mega;
 383         else
 384                 e.think = spawnfunc_item_invincible;
 385
 386         e.nextthink = time + 0.1;
 387         e.spawnflags = self.spawnflags;
 388         e.noalign = self.noalign;
 389         setorigin(e, self.origin);
 390
 391         return TRUE;
 392 }
 393
 394 MUTATOR_HOOKFUNCTION(minstagib_BuildMutatorsString)
 395 {
 396         ret_string = strcat(ret_string, ":MinstaGib");
 397         return FALSE;
 398 }
 399
 400 MUTATOR_HOOKFUNCTION(minstagib_BuildMutatorsPrettyString)
 401 {
 402         ret_string = strcat(ret_string, ", MinstaGib");
 403         return FALSE;
 404 }
 405
 406 MUTATOR_DEFINITION(mutator_minstagib)
 407 {
 408         MUTATOR_HOOK(MatchEnd, minstagib_MatchEnd, CBC_ORDER_ANY);
 409         MUTATOR_HOOK(BotShouldAttack, minstagib_BotShouldAttack, CBC_ORDER_ANY);
 410         MUTATOR_HOOK(PlayerPhysics, minstagib_PlayerPhysics, CBC_ORDER_ANY);
 411         MUTATOR_HOOK(PlayerSpawn, minstagib_PlayerSpawn, CBC_ORDER_ANY);
 412         MUTATOR_HOOK(PlayerDamage_Calculate, minstagib_PlayerDamage, CBC_ORDER_ANY);
 413         MUTATOR_HOOK(MakePlayerObserver, minstagib_MakePlayerObserver, CBC_ORDER_ANY);
 414         MUTATOR_HOOK(SetStartItems, minstagib_SetStartItems, CBC_ORDER_ANY);
 415         MUTATOR_HOOK(ItemTouch, minstagib_ItemTouch, CBC_ORDER_ANY);
 416         MUTATOR_HOOK(FilterItem, minstagib_FilterItem, CBC_ORDER_ANY);
 417         MUTATOR_HOOK(CustomizeWaypoint, minstagib_CustomizeWaypoint, CBC_ORDER_ANY);
 418         MUTATOR_HOOK(Item_RespawnCountdown, minstagib_ItemCountdown, CBC_ORDER_ANY);
 419         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, minstagib_SplitHealthArmor, CBC_ORDER_ANY);
 420         MUTATOR_HOOK(PlayerPowerups, minstagib_PlayerPowerups, CBC_ORDER_ANY);
 421         MUTATOR_HOOK(ForbidThrowCurrentWeapon, minstagib_ForbidThrowing, CBC_ORDER_ANY);
 422         MUTATOR_HOOK(PlayerPreThink, minstagib_PlayerPreThink, CBC_ORDER_ANY);
 423         MUTATOR_HOOK(OnEntityPreSpawn, minstagib_OnEntityPreSpawn, CBC_ORDER_ANY);
 424         MUTATOR_HOOK(BuildMutatorsString, minstagib_BuildMutatorsString, CBC_ORDER_ANY);
 425         MUTATOR_HOOK(BuildMutatorsPrettyString, minstagib_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 426
 427         return FALSE;
 428 }