qcsrc/server/mutators/mutator_nades.qc

   1 #include "../../common/triggers/target/music.qh"
   2
   3 .entity nade_spawnloc;
   4
   5 void nade_timer_think()
   6 {
   7         self.skin = 8 - (self.owner.wait - time) / (autocvar_g_nades_nade_lifetime / 10);
   8         self.nextthink = time;
   9         if(!self.owner || wasfreed(self.owner))
  10                 remove(self);
  11 }
  12
  13 void nade_burn_spawn(entity _nade)
  14 {
  15         CSQCProjectile(_nade, true, Nade_ProjectileFromID(_nade.nade_type, true), true);
  16 }
  17
  18 void nade_spawn(entity _nade)
  19 {
  20         entity timer = spawn();
  21         setmodel(timer, "models/ok_nade_counter/ok_nade_counter.md3");
  22         setattachment(timer, _nade, "");
  23         timer.classname = "nade_timer";
  24         timer.colormap = _nade.colormap;
  25         timer.glowmod = _nade.glowmod;
  26         timer.think = nade_timer_think;
  27         timer.nextthink = time;
  28         timer.wait = _nade.wait;
  29         timer.owner = _nade;
  30         timer.skin = 10;
  31
  32         _nade.effects |= EF_LOWPRECISION;
  33
  34         CSQCProjectile(_nade, true, Nade_ProjectileFromID(_nade.nade_type, false), true);
  35 }
  36
  37 void napalm_damage(float dist, float damage, float edgedamage, float burntime)
  38 {
  39         entity e;
  40         float d;
  41         vector p;
  42
  43         if ( damage < 0 )
  44                 return;
  45
  46         RandomSelection_Init();
  47         for(e = WarpZone_FindRadius(self.origin, dist, true); e; e = e.chain)
  48                 if(e.takedamage == DAMAGE_AIM)
  49                 if(self.realowner != e || autocvar_g_nades_napalm_selfdamage)
  50                 if(!IS_PLAYER(e) || !self.realowner || DIFF_TEAM(e, self))
  51                 if(!e.frozen)
  52                 {
  53                         p = e.origin;
  54                         p.x += e.mins.x + random() * (e.maxs.x - e.mins.x);
  55                         p.y += e.mins.y + random() * (e.maxs.y - e.mins.y);
  56                         p.z += e.mins.z + random() * (e.maxs.z - e.mins.z);
  57                         d = vlen(WarpZone_UnTransformOrigin(e, self.origin) - p);
  58                         if(d < dist)
  59                         {
  60                                 e.fireball_impactvec = p;
  61                                 RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
  62                         }
  63                 }
  64         if(RandomSelection_chosen_ent)
  65         {
  66                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, self.origin) - RandomSelection_chosen_ent.fireball_impactvec);
  67                 d = damage + (edgedamage - damage) * (d / dist);
  68                 Fire_AddDamage(RandomSelection_chosen_ent, self.realowner, d * burntime, burntime, self.projectiledeathtype | HITTYPE_BOUNCE);
  69                 //trailparticles(self, particleeffectnum("fireball_laser"), self.origin, RandomSelection_chosen_ent.fireball_impactvec);
  70                 pointparticles(particleeffectnum("fireball_laser"), self.origin, RandomSelection_chosen_ent.fireball_impactvec - self.origin, 1);
  71         }
  72 }
  73
  74
  75 void napalm_ball_think()
  76 {
  77         if(round_handler_IsActive())
  78         if(!round_handler_IsRoundStarted())
  79         {
  80                 remove(self);
  81                 return;
  82         }
  83
  84         if(time > self.pushltime)
  85         {
  86                 remove(self);
  87                 return;
  88         }
  89
  90         vector midpoint = ((self.absmin + self.absmax) * 0.5);
  91         if(pointcontents(midpoint) == CONTENT_WATER)
  92         {
  93                 self.velocity = self.velocity * 0.5;
  94
  95                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
  96                         { self.velocity_z = 200; }
  97         }
  98
  99         self.angles = vectoangles(self.velocity);
 100
 101         napalm_damage(autocvar_g_nades_napalm_ball_radius,autocvar_g_nades_napalm_ball_damage,
 102                                   autocvar_g_nades_napalm_ball_damage,autocvar_g_nades_napalm_burntime);
 103
 104         self.nextthink = time + 0.1;
 105 }
 106
 107
 108 void nade_napalm_ball()
 109 {
 110         entity proj;
 111         vector kick;
 112
 113         spamsound(self, CH_SHOTS, "weapons/fireball_fire.wav", VOL_BASE, ATTEN_NORM);
 114
 115         proj = spawn ();
 116         proj.owner = self.owner;
 117         proj.realowner = self.realowner;
 118         proj.team = self.owner.team;
 119         proj.classname = "grenade";
 120         proj.bot_dodge = true;
 121         proj.bot_dodgerating = autocvar_g_nades_napalm_ball_damage;
 122         proj.movetype = MOVETYPE_BOUNCE;
 123         proj.projectiledeathtype = DEATH_NADE_NAPALM;
 124         PROJECTILE_MAKETRIGGER(proj);
 125         setmodel(proj, "null");
 126         proj.scale = 1;//0.5;
 127         setsize(proj, '-4 -4 -4', '4 4 4');
 128         setorigin(proj, self.origin);
 129         proj.think = napalm_ball_think;
 130         proj.nextthink = time;
 131         proj.damageforcescale = autocvar_g_nades_napalm_ball_damageforcescale;
 132         proj.effects = EF_LOWPRECISION | EF_FLAME;
 133
 134         kick.x =(random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 135         kick.y = (random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 136         kick.z = (random()/2+0.5) * autocvar_g_nades_napalm_ball_spread;
 137         proj.velocity = kick;
 138
 139         proj.pushltime = time + autocvar_g_nades_napalm_ball_lifetime;
 140
 141         proj.angles = vectoangles(proj.velocity);
 142         proj.flags = FL_PROJECTILE;
 143         proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
 144
 145         //CSQCProjectile(proj, true, PROJECTILE_NAPALM_FIRE, true);
 146 }
 147
 148
 149 void napalm_fountain_think()
 150 {
 151
 152         if(round_handler_IsActive())
 153         if(!round_handler_IsRoundStarted())
 154         {
 155                 remove(self);
 156                 return;
 157         }
 158
 159         if(time >= self.ltime)
 160         {
 161                 remove(self);
 162                 return;
 163         }
 164
 165         vector midpoint = ((self.absmin + self.absmax) * 0.5);
 166         if(pointcontents(midpoint) == CONTENT_WATER)
 167         {
 168                 self.velocity = self.velocity * 0.5;
 169
 170                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 171                         { self.velocity_z = 200; }
 172
 173                 UpdateCSQCProjectile(self);
 174         }
 175
 176         napalm_damage(autocvar_g_nades_napalm_fountain_radius, autocvar_g_nades_napalm_fountain_damage,
 177                 autocvar_g_nades_napalm_fountain_edgedamage, autocvar_g_nades_napalm_burntime);
 178
 179         self.nextthink = time + 0.1;
 180         if(time >= self.nade_special_time)
 181         {
 182                 self.nade_special_time = time + autocvar_g_nades_napalm_fountain_delay;
 183                 nade_napalm_ball();
 184         }
 185 }
 186
 187 void nade_napalm_boom()
 188 {
 189         entity fountain;
 190         int c;
 191         for (c = 0; c < autocvar_g_nades_napalm_ball_count; c++)
 192                 nade_napalm_ball();
 193
 194
 195         fountain = spawn();
 196         fountain.owner = self.owner;
 197         fountain.realowner = self.realowner;
 198         fountain.origin = self.origin;
 199         setorigin(fountain, fountain.origin);
 200         fountain.think = napalm_fountain_think;
 201         fountain.nextthink = time;
 202         fountain.ltime = time + autocvar_g_nades_napalm_fountain_lifetime;
 203         fountain.pushltime = fountain.ltime;
 204         fountain.team = self.team;
 205         fountain.movetype = MOVETYPE_TOSS;
 206         fountain.projectiledeathtype = DEATH_NADE_NAPALM;
 207         fountain.bot_dodge = true;
 208         fountain.bot_dodgerating = autocvar_g_nades_napalm_fountain_damage;
 209         fountain.nade_special_time = time;
 210         setsize(fountain, '-16 -16 -16', '16 16 16');
 211         CSQCProjectile(fountain, true, PROJECTILE_NAPALM_FOUNTAIN, true);
 212 }
 213
 214 void nade_ice_freeze(entity freezefield, entity frost_target, float freeze_time)
 215 {
 216         frost_target.frozen_by = freezefield.realowner;
 217         pointparticles(particleeffectnum("electro_impact"), frost_target.origin, '0 0 0', 1);
 218         Freeze(frost_target, 1/freeze_time, 3, false);
 219         if(frost_target.ballcarried)
 220         if(g_keepaway) { ka_DropEvent(frost_target); }
 221         else { DropBall(frost_target.ballcarried, frost_target.origin, frost_target.velocity);}
 222         if(frost_target.flagcarried) { ctf_Handle_Throw(frost_target, world, DROP_THROW); }
 223         if(frost_target.nade) { toss_nade(frost_target, '0 0 0', time + 0.05); }
 224
 225         kh_Key_DropAll(frost_target, false);
 226 }
 227
 228 void nade_ice_think()
 229 {
 230
 231         if(round_handler_IsActive())
 232         if(!round_handler_IsRoundStarted())
 233         {
 234                 remove(self);
 235                 return;
 236         }
 237
 238         if(time >= self.ltime)
 239         {
 240                 if ( autocvar_g_nades_ice_explode )
 241                 {
 242                         string expef;
 243                         switch(self.realowner.team)
 244                         {
 245                                 case NUM_TEAM_1: expef = "nade_red_explode"; break;
 246                                 case NUM_TEAM_2: expef = "nade_blue_explode"; break;
 247                                 case NUM_TEAM_3: expef = "nade_yellow_explode"; break;
 248                                 case NUM_TEAM_4: expef = "nade_pink_explode"; break;
 249                                 default:                 expef = "nade_neutral_explode"; break;
 250                         }
 251                         pointparticles(particleeffectnum(expef), self.origin + '0 0 1', '0 0 0', 1);
 252                         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 253
 254                         RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 255                                 autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
 256                         Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 257                                 autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
 258                 }
 259                 remove(self);
 260                 return;
 261         }
 262
 263
 264         self.nextthink = time+0.1;
 265
 266         // gaussian
 267         float randomr;
 268         randomr = random();
 269         randomr = exp(-5*randomr*randomr)*autocvar_g_nades_nade_radius;
 270         float randomw;
 271         randomw = random()*M_PI*2;
 272         vector randomp;
 273         randomp.x = randomr*cos(randomw);
 274         randomp.y = randomr*sin(randomw);
 275         randomp.z = 1;
 276         pointparticles(particleeffectnum("electro_muzzleflash"), self.origin + randomp, '0 0 0', 1);
 277
 278         if(time >= self.nade_special_time)
 279         {
 280                 self.nade_special_time = time+0.7;
 281
 282
 283                 pointparticles(particleeffectnum("electro_impact"), self.origin, '0 0 0', 1);
 284                 pointparticles(particleeffectnum("icefield"), self.origin, '0 0 0', 1);
 285         }
 286
 287
 288         float current_freeze_time = self.ltime - time - 0.1;
 289
 290         entity e;
 291         for(e = findradius(self.origin, autocvar_g_nades_nade_radius); e; e = e.chain)
 292         if(e != self)
 293         if(!autocvar_g_nades_ice_teamcheck || (DIFF_TEAM(e, self.realowner) || e == self.realowner))
 294         if(e.takedamage && e.deadflag == DEAD_NO)
 295         if(e.health > 0)
 296         if(!e.revival_time || ((time - e.revival_time) >= 1.5))
 297         if(!e.frozen)
 298         if(current_freeze_time > 0)
 299                 nade_ice_freeze(self, e, current_freeze_time);
 300 }
 301
 302 void nade_ice_boom()
 303 {
 304         entity fountain;
 305         fountain = spawn();
 306         fountain.owner = self.owner;
 307         fountain.realowner = self.realowner;
 308         fountain.origin = self.origin;
 309         setorigin(fountain, fountain.origin);
 310         fountain.think = nade_ice_think;
 311         fountain.nextthink = time;
 312         fountain.ltime = time + autocvar_g_nades_ice_freeze_time;
 313         fountain.pushltime = fountain.wait = fountain.ltime;
 314         fountain.team = self.team;
 315         fountain.movetype = MOVETYPE_TOSS;
 316         fountain.projectiledeathtype = DEATH_NADE_ICE;
 317         fountain.bot_dodge = false;
 318         setsize(fountain, '-16 -16 -16', '16 16 16');
 319         fountain.nade_special_time = time+0.3;
 320         fountain.angles = self.angles;
 321
 322         if ( autocvar_g_nades_ice_explode )
 323         {
 324                 setmodel(fountain, "models/grenademodel.md3");
 325                 entity timer = spawn();
 326                 setmodel(timer, "models/ok_nade_counter/ok_nade_counter.md3");
 327                 setattachment(timer, fountain, "");
 328                 timer.classname = "nade_timer";
 329                 timer.colormap = self.colormap;
 330                 timer.glowmod = self.glowmod;
 331                 timer.think = nade_timer_think;
 332                 timer.nextthink = time;
 333                 timer.wait = fountain.ltime;
 334                 timer.owner = fountain;
 335                 timer.skin = 10;
 336         }
 337         else
 338                 setmodel(fountain, "null");
 339 }
 340
 341 void nade_translocate_boom()
 342 {
 343         if(self.realowner.vehicle)
 344                 return;
 345
 346         vector locout = self.origin + '0 0 1' * (1 - self.realowner.mins.z - 24);
 347         tracebox(locout, self.realowner.mins, self.realowner.maxs, locout, MOVE_NOMONSTERS, self.realowner);
 348         locout = trace_endpos;
 349
 350         makevectors(self.realowner.angles);
 351
 352         entity oldself = self;
 353         self = self.realowner;
 354         MUTATOR_CALLHOOK(PortalTeleport);
 355         self.realowner = self;
 356         self = oldself;
 357
 358         TeleportPlayer(self, self.realowner, locout, self.realowner.mangle, v_forward * vlen(self.realowner.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 359 }
 360
 361 void nade_spawn_boom()
 362 {
 363         entity spawnloc = spawn();
 364         setorigin(spawnloc, self.origin);
 365         setsize(spawnloc, self.realowner.mins, self.realowner.maxs);
 366         spawnloc.movetype = MOVETYPE_NONE;
 367         spawnloc.solid = SOLID_NOT;
 368         spawnloc.drawonlytoclient = self.realowner;
 369         spawnloc.effects = EF_STARDUST;
 370         spawnloc.cnt = autocvar_g_nades_spawn_count;
 371
 372         if(self.realowner.nade_spawnloc)
 373         {
 374                 remove(self.realowner.nade_spawnloc);
 375                 self.realowner.nade_spawnloc = world;
 376         }
 377
 378         self.realowner.nade_spawnloc = spawnloc;
 379 }
 380
 381 void nade_heal_think()
 382 {
 383         if(time >= self.ltime)
 384         {
 385                 remove(self);
 386                 return;
 387         }
 388
 389         self.nextthink = time;
 390
 391         if(time >= self.nade_special_time)
 392         {
 393                 self.nade_special_time = time+0.25;
 394                 self.nade_show_particles = 1;
 395         }
 396         else
 397                 self.nade_show_particles = 0;
 398 }
 399
 400 void nade_heal_touch()
 401 {
 402         float maxhealth;
 403         float health_factor;
 404         if(IS_PLAYER(other) || (other.flags & FL_MONSTER))
 405         if(other.deadflag == DEAD_NO)
 406         if(!other.frozen)
 407         {
 408                 health_factor = autocvar_g_nades_heal_rate*frametime/2;
 409                 if ( other != self.realowner )
 410                 {
 411                         if ( SAME_TEAM(other,self) )
 412                                 health_factor *= autocvar_g_nades_heal_friend;
 413                         else
 414                                 health_factor *= autocvar_g_nades_heal_foe;
 415                 }
 416                 if ( health_factor > 0 )
 417                 {
 418                         maxhealth = (other.flags & FL_MONSTER) ? other.max_health : g_pickup_healthmega_max;
 419                         if ( other.health < maxhealth )
 420                         {
 421                                 if ( self.nade_show_particles )
 422                                         pointparticles(particleeffectnum("healing_fx"), other.origin, '0 0 0', 1);
 423                                 other.health = min(other.health+health_factor, maxhealth);
 424                         }
 425                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 426                 }
 427                 else if ( health_factor < 0 )
 428                 {
 429                         Damage(other,self,self.realowner,-health_factor,DEATH_NADE_HEAL,other.origin,'0 0 0');
 430                 }
 431
 432         }
 433
 434         if ( IS_REAL_CLIENT(other) || (other.vehicle_flags & VHF_ISVEHICLE) )
 435         {
 436                 entity show_red = (other.vehicle_flags & VHF_ISVEHICLE) ? other.owner : other;
 437                 show_red.stat_healing_orb = time+0.1;
 438                 show_red.stat_healing_orb_alpha = 0.75 * (self.ltime - time) / self.healer_lifetime;
 439         }
 440 }
 441
 442 void nade_heal_boom()
 443 {
 444         entity healer;
 445         healer = spawn();
 446         healer.owner = self.owner;
 447         healer.realowner = self.realowner;
 448         setorigin(healer, self.origin);
 449         healer.healer_lifetime = autocvar_g_nades_heal_time; // save the cvar
 450         healer.ltime = time + healer.healer_lifetime;
 451         healer.team = self.realowner.team;
 452         healer.bot_dodge = false;
 453         healer.solid = SOLID_TRIGGER;
 454         healer.touch = nade_heal_touch;
 455
 456         setmodel(healer, "models/ctf/shield.md3");
 457         healer.healer_radius = autocvar_g_nades_nade_radius;
 458         vector size = '1 1 1' * healer.healer_radius / 2;
 459         setsize(healer,-size,size);
 460
 461         Net_LinkEntity(healer, true, 0, healer_send);
 462
 463         healer.think = nade_heal_think;
 464         healer.nextthink = time;
 465         healer.SendFlags |= 1;
 466 }
 467
 468 void nade_monster_boom()
 469 {
 470         entity e = spawnmonster(self.pokenade_type, 0, self.realowner, self.realowner, self.origin, false, false, 1);
 471
 472         if(autocvar_g_nades_pokenade_monster_lifetime > 0)
 473                 e.monster_lifetime = time + autocvar_g_nades_pokenade_monster_lifetime;
 474         e.monster_skill = MONSTER_SKILL_INSANE;
 475 }
 476
 477 void nade_boom()
 478 {
 479         string expef;
 480         bool nade_blast = true;
 481
 482         switch ( self.nade_type )
 483         {
 484                 case NADE_TYPE_NAPALM:
 485                         nade_blast = autocvar_g_nades_napalm_blast;
 486                         expef = "explosion_medium";
 487                         break;
 488                 case NADE_TYPE_ICE:
 489                         nade_blast = false;
 490                         expef = "electro_combo"; // hookbomb_explode electro_combo bigplasma_impact
 491                         break;
 492                 case NADE_TYPE_TRANSLOCATE:
 493                         nade_blast = false;
 494                         expef = "";
 495                         break;
 496                 case NADE_TYPE_MONSTER:
 497                 case NADE_TYPE_SPAWN:
 498                         nade_blast = false;
 499                         switch(self.realowner.team)
 500                         {
 501                                 case NUM_TEAM_1: expef = "spawn_event_red"; break;
 502                                 case NUM_TEAM_2: expef = "spawn_event_blue"; break;
 503                                 case NUM_TEAM_3: expef = "spawn_event_yellow"; break;
 504                                 case NUM_TEAM_4: expef = "spawn_event_pink"; break;
 505                                 default: expef = "spawn_event_neutral"; break;
 506                         }
 507                         break;
 508                 case NADE_TYPE_HEAL:
 509                         nade_blast = false;
 510                         expef = "spawn_event_red";
 511                         break;
 512
 513                 default:
 514                 case NADE_TYPE_NORMAL:
 515                         switch(self.realowner.team)
 516                         {
 517                                 case NUM_TEAM_1: expef = "nade_red_explode"; break;
 518                                 case NUM_TEAM_2: expef = "nade_blue_explode"; break;
 519                                 case NUM_TEAM_3: expef = "nade_yellow_explode"; break;
 520                                 case NUM_TEAM_4: expef = "nade_pink_explode"; break;
 521                                 default:                 expef = "nade_neutral_explode"; break;
 522                         }
 523         }
 524
 525         if(expef != "")
 526                 pointparticles(particleeffectnum(expef), findbetterlocation(self.origin, 8), '0 0 0', 1);
 527
 528         sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
 529         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 530
 531         self.event_damage = func_null; // prevent somehow calling damage in the next call
 532
 533         if(nade_blast)
 534         {
 535                 RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 536                                  autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
 537                 Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage, autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
 538         }
 539
 540         if(self.takedamage)
 541         switch ( self.nade_type )
 542         {
 543                 case NADE_TYPE_NAPALM: nade_napalm_boom(); break;
 544                 case NADE_TYPE_ICE: nade_ice_boom(); break;
 545                 case NADE_TYPE_TRANSLOCATE: nade_translocate_boom(); break;
 546                 case NADE_TYPE_SPAWN: nade_spawn_boom(); break;
 547                 case NADE_TYPE_HEAL: nade_heal_boom(); break;
 548                 case NADE_TYPE_MONSTER: nade_monster_boom(); break;
 549         }
 550
 551         remove(self);
 552 }
 553
 554 void nade_touch()
 555 {
 556         /*float is_weapclip = 0;
 557         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 558         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 559         if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 560                 is_weapclip = 1;*/
 561         if(ITEM_TOUCH_NEEDKILL()) // || is_weapclip)
 562         {
 563                 remove(self);
 564                 return;
 565         }
 566
 567         PROJECTILE_TOUCH;
 568
 569         //setsize(self, '-2 -2 -2', '2 2 2');
 570         //UpdateCSQCProjectile(self);
 571         if(self.health == self.max_health)
 572         {
 573                 spamsound(self, CH_SHOTS, strcat("weapons/grenade_bounce", ftos(1 + rint(random() * 5)), ".wav"), VOL_BASE, ATTEN_NORM);
 574                 return;
 575         }
 576
 577         self.enemy = other;
 578         nade_boom();
 579 }
 580
 581 void nade_beep()
 582 {
 583         sound(self, CH_SHOTS_SINGLE, "overkill/grenadebip.ogg", VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 584         self.think = nade_boom;
 585         self.nextthink = max(self.wait, time);
 586 }
 587
 588 void nade_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 589 {
 590         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 591         {
 592                 self.takedamage = DAMAGE_NO;
 593                 nade_boom();
 594                 return;
 595         }
 596
 597         if(self.nade_type == NADE_TYPE_TRANSLOCATE || self.nade_type == NADE_TYPE_SPAWN)
 598                 return;
 599
 600         if(DEATH_ISWEAPON(deathtype, WEP_BLASTER))
 601         {
 602                 force *= 1.5;
 603                 damage = 0;
 604         }
 605
 606         if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER) && (deathtype & HITTYPE_SECONDARY))
 607         {
 608                 force *= 0.5; // too much
 609                 frag_damage = 0;
 610         }
 611
 612         if(DEATH_ISWEAPON(deathtype, WEP_VORTEX) || DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
 613         {
 614                 force *= 6;
 615                 damage = self.max_health * 0.55;
 616         }
 617
 618         if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN) || DEATH_ISWEAPON(deathtype, WEP_HMG))
 619                 damage = self.max_health * 0.1;
 620
 621         if(DEATH_ISWEAPON(deathtype, WEP_SHOCKWAVE) || DEATH_ISWEAPON(deathtype, WEP_SHOTGUN)) // WEAPONTODO
 622         if(deathtype & HITTYPE_SECONDARY)
 623         {
 624                 damage = self.max_health * 0.1;
 625                 force *= 10;
 626         }
 627         else
 628                 damage = self.max_health * 1.15;
 629
 630         self.velocity += force;
 631         UpdateCSQCProjectile(self);
 632
 633         if(damage <= 0 || ((self.flags & FL_ONGROUND) && IS_PLAYER(attacker)))
 634                 return;
 635
 636         if(self.health == self.max_health)
 637         {
 638                 sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 639                 self.nextthink = max(time + autocvar_g_nades_nade_lifetime, time);
 640                 self.think = nade_beep;
 641         }
 642
 643         self.health -= damage;
 644
 645         if ( self.nade_type != NADE_TYPE_HEAL || IS_PLAYER(attacker) )
 646                 self.realowner = attacker;
 647
 648         if(self.health <= 0)
 649                 W_PrepareExplosionByDamage(attacker, nade_boom);
 650         else
 651                 nade_burn_spawn(self);
 652 }
 653
 654 void toss_nade(entity e, vector _velocity, float _time)
 655 {
 656         if(e.nade == world)
 657                 return;
 658
 659         entity _nade = e.nade;
 660         e.nade = world;
 661
 662         remove(e.fake_nade);
 663         e.fake_nade = world;
 664
 665         makevectors(e.v_angle);
 666
 667         W_SetupShot(e, false, false, "", CH_WEAPON_A, 0);
 668
 669         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_NADES);
 670
 671         vector offset = (v_forward * autocvar_g_nades_throw_offset.x)
 672                                   + (v_right * autocvar_g_nades_throw_offset.y)
 673                                   + (v_up * autocvar_g_nades_throw_offset.z);
 674         if(autocvar_g_nades_throw_offset == '0 0 0')
 675                 offset = '0 0 0';
 676
 677         setorigin(_nade, w_shotorg + offset + (v_right * 25) * -1);
 678         //setmodel(_nade, "models/weapons/v_ok_grenade.md3");
 679         //setattachment(_nade, world, "");
 680         PROJECTILE_MAKETRIGGER(_nade);
 681         setsize(_nade, '-16 -16 -16', '16 16 16');
 682         _nade.movetype = MOVETYPE_BOUNCE;
 683
 684         tracebox(_nade.origin, _nade.mins, _nade.maxs, _nade.origin, false, _nade);
 685         if (trace_startsolid)
 686                 setorigin(_nade, e.origin);
 687
 688         if(self.v_angle.x >= 70 && self.v_angle.x <= 110 && self.BUTTON_CROUCH)
 689                 _nade.velocity = '0 0 100';
 690         else if(autocvar_g_nades_nade_newton_style == 1)
 691                 _nade.velocity = e.velocity + _velocity;
 692         else if(autocvar_g_nades_nade_newton_style == 2)
 693                 _nade.velocity = _velocity;
 694         else
 695                 _nade.velocity = W_CalculateProjectileVelocity(e.velocity, _velocity, true);
 696
 697         _nade.touch = nade_touch;
 698         _nade.health = autocvar_g_nades_nade_health;
 699         _nade.max_health = _nade.health;
 700         _nade.takedamage = DAMAGE_AIM;
 701         _nade.event_damage = nade_damage;
 702         _nade.customizeentityforclient = func_null;
 703         _nade.exteriormodeltoclient = world;
 704         _nade.traileffectnum = 0;
 705         _nade.teleportable = true;
 706         _nade.pushable = true;
 707         _nade.gravity = 1;
 708         _nade.missile_flags = MIF_SPLASH | MIF_ARC;
 709         _nade.damagedbycontents = true;
 710         _nade.angles = vectoangles(_nade.velocity);
 711         _nade.flags = FL_PROJECTILE;
 712         _nade.projectiledeathtype = DEATH_NADE;
 713         _nade.toss_time = time;
 714         _nade.solid = SOLID_CORPSE; //((_nade.nade_type == NADE_TYPE_TRANSLOCATE) ? SOLID_CORPSE : SOLID_BBOX);
 715
 716         if(_nade.nade_type == NADE_TYPE_TRANSLOCATE || _nade.nade_type == NADE_TYPE_SPAWN)
 717                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 718         else
 719                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 720
 721         nade_spawn(_nade);
 722
 723         if(_time)
 724         {
 725                 _nade.think = nade_boom;
 726                 _nade.nextthink = _time;
 727         }
 728
 729         e.nade_refire = time + autocvar_g_nades_nade_refire;
 730         e.nade_timer = 0;
 731 }
 732
 733 void nades_GiveBonus(entity player, float score)
 734 {
 735         if (autocvar_g_nades)
 736         if (autocvar_g_nades_bonus)
 737         if (IS_REAL_CLIENT(player))
 738         if (IS_PLAYER(player) && player.bonus_nades < autocvar_g_nades_bonus_max)
 739         if (player.frozen == 0)
 740         if (player.deadflag == DEAD_NO)
 741         {
 742                 if ( player.bonus_nade_score < 1 )
 743                         player.bonus_nade_score += score/autocvar_g_nades_bonus_score_max;
 744
 745                 if ( player.bonus_nade_score >= 1 )
 746                 {
 747                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_NADE_BONUS);
 748                         play2(player,"kh/alarm.wav");
 749                         player.bonus_nades++;
 750                         player.bonus_nade_score -= 1;
 751                 }
 752         }
 753 }
 754
 755 void nades_RemoveBonus(entity player)
 756 {
 757         player.bonus_nades = player.bonus_nade_score = 0;
 758 }
 759
 760 float nade_customize()
 761 {
 762         //if(IS_SPEC(other)) { return false; }
 763         if(other == self.realowner || (IS_SPEC(other) && other.enemy == self.realowner))
 764         {
 765                 // somewhat hide the model, but keep the glow
 766                 //self.effects = 0;
 767                 if(self.traileffectnum)
 768                         self.traileffectnum = 0;
 769                 self.alpha = -1;
 770         }
 771         else
 772         {
 773                 //self.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 774                 if(!self.traileffectnum)
 775                         self.traileffectnum = particleeffectnum(Nade_TrailEffect(Nade_ProjectileFromID(self.nade_type, false), self.team));
 776                 self.alpha = 1;
 777         }
 778
 779         return true;
 780 }
 781
 782 void nade_prime()
 783 {
 784         if(self.nade)
 785                 remove(self.nade);
 786
 787         if(self.fake_nade)
 788                 remove(self.fake_nade);
 789
 790         entity n = spawn(), fn = spawn();
 791
 792         n.classname = "nade";
 793         fn.classname = "fake_nade";
 794
 795         if(self.items & IT_STRENGTH && autocvar_g_nades_bonus_onstrength)
 796                 n.nade_type = self.nade_type;
 797         else if (self.bonus_nades >= 1)
 798         {
 799                 n.nade_type = self.nade_type;
 800                 n.pokenade_type = self.pokenade_type;
 801                 self.bonus_nades -= 1;
 802         }
 803         else
 804         {
 805                 n.nade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_nade_type : autocvar_g_nades_nade_type);
 806                 n.pokenade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_pokenade_type : autocvar_g_nades_pokenade_monster_type);
 807         }
 808
 809         n.nade_type = bound(1, n.nade_type, NADE_TYPE_LAST);
 810
 811         setmodel(n, "models/weapons/v_ok_grenade.md3");
 812         //setattachment(n, self, "bip01 l hand");
 813         n.exteriormodeltoclient = self;
 814         n.customizeentityforclient = nade_customize;
 815         n.traileffectnum = particleeffectnum(Nade_TrailEffect(Nade_ProjectileFromID(n.nade_type, false), self.team));
 816         n.colormod = Nade_Color(n.nade_type);
 817         n.realowner = self;
 818         n.colormap = self.colormap;
 819         n.glowmod = self.glowmod;
 820         n.wait = time + autocvar_g_nades_nade_lifetime;
 821         n.lifetime = time;
 822         n.think = nade_beep;
 823         n.nextthink = max(n.wait - 3, time);
 824         n.projectiledeathtype = DEATH_NADE;
 825
 826         setmodel(fn, "models/weapons/h_ok_grenade.iqm");
 827         setattachment(fn, self.weaponentity, "");
 828         fn.realowner = fn.owner = self;
 829         fn.colormod = Nade_Color(n.nade_type);
 830         fn.colormap = self.colormap;
 831         fn.glowmod = self.glowmod;
 832         fn.think = SUB_Remove;
 833         fn.nextthink = n.wait;
 834
 835         self.nade = n;
 836         self.fake_nade = fn;
 837 }
 838
 839 float CanThrowNade()
 840 {
 841         if(self.vehicle)
 842                 return false;
 843
 844         if(gameover)
 845                 return false;
 846
 847         if(self.deadflag != DEAD_NO)
 848                 return false;
 849
 850         if (!autocvar_g_nades)
 851                 return false; // allow turning them off mid match
 852
 853         if(forbidWeaponUse())
 854                 return false;
 855
 856         if (!IS_PLAYER(self))
 857                 return false;
 858
 859         return true;
 860 }
 861
 862 void nades_CheckThrow()
 863 {
 864         if(!CanThrowNade())
 865                 return;
 866
 867         if(!self.nade)
 868         {
 869                 if(self.nade_refire < time)
 870                 {
 871                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_NADE_THROW);
 872                         nade_prime();
 873                         self.nade_refire = time + autocvar_g_nades_nade_refire;
 874                 }
 875         }
 876         else
 877         {
 878                 if(time - self.nade.lifetime >= 1)
 879                 {
 880                         makevectors(self.v_angle);
 881                         float _force = time - self.nade.lifetime;
 882                         _force /= autocvar_g_nades_nade_lifetime;
 883                         _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
 884                         toss_nade(self, (v_forward * 0.75 + v_up * 0.2 + v_right * 0.05) * _force, 0);
 885                 }
 886         }
 887 }
 888
 889 void nades_Clear(entity player)
 890 {
 891         if(player.nade)
 892                 remove(player.nade);
 893         if(player.fake_nade)
 894                 remove(player.fake_nade);
 895
 896         player.nade = player.fake_nade = world;
 897         player.nade_timer = 0;
 898 }
 899
 900 MUTATOR_HOOKFUNCTION(nades_CheckThrow)
 901 {
 902         if(MUTATOR_RETURNVALUE) { nades_CheckThrow(); }
 903         return false;
 904 }
 905
 906 MUTATOR_HOOKFUNCTION(nades_VehicleEnter)
 907 {
 908         if(vh_player.nade)
 909                 toss_nade(vh_player, '0 0 100', max(vh_player.nade.wait, time + 0.05));
 910
 911         return false;
 912 }
 913
 914 MUTATOR_HOOKFUNCTION(nades_PlayerPreThink)
 915 {
 916         if(!IS_PLAYER(self)) { return false; }
 917
 918         float key_pressed = self.BUTTON_HOOK;
 919         float time_score;
 920
 921         if(g_grappling_hook || client_hasweapon(self, WEP_HOOK, false, false) || (weaponsInMap & WEPSET_HOOK))
 922                 key_pressed = self.button16; // if hook is enabled, use an alternate key
 923
 924         if(self.nade)
 925         {
 926                 self.nade_timer = bound(0, (time - self.nade.lifetime) / autocvar_g_nades_nade_lifetime, 1);
 927                 //print(sprintf("%d %d\n", self.nade_timer, time - self.nade.lifetime));
 928                 makevectors(self.angles);
 929                 self.nade.velocity = self.velocity;
 930
 931                 setorigin(self.nade, self.origin + self.view_ofs + v_forward * 8 + v_right * -8 + v_up * 0);
 932                 self.nade.angles_y = self.angles.y;
 933         }
 934
 935         if(self.nade)
 936         if(self.nade.wait - 0.1 <= time)
 937                 toss_nade(self, '0 0 0', time + 0.05);
 938
 939         if(CanThrowNade())
 940         if(self.nade_refire < time)
 941         {
 942                 if(key_pressed)
 943                 {
 944                         if(!self.nade)
 945                                 nade_prime();
 946                 }
 947                 else if(time - self.nade.lifetime >= 1)
 948                 {
 949                         if(self.nade)
 950                         {
 951                                 makevectors(self.v_angle);
 952                                 float _force = time - self.nade.lifetime;
 953                                 _force /= autocvar_g_nades_nade_lifetime;
 954                                 _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
 955                                 toss_nade(self, (v_forward * 0.7 + v_up * 0.2 + v_right * 0.1) * _force, 0);
 956                         }
 957                 }
 958         }
 959
 960         if(IS_PLAYER(self))
 961         {
 962                 if ( autocvar_g_nades_bonus && autocvar_g_nades )
 963                 {
 964                         entity key;
 965                         float key_count = 0;
 966                         FOR_EACH_KH_KEY(key) if(key.owner == self) { ++key_count; }
 967
 968                         if(self.flagcarried || self.ballcarried) // this player is important
 969                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier;
 970                         else
 971                                 time_score = autocvar_g_nades_bonus_score_time;
 972
 973                         if(key_count)
 974                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier * key_count; // multiply by the number of keys the player is holding
 975
 976                         if(autocvar_g_nades_bonus_client_select)
 977                         {
 978                                 self.nade_type = self.cvar_cl_nade_type;
 979                                 self.pokenade_type = self.cvar_cl_pokenade_type;
 980                         }
 981                         else
 982                         {
 983                                 self.nade_type = autocvar_g_nades_bonus_type;
 984                                 self.pokenade_type = autocvar_g_nades_pokenade_monster_type;
 985                         }
 986
 987                         self.nade_type = bound(1, self.nade_type, NADE_TYPE_LAST);
 988
 989                         if(self.bonus_nade_score >= 0 && autocvar_g_nades_bonus_score_max)
 990                                 nades_GiveBonus(self, time_score / autocvar_g_nades_bonus_score_max);
 991                 }
 992                 else
 993                 {
 994                         self.bonus_nades = self.bonus_nade_score = 0;
 995                 }
 996         }
 997
 998         float n = 0;
 999         entity o = world;
1000         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
1001                 n = -1;
1002         else
1003         {
1004                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
1005                 n = 0;
1006                 FOR_EACH_PLAYER(other) if(self != other)
1007                 {
1008                         if(other.deadflag == DEAD_NO)
1009                         if(other.frozen == 0)
1010                         if(SAME_TEAM(other, self))
1011                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
1012                         {
1013                                 if(!o)
1014                                         o = other;
1015                                 if(self.frozen == 1)
1016                                         other.reviving = true;
1017                                 ++n;
1018                         }
1019                 }
1020         }
1021
1022         if(n && self.frozen == 3) // OK, there is at least one teammate reviving us
1023         {
1024                 self.revive_progress = bound(0, self.revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
1025                 self.health = max(1, self.revive_progress * start_health);
1026
1027                 if(self.revive_progress >= 1)
1028                 {
1029                         Unfreeze(self);
1030
1031                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
1032                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, self.netname);
1033                 }
1034
1035                 FOR_EACH_PLAYER(other) if(other.reviving)
1036                 {
1037                         other.revive_progress = self.revive_progress;
1038                         other.reviving = false;
1039                 }
1040         }
1041
1042         return false;
1043 }
1044
1045 MUTATOR_HOOKFUNCTION(nades_PlayerSpawn)
1046 {
1047         if(autocvar_g_nades_spawn)
1048                 self.nade_refire = time + autocvar_g_spawnshieldtime;
1049         else
1050                 self.nade_refire  = time + autocvar_g_nades_nade_refire;
1051
1052         if(autocvar_g_nades_bonus_client_select)
1053                 self.nade_type = self.cvar_cl_nade_type;
1054
1055         self.nade_timer = 0;
1056
1057         if(self.nade_spawnloc)
1058         {
1059                 setorigin(self, self.nade_spawnloc.origin);
1060                 self.nade_spawnloc.cnt -= 1;
1061
1062                 if(self.nade_spawnloc.cnt <= 0)
1063                 {
1064                         remove(self.nade_spawnloc);
1065                         self.nade_spawnloc = world;
1066                 }
1067         }
1068
1069         return false;
1070 }
1071
1072 MUTATOR_HOOKFUNCTION(nades_PlayerDies)
1073 {
1074         if(frag_target.nade)
1075         if(!frag_target.frozen || !autocvar_g_freezetag_revive_nade)
1076                 toss_nade(frag_target, '0 0 100', max(frag_target.nade.wait, time + 0.05));
1077
1078         float killcount_bonus = ((frag_attacker.killcount >= 1) ? bound(0, autocvar_g_nades_bonus_score_minor * frag_attacker.killcount, autocvar_g_nades_bonus_score_medium) : autocvar_g_nades_bonus_score_minor);
1079
1080         if(IS_PLAYER(frag_attacker))
1081         {
1082                 if (SAME_TEAM(frag_attacker, frag_target) || frag_attacker == frag_target)
1083                         nades_RemoveBonus(frag_attacker);
1084                 else if(frag_target.flagcarried)
1085                         nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_medium);
1086                 else if(autocvar_g_nades_bonus_score_spree && frag_attacker.killcount > 1)
1087                 {
1088                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
1089                                 case counta: { nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_spree); break; }
1090                         switch(frag_attacker.killcount)
1091                         {
1092                                 KILL_SPREE_LIST
1093                                 default: nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor); break;
1094                         }
1095                         #undef SPREE_ITEM
1096                 }
1097                 else
1098                         nades_GiveBonus(frag_attacker, killcount_bonus);
1099         }
1100
1101         nades_RemoveBonus(frag_target);
1102
1103         return false;
1104 }
1105
1106 MUTATOR_HOOKFUNCTION(nades_PlayerDamage)
1107 {
1108         if(frag_target.frozen)
1109         if(autocvar_g_freezetag_revive_nade)
1110         if(frag_attacker == frag_target)
1111         if(frag_deathtype == DEATH_NADE)
1112         if(time - frag_inflictor.toss_time <= 0.1)
1113         {
1114                 Unfreeze(frag_target);
1115                 frag_target.health = autocvar_g_freezetag_revive_nade_health;
1116                 pointparticles(particleeffectnum("iceorglass"), frag_target.origin, '0 0 0', 3);
1117                 frag_damage = 0;
1118                 frag_force = '0 0 0';
1119                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED_NADE, frag_target.netname);
1120                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_SELF);
1121         }
1122
1123         return false;
1124 }
1125
1126 MUTATOR_HOOKFUNCTION(nades_MonsterDies)
1127 {
1128         if(IS_PLAYER(frag_attacker))
1129         if(DIFF_TEAM(frag_attacker, self))
1130         if(!(self.spawnflags & MONSTERFLAG_SPAWNED))
1131                 nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor);
1132
1133         return false;
1134 }
1135
1136 MUTATOR_HOOKFUNCTION(nades_RemovePlayer)
1137 {
1138         nades_Clear(self);
1139         nades_RemoveBonus(self);
1140         return false;
1141 }
1142
1143 MUTATOR_HOOKFUNCTION(nades_SpectateCopy)
1144 {
1145         self.nade_timer = other.nade_timer;
1146         self.nade_type = other.nade_type;
1147         self.pokenade_type = other.pokenade_type;
1148         self.bonus_nades = other.bonus_nades;
1149         self.bonus_nade_score = other.bonus_nade_score;
1150         self.stat_healing_orb = other.stat_healing_orb;
1151         self.stat_healing_orb_alpha = other.stat_healing_orb_alpha;
1152         return false;
1153 }
1154
1155 MUTATOR_HOOKFUNCTION(nades_GetCvars)
1156 {
1157         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_nade_type, "cl_nade_type");
1158         GetCvars_handleString(get_cvars_s, get_cvars_f, cvar_cl_pokenade_type, "cl_pokenade_type");
1159
1160         return false;
1161 }
1162
1163 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsString)
1164 {
1165         ret_string = strcat(ret_string, ":Nades");
1166         return false;
1167 }
1168
1169 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsPrettyString)
1170 {
1171         ret_string = strcat(ret_string, ", Nades");
1172         return false;
1173 }
1174
1175 void nades_Initialize()
1176 {
1177         addstat(STAT_NADE_TIMER, AS_FLOAT, nade_timer);
1178         addstat(STAT_NADE_BONUS, AS_FLOAT, bonus_nades);
1179         addstat(STAT_NADE_BONUS_TYPE, AS_INT, nade_type);
1180         addstat(STAT_NADE_BONUS_SCORE, AS_FLOAT, bonus_nade_score);
1181         addstat(STAT_HEALING_ORB, AS_FLOAT, stat_healing_orb);
1182         addstat(STAT_HEALING_ORB_ALPHA, AS_FLOAT, stat_healing_orb_alpha);
1183
1184         precache_model("models/ok_nade_counter/ok_nade_counter.md3");
1185         precache_model("models/weapons/h_ok_grenade.iqm");
1186         precache_model("models/weapons/v_ok_grenade.md3");
1187         precache_model("models/ctf/shield.md3");
1188
1189         precache_sound("weapons/rocket_impact.wav");
1190         precache_sound("weapons/grenade_bounce1.wav");
1191         precache_sound("weapons/grenade_bounce2.wav");
1192         precache_sound("weapons/grenade_bounce3.wav");
1193         precache_sound("weapons/grenade_bounce4.wav");
1194         precache_sound("weapons/grenade_bounce5.wav");
1195         precache_sound("weapons/grenade_bounce6.wav");
1196         precache_sound("overkill/grenadebip.ogg");
1197 }
1198
1199 MUTATOR_DEFINITION(mutator_nades)
1200 {
1201         MUTATOR_HOOK(ForbidThrowCurrentWeapon, nades_CheckThrow, CBC_ORDER_LAST);
1202         MUTATOR_HOOK(VehicleEnter, nades_VehicleEnter, CBC_ORDER_ANY);
1203         MUTATOR_HOOK(PlayerPreThink, nades_PlayerPreThink, CBC_ORDER_ANY);
1204         MUTATOR_HOOK(PlayerSpawn, nades_PlayerSpawn, CBC_ORDER_ANY);
1205         MUTATOR_HOOK(PlayerDies, nades_PlayerDies, CBC_ORDER_LAST);
1206         MUTATOR_HOOK(PlayerDamage_Calculate, nades_PlayerDamage, CBC_ORDER_ANY);
1207         MUTATOR_HOOK(MonsterDies, nades_MonsterDies, CBC_ORDER_ANY);
1208         MUTATOR_HOOK(MakePlayerObserver, nades_RemovePlayer, CBC_ORDER_ANY);
1209         MUTATOR_HOOK(ClientDisconnect, nades_RemovePlayer, CBC_ORDER_ANY);
1210         MUTATOR_HOOK(SpectateCopy, nades_SpectateCopy, CBC_ORDER_ANY);
1211         MUTATOR_HOOK(GetCvars, nades_GetCvars, CBC_ORDER_ANY);
1212         MUTATOR_HOOK(reset_map_global, nades_RemovePlayer, CBC_ORDER_ANY);
1213         MUTATOR_HOOK(BuildMutatorsString, nades_BuildMutatorsString, CBC_ORDER_ANY);
1214         MUTATOR_HOOK(BuildMutatorsPrettyString, nades_BuildMutatorsPrettyString, CBC_ORDER_ANY);
1215
1216         MUTATOR_ONADD
1217         {
1218                 nades_Initialize();
1219         }
1220
1221         return false;
1222 }