Merge branch 'master' into Mario/vaporizer_damage
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / mutators / mutator_nades.qc
1 #include "mutator_nades.qh"
2 #include "../_all.qh"
3
4 #include "mutator.qh"
5
6 #include "gamemode_keyhunt.qh"
7 #include "gamemode_freezetag.qh"
8 #include "../../common/nades.qh"
9 #include "../../common/monsters/spawn.qh"
10 #include "../../common/monsters/sv_monsters.qh"
11
12 .float lifetime;
13
14 .entity nade_spawnloc;
15
16 void nade_timer_think()
17 {
18         self.skin = 8 - (self.owner.wait - time) / (autocvar_g_nades_nade_lifetime / 10);
19         self.nextthink = time;
20         if(!self.owner || wasfreed(self.owner))
21                 remove(self);
22 }
23
24 void nade_burn_spawn(entity _nade)
25 {
26         CSQCProjectile(_nade, true, NADES[_nade.nade_type].m_projectile[true], true);
27 }
28
29 void nade_spawn(entity _nade)
30 {
31         entity timer = spawn();
32         setmodel(timer, "models/ok_nade_counter/ok_nade_counter.md3");
33         setattachment(timer, _nade, "");
34         timer.classname = "nade_timer";
35         timer.colormap = _nade.colormap;
36         timer.glowmod = _nade.glowmod;
37         timer.think = nade_timer_think;
38         timer.nextthink = time;
39         timer.wait = _nade.wait;
40         timer.owner = _nade;
41         timer.skin = 10;
42
43         _nade.effects |= EF_LOWPRECISION;
44
45         CSQCProjectile(_nade, true, NADES[_nade.nade_type].m_projectile[false], true);
46 }
47
48 void napalm_damage(float dist, float damage, float edgedamage, float burntime)
49 {
50         entity e;
51         float d;
52         vector p;
53
54         if ( damage < 0 )
55                 return;
56
57         RandomSelection_Init();
58         for(e = WarpZone_FindRadius(self.origin, dist, true); e; e = e.chain)
59                 if(e.takedamage == DAMAGE_AIM)
60                 if(self.realowner != e || autocvar_g_nades_napalm_selfdamage)
61                 if(!IS_PLAYER(e) || !self.realowner || DIFF_TEAM(e, self))
62                 if(!e.frozen)
63                 {
64                         p = e.origin;
65                         p.x += e.mins.x + random() * (e.maxs.x - e.mins.x);
66                         p.y += e.mins.y + random() * (e.maxs.y - e.mins.y);
67                         p.z += e.mins.z + random() * (e.maxs.z - e.mins.z);
68                         d = vlen(WarpZone_UnTransformOrigin(e, self.origin) - p);
69                         if(d < dist)
70                         {
71                                 e.fireball_impactvec = p;
72                                 RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
73                         }
74                 }
75         if(RandomSelection_chosen_ent)
76         {
77                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, self.origin) - RandomSelection_chosen_ent.fireball_impactvec);
78                 d = damage + (edgedamage - damage) * (d / dist);
79                 Fire_AddDamage(RandomSelection_chosen_ent, self.realowner, d * burntime, burntime, self.projectiledeathtype | HITTYPE_BOUNCE);
80                 //trailparticles(self, particleeffectnum(EFFECT_FIREBALL_LASER), self.origin, RandomSelection_chosen_ent.fireball_impactvec);
81                 Send_Effect(EFFECT_FIREBALL_LASER, self.origin, RandomSelection_chosen_ent.fireball_impactvec - self.origin, 1);
82         }
83 }
84
85
86 void napalm_ball_think()
87 {
88         if(round_handler_IsActive())
89         if(!round_handler_IsRoundStarted())
90         {
91                 remove(self);
92                 return;
93         }
94
95         if(time > self.pushltime)
96         {
97                 remove(self);
98                 return;
99         }
100
101         vector midpoint = ((self.absmin + self.absmax) * 0.5);
102         if(pointcontents(midpoint) == CONTENT_WATER)
103         {
104                 self.velocity = self.velocity * 0.5;
105
106                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
107                         { self.velocity_z = 200; }
108         }
109
110         self.angles = vectoangles(self.velocity);
111
112         napalm_damage(autocvar_g_nades_napalm_ball_radius,autocvar_g_nades_napalm_ball_damage,
113                                   autocvar_g_nades_napalm_ball_damage,autocvar_g_nades_napalm_burntime);
114
115         self.nextthink = time + 0.1;
116 }
117
118
119 void nade_napalm_ball()
120 {
121         entity proj;
122         vector kick;
123
124         spamsound(self, CH_SHOTS, W_Sound("fireball_fire"), VOL_BASE, ATTEN_NORM);
125
126         proj = spawn ();
127         proj.owner = self.owner;
128         proj.realowner = self.realowner;
129         proj.team = self.owner.team;
130         proj.classname = "grenade";
131         proj.bot_dodge = true;
132         proj.bot_dodgerating = autocvar_g_nades_napalm_ball_damage;
133         proj.movetype = MOVETYPE_BOUNCE;
134         proj.projectiledeathtype = DEATH_NADE_NAPALM;
135         PROJECTILE_MAKETRIGGER(proj);
136         setmodel(proj, "null");
137         proj.scale = 1;//0.5;
138         setsize(proj, '-4 -4 -4', '4 4 4');
139         setorigin(proj, self.origin);
140         proj.think = napalm_ball_think;
141         proj.nextthink = time;
142         proj.damageforcescale = autocvar_g_nades_napalm_ball_damageforcescale;
143         proj.effects = EF_LOWPRECISION | EF_FLAME;
144
145         kick.x =(random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
146         kick.y = (random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
147         kick.z = (random()/2+0.5) * autocvar_g_nades_napalm_ball_spread;
148         proj.velocity = kick;
149
150         proj.pushltime = time + autocvar_g_nades_napalm_ball_lifetime;
151
152         proj.angles = vectoangles(proj.velocity);
153         proj.flags = FL_PROJECTILE;
154         proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
155
156         //CSQCProjectile(proj, true, PROJECTILE_NAPALM_FIRE, true);
157 }
158
159
160 void napalm_fountain_think()
161 {
162
163         if(round_handler_IsActive())
164         if(!round_handler_IsRoundStarted())
165         {
166                 remove(self);
167                 return;
168         }
169
170         if(time >= self.ltime)
171         {
172                 remove(self);
173                 return;
174         }
175
176         vector midpoint = ((self.absmin + self.absmax) * 0.5);
177         if(pointcontents(midpoint) == CONTENT_WATER)
178         {
179                 self.velocity = self.velocity * 0.5;
180
181                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
182                         { self.velocity_z = 200; }
183
184                 UpdateCSQCProjectile(self);
185         }
186
187         napalm_damage(autocvar_g_nades_napalm_fountain_radius, autocvar_g_nades_napalm_fountain_damage,
188                 autocvar_g_nades_napalm_fountain_edgedamage, autocvar_g_nades_napalm_burntime);
189
190         self.nextthink = time + 0.1;
191         if(time >= self.nade_special_time)
192         {
193                 self.nade_special_time = time + autocvar_g_nades_napalm_fountain_delay;
194                 nade_napalm_ball();
195         }
196 }
197
198 void nade_napalm_boom()
199 {
200         entity fountain;
201         int c;
202         for (c = 0; c < autocvar_g_nades_napalm_ball_count; c++)
203                 nade_napalm_ball();
204
205
206         fountain = spawn();
207         fountain.owner = self.owner;
208         fountain.realowner = self.realowner;
209         fountain.origin = self.origin;
210         setorigin(fountain, fountain.origin);
211         fountain.think = napalm_fountain_think;
212         fountain.nextthink = time;
213         fountain.ltime = time + autocvar_g_nades_napalm_fountain_lifetime;
214         fountain.pushltime = fountain.ltime;
215         fountain.team = self.team;
216         fountain.movetype = MOVETYPE_TOSS;
217         fountain.projectiledeathtype = DEATH_NADE_NAPALM;
218         fountain.bot_dodge = true;
219         fountain.bot_dodgerating = autocvar_g_nades_napalm_fountain_damage;
220         fountain.nade_special_time = time;
221         setsize(fountain, '-16 -16 -16', '16 16 16');
222         CSQCProjectile(fountain, true, PROJECTILE_NAPALM_FOUNTAIN, true);
223 }
224
225 void nade_ice_freeze(entity freezefield, entity frost_target, float freeze_time)
226 {
227         frost_target.frozen_by = freezefield.realowner;
228         Send_Effect(EFFECT_ELECTRO_IMPACT, frost_target.origin, '0 0 0', 1);
229         Freeze(frost_target, 1/freeze_time, 3, false);
230         if(frost_target.ballcarried)
231         if(g_keepaway) { ka_DropEvent(frost_target); }
232         else { DropBall(frost_target.ballcarried, frost_target.origin, frost_target.velocity);}
233         if(frost_target.flagcarried) { ctf_Handle_Throw(frost_target, world, DROP_THROW); }
234         if(frost_target.nade) { toss_nade(frost_target, '0 0 0', time + 0.05); }
235
236         kh_Key_DropAll(frost_target, false);
237 }
238
239 void nade_ice_think()
240 {
241
242         if(round_handler_IsActive())
243         if(!round_handler_IsRoundStarted())
244         {
245                 remove(self);
246                 return;
247         }
248
249         if(time >= self.ltime)
250         {
251                 if ( autocvar_g_nades_ice_explode )
252                 {
253                         entity expef = NULL;
254                         switch(self.realowner.team)
255                         {
256                                 case NUM_TEAM_1: expef = EFFECT_NADE_RED_EXPLODE; break;
257                                 case NUM_TEAM_2: expef = EFFECT_NADE_BLUE_EXPLODE; break;
258                                 case NUM_TEAM_3: expef = EFFECT_NADE_YELLOW_EXPLODE; break;
259                                 case NUM_TEAM_4: expef = EFFECT_NADE_PINK_EXPLODE; break;
260                                 default:                 expef = EFFECT_NADE_NEUTRAL_EXPLODE; break;
261                         }
262                         Send_Effect(expef, self.origin + '0 0 1', '0 0 0', 1);
263                         sound(self, CH_SHOTS, W_Sound("rocket_impact"), VOL_BASE, ATTEN_NORM);
264
265                         RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
266                                 autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
267                         Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
268                                 autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
269                 }
270                 remove(self);
271                 return;
272         }
273
274
275         self.nextthink = time+0.1;
276
277         // gaussian
278         float randomr;
279         randomr = random();
280         randomr = exp(-5*randomr*randomr)*autocvar_g_nades_nade_radius;
281         float randomw;
282         randomw = random()*M_PI*2;
283         vector randomp;
284         randomp.x = randomr*cos(randomw);
285         randomp.y = randomr*sin(randomw);
286         randomp.z = 1;
287         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, self.origin + randomp, '0 0 0', 1);
288
289         if(time >= self.nade_special_time)
290         {
291                 self.nade_special_time = time+0.7;
292
293                 Send_Effect(EFFECT_ELECTRO_IMPACT, self.origin, '0 0 0', 1);
294                 Send_Effect(EFFECT_ICEFIELD, self.origin, '0 0 0', 1);
295         }
296
297
298         float current_freeze_time = self.ltime - time - 0.1;
299
300         entity e;
301         for(e = findradius(self.origin, autocvar_g_nades_nade_radius); e; e = e.chain)
302         if(e != self)
303         if(!autocvar_g_nades_ice_teamcheck || (DIFF_TEAM(e, self.realowner) || e == self.realowner))
304         if(e.takedamage && e.deadflag == DEAD_NO)
305         if(e.health > 0)
306         if(!e.revival_time || ((time - e.revival_time) >= 1.5))
307         if(!e.frozen)
308         if(current_freeze_time > 0)
309                 nade_ice_freeze(self, e, current_freeze_time);
310 }
311
312 void nade_ice_boom()
313 {
314         entity fountain;
315         fountain = spawn();
316         fountain.owner = self.owner;
317         fountain.realowner = self.realowner;
318         fountain.origin = self.origin;
319         setorigin(fountain, fountain.origin);
320         fountain.think = nade_ice_think;
321         fountain.nextthink = time;
322         fountain.ltime = time + autocvar_g_nades_ice_freeze_time;
323         fountain.pushltime = fountain.wait = fountain.ltime;
324         fountain.team = self.team;
325         fountain.movetype = MOVETYPE_TOSS;
326         fountain.projectiledeathtype = DEATH_NADE_ICE;
327         fountain.bot_dodge = false;
328         setsize(fountain, '-16 -16 -16', '16 16 16');
329         fountain.nade_special_time = time+0.3;
330         fountain.angles = self.angles;
331
332         if ( autocvar_g_nades_ice_explode )
333         {
334                 setmodel(fountain, "models/grenademodel.md3");
335                 entity timer = spawn();
336                 setmodel(timer, "models/ok_nade_counter/ok_nade_counter.md3");
337                 setattachment(timer, fountain, "");
338                 timer.classname = "nade_timer";
339                 timer.colormap = self.colormap;
340                 timer.glowmod = self.glowmod;
341                 timer.think = nade_timer_think;
342                 timer.nextthink = time;
343                 timer.wait = fountain.ltime;
344                 timer.owner = fountain;
345                 timer.skin = 10;
346         }
347         else
348                 setmodel(fountain, "null");
349 }
350
351 void nade_translocate_boom()
352 {
353         if(self.realowner.vehicle)
354                 return;
355
356         vector locout = self.origin + '0 0 1' * (1 - self.realowner.mins.z - 24);
357         tracebox(locout, self.realowner.mins, self.realowner.maxs, locout, MOVE_NOMONSTERS, self.realowner);
358         locout = trace_endpos;
359
360         makevectors(self.realowner.angles);
361
362         MUTATOR_CALLHOOK(PortalTeleport, self.realowner);
363
364         TeleportPlayer(self, self.realowner, locout, self.realowner.angles, v_forward * vlen(self.realowner.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
365 }
366
367 void nade_spawn_boom()
368 {
369         entity spawnloc = spawn();
370         setorigin(spawnloc, self.origin);
371         setsize(spawnloc, self.realowner.mins, self.realowner.maxs);
372         spawnloc.movetype = MOVETYPE_NONE;
373         spawnloc.solid = SOLID_NOT;
374         spawnloc.drawonlytoclient = self.realowner;
375         spawnloc.effects = EF_STARDUST;
376         spawnloc.cnt = autocvar_g_nades_spawn_count;
377
378         if(self.realowner.nade_spawnloc)
379         {
380                 remove(self.realowner.nade_spawnloc);
381                 self.realowner.nade_spawnloc = world;
382         }
383
384         self.realowner.nade_spawnloc = spawnloc;
385 }
386
387 void nade_heal_think()
388 {
389         if(time >= self.ltime)
390         {
391                 remove(self);
392                 return;
393         }
394
395         self.nextthink = time;
396
397         if(time >= self.nade_special_time)
398         {
399                 self.nade_special_time = time+0.25;
400                 self.nade_show_particles = 1;
401         }
402         else
403                 self.nade_show_particles = 0;
404 }
405
406 void nade_heal_touch()
407 {
408         float maxhealth;
409         float health_factor;
410         if(IS_PLAYER(other) || IS_MONSTER(other))
411         if(other.deadflag == DEAD_NO)
412         if(!other.frozen)
413         {
414                 health_factor = autocvar_g_nades_heal_rate*frametime/2;
415                 if ( other != self.realowner )
416                 {
417                         if ( SAME_TEAM(other,self) )
418                                 health_factor *= autocvar_g_nades_heal_friend;
419                         else
420                                 health_factor *= autocvar_g_nades_heal_foe;
421                 }
422                 if ( health_factor > 0 )
423                 {
424                         maxhealth = (IS_MONSTER(other)) ? other.max_health : g_pickup_healthmega_max;
425                         if ( other.health < maxhealth )
426                         {
427                                 if ( self.nade_show_particles )
428                                         Send_Effect(EFFECT_HEALING, other.origin, '0 0 0', 1);
429                                 other.health = min(other.health+health_factor, maxhealth);
430                         }
431                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
432                 }
433                 else if ( health_factor < 0 )
434                 {
435                         Damage(other,self,self.realowner,-health_factor,DEATH_NADE_HEAL,other.origin,'0 0 0');
436                 }
437
438         }
439
440         if ( IS_REAL_CLIENT(other) || IS_VEHICLE(other) )
441         {
442                 entity show_red = (IS_VEHICLE(other)) ? other.owner : other;
443                 show_red.stat_healing_orb = time+0.1;
444                 show_red.stat_healing_orb_alpha = 0.75 * (self.ltime - time) / self.healer_lifetime;
445         }
446 }
447
448 void nade_heal_boom()
449 {
450         entity healer;
451         healer = spawn();
452         healer.owner = self.owner;
453         healer.realowner = self.realowner;
454         setorigin(healer, self.origin);
455         healer.healer_lifetime = autocvar_g_nades_heal_time; // save the cvar
456         healer.ltime = time + healer.healer_lifetime;
457         healer.team = self.realowner.team;
458         healer.bot_dodge = false;
459         healer.solid = SOLID_TRIGGER;
460         healer.touch = nade_heal_touch;
461
462         setmodel(healer, "models/ctf/shield.md3");
463         healer.healer_radius = autocvar_g_nades_nade_radius;
464         vector size = '1 1 1' * healer.healer_radius / 2;
465         setsize(healer,-size,size);
466
467         Net_LinkEntity(healer, true, 0, healer_send);
468
469         healer.think = nade_heal_think;
470         healer.nextthink = time;
471         healer.SendFlags |= 1;
472 }
473
474 void nade_monster_boom()
475 {
476         entity e = spawnmonster(self.pokenade_type, 0, self.realowner, self.realowner, self.origin, false, false, 1);
477
478         if(autocvar_g_nades_pokenade_monster_lifetime > 0)
479                 e.monster_lifetime = time + autocvar_g_nades_pokenade_monster_lifetime;
480         e.monster_skill = MONSTER_SKILL_INSANE;
481 }
482
483 void nade_boom()
484 {
485         entity expef = NULL;
486         bool nade_blast = true;
487
488         switch ( NADES[self.nade_type] )
489         {
490                 case NADE_TYPE_NAPALM:
491                         nade_blast = autocvar_g_nades_napalm_blast;
492                         expef = EFFECT_EXPLOSION_MEDIUM;
493                         break;
494                 case NADE_TYPE_ICE:
495                         nade_blast = false;
496                         expef = EFFECT_ELECTRO_COMBO; // hookbomb_explode electro_combo bigplasma_impact
497                         break;
498                 case NADE_TYPE_TRANSLOCATE:
499                         nade_blast = false;
500                         break;
501                 case NADE_TYPE_MONSTER:
502                 case NADE_TYPE_SPAWN:
503                         nade_blast = false;
504                         switch(self.realowner.team)
505                         {
506                                 case NUM_TEAM_1: expef = EFFECT_SPAWN_RED; break;
507                                 case NUM_TEAM_2: expef = EFFECT_SPAWN_BLUE; break;
508                                 case NUM_TEAM_3: expef = EFFECT_SPAWN_YELLOW; break;
509                                 case NUM_TEAM_4: expef = EFFECT_SPAWN_PINK; break;
510                                 default: expef = EFFECT_SPAWN_NEUTRAL; break;
511                         }
512                         break;
513                 case NADE_TYPE_HEAL:
514                         nade_blast = false;
515                         expef = EFFECT_SPAWN_RED;
516                         break;
517
518                 default:
519                 case NADE_TYPE_NORMAL:
520                         switch(self.realowner.team)
521                         {
522                                 case NUM_TEAM_1: expef = EFFECT_NADE_RED_EXPLODE; break;
523                                 case NUM_TEAM_2: expef = EFFECT_NADE_BLUE_EXPLODE; break;
524                                 case NUM_TEAM_3: expef = EFFECT_NADE_YELLOW_EXPLODE; break;
525                                 case NUM_TEAM_4: expef = EFFECT_NADE_PINK_EXPLODE; break;
526                                 default:                 expef = EFFECT_NADE_NEUTRAL_EXPLODE; break;
527                         }
528         }
529
530         if(expef)
531                 Send_Effect(expef, findbetterlocation(self.origin, 8), '0 0 0', 1);
532
533         sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
534         sound(self, CH_SHOTS, W_Sound("rocket_impact"), VOL_BASE, ATTEN_NORM);
535
536         self.event_damage = func_null; // prevent somehow calling damage in the next call
537
538         if(nade_blast)
539         {
540                 RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
541                                  autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
542                 Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage, autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
543         }
544
545         if(self.takedamage)
546         switch ( NADES[self.nade_type] )
547         {
548                 case NADE_TYPE_NAPALM: nade_napalm_boom(); break;
549                 case NADE_TYPE_ICE: nade_ice_boom(); break;
550                 case NADE_TYPE_TRANSLOCATE: nade_translocate_boom(); break;
551                 case NADE_TYPE_SPAWN: nade_spawn_boom(); break;
552                 case NADE_TYPE_HEAL: nade_heal_boom(); break;
553                 case NADE_TYPE_MONSTER: nade_monster_boom(); break;
554         }
555
556         entity head;
557         for(head = world; (head = find(head, classname, "grapplinghook")); )
558         if(head.aiment == self)
559                 RemoveGrapplingHook(head.realowner);
560
561         remove(self);
562 }
563
564 void nade_touch()
565 {
566         /*float is_weapclip = 0;
567         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
568         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
569         if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
570                 is_weapclip = 1;*/
571         if(ITEM_TOUCH_NEEDKILL()) // || is_weapclip)
572         {
573                 entity head;
574                 for(head = world; (head = find(head, classname, "grapplinghook")); )
575                 if(head.aiment == self)
576                         RemoveGrapplingHook(head.realowner);
577                 remove(self);
578                 return;
579         }
580
581         PROJECTILE_TOUCH;
582
583         //setsize(self, '-2 -2 -2', '2 2 2');
584         //UpdateCSQCProjectile(self);
585         if(self.health == self.max_health)
586         {
587                 spamsound(self, CH_SHOTS, W_Sound(strcat("grenade_bounce", ftos(1 + rint(random() * 5)))), VOL_BASE, ATTEN_NORM);
588                 return;
589         }
590
591         self.enemy = other;
592         nade_boom();
593 }
594
595 void nade_beep()
596 {
597         sound(self, CH_SHOTS_SINGLE, "overkill/grenadebip.ogg", VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
598         self.think = nade_boom;
599         self.nextthink = max(self.wait, time);
600 }
601
602 void nade_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
603 {
604         if(ITEM_DAMAGE_NEEDKILL(deathtype))
605         {
606                 self.takedamage = DAMAGE_NO;
607                 nade_boom();
608                 return;
609         }
610
611         if(self.nade_type == NADE_TYPE_TRANSLOCATE.m_id || self.nade_type == NADE_TYPE_SPAWN.m_id)
612                 return;
613
614         if(DEATH_ISWEAPON(deathtype, WEP_BLASTER.m_id))
615         {
616                 force *= 1.5;
617                 damage = 0;
618         }
619
620         if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER.m_id) && (deathtype & HITTYPE_SECONDARY))
621         {
622                 force *= 0.5; // too much
623                 frag_damage = 0;
624         }
625
626         if(DEATH_ISWEAPON(deathtype, WEP_VORTEX.m_id) || DEATH_ISWEAPON(deathtype, WEP_VAPORIZER.m_id))
627         {
628                 force *= 6;
629                 damage = self.max_health * 0.55;
630         }
631
632         if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN.m_id) || DEATH_ISWEAPON(deathtype, WEP_HMG.m_id))
633                 damage = self.max_health * 0.1;
634
635         if(DEATH_ISWEAPON(deathtype, WEP_SHOCKWAVE.m_id) || DEATH_ISWEAPON(deathtype, WEP_SHOTGUN.m_id)) // WEAPONTODO
636         if(deathtype & HITTYPE_SECONDARY)
637         {
638                 damage = self.max_health * 0.1;
639                 force *= 10;
640         }
641         else
642                 damage = self.max_health * 1.15;
643
644         self.velocity += force;
645         UpdateCSQCProjectile(self);
646
647         if(damage <= 0 || ((self.flags & FL_ONGROUND) && IS_PLAYER(attacker)))
648                 return;
649
650         if(self.health == self.max_health)
651         {
652                 sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
653                 self.nextthink = max(time + autocvar_g_nades_nade_lifetime, time);
654                 self.think = nade_beep;
655         }
656
657         self.health -= damage;
658
659         if ( self.nade_type != NADE_TYPE_HEAL.m_id || IS_PLAYER(attacker) )
660                 self.realowner = attacker;
661
662         if(self.health <= 0)
663                 W_PrepareExplosionByDamage(attacker, nade_boom);
664         else
665                 nade_burn_spawn(self);
666 }
667
668 void toss_nade(entity e, vector _velocity, float _time)
669 {
670         if(e.nade == world)
671                 return;
672
673         entity _nade = e.nade;
674         e.nade = world;
675
676         remove(e.fake_nade);
677         e.fake_nade = world;
678
679         makevectors(e.v_angle);
680
681         W_SetupShot(e, false, false, "", CH_WEAPON_A, 0);
682
683         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_NADES);
684
685         vector offset = (v_forward * autocvar_g_nades_throw_offset.x)
686                                   + (v_right * autocvar_g_nades_throw_offset.y)
687                                   + (v_up * autocvar_g_nades_throw_offset.z);
688         if(autocvar_g_nades_throw_offset == '0 0 0')
689                 offset = '0 0 0';
690
691         setorigin(_nade, w_shotorg + offset + (v_right * 25) * -1);
692         //setmodel(_nade, W_Model("v_ok_grenade.md3"));
693         //setattachment(_nade, world, "");
694         PROJECTILE_MAKETRIGGER(_nade);
695         setsize(_nade, '-16 -16 -16', '16 16 16');
696         _nade.movetype = MOVETYPE_BOUNCE;
697
698         tracebox(_nade.origin, _nade.mins, _nade.maxs, _nade.origin, false, _nade);
699         if (trace_startsolid)
700                 setorigin(_nade, e.origin);
701
702         if(self.v_angle.x >= 70 && self.v_angle.x <= 110 && self.BUTTON_CROUCH)
703                 _nade.velocity = '0 0 100';
704         else if(autocvar_g_nades_nade_newton_style == 1)
705                 _nade.velocity = e.velocity + _velocity;
706         else if(autocvar_g_nades_nade_newton_style == 2)
707                 _nade.velocity = _velocity;
708         else
709                 _nade.velocity = W_CalculateProjectileVelocity(e.velocity, _velocity, true);
710
711         _nade.touch = nade_touch;
712         _nade.health = autocvar_g_nades_nade_health;
713         _nade.max_health = _nade.health;
714         _nade.takedamage = DAMAGE_AIM;
715         _nade.event_damage = nade_damage;
716         _nade.customizeentityforclient = func_null;
717         _nade.exteriormodeltoclient = world;
718         _nade.traileffectnum = 0;
719         _nade.teleportable = true;
720         _nade.pushable = true;
721         _nade.gravity = 1;
722         _nade.missile_flags = MIF_SPLASH | MIF_ARC;
723         _nade.damagedbycontents = true;
724         _nade.angles = vectoangles(_nade.velocity);
725         _nade.flags = FL_PROJECTILE;
726         _nade.projectiledeathtype = DEATH_NADE;
727         _nade.toss_time = time;
728         _nade.solid = SOLID_CORPSE; //((_nade.nade_type == NADE_TYPE_TRANSLOCATE) ? SOLID_CORPSE : SOLID_BBOX);
729
730         if(_nade.nade_type == NADE_TYPE_TRANSLOCATE.m_id || _nade.nade_type == NADE_TYPE_SPAWN.m_id)
731                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
732         else
733                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
734
735         nade_spawn(_nade);
736
737         if(_time)
738         {
739                 _nade.think = nade_boom;
740                 _nade.nextthink = _time;
741         }
742
743         e.nade_refire = time + autocvar_g_nades_nade_refire;
744         e.nade_timer = 0;
745 }
746
747 void nades_GiveBonus(entity player, float score)
748 {
749         if (autocvar_g_nades)
750         if (autocvar_g_nades_bonus)
751         if (IS_REAL_CLIENT(player))
752         if (IS_PLAYER(player) && player.bonus_nades < autocvar_g_nades_bonus_max)
753         if (player.frozen == 0)
754         if (player.deadflag == DEAD_NO)
755         {
756                 if ( player.bonus_nade_score < 1 )
757                         player.bonus_nade_score += score/autocvar_g_nades_bonus_score_max;
758
759                 if ( player.bonus_nade_score >= 1 )
760                 {
761                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_NADE_BONUS);
762                         play2(player,"kh/alarm.wav");
763                         player.bonus_nades++;
764                         player.bonus_nade_score -= 1;
765                 }
766         }
767 }
768
769 void nades_RemoveBonus(entity player)
770 {
771         player.bonus_nades = player.bonus_nade_score = 0;
772 }
773
774 float nade_customize()
775 {
776         //if(IS_SPEC(other)) { return false; }
777         if(other == self.realowner || (IS_SPEC(other) && other.enemy == self.realowner))
778         {
779                 // somewhat hide the model, but keep the glow
780                 //self.effects = 0;
781                 if(self.traileffectnum)
782                         self.traileffectnum = 0;
783                 self.alpha = -1;
784         }
785         else
786         {
787                 //self.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
788                 if(!self.traileffectnum)
789                         self.traileffectnum = _particleeffectnum(Nade_TrailEffect(NADES[self.nade_type].m_projectile[false], self.team));
790                 self.alpha = 1;
791         }
792
793         return true;
794 }
795
796 void nade_prime()
797 {
798         if(autocvar_g_nades_bonus_only)
799         if(!self.bonus_nades)
800                 return; // only allow bonus nades
801
802         if(self.nade)
803                 remove(self.nade);
804
805         if(self.fake_nade)
806                 remove(self.fake_nade);
807
808         entity n = spawn(), fn = spawn();
809
810         n.classname = "nade";
811         fn.classname = "fake_nade";
812
813         if(self.items & ITEM_Strength.m_itemid && autocvar_g_nades_bonus_onstrength)
814                 n.nade_type = self.nade_type;
815         else if (self.bonus_nades >= 1)
816         {
817                 n.nade_type = self.nade_type;
818                 n.pokenade_type = self.pokenade_type;
819                 self.bonus_nades -= 1;
820         }
821         else
822         {
823                 n.nade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_nade_type : autocvar_g_nades_nade_type);
824                 n.pokenade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_pokenade_type : autocvar_g_nades_pokenade_monster_type);
825         }
826
827         n.nade_type = bound(1, n.nade_type, NADES_COUNT);
828
829         setmodel(n, W_Model("v_ok_grenade.md3"));
830         //setattachment(n, self, "bip01 l hand");
831         n.exteriormodeltoclient = self;
832         n.customizeentityforclient = nade_customize;
833         n.traileffectnum = _particleeffectnum(Nade_TrailEffect(NADES[n.nade_type].m_projectile[false], self.team));
834         n.colormod = NADES[n.nade_type].m_color;
835         n.realowner = self;
836         n.colormap = self.colormap;
837         n.glowmod = self.glowmod;
838         n.wait = time + autocvar_g_nades_nade_lifetime;
839         n.lifetime = time;
840         n.think = nade_beep;
841         n.nextthink = max(n.wait - 3, time);
842         n.projectiledeathtype = DEATH_NADE;
843
844         setmodel(fn, W_Model("h_ok_grenade.iqm"));
845         setattachment(fn, self.weaponentity, "");
846         fn.realowner = fn.owner = self;
847         fn.colormod = NADES[n.nade_type].m_color;
848         fn.colormap = self.colormap;
849         fn.glowmod = self.glowmod;
850         fn.think = SUB_Remove;
851         fn.nextthink = n.wait;
852
853         self.nade = n;
854         self.fake_nade = fn;
855 }
856
857 float CanThrowNade()
858 {
859         if(self.vehicle)
860                 return false;
861
862         if(gameover)
863                 return false;
864
865         if(self.deadflag != DEAD_NO)
866                 return false;
867
868         if (!autocvar_g_nades)
869                 return false; // allow turning them off mid match
870
871         if(forbidWeaponUse(self))
872                 return false;
873
874         if (!IS_PLAYER(self))
875                 return false;
876
877         return true;
878 }
879
880 void nades_CheckThrow()
881 {
882         if(!CanThrowNade())
883                 return;
884
885         if(!self.nade)
886         {
887                 if(self.nade_refire < time)
888                 {
889                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_NADE_THROW);
890                         nade_prime();
891                         self.nade_refire = time + autocvar_g_nades_nade_refire;
892                 }
893         }
894         else
895         {
896                 if(time - self.nade.lifetime >= 1)
897                 {
898                         makevectors(self.v_angle);
899                         float _force = time - self.nade.lifetime;
900                         _force /= autocvar_g_nades_nade_lifetime;
901                         _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
902                         toss_nade(self, (v_forward * 0.75 + v_up * 0.2 + v_right * 0.05) * _force, 0);
903                 }
904         }
905 }
906
907 void nades_Clear(entity player)
908 {
909         if(player.nade)
910                 remove(player.nade);
911         if(player.fake_nade)
912                 remove(player.fake_nade);
913
914         player.nade = player.fake_nade = world;
915         player.nade_timer = 0;
916 }
917
918 MUTATOR_HOOKFUNCTION(nades_CheckThrow)
919 {
920         if(MUTATOR_RETURNVALUE) { nades_CheckThrow(); }
921         return false;
922 }
923
924 MUTATOR_HOOKFUNCTION(nades_VehicleEnter)
925 {
926         if(vh_player.nade)
927                 toss_nade(vh_player, '0 0 100', max(vh_player.nade.wait, time + 0.05));
928
929         return false;
930 }
931
932 MUTATOR_HOOKFUNCTION(nades_PlayerPreThink)
933 {
934         if(!IS_PLAYER(self)) { return false; }
935
936         float key_pressed = self.BUTTON_HOOK;
937         float time_score;
938
939         if(g_grappling_hook || client_hasweapon(self, WEP_HOOK.m_id, false, false) || (weaponsInMap & WEPSET_HOOK))
940                 key_pressed = self.button16; // if hook is enabled, use an alternate key
941
942         if(self.nade)
943         {
944                 self.nade_timer = bound(0, (time - self.nade.lifetime) / autocvar_g_nades_nade_lifetime, 1);
945                 //print(sprintf("%d %d\n", self.nade_timer, time - self.nade.lifetime));
946                 makevectors(self.angles);
947                 self.nade.velocity = self.velocity;
948
949                 setorigin(self.nade, self.origin + self.view_ofs + v_forward * 8 + v_right * -8 + v_up * 0);
950                 self.nade.angles_y = self.angles.y;
951         }
952
953         if(self.nade)
954         if(self.nade.wait - 0.1 <= time)
955                 toss_nade(self, '0 0 0', time + 0.05);
956
957         if(CanThrowNade())
958         if(self.nade_refire < time)
959         {
960                 if(key_pressed)
961                 {
962                         if(!self.nade)
963                                 nade_prime();
964                 }
965                 else if(time - self.nade.lifetime >= 1)
966                 {
967                         if(self.nade)
968                         {
969                                 makevectors(self.v_angle);
970                                 float _force = time - self.nade.lifetime;
971                                 _force /= autocvar_g_nades_nade_lifetime;
972                                 _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
973                                 toss_nade(self, (v_forward * 0.7 + v_up * 0.2 + v_right * 0.1) * _force, 0);
974                         }
975                 }
976         }
977
978         if(IS_PLAYER(self))
979         {
980                 if ( autocvar_g_nades_bonus && autocvar_g_nades )
981                 {
982                         entity key;
983                         float key_count = 0;
984                         FOR_EACH_KH_KEY(key) if(key.owner == self) { ++key_count; }
985
986                         if(self.flagcarried || self.ballcarried) // this player is important
987                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier;
988                         else
989                                 time_score = autocvar_g_nades_bonus_score_time;
990
991                         if(key_count)
992                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier * key_count; // multiply by the number of keys the player is holding
993
994                         if(autocvar_g_nades_bonus_client_select)
995                         {
996                                 self.nade_type = self.cvar_cl_nade_type;
997                                 self.pokenade_type = self.cvar_cl_pokenade_type;
998                         }
999                         else
1000                         {
1001                                 self.nade_type = autocvar_g_nades_bonus_type;
1002                                 self.pokenade_type = autocvar_g_nades_pokenade_monster_type;
1003                         }
1004
1005                         self.nade_type = bound(1, self.nade_type, NADES_COUNT);
1006
1007                         if(self.bonus_nade_score >= 0 && autocvar_g_nades_bonus_score_max)
1008                                 nades_GiveBonus(self, time_score / autocvar_g_nades_bonus_score_max);
1009                 }
1010                 else
1011                 {
1012                         self.bonus_nades = self.bonus_nade_score = 0;
1013                 }
1014         }
1015
1016         float n = 0;
1017         entity o = world;
1018         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
1019                 n = -1;
1020         else
1021         {
1022                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
1023                 n = 0;
1024                 FOR_EACH_PLAYER(other) if(self != other)
1025                 {
1026                         if(other.deadflag == DEAD_NO)
1027                         if(other.frozen == 0)
1028                         if(SAME_TEAM(other, self))
1029                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
1030                         {
1031                                 if(!o)
1032                                         o = other;
1033                                 if(self.frozen == 1)
1034                                         other.reviving = true;
1035                                 ++n;
1036                         }
1037                 }
1038         }
1039
1040         if(n && self.frozen == 3) // OK, there is at least one teammate reviving us
1041         {
1042                 self.revive_progress = bound(0, self.revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
1043                 self.health = max(1, self.revive_progress * start_health);
1044
1045                 if(self.revive_progress >= 1)
1046                 {
1047                         Unfreeze(self);
1048
1049                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
1050                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, self.netname);
1051                 }
1052
1053                 FOR_EACH_PLAYER(other) if(other.reviving)
1054                 {
1055                         other.revive_progress = self.revive_progress;
1056                         other.reviving = false;
1057                 }
1058         }
1059
1060         return false;
1061 }
1062
1063 MUTATOR_HOOKFUNCTION(nades_PlayerSpawn)
1064 {
1065         if(autocvar_g_nades_spawn)
1066                 self.nade_refire = time + autocvar_g_spawnshieldtime;
1067         else
1068                 self.nade_refire  = time + autocvar_g_nades_nade_refire;
1069
1070         if(autocvar_g_nades_bonus_client_select)
1071                 self.nade_type = self.cvar_cl_nade_type;
1072
1073         self.nade_timer = 0;
1074
1075         if(self.nade_spawnloc)
1076         {
1077                 setorigin(self, self.nade_spawnloc.origin);
1078                 self.nade_spawnloc.cnt -= 1;
1079
1080                 if(self.nade_spawnloc.cnt <= 0)
1081                 {
1082                         remove(self.nade_spawnloc);
1083                         self.nade_spawnloc = world;
1084                 }
1085         }
1086
1087         return false;
1088 }
1089
1090 MUTATOR_HOOKFUNCTION(nades_PlayerDies)
1091 {
1092         if(frag_target.nade)
1093         if(!frag_target.frozen || !autocvar_g_freezetag_revive_nade)
1094                 toss_nade(frag_target, '0 0 100', max(frag_target.nade.wait, time + 0.05));
1095
1096         float killcount_bonus = ((frag_attacker.killcount >= 1) ? bound(0, autocvar_g_nades_bonus_score_minor * frag_attacker.killcount, autocvar_g_nades_bonus_score_medium) : autocvar_g_nades_bonus_score_minor);
1097
1098         if(IS_PLAYER(frag_attacker))
1099         {
1100                 if (SAME_TEAM(frag_attacker, frag_target) || frag_attacker == frag_target)
1101                         nades_RemoveBonus(frag_attacker);
1102                 else if(frag_target.flagcarried)
1103                         nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_medium);
1104                 else if(autocvar_g_nades_bonus_score_spree && frag_attacker.killcount > 1)
1105                 {
1106                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
1107                                 case counta: { nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_spree); break; }
1108                         switch(frag_attacker.killcount)
1109                         {
1110                                 KILL_SPREE_LIST
1111                                 default: nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor); break;
1112                         }
1113                         #undef SPREE_ITEM
1114                 }
1115                 else
1116                         nades_GiveBonus(frag_attacker, killcount_bonus);
1117         }
1118
1119         nades_RemoveBonus(frag_target);
1120
1121         return false;
1122 }
1123
1124 MUTATOR_HOOKFUNCTION(nades_PlayerDamage)
1125 {
1126         if(frag_target.frozen)
1127         if(autocvar_g_freezetag_revive_nade)
1128         if(frag_attacker == frag_target)
1129         if(frag_deathtype == DEATH_NADE)
1130         if(time - frag_inflictor.toss_time <= 0.1)
1131         {
1132                 Unfreeze(frag_target);
1133                 frag_target.health = autocvar_g_freezetag_revive_nade_health;
1134                 Send_Effect(EFFECT_ICEORGLASS, frag_target.origin, '0 0 0', 3);
1135                 frag_damage = 0;
1136                 frag_force = '0 0 0';
1137                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED_NADE, frag_target.netname);
1138                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_SELF);
1139         }
1140
1141         return false;
1142 }
1143
1144 MUTATOR_HOOKFUNCTION(nades_MonsterDies)
1145 {
1146         if(IS_PLAYER(frag_attacker))
1147         if(DIFF_TEAM(frag_attacker, self))
1148         if(!(self.spawnflags & MONSTERFLAG_SPAWNED))
1149                 nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor);
1150
1151         return false;
1152 }
1153
1154 MUTATOR_HOOKFUNCTION(nades_RemovePlayer)
1155 {
1156         nades_Clear(self);
1157         nades_RemoveBonus(self);
1158         return false;
1159 }
1160
1161 MUTATOR_HOOKFUNCTION(nades_SpectateCopy)
1162 {
1163         self.nade_timer = other.nade_timer;
1164         self.nade_type = other.nade_type;
1165         self.pokenade_type = other.pokenade_type;
1166         self.bonus_nades = other.bonus_nades;
1167         self.bonus_nade_score = other.bonus_nade_score;
1168         self.stat_healing_orb = other.stat_healing_orb;
1169         self.stat_healing_orb_alpha = other.stat_healing_orb_alpha;
1170         return false;
1171 }
1172
1173 MUTATOR_HOOKFUNCTION(nades_GetCvars)
1174 {
1175         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_nade_type, "cl_nade_type");
1176         GetCvars_handleString(get_cvars_s, get_cvars_f, cvar_cl_pokenade_type, "cl_pokenade_type");
1177
1178         return false;
1179 }
1180
1181 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsString)
1182 {
1183         ret_string = strcat(ret_string, ":Nades");
1184         return false;
1185 }
1186
1187 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsPrettyString)
1188 {
1189         ret_string = strcat(ret_string, ", Nades");
1190         return false;
1191 }
1192
1193 void nades_Initialize()
1194 {
1195         addstat(STAT_NADE_TIMER, AS_FLOAT, nade_timer);
1196         addstat(STAT_NADE_BONUS, AS_FLOAT, bonus_nades);
1197         addstat(STAT_NADE_BONUS_TYPE, AS_INT, nade_type);
1198         addstat(STAT_NADE_BONUS_SCORE, AS_FLOAT, bonus_nade_score);
1199         addstat(STAT_HEALING_ORB, AS_FLOAT, stat_healing_orb);
1200         addstat(STAT_HEALING_ORB_ALPHA, AS_FLOAT, stat_healing_orb_alpha);
1201
1202         precache_model("models/ok_nade_counter/ok_nade_counter.md3");
1203         precache_model(W_Model("h_ok_grenade.iqm"));
1204         precache_model(W_Model("v_ok_grenade.md3"));
1205         precache_model("models/ctf/shield.md3");
1206
1207         precache_sound(W_Sound("rocket_impact"));
1208         precache_sound(W_Sound("grenade_bounce1"));
1209         precache_sound(W_Sound("grenade_bounce2"));
1210         precache_sound(W_Sound("grenade_bounce3"));
1211         precache_sound(W_Sound("grenade_bounce4"));
1212         precache_sound(W_Sound("grenade_bounce5"));
1213         precache_sound(W_Sound("grenade_bounce6"));
1214         precache_sound("overkill/grenadebip.ogg");
1215 }
1216
1217 MUTATOR_DEFINITION(mutator_nades)
1218 {
1219         MUTATOR_HOOK(ForbidThrowCurrentWeapon, nades_CheckThrow, CBC_ORDER_LAST);
1220         MUTATOR_HOOK(VehicleEnter, nades_VehicleEnter, CBC_ORDER_ANY);
1221         MUTATOR_HOOK(PlayerPreThink, nades_PlayerPreThink, CBC_ORDER_ANY);
1222         MUTATOR_HOOK(PlayerSpawn, nades_PlayerSpawn, CBC_ORDER_ANY);
1223         MUTATOR_HOOK(PlayerDies, nades_PlayerDies, CBC_ORDER_LAST);
1224         MUTATOR_HOOK(PlayerDamage_Calculate, nades_PlayerDamage, CBC_ORDER_ANY);
1225         MUTATOR_HOOK(MonsterDies, nades_MonsterDies, CBC_ORDER_ANY);
1226         MUTATOR_HOOK(MakePlayerObserver, nades_RemovePlayer, CBC_ORDER_ANY);
1227         MUTATOR_HOOK(ClientDisconnect, nades_RemovePlayer, CBC_ORDER_ANY);
1228         MUTATOR_HOOK(SpectateCopy, nades_SpectateCopy, CBC_ORDER_ANY);
1229         MUTATOR_HOOK(GetCvars, nades_GetCvars, CBC_ORDER_ANY);
1230         MUTATOR_HOOK(reset_map_global, nades_RemovePlayer, CBC_ORDER_ANY);
1231         MUTATOR_HOOK(BuildMutatorsString, nades_BuildMutatorsString, CBC_ORDER_ANY);
1232         MUTATOR_HOOK(BuildMutatorsPrettyString, nades_BuildMutatorsPrettyString, CBC_ORDER_ANY);
1233
1234         MUTATOR_ONADD
1235         {
1236                 nades_Initialize();
1237         }
1238
1239         return false;
1240 }