Merge branch 'master' into Mario/mutator_minstagib
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / mutators / mutator_minstagib.qc
1 void spawnfunc_item_minst_cells (void) 
2 {
3         if not(g_minstagib) { remove(self); return; }
4         if not(self.ammo_cells)
5                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
6                 
7         StartItem ("models/items/a_cells.md3",
8                            "misc/itempickup.wav", 45, 0,
9                            "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
10 }
11
12 void minstagib_health_mega()
13 {
14         self.max_health = 1;
15         StartItem ("models/items/g_h100.md3",
16                            "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
17                            "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
18 }
19
20 .float minstagib_nextthink;
21 .float minstagib_needammo;
22 void minstagib_stop_countdown(entity e)
23 {
24         if (!e.minstagib_needammo)
25                 return;
26         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_MINSTA_FINDAMMO);
27         e.minstagib_needammo = FALSE;
28 }
29 void minstagib_ammocheck(void)
30 {
31         if not(IS_PLAYER(self))
32                 return; // not a player
33         if (time < self.minstagib_nextthink)
34                 return;
35
36         if (self.deadflag || gameover)
37                 minstagib_stop_countdown(self);
38         else if (self.ammo_cells > 0 || (self.items & IT_UNLIMITED_WEAPON_AMMO))
39                 minstagib_stop_countdown(self);
40         else
41         {
42                 self.minstagib_needammo = TRUE;
43                 if (self.health == 5)
44                 {
45                         Damage(self, self, self, 5, DEATH_NOAMMO, self.origin, '0 0 0');
46                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_MINSTAGIB_TERMINATED);
47                 }
48                 else if (self.health == 10)
49                 {
50                         Damage(self, self, self, 5, DEATH_NOAMMO, self.origin, '0 0 0');
51                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_1);
52                 }
53                 else if (self.health == 20)
54                 {
55                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
56                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_2);
57                 }
58                 else if (self.health == 30)
59                 {
60                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
61                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_3);
62                 }
63                 else if (self.health == 40)
64                 {
65                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
66                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_4);
67                 }
68                 else if (self.health == 50)
69                 {
70                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
71                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_5);
72                 }
73                 else if (self.health == 60)
74                 {
75                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
76                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_6);
77                 }
78                 else if (self.health == 70)
79                 {
80                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
81                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_7);
82                 }
83                 else if (self.health == 80)
84                 {
85                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
86                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_8);
87                 }
88                 else if (self.health == 90)
89                 {
90                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MINSTA_FINDAMMO);
91                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
92                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_9);
93                 }
94                 else if (self.health == 100)
95                 {
96                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_MULTI, MULTI_MINSTA_FINDAMMO);
97                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
98                 }
99         }
100         self.minstagib_nextthink = time + 1;
101 }
102
103 MUTATOR_HOOKFUNCTION(minstagib_MatchEnd)
104 {
105         entity head;
106         FOR_EACH_PLAYER(head)
107                 minstagib_stop_countdown(head);
108                 
109         return FALSE;
110 }
111
112 MUTATOR_HOOKFUNCTION(minstagib_BotShouldAttack)
113 {
114         if(checkentity.items & IT_STRENGTH)
115                 return TRUE;
116                 
117         return FALSE;
118 }
119
120 MUTATOR_HOOKFUNCTION(minstagib_MakePlayerObserver)
121 {
122         minstagib_stop_countdown(self);
123         return FALSE;
124 }
125
126 MUTATOR_HOOKFUNCTION(minstagib_PlayerSpawn)
127 {
128         self.effects |= EF_FULLBRIGHT;
129         return FALSE;
130 }
131
132 MUTATOR_HOOKFUNCTION(minstagib_PlayerPreThink)
133 {
134         minstagib_ammocheck();
135         return FALSE;
136 }
137
138 MUTATOR_HOOKFUNCTION(minstagib_PlayerPowerups)
139 {
140         if not(self.effects & EF_FULLBRIGHT)
141                 self.effects |= EF_FULLBRIGHT;
142
143         if (self.items & IT_STRENGTH)
144         {
145                 play_countdown(self.strength_finished, "misc/poweroff.wav");
146                 if (time > self.strength_finished)
147                 {
148                         self.alpha = default_player_alpha;
149                         self.exteriorweaponentity.alpha = default_weapon_alpha;
150                         self.items &~= IT_STRENGTH;
151                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
152                 }
153         }
154         else
155         {
156                 if (time < self.strength_finished)
157                 {
158                         self.alpha = autocvar_g_minstagib_invis_alpha;
159                         self.exteriorweaponentity.alpha = autocvar_g_minstagib_invis_alpha;
160                         self.items |= IT_STRENGTH;
161                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
162                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
163                 }
164         }
165
166         if (self.items & IT_INVINCIBLE)
167         {
168                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
169                 if (time > self.invincible_finished)
170                 {
171                         self.items &~= IT_INVINCIBLE;
172                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
173                 }
174         }
175         else
176         {
177                 if (time < self.invincible_finished)
178                 {
179                         self.items |= IT_INVINCIBLE;
180                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
181                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
182                 }
183         }
184         return FALSE;
185 }
186
187 MUTATOR_HOOKFUNCTION(minstagib_PlayerPhysics)
188 {
189         if(self.items & IT_INVINCIBLE)
190                 self.stat_sv_maxspeed = self.stat_sv_maxspeed * autocvar_g_minstagib_speed_highspeed;
191                 
192         return FALSE;
193 }
194
195 MUTATOR_HOOKFUNCTION(minstagib_SplitHealthArmor)
196 {
197         damage_save = 0;
198         //damage_take = frag_damage; // frag_damage isn't even set here?!
199         
200         return FALSE;
201 }
202
203 MUTATOR_HOOKFUNCTION(minstagib_ForbidThrowing)
204 {
205         if (self.health < 1)
206                 return FALSE;
207                 
208         return TRUE;
209 }
210
211 MUTATOR_HOOKFUNCTION(minstagib_PlayerDamage)
212 {
213         if(autocvar_g_friendlyfire == 0 && !IsDifferentTeam(frag_target, frag_attacker) && IS_PLAYER(frag_target))
214                 frag_damage = 0;
215                 
216         if(IS_PLAYER(frag_target))
217         {
218                 if ((frag_deathtype == DEATH_FALL)  ||
219                         (frag_deathtype == DEATH_DROWN) ||
220                         (frag_deathtype == DEATH_SLIME) ||
221                         (frag_deathtype == DEATH_LAVA))
222                 {
223                         frag_damage = 0;
224                 }
225                 
226                 if (frag_target.armorvalue && (frag_deathtype == WEP_MINSTANEX) && frag_damage)
227                 {
228                         frag_target.armorvalue -= 1;
229                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_MINSTA_LIVES_REMAINING, frag_target.armorvalue);
230                         frag_damage = 0;
231                         frag_target.hitsound += 1;
232                         frag_attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
233                 }
234                 if (DEATH_ISWEAPON(frag_deathtype, WEP_LASER))
235                 {
236                         frag_damage = 0;
237                         frag_mirrordamage = 0;
238                         if (frag_target != frag_attacker)
239                         {
240                                 if ((frag_target.health >= 1) && IS_PLAYER(frag_target))
241                                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_MINSTA_SECONDARY);
242                                 frag_force = '0 0 0';
243                                 // keep mirrorfrag_force
244                                 frag_attacker = frag_target;
245                         }
246                 }
247         }
248         
249         if(frag_mirrordamage > 0)
250         {
251                 // just lose extra LIVES, don't kill the player for mirror damage
252                 if(frag_attacker.armorvalue > 0)
253                 {
254                         frag_attacker.armorvalue = frag_attacker.armorvalue - 1;
255                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_MINSTA_LIVES_REMAINING, frag_attacker.armorvalue);
256                         frag_attacker.hitsound += 1;
257                 }
258                 frag_mirrordamage = 0;
259         }
260         
261         if(frag_target.items & IT_STRENGTH)
262                 yoda = 1;
263                 
264         return FALSE;
265 }
266
267 MUTATOR_HOOKFUNCTION(minstagib_SetStartItems)
268 {
269         start_ammo_cells = cvar("g_minstagib_ammo_start");
270         
271         start_health = 100;
272         start_armorvalue = 0;
273         WEPSET_COPY_AW(start_weapons, WEP_MINSTANEX);
274         start_items |= IT_UNLIMITED_SUPERWEAPONS;
275                 
276         return FALSE;
277 }
278
279 MUTATOR_HOOKFUNCTION(minstagib_FilterItem)
280 {
281         if(self.classname == "item_cells")
282                 return TRUE; // no normal cells?
283                 
284         if(self.weapon == WEP_MINSTANEX && self.classname == "droppedweapon")
285         {
286                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
287                 return FALSE;
288         }
289         
290         if(self.weapon == WEP_ROCKET_LAUNCHER || self.weapon == WEP_NEX)
291         {
292                 entity e = spawn();
293                 setorigin(e, self.origin);
294                 entity oldself;
295                 oldself = self;
296                 self = e;
297                 spawnfunc_item_minst_cells();
298                 self = oldself;
299                 return TRUE;
300         }
301                 
302         if(self.flags & FL_POWERUP)
303                 return FALSE;
304                 
305         if(self.ammo_cells > autocvar_g_minstagib_ammo_drop && self.classname != "item_minst_cells")
306                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
307                 
308         if(self.ammo_cells && !self.weapon)
309                 return FALSE;
310                 
311         return TRUE;
312 }
313
314 MUTATOR_HOOKFUNCTION(minstagib_CustomizeWaypoint)
315 {
316         entity e = WaypointSprite_getviewentity(other);
317         
318         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
319         // but only apply this to real players, not to spectators
320         if((self.owner.flags & FL_CLIENT) && (self.owner.items & IT_STRENGTH) && (e == other))
321         if(IsDifferentTeam(self.owner, e))
322                 return TRUE;
323         
324         return FALSE;
325 }
326
327 MUTATOR_HOOKFUNCTION(minstagib_ItemCountdown)
328 {
329         switch(self.items)
330         {
331                 case IT_STRENGTH:   item_name = "item-invis"; item_color = '0 0 1'; break;
332                 case IT_NAILS:      item_name = "item-extralife"; item_color = '1 0 0'; break;
333                 case IT_INVINCIBLE: item_name = "item-speed"; item_color = '1 0 1'; break;
334         }
335         return FALSE;
336 }
337
338 MUTATOR_HOOKFUNCTION(minstagib_ItemTouch)
339 {
340         if(self.ammo_cells)
341         {
342                 // play some cool sounds ;)
343                 if (IS_CLIENT(other))
344                 {
345                         if(other.health <= 5)
346                                 Send_Notification(NOTIF_ONE, other, MSG_ANNCE, ANNCE_MINSTAGIB_LASTSECOND);
347                         else if(other.health < 50)
348                                 Send_Notification(NOTIF_ONE, other, MSG_ANNCE, ANNCE_MINSTAGIB_NARROWLY);
349                 }
350
351                 if(other.health < 100)
352                         other.health = 100;
353         }
354         
355         if(self.max_health)
356         {
357                 other.armorvalue = bound(other.armorvalue, 999, other.armorvalue + autocvar_g_minstagib_extralives);
358                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_EXTRALIVES);
359         }
360                 
361         return FALSE;
362 }
363
364 MUTATOR_HOOKFUNCTION(minstagib_OnEntityPreSpawn)
365 {
366         if not(autocvar_g_powerups) { return FALSE; }
367         if not(self.classname == "item_strength" || self.classname == "item_invincible" || self.classname == "item_health_mega")
368                 return FALSE;
369         
370         entity e = spawn();
371         
372         if(random() < 0.3)
373                 e.think = spawnfunc_item_strength;
374         else if(random() < 0.6)
375                 e.think = minstagib_health_mega;
376         else
377                 e.think = spawnfunc_item_invincible;
378                 
379         e.nextthink = time + 0.1;
380         e.spawnflags = self.spawnflags;
381         e.noalign = self.noalign;
382         setorigin(e, self.origin);
383         
384         return TRUE;
385 }
386
387 MUTATOR_HOOKFUNCTION(minstagib_BuildMutatorsString)
388 {
389         ret_string = strcat(ret_string, ":MinstaGib");
390         return FALSE;
391 }
392
393 MUTATOR_HOOKFUNCTION(minstagib_BuildMutatorsPrettyString)
394 {
395         ret_string = strcat(ret_string, ", MinstaGib");
396         return FALSE;
397 }
398
399 MUTATOR_DEFINITION(mutator_minstagib)
400 {
401         MUTATOR_HOOK(MatchEnd, minstagib_MatchEnd, CBC_ORDER_ANY);
402         MUTATOR_HOOK(BotShouldAttack, minstagib_BotShouldAttack, CBC_ORDER_ANY);
403         MUTATOR_HOOK(PlayerPhysics, minstagib_PlayerPhysics, CBC_ORDER_ANY);
404         MUTATOR_HOOK(PlayerSpawn, minstagib_PlayerSpawn, CBC_ORDER_ANY);
405         MUTATOR_HOOK(PlayerDamage_Calculate, minstagib_PlayerDamage, CBC_ORDER_ANY);
406         MUTATOR_HOOK(MakePlayerObserver, minstagib_MakePlayerObserver, CBC_ORDER_ANY);
407         MUTATOR_HOOK(SetStartItems, minstagib_SetStartItems, CBC_ORDER_ANY);
408         MUTATOR_HOOK(ItemTouch, minstagib_ItemTouch, CBC_ORDER_ANY);
409         MUTATOR_HOOK(FilterItem, minstagib_FilterItem, CBC_ORDER_ANY);
410         MUTATOR_HOOK(CustomizeWaypoint, minstagib_CustomizeWaypoint, CBC_ORDER_ANY);
411         MUTATOR_HOOK(Item_RespawnCountdown, minstagib_ItemCountdown, CBC_ORDER_ANY);
412         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, minstagib_SplitHealthArmor, CBC_ORDER_ANY);
413         MUTATOR_HOOK(PlayerPowerups, minstagib_PlayerPowerups, CBC_ORDER_ANY);
414         MUTATOR_HOOK(ForbidThrowCurrentWeapon, minstagib_ForbidThrowing, CBC_ORDER_ANY);
415         MUTATOR_HOOK(PlayerPreThink, minstagib_PlayerPreThink, CBC_ORDER_ANY);
416         MUTATOR_HOOK(OnEntityPreSpawn, minstagib_OnEntityPreSpawn, CBC_ORDER_ANY);
417         MUTATOR_HOOK(BuildMutatorsString, minstagib_BuildMutatorsString, CBC_ORDER_ANY);
418         MUTATOR_HOOK(BuildMutatorsPrettyString, minstagib_BuildMutatorsPrettyString, CBC_ORDER_ANY);
419
420         return FALSE;
421 }