qcsrc/server/mutators/mutator_multijump.qc

   1 .float multijump_count;
   2 .float multijump_ready;
   3
   4 #ifdef CSQC
   5
   6 #define PHYS_MULTIJUMP                          getstati(STAT_MULTIJUMP)
   7 #define PHYS_MULTIJUMP_SPEED            getstatf(STAT_MULTIJUMP_SPEED)
   8 #define PHYS_MULTIJUMP_ADD                      getstati(STAT_MULTIJUMP_ADD)
   9
  10 #elif defined(SVQC)
  11
  12 #define PHYS_MULTIJUMP                          autocvar_g_multijump
  13 #define PHYS_MULTIJUMP_SPEED            autocvar_g_multijump_speed
  14 #define PHYS_MULTIJUMP_ADD                      autocvar_g_multijump_add
  15
  16
  17 .float stat_multijump;
  18 .float stat_multijump_speed;
  19 .float stat_multijump_add;
  20
  21 void multijump_UpdateStats()
  22 {
  23         self.stat_multijump = PHYS_MULTIJUMP;
  24         self.stat_multijump_speed = PHYS_MULTIJUMP_SPEED;
  25         self.stat_multijump_add = PHYS_MULTIJUMP_ADD;
  26 }
  27
  28 void multijump_AddStats()
  29 {
  30         addstat(STAT_MULTIJUMP, AS_INT, stat_multijump);
  31         addstat(STAT_MULTIJUMP_SPEED, AS_FLOAT, stat_multijump_speed);
  32         addstat(STAT_MULTIJUMP_ADD, AS_INT, stat_multijump_add);
  33 }
  34
  35 #endif
  36
  37 void PM_multijump()
  38 {
  39         if(!PHYS_MULTIJUMP) { return; }
  40
  41         if(IS_ONGROUND(self))
  42         {
  43                 self.multijump_count = 0;
  44         }
  45 }
  46
  47 float PM_multijump_checkjump()
  48 {
  49         if(!PHYS_MULTIJUMP) { return false; }
  50
  51         if (!IS_JUMP_HELD(self) && !IS_ONGROUND(self)) // jump button pressed this frame and we are in midair
  52                 self.multijump_ready = true;  // this is necessary to check that we released the jump button and pressed it again
  53         else
  54                 self.multijump_ready = false;
  55
  56         if(!player_multijump && self.multijump_ready && (self.multijump_count < PHYS_MULTIJUMP || PHYS_MULTIJUMP == -1) && self.velocity_z > PHYS_MULTIJUMP_SPEED)
  57         {
  58                 if (PHYS_MULTIJUMP)
  59                 {
  60                         if (!PHYS_MULTIJUMP_ADD) // in this case we make the z velocity == jumpvelocity
  61                         {
  62                                 if (self.velocity_z < PHYS_JUMPVELOCITY)
  63                                 {
  64                                         player_multijump = true;
  65                                         self.velocity_z = 0;
  66                                 }
  67                         }
  68                         else
  69                                 player_multijump = true;
  70
  71                         if(player_multijump)
  72                         {
  73                                 if(PHYS_INPUT_MOVEVALUES(self)_x != 0 || PHYS_INPUT_MOVEVALUES(self)_y != 0) // don't remove all speed if player isnt pressing any movement keys
  74                                 {
  75                                         float curspeed;
  76                                         vector wishvel, wishdir;
  77
  78 #ifdef SVQC
  79                                         curspeed = max(
  80                                                 vlen(vec2(self.velocity)), // current xy speed
  81                                                 vlen(vec2(antilag_takebackavgvelocity(self, max(self.lastteleporttime + sys_frametime, time - 0.25), time))) // average xy topspeed over the last 0.25 secs
  82                                         );
  83 #elif defined(CSQC)
  84                                         curspeed = vlen(vec2(self.velocity));
  85 #endif
  86
  87                                         makevectors(PHYS_INPUT_ANGLES(self)_y * '0 1 0');
  88                                         wishvel = v_forward * PHYS_INPUT_MOVEVALUES(self)_x + v_right * PHYS_INPUT_MOVEVALUES(self)_y;
  89                                         wishdir = normalize(wishvel);
  90
  91                                         self.velocity_x = wishdir_x * curspeed; // allow "dodging" at a multijump
  92                                         self.velocity_y = wishdir_y * curspeed;
  93                                         // keep velocity_z unchanged!
  94                                 }
  95                                 self.multijump_count += 1;
  96                         }
  97                 }
  98                 self.multijump_ready = false; // require releasing and pressing the jump button again for the next jump
  99         }
 100
 101         return false;
 102 }
 103
 104 #ifdef SVQC
 105 MUTATOR_HOOKFUNCTION(multijump_PlayerPhysics)
 106 {
 107         multijump_UpdateStats();
 108         PM_multijump();
 109
 110         return false;
 111 }
 112
 113 MUTATOR_HOOKFUNCTION(multijump_PlayerJump)
 114 {
 115         return PM_multijump_checkjump();
 116 }
 117
 118 MUTATOR_HOOKFUNCTION(multijump_BuildMutatorsString)
 119 {
 120         ret_string = strcat(ret_string, ":multijump");
 121         return false;
 122 }
 123
 124 MUTATOR_HOOKFUNCTION(multijump_BuildMutatorsPrettyString)
 125 {
 126         ret_string = strcat(ret_string, ", Multi jump");
 127         return false;
 128 }
 129
 130 MUTATOR_DEFINITION(mutator_multijump)
 131 {
 132         MUTATOR_HOOK(PlayerPhysics, multijump_PlayerPhysics, CBC_ORDER_ANY);
 133         MUTATOR_HOOK(PlayerJump, multijump_PlayerJump, CBC_ORDER_ANY);
 134         MUTATOR_HOOK(BuildMutatorsString, multijump_BuildMutatorsString, CBC_ORDER_ANY);
 135         MUTATOR_HOOK(BuildMutatorsPrettyString, multijump_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 136
 137         MUTATOR_ONADD
 138         {
 139                 multijump_AddStats();
 140         }
 141
 142         return false;
 143 }
 144 #endif