qcsrc/server/mutators/mutator_nades.qc

   1 .entity nade_spawnloc;
   2
   3 void nade_timer_think()
   4 {
   5         self.skin = 8 - (self.owner.wait - time) / (autocvar_g_nades_nade_lifetime / 10);
   6         self.nextthink = time;
   7         if(!self.owner || wasfreed(self.owner))
   8                 remove(self);
   9 }
  10
  11 void nade_burn_spawn(entity _nade)
  12 {
  13         CSQCProjectile(_nade, true, Nade_ProjectileFromID(_nade.nade_type, true), true);
  14 }
  15
  16 void nade_spawn(entity _nade)
  17 {
  18         entity timer = spawn();
  19         setmodel(timer, "models/ok_nade_counter/ok_nade_counter.md3");
  20         setattachment(timer, _nade, "");
  21         timer.classname = "nade_timer";
  22         timer.colormap = _nade.colormap;
  23         timer.glowmod = _nade.glowmod;
  24         timer.think = nade_timer_think;
  25         timer.nextthink = time;
  26         timer.wait = _nade.wait;
  27         timer.owner = _nade;
  28         timer.skin = 10;
  29
  30         _nade.effects |= EF_LOWPRECISION;
  31
  32         CSQCProjectile(_nade, true, Nade_ProjectileFromID(_nade.nade_type, false), true);
  33 }
  34
  35 void napalm_damage(float dist, float damage, float edgedamage, float burntime)
  36 {
  37         entity e;
  38         float d;
  39         vector p;
  40
  41         if ( damage < 0 )
  42                 return;
  43
  44         RandomSelection_Init();
  45         for(e = WarpZone_FindRadius(self.origin, dist, true); e; e = e.chain)
  46                 if(e.takedamage == DAMAGE_AIM)
  47                 if(self.realowner != e || autocvar_g_nades_napalm_selfdamage)
  48                 if(!IS_PLAYER(e) || !self.realowner || DIFF_TEAM(e, self))
  49                 if(!e.frozen)
  50                 {
  51                         p = e.origin;
  52                         p.x += e.mins.x + random() * (e.maxs.x - e.mins.x);
  53                         p.y += e.mins.y + random() * (e.maxs.y - e.mins.y);
  54                         p.z += e.mins.z + random() * (e.maxs.z - e.mins.z);
  55                         d = vlen(WarpZone_UnTransformOrigin(e, self.origin) - p);
  56                         if(d < dist)
  57                         {
  58                                 e.fireball_impactvec = p;
  59                                 RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
  60                         }
  61                 }
  62         if(RandomSelection_chosen_ent)
  63         {
  64                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, self.origin) - RandomSelection_chosen_ent.fireball_impactvec);
  65                 d = damage + (edgedamage - damage) * (d / dist);
  66                 Fire_AddDamage(RandomSelection_chosen_ent, self.realowner, d * burntime, burntime, self.projectiledeathtype | HITTYPE_BOUNCE);
  67                 //trailparticles(self, particleeffectnum("fireball_laser"), self.origin, RandomSelection_chosen_ent.fireball_impactvec);
  68                 pointparticles(particleeffectnum("fireball_laser"), self.origin, RandomSelection_chosen_ent.fireball_impactvec - self.origin, 1);
  69         }
  70 }
  71
  72
  73 void napalm_ball_think()
  74 {
  75         if(round_handler_IsActive())
  76         if(!round_handler_IsRoundStarted())
  77         {
  78                 remove(self);
  79                 return;
  80         }
  81
  82         if(time > self.pushltime)
  83         {
  84                 remove(self);
  85                 return;
  86         }
  87
  88         vector midpoint = ((self.absmin + self.absmax) * 0.5);
  89         if(pointcontents(midpoint) == CONTENT_WATER)
  90         {
  91                 self.velocity = self.velocity * 0.5;
  92
  93                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
  94                         { self.velocity_z = 200; }
  95         }
  96
  97         self.angles = vectoangles(self.velocity);
  98
  99         napalm_damage(autocvar_g_nades_napalm_ball_radius,autocvar_g_nades_napalm_ball_damage,
 100                                   autocvar_g_nades_napalm_ball_damage,autocvar_g_nades_napalm_burntime);
 101
 102         self.nextthink = time + 0.1;
 103 }
 104
 105
 106 void nade_napalm_ball()
 107 {
 108         entity proj;
 109         vector kick;
 110
 111         spamsound(self, CH_SHOTS, "weapons/fireball_fire.wav", VOL_BASE, ATTEN_NORM);
 112
 113         proj = spawn ();
 114         proj.owner = self.owner;
 115         proj.realowner = self.realowner;
 116         proj.team = self.owner.team;
 117         proj.classname = "grenade";
 118         proj.bot_dodge = true;
 119         proj.bot_dodgerating = autocvar_g_nades_napalm_ball_damage;
 120         proj.movetype = MOVETYPE_BOUNCE;
 121         proj.projectiledeathtype = DEATH_NADE_NAPALM;
 122         PROJECTILE_MAKETRIGGER(proj);
 123         setmodel(proj, "null");
 124         proj.scale = 1;//0.5;
 125         setsize(proj, '-4 -4 -4', '4 4 4');
 126         setorigin(proj, self.origin);
 127         proj.think = napalm_ball_think;
 128         proj.nextthink = time;
 129         proj.damageforcescale = autocvar_g_nades_napalm_ball_damageforcescale;
 130         proj.effects = EF_LOWPRECISION | EF_FLAME;
 131
 132         kick.x =(random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 133         kick.y = (random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 134         kick.z = (random()/2+0.5) * autocvar_g_nades_napalm_ball_spread;
 135         proj.velocity = kick;
 136
 137         proj.pushltime = time + autocvar_g_nades_napalm_ball_lifetime;
 138
 139         proj.angles = vectoangles(proj.velocity);
 140         proj.flags = FL_PROJECTILE;
 141         proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
 142
 143         //CSQCProjectile(proj, true, PROJECTILE_NAPALM_FIRE, true);
 144 }
 145
 146
 147 void napalm_fountain_think()
 148 {
 149
 150         if(round_handler_IsActive())
 151         if(!round_handler_IsRoundStarted())
 152         {
 153                 remove(self);
 154                 return;
 155         }
 156
 157         if(time >= self.ltime)
 158         {
 159                 remove(self);
 160                 return;
 161         }
 162
 163         vector midpoint = ((self.absmin + self.absmax) * 0.5);
 164         if(pointcontents(midpoint) == CONTENT_WATER)
 165         {
 166                 self.velocity = self.velocity * 0.5;
 167
 168                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 169                         { self.velocity_z = 200; }
 170
 171                 UpdateCSQCProjectile(self);
 172         }
 173
 174         napalm_damage(autocvar_g_nades_napalm_fountain_radius, autocvar_g_nades_napalm_fountain_damage,
 175                 autocvar_g_nades_napalm_fountain_edgedamage, autocvar_g_nades_napalm_burntime);
 176
 177         self.nextthink = time + 0.1;
 178         if(time >= self.nade_special_time)
 179         {
 180                 self.nade_special_time = time + autocvar_g_nades_napalm_fountain_delay;
 181                 nade_napalm_ball();
 182         }
 183 }
 184
 185 void nade_napalm_boom()
 186 {
 187         entity fountain;
 188         int c;
 189         for (c = 0; c < autocvar_g_nades_napalm_ball_count; c++)
 190                 nade_napalm_ball();
 191
 192
 193         fountain = spawn();
 194         fountain.owner = self.owner;
 195         fountain.realowner = self.realowner;
 196         fountain.origin = self.origin;
 197         setorigin(fountain, fountain.origin);
 198         fountain.think = napalm_fountain_think;
 199         fountain.nextthink = time;
 200         fountain.ltime = time + autocvar_g_nades_napalm_fountain_lifetime;
 201         fountain.pushltime = fountain.ltime;
 202         fountain.team = self.team;
 203         fountain.movetype = MOVETYPE_TOSS;
 204         fountain.projectiledeathtype = DEATH_NADE_NAPALM;
 205         fountain.bot_dodge = true;
 206         fountain.bot_dodgerating = autocvar_g_nades_napalm_fountain_damage;
 207         fountain.nade_special_time = time;
 208         setsize(fountain, '-16 -16 -16', '16 16 16');
 209         CSQCProjectile(fountain, true, PROJECTILE_NAPALM_FOUNTAIN, true);
 210 }
 211
 212 void nade_ice_freeze(entity freezefield, entity frost_target, float freeze_time)
 213 {
 214         frost_target.frozen_by = freezefield.realowner;
 215         pointparticles(particleeffectnum("electro_impact"), frost_target.origin, '0 0 0', 1);
 216         Freeze(frost_target, 1/freeze_time, 3, false);
 217         if(frost_target.ballcarried)
 218         if(g_keepaway) { ka_DropEvent(frost_target); }
 219         else { DropBall(frost_target.ballcarried, frost_target.origin, frost_target.velocity);}
 220         if(frost_target.flagcarried) { ctf_Handle_Throw(frost_target, world, DROP_THROW); }
 221         if(frost_target.nade) { toss_nade(frost_target, '0 0 0', time + 0.05); }
 222
 223         kh_Key_DropAll(frost_target, false);
 224 }
 225
 226 void nade_ice_think()
 227 {
 228
 229         if(round_handler_IsActive())
 230         if(!round_handler_IsRoundStarted())
 231         {
 232                 remove(self);
 233                 return;
 234         }
 235
 236         if(time >= self.ltime)
 237         {
 238                 if ( autocvar_g_nades_ice_explode )
 239                 {
 240                         string expef;
 241                         switch(self.realowner.team)
 242                         {
 243                                 case NUM_TEAM_1: expef = "nade_red_explode"; break;
 244                                 case NUM_TEAM_2: expef = "nade_blue_explode"; break;
 245                                 case NUM_TEAM_3: expef = "nade_yellow_explode"; break;
 246                                 case NUM_TEAM_4: expef = "nade_pink_explode"; break;
 247                                 default:                 expef = "nade_neutral_explode"; break;
 248                         }
 249                         pointparticles(particleeffectnum(expef), self.origin + '0 0 1', '0 0 0', 1);
 250                         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 251
 252                         RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 253                                 autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
 254                         Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 255                                 autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
 256                 }
 257                 remove(self);
 258                 return;
 259         }
 260
 261
 262         self.nextthink = time+0.1;
 263
 264         // gaussian
 265         float randomr;
 266         randomr = random();
 267         randomr = exp(-5*randomr*randomr)*autocvar_g_nades_nade_radius;
 268         float randomw;
 269         randomw = random()*M_PI*2;
 270         vector randomp;
 271         randomp.x = randomr*cos(randomw);
 272         randomp.y = randomr*sin(randomw);
 273         randomp.z = 1;
 274         pointparticles(particleeffectnum("electro_muzzleflash"), self.origin + randomp, '0 0 0', 1);
 275
 276         if(time >= self.nade_special_time)
 277         {
 278                 self.nade_special_time = time+0.7;
 279
 280
 281                 pointparticles(particleeffectnum("electro_impact"), self.origin, '0 0 0', 1);
 282                 pointparticles(particleeffectnum("icefield"), self.origin, '0 0 0', 1);
 283         }
 284
 285
 286         float current_freeze_time = self.ltime - time - 0.1;
 287
 288         entity e;
 289         for(e = findradius(self.origin, autocvar_g_nades_nade_radius); e; e = e.chain)
 290         if(e != self)
 291         if(!autocvar_g_nades_ice_teamcheck || (DIFF_TEAM(e, self.realowner) || e == self.realowner))
 292         if(e.takedamage && e.deadflag == DEAD_NO)
 293         if(e.health > 0)
 294         if(!e.revival_time || ((time - e.revival_time) >= 1.5))
 295         if(!e.frozen)
 296         if(current_freeze_time > 0)
 297                 nade_ice_freeze(self, e, current_freeze_time);
 298 }
 299
 300 void nade_ice_boom()
 301 {
 302         entity fountain;
 303         fountain = spawn();
 304         fountain.owner = self.owner;
 305         fountain.realowner = self.realowner;
 306         fountain.origin = self.origin;
 307         setorigin(fountain, fountain.origin);
 308         fountain.think = nade_ice_think;
 309         fountain.nextthink = time;
 310         fountain.ltime = time + autocvar_g_nades_ice_freeze_time;
 311         fountain.pushltime = fountain.wait = fountain.ltime;
 312         fountain.team = self.team;
 313         fountain.movetype = MOVETYPE_TOSS;
 314         fountain.projectiledeathtype = DEATH_NADE_ICE;
 315         fountain.bot_dodge = false;
 316         setsize(fountain, '-16 -16 -16', '16 16 16');
 317         fountain.nade_special_time = time+0.3;
 318         fountain.angles = self.angles;
 319
 320         if ( autocvar_g_nades_ice_explode )
 321         {
 322                 setmodel(fountain, "models/grenademodel.md3");
 323                 entity timer = spawn();
 324                 setmodel(timer, "models/ok_nade_counter/ok_nade_counter.md3");
 325                 setattachment(timer, fountain, "");
 326                 timer.classname = "nade_timer";
 327                 timer.colormap = self.colormap;
 328                 timer.glowmod = self.glowmod;
 329                 timer.think = nade_timer_think;
 330                 timer.nextthink = time;
 331                 timer.wait = fountain.ltime;
 332                 timer.owner = fountain;
 333                 timer.skin = 10;
 334         }
 335         else
 336                 setmodel(fountain, "null");
 337 }
 338
 339 void nade_translocate_boom()
 340 {
 341         if(self.realowner.vehicle)
 342                 return;
 343
 344         vector locout = self.origin + '0 0 1' * (1 - self.realowner.mins.z - 24);
 345         tracebox(locout, self.realowner.mins, self.realowner.maxs, locout, MOVE_NOMONSTERS, self.realowner);
 346         locout = trace_endpos;
 347
 348         makevectors(self.realowner.angles);
 349
 350         entity oldself = self;
 351         self = self.realowner;
 352         MUTATOR_CALLHOOK(PortalTeleport);
 353         self.realowner = self;
 354         self = oldself;
 355
 356         TeleportPlayer(self, self.realowner, locout, self.realowner.mangle, v_forward * vlen(self.realowner.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 357 }
 358
 359 void nade_spawn_boom()
 360 {
 361         entity spawnloc = spawn();
 362         setorigin(spawnloc, self.origin);
 363         setsize(spawnloc, self.realowner.mins, self.realowner.maxs);
 364         spawnloc.movetype = MOVETYPE_NONE;
 365         spawnloc.solid = SOLID_NOT;
 366         spawnloc.drawonlytoclient = self.realowner;
 367         spawnloc.effects = EF_STARDUST;
 368         spawnloc.cnt = autocvar_g_nades_spawn_count;
 369
 370         if(self.realowner.nade_spawnloc)
 371         {
 372                 remove(self.realowner.nade_spawnloc);
 373                 self.realowner.nade_spawnloc = world;
 374         }
 375
 376         self.realowner.nade_spawnloc = spawnloc;
 377 }
 378
 379 void nade_heal_think()
 380 {
 381         if(time >= self.ltime)
 382         {
 383                 remove(self);
 384                 return;
 385         }
 386
 387         self.nextthink = time;
 388
 389         if(time >= self.nade_special_time)
 390         {
 391                 self.nade_special_time = time+0.25;
 392                 self.nade_show_particles = 1;
 393         }
 394         else
 395                 self.nade_show_particles = 0;
 396 }
 397
 398 void nade_heal_touch()
 399 {
 400         float maxhealth;
 401         float health_factor;
 402         if(IS_PLAYER(other) || (other.flags & FL_MONSTER))
 403         if(other.deadflag == DEAD_NO)
 404         if(!other.frozen)
 405         {
 406                 health_factor = autocvar_g_nades_heal_rate*frametime/2;
 407                 if ( other != self.realowner )
 408                 {
 409                         if ( SAME_TEAM(other,self) )
 410                                 health_factor *= autocvar_g_nades_heal_friend;
 411                         else
 412                                 health_factor *= autocvar_g_nades_heal_foe;
 413                 }
 414                 if ( health_factor > 0 )
 415                 {
 416                         maxhealth = (other.flags & FL_MONSTER) ? other.max_health : g_pickup_healthmega_max;
 417                         if ( other.health < maxhealth )
 418                         {
 419                                 if ( self.nade_show_particles )
 420                                         pointparticles(particleeffectnum("healing_fx"), other.origin, '0 0 0', 1);
 421                                 other.health = min(other.health+health_factor, maxhealth);
 422                         }
 423                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 424                 }
 425                 else if ( health_factor < 0 )
 426                 {
 427                         Damage(other,self,self.realowner,-health_factor,DEATH_NADE_HEAL,other.origin,'0 0 0');
 428                 }
 429
 430         }
 431
 432         if ( IS_REAL_CLIENT(other) || (other.vehicle_flags & VHF_ISVEHICLE) )
 433         {
 434                 entity show_red = (other.vehicle_flags & VHF_ISVEHICLE) ? other.owner : other;
 435                 show_red.stat_healing_orb = time+0.1;
 436                 show_red.stat_healing_orb_alpha = 0.75 * (self.ltime - time) / self.healer_lifetime;
 437         }
 438 }
 439
 440 void nade_heal_boom()
 441 {
 442         entity healer;
 443         healer = spawn();
 444         healer.owner = self.owner;
 445         healer.realowner = self.realowner;
 446         setorigin(healer, self.origin);
 447         healer.healer_lifetime = autocvar_g_nades_heal_time; // save the cvar
 448         healer.ltime = time + healer.healer_lifetime;
 449         healer.team = self.realowner.team;
 450         healer.bot_dodge = false;
 451         healer.solid = SOLID_TRIGGER;
 452         healer.touch = nade_heal_touch;
 453
 454         setmodel(healer, "models/ctf/shield.md3");
 455         healer.healer_radius = autocvar_g_nades_nade_radius;
 456         vector size = '1 1 1' * healer.healer_radius / 2;
 457         setsize(healer,-size,size);
 458
 459         Net_LinkEntity(healer, true, 0, healer_send);
 460
 461         healer.think = nade_heal_think;
 462         healer.nextthink = time;
 463         healer.SendFlags |= 1;
 464 }
 465
 466 void nade_monster_boom()
 467 {
 468         entity e = spawnmonster(self.pokenade_type, 0, self.realowner, self.realowner, self.origin, false, false, 1);
 469
 470         if(autocvar_g_nades_pokenade_monster_lifetime > 0)
 471                 e.monster_lifetime = time + autocvar_g_nades_pokenade_monster_lifetime;
 472         e.monster_skill = MONSTER_SKILL_INSANE;
 473 }
 474
 475 void nade_boom()
 476 {
 477         string expef;
 478         float nade_blast = 1;
 479
 480         switch ( self.nade_type )
 481         {
 482                 case NADE_TYPE_NAPALM:
 483                         nade_blast = autocvar_g_nades_napalm_blast;
 484                         expef = "explosion_medium";
 485                         break;
 486                 case NADE_TYPE_ICE:
 487                         nade_blast = 0;
 488                         expef = "electro_combo"; // hookbomb_explode electro_combo bigplasma_impact
 489                         break;
 490                 case NADE_TYPE_TRANSLOCATE:
 491                         nade_blast = 0;
 492                         expef = "";
 493                         break;
 494                 case NADE_TYPE_MONSTER:
 495                 case NADE_TYPE_SPAWN:
 496                         nade_blast = 0;
 497                         switch(self.realowner.team)
 498                         {
 499                                 case NUM_TEAM_1: expef = "spawn_event_red"; break;
 500                                 case NUM_TEAM_2: expef = "spawn_event_blue"; break;
 501                                 case NUM_TEAM_3: expef = "spawn_event_yellow"; break;
 502                                 case NUM_TEAM_4: expef = "spawn_event_pink"; break;
 503                                 default: expef = "spawn_event_neutral"; break;
 504                         }
 505                         break;
 506                 case NADE_TYPE_HEAL:
 507                         nade_blast = 0;
 508                         expef = "spawn_event_red";
 509                         break;
 510
 511                 default:
 512                 case NADE_TYPE_NORMAL:
 513                         switch(self.realowner.team)
 514                         {
 515                                 case NUM_TEAM_1: expef = "nade_red_explode"; break;
 516                                 case NUM_TEAM_2: expef = "nade_blue_explode"; break;
 517                                 case NUM_TEAM_3: expef = "nade_yellow_explode"; break;
 518                                 case NUM_TEAM_4: expef = "nade_pink_explode"; break;
 519                                 default:                 expef = "nade_neutral_explode"; break;
 520                         }
 521         }
 522
 523         if(expef != "")
 524                 pointparticles(particleeffectnum(expef), findbetterlocation(self.origin, 8), '0 0 0', 1);
 525
 526         sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
 527         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 528
 529         self.event_damage = func_null; // prevent somehow calling damage in the next call
 530
 531         if(nade_blast)
 532         {
 533                 RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 534                                  autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
 535                 Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage, autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
 536         }
 537
 538         if(self.takedamage)
 539         switch ( self.nade_type )
 540         {
 541                 case NADE_TYPE_NAPALM: nade_napalm_boom(); break;
 542                 case NADE_TYPE_ICE: nade_ice_boom(); break;
 543                 case NADE_TYPE_TRANSLOCATE: nade_translocate_boom(); break;
 544                 case NADE_TYPE_SPAWN: nade_spawn_boom(); break;
 545                 case NADE_TYPE_HEAL: nade_heal_boom(); break;
 546                 case NADE_TYPE_MONSTER: nade_monster_boom(); break;
 547         }
 548
 549         remove(self);
 550 }
 551
 552 void nade_touch()
 553 {
 554         float is_weapclip = 0;
 555         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 556         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 557         if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 558                 is_weapclip = 1;
 559         if(ITEM_TOUCH_NEEDKILL() || is_weapclip)
 560         {
 561                 remove(self);
 562                 return;
 563         }
 564
 565         PROJECTILE_TOUCH;
 566
 567         //setsize(self, '-2 -2 -2', '2 2 2');
 568         //UpdateCSQCProjectile(self);
 569         if(self.health == self.max_health)
 570         {
 571                 spamsound(self, CH_SHOTS, strcat("weapons/grenade_bounce", ftos(1 + rint(random() * 5)), ".wav"), VOL_BASE, ATTEN_NORM);
 572                 return;
 573         }
 574
 575         self.enemy = other;
 576         nade_boom();
 577 }
 578
 579 void nade_beep()
 580 {
 581         sound(self, CH_SHOTS_SINGLE, "overkill/grenadebip.ogg", VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 582         self.think = nade_boom;
 583         self.nextthink = max(self.wait, time);
 584 }
 585
 586 void nade_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 587 {
 588         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 589         {
 590                 self.takedamage = DAMAGE_NO;
 591                 nade_boom();
 592                 return;
 593         }
 594
 595         if(self.nade_type == NADE_TYPE_TRANSLOCATE || self.nade_type == NADE_TYPE_SPAWN)
 596                 return;
 597
 598         if(DEATH_ISWEAPON(deathtype, WEP_BLASTER))
 599         {
 600                 force *= 1.5;
 601                 damage = 0;
 602         }
 603
 604         if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER) && (deathtype & HITTYPE_SECONDARY))
 605         {
 606                 force *= 0.5; // too much
 607                 frag_damage = 0;
 608         }
 609
 610         if(DEATH_ISWEAPON(deathtype, WEP_VORTEX) || DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
 611         {
 612                 force *= 6;
 613                 damage = self.max_health * 0.55;
 614         }
 615
 616         if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN) || DEATH_ISWEAPON(deathtype, WEP_HMG))
 617                 damage = self.max_health * 0.1;
 618
 619         if(DEATH_ISWEAPON(deathtype, WEP_SHOCKWAVE) || DEATH_ISWEAPON(deathtype, WEP_SHOTGUN)) // WEAPONTODO
 620         if(deathtype & HITTYPE_SECONDARY)
 621         {
 622                 damage = self.max_health * 0.1;
 623                 force *= 10;
 624         }
 625         else
 626                 damage = self.max_health * 1.15;
 627
 628         self.velocity += force;
 629         UpdateCSQCProjectile(self);
 630
 631         if(damage <= 0 || ((self.flags & FL_ONGROUND) && IS_PLAYER(attacker)))
 632                 return;
 633
 634         if(self.health == self.max_health)
 635         {
 636                 sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 637                 self.nextthink = max(time + autocvar_g_nades_nade_lifetime, time);
 638                 self.think = nade_beep;
 639         }
 640
 641         self.health -= damage;
 642
 643         if ( self.nade_type != NADE_TYPE_HEAL || IS_PLAYER(attacker) )
 644                 self.realowner = attacker;
 645
 646         if(self.health <= 0)
 647                 W_PrepareExplosionByDamage(attacker, nade_boom);
 648         else
 649                 nade_burn_spawn(self);
 650 }
 651
 652 void toss_nade(entity e, vector _velocity, float _time)
 653 {
 654         if(e.nade == world)
 655                 return;
 656
 657         entity _nade = e.nade;
 658         e.nade = world;
 659
 660         remove(e.fake_nade);
 661         e.fake_nade = world;
 662
 663         makevectors(e.v_angle);
 664
 665         W_SetupShot(e, false, false, "", CH_WEAPON_A, 0);
 666
 667         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_NADES);
 668
 669         setorigin(_nade, w_shotorg + (v_right * 25) * -1);
 670         //setmodel(_nade, "models/weapons/v_ok_grenade.md3");
 671         //setattachment(_nade, world, "");
 672         PROJECTILE_MAKETRIGGER(_nade);
 673         setsize(_nade, '-16 -16 -16', '16 16 16');
 674         _nade.movetype = MOVETYPE_BOUNCE;
 675
 676         tracebox(_nade.origin, _nade.mins, _nade.maxs, _nade.origin, false, _nade);
 677         if (trace_startsolid)
 678                 setorigin(_nade, e.origin);
 679
 680         if(self.v_angle.x >= 70 && self.v_angle.x <= 110)
 681                 _nade.velocity = '0 0 100';
 682         else if(autocvar_g_nades_nade_newton_style == 1)
 683                 _nade.velocity = e.velocity + _velocity;
 684         else if(autocvar_g_nades_nade_newton_style == 2)
 685                 _nade.velocity = _velocity;
 686         else
 687                 _nade.velocity = W_CalculateProjectileVelocity(e.velocity, _velocity, true);
 688
 689         _nade.touch = nade_touch;
 690         _nade.health = autocvar_g_nades_nade_health;
 691         _nade.max_health = _nade.health;
 692         _nade.takedamage = DAMAGE_AIM;
 693         _nade.event_damage = nade_damage;
 694         _nade.customizeentityforclient = func_null;
 695         _nade.exteriormodeltoclient = world;
 696         _nade.traileffectnum = 0;
 697         _nade.teleportable = true;
 698         _nade.pushable = true;
 699         _nade.gravity = 1;
 700         _nade.missile_flags = MIF_SPLASH | MIF_ARC;
 701         _nade.damagedbycontents = true;
 702         _nade.angles = vectoangles(_nade.velocity);
 703         _nade.flags = FL_PROJECTILE;
 704         _nade.projectiledeathtype = DEATH_NADE;
 705         _nade.toss_time = time;
 706         _nade.solid = SOLID_CORPSE; //((_nade.nade_type == NADE_TYPE_TRANSLOCATE) ? SOLID_CORPSE : SOLID_BBOX);
 707
 708         if(_nade.nade_type == NADE_TYPE_TRANSLOCATE || _nade.nade_type == NADE_TYPE_SPAWN)
 709                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 710         else
 711                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 712
 713         nade_spawn(_nade);
 714
 715         if(_time)
 716         {
 717                 _nade.think = nade_boom;
 718                 _nade.nextthink = _time;
 719         }
 720
 721         e.nade_refire = time + autocvar_g_nades_nade_refire;
 722         e.nade_timer = 0;
 723 }
 724
 725 void nades_GiveBonus(entity player, float score)
 726 {
 727         if (autocvar_g_nades)
 728         if (autocvar_g_nades_bonus)
 729         if (IS_REAL_CLIENT(player))
 730         if (IS_PLAYER(player) && player.bonus_nades < autocvar_g_nades_bonus_max)
 731         if (player.frozen == 0)
 732         if (player.deadflag == DEAD_NO)
 733         {
 734                 if ( player.bonus_nade_score < 1 )
 735                         player.bonus_nade_score += score/autocvar_g_nades_bonus_score_max;
 736
 737                 if ( player.bonus_nade_score >= 1 )
 738                 {
 739                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_NADE_BONUS);
 740                         play2(player,"kh/alarm.wav");
 741                         player.bonus_nades++;
 742                         player.bonus_nade_score -= 1;
 743                 }
 744         }
 745 }
 746
 747 void nades_RemoveBonus(entity player)
 748 {
 749         player.bonus_nades = player.bonus_nade_score = 0;
 750 }
 751
 752 float nade_customize()
 753 {
 754         //if(IS_SPEC(other)) { return false; }
 755         if(other == self.realowner || (IS_SPEC(other) && other.enemy == self.realowner))
 756         {
 757                 // somewhat hide the model, but keep the glow
 758                 //self.effects = 0;
 759                 if(self.traileffectnum)
 760                         self.traileffectnum = 0;
 761                 self.alpha = -1;
 762         }
 763         else
 764         {
 765                 //self.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 766                 if(!self.traileffectnum)
 767                         self.traileffectnum = particleeffectnum(Nade_TrailEffect(Nade_ProjectileFromID(self.nade_type, false), self.team));
 768                 self.alpha = 1;
 769         }
 770
 771         return true;
 772 }
 773
 774 void nade_prime()
 775 {
 776         if(self.nade)
 777                 remove(self.nade);
 778
 779         if(self.fake_nade)
 780                 remove(self.fake_nade);
 781
 782         entity n = spawn(), fn = spawn();
 783
 784         n.classname = "nade";
 785         fn.classname = "fake_nade";
 786
 787         if(self.items & IT_STRENGTH && autocvar_g_nades_bonus_onstrength)
 788                 n.nade_type = self.nade_type;
 789         else if (self.bonus_nades >= 1)
 790         {
 791                 n.nade_type = self.nade_type;
 792                 n.pokenade_type = self.pokenade_type;
 793                 self.bonus_nades -= 1;
 794         }
 795         else
 796         {
 797                 n.nade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_nade_type : autocvar_g_nades_nade_type);
 798                 n.pokenade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_pokenade_type : autocvar_g_nades_pokenade_monster_type);
 799         }
 800
 801         n.nade_type = bound(1, n.nade_type, NADE_TYPE_LAST);
 802
 803         setmodel(n, "models/weapons/v_ok_grenade.md3");
 804         //setattachment(n, self, "bip01 l hand");
 805         n.exteriormodeltoclient = self;
 806         n.customizeentityforclient = nade_customize;
 807         n.traileffectnum = particleeffectnum(Nade_TrailEffect(Nade_ProjectileFromID(n.nade_type, false), self.team));
 808         n.colormod = Nade_Color(n.nade_type);
 809         n.realowner = self;
 810         n.colormap = self.colormap;
 811         n.glowmod = self.glowmod;
 812         n.wait = time + autocvar_g_nades_nade_lifetime;
 813         n.lifetime = time;
 814         n.think = nade_beep;
 815         n.nextthink = max(n.wait - 3, time);
 816         n.projectiledeathtype = DEATH_NADE;
 817
 818         setmodel(fn, "models/weapons/h_ok_grenade.iqm");
 819         setattachment(fn, self.weaponentity, "");
 820         fn.realowner = fn.owner = self;
 821         fn.colormod = Nade_Color(n.nade_type);
 822         fn.colormap = self.colormap;
 823         fn.glowmod = self.glowmod;
 824         fn.think = SUB_Remove;
 825         fn.nextthink = n.wait;
 826
 827         self.nade = n;
 828         self.fake_nade = fn;
 829 }
 830
 831 float CanThrowNade()
 832 {
 833         if(self.vehicle)
 834                 return false;
 835
 836         if(gameover)
 837                 return false;
 838
 839         if(self.deadflag != DEAD_NO)
 840                 return false;
 841
 842         if (!autocvar_g_nades)
 843                 return false; // allow turning them off mid match
 844
 845         if(forbidWeaponUse())
 846                 return false;
 847
 848         if (!IS_PLAYER(self))
 849                 return false;
 850
 851         return true;
 852 }
 853
 854 void nades_CheckThrow()
 855 {
 856         if(!CanThrowNade())
 857                 return;
 858
 859         if(!self.nade)
 860         {
 861                 if(self.nade_refire < time)
 862                 {
 863                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_NADE_THROW);
 864                         nade_prime();
 865                         self.nade_refire = time + autocvar_g_nades_nade_refire;
 866                 }
 867         }
 868         else
 869         {
 870                 if(time - self.nade.lifetime >= 1)
 871                 {
 872                         makevectors(self.v_angle);
 873                         float _force = time - self.nade.lifetime;
 874                         _force /= autocvar_g_nades_nade_lifetime;
 875                         _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
 876                         toss_nade(self, (v_forward * 0.75 + v_up * 0.2 + v_right * 0.05) * _force, 0);
 877                 }
 878         }
 879 }
 880
 881 void nades_Clear(entity player)
 882 {
 883         if(player.nade)
 884                 remove(player.nade);
 885         if(player.fake_nade)
 886                 remove(player.fake_nade);
 887
 888         player.nade = player.fake_nade = world;
 889         player.nade_timer = 0;
 890 }
 891
 892 MUTATOR_HOOKFUNCTION(nades_CheckThrow)
 893 {
 894         if(MUTATOR_RETURNVALUE) { nades_CheckThrow(); }
 895         return false;
 896 }
 897
 898 MUTATOR_HOOKFUNCTION(nades_VehicleEnter)
 899 {
 900         if(vh_player.nade)
 901                 toss_nade(vh_player, '0 0 100', max(vh_player.nade.wait, time + 0.05));
 902
 903         return false;
 904 }
 905
 906 MUTATOR_HOOKFUNCTION(nades_PlayerPreThink)
 907 {
 908         if(!IS_PLAYER(self)) { return false; }
 909
 910         float key_pressed = self.BUTTON_HOOK;
 911         float time_score;
 912
 913         if(g_grappling_hook || client_hasweapon(self, WEP_HOOK, false, false) || (weaponsInMap & WEPSET_HOOK))
 914                 key_pressed = self.button16; // if hook is enabled, use an alternate key
 915
 916         if(self.nade)
 917         {
 918                 self.nade_timer = bound(0, (time - self.nade.lifetime) / autocvar_g_nades_nade_lifetime, 1);
 919                 //print(sprintf("%d %d\n", self.nade_timer, time - self.nade.lifetime));
 920                 makevectors(self.angles);
 921                 self.nade.velocity = self.velocity;
 922
 923                 setorigin(self.nade, self.origin + self.view_ofs + v_forward * 8 + v_right * -8 + v_up * 0);
 924                 self.nade.angles_y = self.angles.y;
 925         }
 926
 927         if(self.nade)
 928         if(self.nade.wait - 0.1 <= time)
 929                 toss_nade(self, '0 0 0', time + 0.05);
 930
 931         if(CanThrowNade())
 932         if(self.nade_refire < time)
 933         {
 934                 if(key_pressed)
 935                 {
 936                         if(!self.nade)
 937                                 nade_prime();
 938                 }
 939                 else if(time - self.nade.lifetime >= 1)
 940                 {
 941                         if(self.nade)
 942                         {
 943                                 makevectors(self.v_angle);
 944                                 float _force = time - self.nade.lifetime;
 945                                 _force /= autocvar_g_nades_nade_lifetime;
 946                                 _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
 947                                 toss_nade(self, (v_forward * 0.7 + v_up * 0.2 + v_right * 0.1) * _force, 0);
 948                         }
 949                 }
 950         }
 951
 952         if(IS_PLAYER(self))
 953         {
 954                 if ( autocvar_g_nades_bonus && autocvar_g_nades )
 955                 {
 956                         entity key;
 957                         float key_count = 0;
 958                         FOR_EACH_KH_KEY(key) if(key.owner == self) { ++key_count; }
 959
 960                         if(self.flagcarried || self.ballcarried) // this player is important
 961                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier;
 962                         else
 963                                 time_score = autocvar_g_nades_bonus_score_time;
 964
 965                         if(key_count)
 966                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier * key_count; // multiply by the number of keys the player is holding
 967
 968                         if(autocvar_g_nades_bonus_client_select)
 969                         {
 970                                 self.nade_type = self.cvar_cl_nade_type;
 971                                 self.pokenade_type = self.cvar_cl_pokenade_type;
 972                         }
 973                         else
 974                         {
 975                                 self.nade_type = autocvar_g_nades_bonus_type;
 976                                 self.pokenade_type = autocvar_g_nades_pokenade_monster_type;
 977                         }
 978
 979                         self.nade_type = bound(1, self.nade_type, NADE_TYPE_LAST);
 980
 981                         if(self.bonus_nade_score >= 0 && autocvar_g_nades_bonus_score_max)
 982                                 nades_GiveBonus(self, time_score / autocvar_g_nades_bonus_score_max);
 983                 }
 984                 else
 985                 {
 986                         self.bonus_nades = self.bonus_nade_score = 0;
 987                 }
 988         }
 989
 990         float n = 0;
 991         entity o = world;
 992         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
 993                 n = -1;
 994         else
 995         {
 996                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 997                 n = 0;
 998                 FOR_EACH_PLAYER(other) if(self != other)
 999                 {
1000                         if(other.deadflag == DEAD_NO)
1001                         if(other.frozen == 0)
1002                         if(SAME_TEAM(other, self))
1003                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
1004                         {
1005                                 if(!o)
1006                                         o = other;
1007                                 if(self.frozen == 1)
1008                                         other.reviving = true;
1009                                 ++n;
1010                         }
1011                 }
1012         }
1013
1014         if(n && self.frozen == 3) // OK, there is at least one teammate reviving us
1015         {
1016                 self.revive_progress = bound(0, self.revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
1017                 self.health = max(1, self.revive_progress * start_health);
1018
1019                 if(self.revive_progress >= 1)
1020                 {
1021                         Unfreeze(self);
1022
1023                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
1024                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, self.netname);
1025                 }
1026
1027                 FOR_EACH_PLAYER(other) if(other.reviving)
1028                 {
1029                         other.revive_progress = self.revive_progress;
1030                         other.reviving = false;
1031                 }
1032         }
1033
1034         return false;
1035 }
1036
1037 MUTATOR_HOOKFUNCTION(nades_PlayerSpawn)
1038 {
1039         if(autocvar_g_nades_spawn)
1040                 self.nade_refire = time + autocvar_g_spawnshieldtime;
1041         else
1042                 self.nade_refire  = time + autocvar_g_nades_nade_refire;
1043
1044         if(autocvar_g_nades_bonus_client_select)
1045                 self.nade_type = self.cvar_cl_nade_type;
1046
1047         self.nade_timer = 0;
1048
1049         if(self.nade_spawnloc)
1050         {
1051                 setorigin(self, self.nade_spawnloc.origin);
1052                 self.nade_spawnloc.cnt -= 1;
1053
1054                 if(self.nade_spawnloc.cnt <= 0)
1055                 {
1056                         remove(self.nade_spawnloc);
1057                         self.nade_spawnloc = world;
1058                 }
1059         }
1060
1061         return false;
1062 }
1063
1064 MUTATOR_HOOKFUNCTION(nades_PlayerDies)
1065 {
1066         if(frag_target.nade)
1067         if(!frag_target.frozen || !autocvar_g_freezetag_revive_nade)
1068                 toss_nade(frag_target, '0 0 100', max(frag_target.nade.wait, time + 0.05));
1069
1070         float killcount_bonus = ((frag_attacker.killcount >= 1) ? bound(0, autocvar_g_nades_bonus_score_minor * frag_attacker.killcount, autocvar_g_nades_bonus_score_medium) : autocvar_g_nades_bonus_score_minor);
1071
1072         if(IS_PLAYER(frag_attacker))
1073         {
1074                 if (SAME_TEAM(frag_attacker, frag_target) || frag_attacker == frag_target)
1075                         nades_RemoveBonus(frag_attacker);
1076                 else if(frag_target.flagcarried)
1077                         nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_medium);
1078                 else if(autocvar_g_nades_bonus_score_spree && frag_attacker.killcount > 1)
1079                 {
1080                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
1081                                 case counta: { nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_spree); break; }
1082                         switch(frag_attacker.killcount)
1083                         {
1084                                 KILL_SPREE_LIST
1085                                 default: nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor); break;
1086                         }
1087                         #undef SPREE_ITEM
1088                 }
1089                 else
1090                         nades_GiveBonus(frag_attacker, killcount_bonus);
1091         }
1092
1093         nades_RemoveBonus(frag_target);
1094
1095         return false;
1096 }
1097
1098 MUTATOR_HOOKFUNCTION(nades_PlayerDamage)
1099 {
1100         if(frag_target.frozen)
1101         if(autocvar_g_freezetag_revive_nade)
1102         if(frag_attacker == frag_target)
1103         if(frag_deathtype == DEATH_NADE)
1104         if(time - frag_inflictor.toss_time <= 0.1)
1105         {
1106                 Unfreeze(frag_target);
1107                 frag_target.health = autocvar_g_freezetag_revive_nade_health;
1108                 pointparticles(particleeffectnum("iceorglass"), frag_target.origin, '0 0 0', 3);
1109                 frag_damage = 0;
1110                 frag_force = '0 0 0';
1111                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED_NADE, frag_target.netname);
1112                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_SELF);
1113         }
1114
1115         return false;
1116 }
1117
1118 MUTATOR_HOOKFUNCTION(nades_MonsterDies)
1119 {
1120         if(IS_PLAYER(frag_attacker))
1121         if(DIFF_TEAM(frag_attacker, self))
1122         if(!(self.spawnflags & MONSTERFLAG_SPAWNED))
1123                 nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor);
1124
1125         return false;
1126 }
1127
1128 MUTATOR_HOOKFUNCTION(nades_RemovePlayer)
1129 {
1130         nades_Clear(self);
1131         nades_RemoveBonus(self);
1132         return false;
1133 }
1134
1135 MUTATOR_HOOKFUNCTION(nades_SpectateCopy)
1136 {
1137         self.nade_timer = other.nade_timer;
1138         self.nade_type = other.nade_type;
1139         self.pokenade_type = other.pokenade_type;
1140         self.bonus_nades = other.bonus_nades;
1141         self.bonus_nade_score = other.bonus_nade_score;
1142         self.stat_healing_orb = other.stat_healing_orb;
1143         self.stat_healing_orb_alpha = other.stat_healing_orb_alpha;
1144         return false;
1145 }
1146
1147 MUTATOR_HOOKFUNCTION(nades_GetCvars)
1148 {
1149         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_nade_type, "cl_nade_type");
1150         GetCvars_handleString(get_cvars_s, get_cvars_f, cvar_cl_pokenade_type, "cl_pokenade_type");
1151
1152         return false;
1153 }
1154
1155 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsString)
1156 {
1157         ret_string = strcat(ret_string, ":Nades");
1158         return false;
1159 }
1160
1161 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsPrettyString)
1162 {
1163         ret_string = strcat(ret_string, ", Nades");
1164         return false;
1165 }
1166
1167 void nades_Initialize()
1168 {
1169         addstat(STAT_NADE_TIMER, AS_FLOAT, nade_timer);
1170         addstat(STAT_NADE_BONUS, AS_FLOAT, bonus_nades);
1171         addstat(STAT_NADE_BONUS_TYPE, AS_INT, nade_type);
1172         addstat(STAT_NADE_BONUS_SCORE, AS_FLOAT, bonus_nade_score);
1173         addstat(STAT_HEALING_ORB, AS_FLOAT, stat_healing_orb);
1174         addstat(STAT_HEALING_ORB_ALPHA, AS_FLOAT, stat_healing_orb_alpha);
1175
1176         precache_model("models/ok_nade_counter/ok_nade_counter.md3");
1177         precache_model("models/weapons/h_ok_grenade.iqm");
1178         precache_model("models/weapons/v_ok_grenade.md3");
1179         precache_model("models/ctf/shield.md3");
1180
1181         precache_sound("weapons/rocket_impact.wav");
1182         precache_sound("weapons/grenade_bounce1.wav");
1183         precache_sound("weapons/grenade_bounce2.wav");
1184         precache_sound("weapons/grenade_bounce3.wav");
1185         precache_sound("weapons/grenade_bounce4.wav");
1186         precache_sound("weapons/grenade_bounce5.wav");
1187         precache_sound("weapons/grenade_bounce6.wav");
1188         precache_sound("overkill/grenadebip.ogg");
1189 }
1190
1191 MUTATOR_DEFINITION(mutator_nades)
1192 {
1193         MUTATOR_HOOK(ForbidThrowCurrentWeapon, nades_CheckThrow, CBC_ORDER_LAST);
1194         MUTATOR_HOOK(VehicleEnter, nades_VehicleEnter, CBC_ORDER_ANY);
1195         MUTATOR_HOOK(PlayerPreThink, nades_PlayerPreThink, CBC_ORDER_ANY);
1196         MUTATOR_HOOK(PlayerSpawn, nades_PlayerSpawn, CBC_ORDER_ANY);
1197         MUTATOR_HOOK(PlayerDies, nades_PlayerDies, CBC_ORDER_LAST);
1198         MUTATOR_HOOK(PlayerDamage_Calculate, nades_PlayerDamage, CBC_ORDER_ANY);
1199         MUTATOR_HOOK(MonsterDies, nades_MonsterDies, CBC_ORDER_ANY);
1200         MUTATOR_HOOK(MakePlayerObserver, nades_RemovePlayer, CBC_ORDER_ANY);
1201         MUTATOR_HOOK(ClientDisconnect, nades_RemovePlayer, CBC_ORDER_ANY);
1202         MUTATOR_HOOK(SpectateCopy, nades_SpectateCopy, CBC_ORDER_ANY);
1203         MUTATOR_HOOK(GetCvars, nades_GetCvars, CBC_ORDER_ANY);
1204         MUTATOR_HOOK(reset_map_global, nades_RemovePlayer, CBC_ORDER_ANY);
1205         MUTATOR_HOOK(BuildMutatorsString, nades_BuildMutatorsString, CBC_ORDER_ANY);
1206         MUTATOR_HOOK(BuildMutatorsPrettyString, nades_BuildMutatorsPrettyString, CBC_ORDER_ANY);
1207
1208         MUTATOR_ONADD
1209         {
1210                 nades_Initialize();
1211         }
1212
1213         return false;
1214 }