Merge branch 'master' into Mario/vehicles
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / mutators / mutator_nades.qc
1 #include "mutator_nades.qh"
2 #include "../_all.qh"
3
4 #include "mutator.qh"
5
6 #include "gamemode_keyhunt.qh"
7 #include "gamemode_freezetag.qh"
8 #include "../../common/nades.qh"
9 #include "../../common/monsters/spawn.qh"
10 #include "../../common/monsters/sv_monsters.qh"
11
12 .float lifetime;
13
14 .entity nade_spawnloc;
15
16 void nade_timer_think()
17 {
18         self.skin = 8 - (self.owner.wait - time) / (autocvar_g_nades_nade_lifetime / 10);
19         self.nextthink = time;
20         if(!self.owner || wasfreed(self.owner))
21                 remove(self);
22 }
23
24 void nade_burn_spawn(entity _nade)
25 {
26         CSQCProjectile(_nade, true, NADES[_nade.nade_type].m_projectile[true], true);
27 }
28
29 void nade_spawn(entity _nade)
30 {
31         entity timer = spawn();
32         setmodel(timer, "models/ok_nade_counter/ok_nade_counter.md3");
33         setattachment(timer, _nade, "");
34         timer.classname = "nade_timer";
35         timer.colormap = _nade.colormap;
36         timer.glowmod = _nade.glowmod;
37         timer.think = nade_timer_think;
38         timer.nextthink = time;
39         timer.wait = _nade.wait;
40         timer.owner = _nade;
41         timer.skin = 10;
42
43         _nade.effects |= EF_LOWPRECISION;
44
45         CSQCProjectile(_nade, true, NADES[_nade.nade_type].m_projectile[false], true);
46 }
47
48 void napalm_damage(float dist, float damage, float edgedamage, float burntime)
49 {
50         entity e;
51         float d;
52         vector p;
53
54         if ( damage < 0 )
55                 return;
56
57         RandomSelection_Init();
58         for(e = WarpZone_FindRadius(self.origin, dist, true); e; e = e.chain)
59                 if(e.takedamage == DAMAGE_AIM)
60                 if(self.realowner != e || autocvar_g_nades_napalm_selfdamage)
61                 if(!IS_PLAYER(e) || !self.realowner || DIFF_TEAM(e, self))
62                 if(!e.frozen)
63                 {
64                         p = e.origin;
65                         p.x += e.mins.x + random() * (e.maxs.x - e.mins.x);
66                         p.y += e.mins.y + random() * (e.maxs.y - e.mins.y);
67                         p.z += e.mins.z + random() * (e.maxs.z - e.mins.z);
68                         d = vlen(WarpZone_UnTransformOrigin(e, self.origin) - p);
69                         if(d < dist)
70                         {
71                                 e.fireball_impactvec = p;
72                                 RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
73                         }
74                 }
75         if(RandomSelection_chosen_ent)
76         {
77                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, self.origin) - RandomSelection_chosen_ent.fireball_impactvec);
78                 d = damage + (edgedamage - damage) * (d / dist);
79                 Fire_AddDamage(RandomSelection_chosen_ent, self.realowner, d * burntime, burntime, self.projectiledeathtype | HITTYPE_BOUNCE);
80                 //trailparticles(self, particleeffectnum("fireball_laser"), self.origin, RandomSelection_chosen_ent.fireball_impactvec);
81                 Send_Effect("fireball_laser", self.origin, RandomSelection_chosen_ent.fireball_impactvec - self.origin, 1);
82         }
83 }
84
85
86 void napalm_ball_think()
87 {
88         if(round_handler_IsActive())
89         if(!round_handler_IsRoundStarted())
90         {
91                 remove(self);
92                 return;
93         }
94
95         if(time > self.pushltime)
96         {
97                 remove(self);
98                 return;
99         }
100
101         vector midpoint = ((self.absmin + self.absmax) * 0.5);
102         if(pointcontents(midpoint) == CONTENT_WATER)
103         {
104                 self.velocity = self.velocity * 0.5;
105
106                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
107                         { self.velocity_z = 200; }
108         }
109
110         self.angles = vectoangles(self.velocity);
111
112         napalm_damage(autocvar_g_nades_napalm_ball_radius,autocvar_g_nades_napalm_ball_damage,
113                                   autocvar_g_nades_napalm_ball_damage,autocvar_g_nades_napalm_burntime);
114
115         self.nextthink = time + 0.1;
116 }
117
118
119 void nade_napalm_ball()
120 {
121         entity proj;
122         vector kick;
123
124         spamsound(self, CH_SHOTS, "weapons/fireball_fire.wav", VOL_BASE, ATTEN_NORM);
125
126         proj = spawn ();
127         proj.owner = self.owner;
128         proj.realowner = self.realowner;
129         proj.team = self.owner.team;
130         proj.classname = "grenade";
131         proj.bot_dodge = true;
132         proj.bot_dodgerating = autocvar_g_nades_napalm_ball_damage;
133         proj.movetype = MOVETYPE_BOUNCE;
134         proj.projectiledeathtype = DEATH_NADE_NAPALM;
135         PROJECTILE_MAKETRIGGER(proj);
136         setmodel(proj, "null");
137         proj.scale = 1;//0.5;
138         setsize(proj, '-4 -4 -4', '4 4 4');
139         setorigin(proj, self.origin);
140         proj.think = napalm_ball_think;
141         proj.nextthink = time;
142         proj.damageforcescale = autocvar_g_nades_napalm_ball_damageforcescale;
143         proj.effects = EF_LOWPRECISION | EF_FLAME;
144
145         kick.x =(random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
146         kick.y = (random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
147         kick.z = (random()/2+0.5) * autocvar_g_nades_napalm_ball_spread;
148         proj.velocity = kick;
149
150         proj.pushltime = time + autocvar_g_nades_napalm_ball_lifetime;
151
152         proj.angles = vectoangles(proj.velocity);
153         proj.flags = FL_PROJECTILE;
154         proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
155
156         //CSQCProjectile(proj, true, PROJECTILE_NAPALM_FIRE, true);
157 }
158
159
160 void napalm_fountain_think()
161 {
162
163         if(round_handler_IsActive())
164         if(!round_handler_IsRoundStarted())
165         {
166                 remove(self);
167                 return;
168         }
169
170         if(time >= self.ltime)
171         {
172                 remove(self);
173                 return;
174         }
175
176         vector midpoint = ((self.absmin + self.absmax) * 0.5);
177         if(pointcontents(midpoint) == CONTENT_WATER)
178         {
179                 self.velocity = self.velocity * 0.5;
180
181                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
182                         { self.velocity_z = 200; }
183
184                 UpdateCSQCProjectile(self);
185         }
186
187         napalm_damage(autocvar_g_nades_napalm_fountain_radius, autocvar_g_nades_napalm_fountain_damage,
188                 autocvar_g_nades_napalm_fountain_edgedamage, autocvar_g_nades_napalm_burntime);
189
190         self.nextthink = time + 0.1;
191         if(time >= self.nade_special_time)
192         {
193                 self.nade_special_time = time + autocvar_g_nades_napalm_fountain_delay;
194                 nade_napalm_ball();
195         }
196 }
197
198 void nade_napalm_boom()
199 {
200         entity fountain;
201         int c;
202         for (c = 0; c < autocvar_g_nades_napalm_ball_count; c++)
203                 nade_napalm_ball();
204
205
206         fountain = spawn();
207         fountain.owner = self.owner;
208         fountain.realowner = self.realowner;
209         fountain.origin = self.origin;
210         setorigin(fountain, fountain.origin);
211         fountain.think = napalm_fountain_think;
212         fountain.nextthink = time;
213         fountain.ltime = time + autocvar_g_nades_napalm_fountain_lifetime;
214         fountain.pushltime = fountain.ltime;
215         fountain.team = self.team;
216         fountain.movetype = MOVETYPE_TOSS;
217         fountain.projectiledeathtype = DEATH_NADE_NAPALM;
218         fountain.bot_dodge = true;
219         fountain.bot_dodgerating = autocvar_g_nades_napalm_fountain_damage;
220         fountain.nade_special_time = time;
221         setsize(fountain, '-16 -16 -16', '16 16 16');
222         CSQCProjectile(fountain, true, PROJECTILE_NAPALM_FOUNTAIN, true);
223 }
224
225 void nade_ice_freeze(entity freezefield, entity frost_target, float freeze_time)
226 {
227         frost_target.frozen_by = freezefield.realowner;
228         Send_Effect("electro_impact", frost_target.origin, '0 0 0', 1);
229         Freeze(frost_target, 1/freeze_time, 3, false);
230         if(frost_target.ballcarried)
231         if(g_keepaway) { ka_DropEvent(frost_target); }
232         else { DropBall(frost_target.ballcarried, frost_target.origin, frost_target.velocity);}
233         if(frost_target.flagcarried) { ctf_Handle_Throw(frost_target, world, DROP_THROW); }
234         if(frost_target.nade) { toss_nade(frost_target, '0 0 0', time + 0.05); }
235
236         kh_Key_DropAll(frost_target, false);
237 }
238
239 void nade_ice_think()
240 {
241
242         if(round_handler_IsActive())
243         if(!round_handler_IsRoundStarted())
244         {
245                 remove(self);
246                 return;
247         }
248
249         if(time >= self.ltime)
250         {
251                 if ( autocvar_g_nades_ice_explode )
252                 {
253                         string expef;
254                         switch(self.realowner.team)
255                         {
256                                 case NUM_TEAM_1: expef = "nade_red_explode"; break;
257                                 case NUM_TEAM_2: expef = "nade_blue_explode"; break;
258                                 case NUM_TEAM_3: expef = "nade_yellow_explode"; break;
259                                 case NUM_TEAM_4: expef = "nade_pink_explode"; break;
260                                 default:                 expef = "nade_neutral_explode"; break;
261                         }
262                         Send_Effect(expef, self.origin + '0 0 1', '0 0 0', 1);
263                         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
264
265                         RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
266                                 autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
267                         Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
268                                 autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
269                 }
270                 remove(self);
271                 return;
272         }
273
274
275         self.nextthink = time+0.1;
276
277         // gaussian
278         float randomr;
279         randomr = random();
280         randomr = exp(-5*randomr*randomr)*autocvar_g_nades_nade_radius;
281         float randomw;
282         randomw = random()*M_PI*2;
283         vector randomp;
284         randomp.x = randomr*cos(randomw);
285         randomp.y = randomr*sin(randomw);
286         randomp.z = 1;
287         Send_Effect("electro_muzzleflash", self.origin + randomp, '0 0 0', 1);
288
289         if(time >= self.nade_special_time)
290         {
291                 self.nade_special_time = time+0.7;
292
293
294                 Send_Effect("electro_impact", self.origin, '0 0 0', 1);
295                 Send_Effect("icefield", self.origin, '0 0 0', 1);
296         }
297
298
299         float current_freeze_time = self.ltime - time - 0.1;
300
301         entity e;
302         for(e = findradius(self.origin, autocvar_g_nades_nade_radius); e; e = e.chain)
303         if(e != self)
304         if(!autocvar_g_nades_ice_teamcheck || (DIFF_TEAM(e, self.realowner) || e == self.realowner))
305         if(e.takedamage && e.deadflag == DEAD_NO)
306         if(e.health > 0)
307         if(!e.revival_time || ((time - e.revival_time) >= 1.5))
308         if(!e.frozen)
309         if(current_freeze_time > 0)
310                 nade_ice_freeze(self, e, current_freeze_time);
311 }
312
313 void nade_ice_boom()
314 {
315         entity fountain;
316         fountain = spawn();
317         fountain.owner = self.owner;
318         fountain.realowner = self.realowner;
319         fountain.origin = self.origin;
320         setorigin(fountain, fountain.origin);
321         fountain.think = nade_ice_think;
322         fountain.nextthink = time;
323         fountain.ltime = time + autocvar_g_nades_ice_freeze_time;
324         fountain.pushltime = fountain.wait = fountain.ltime;
325         fountain.team = self.team;
326         fountain.movetype = MOVETYPE_TOSS;
327         fountain.projectiledeathtype = DEATH_NADE_ICE;
328         fountain.bot_dodge = false;
329         setsize(fountain, '-16 -16 -16', '16 16 16');
330         fountain.nade_special_time = time+0.3;
331         fountain.angles = self.angles;
332
333         if ( autocvar_g_nades_ice_explode )
334         {
335                 setmodel(fountain, "models/grenademodel.md3");
336                 entity timer = spawn();
337                 setmodel(timer, "models/ok_nade_counter/ok_nade_counter.md3");
338                 setattachment(timer, fountain, "");
339                 timer.classname = "nade_timer";
340                 timer.colormap = self.colormap;
341                 timer.glowmod = self.glowmod;
342                 timer.think = nade_timer_think;
343                 timer.nextthink = time;
344                 timer.wait = fountain.ltime;
345                 timer.owner = fountain;
346                 timer.skin = 10;
347         }
348         else
349                 setmodel(fountain, "null");
350 }
351
352 void nade_translocate_boom()
353 {
354         if(self.realowner.vehicle)
355                 return;
356
357         vector locout = self.origin + '0 0 1' * (1 - self.realowner.mins.z - 24);
358         tracebox(locout, self.realowner.mins, self.realowner.maxs, locout, MOVE_NOMONSTERS, self.realowner);
359         locout = trace_endpos;
360
361         makevectors(self.realowner.angles);
362
363         MUTATOR_CALLHOOK(PortalTeleport, self.realowner);
364
365         TeleportPlayer(self, self.realowner, locout, self.realowner.angles, v_forward * vlen(self.realowner.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
366 }
367
368 void nade_spawn_boom()
369 {
370         entity spawnloc = spawn();
371         setorigin(spawnloc, self.origin);
372         setsize(spawnloc, self.realowner.mins, self.realowner.maxs);
373         spawnloc.movetype = MOVETYPE_NONE;
374         spawnloc.solid = SOLID_NOT;
375         spawnloc.drawonlytoclient = self.realowner;
376         spawnloc.effects = EF_STARDUST;
377         spawnloc.cnt = autocvar_g_nades_spawn_count;
378
379         if(self.realowner.nade_spawnloc)
380         {
381                 remove(self.realowner.nade_spawnloc);
382                 self.realowner.nade_spawnloc = world;
383         }
384
385         self.realowner.nade_spawnloc = spawnloc;
386 }
387
388 void nade_heal_think()
389 {
390         if(time >= self.ltime)
391         {
392                 remove(self);
393                 return;
394         }
395
396         self.nextthink = time;
397
398         if(time >= self.nade_special_time)
399         {
400                 self.nade_special_time = time+0.25;
401                 self.nade_show_particles = 1;
402         }
403         else
404                 self.nade_show_particles = 0;
405 }
406
407 void nade_heal_touch()
408 {
409         float maxhealth;
410         float health_factor;
411         if(IS_PLAYER(other) || IS_MONSTER(other))
412         if(other.deadflag == DEAD_NO)
413         if(!other.frozen)
414         {
415                 health_factor = autocvar_g_nades_heal_rate*frametime/2;
416                 if ( other != self.realowner )
417                 {
418                         if ( SAME_TEAM(other,self) )
419                                 health_factor *= autocvar_g_nades_heal_friend;
420                         else
421                                 health_factor *= autocvar_g_nades_heal_foe;
422                 }
423                 if ( health_factor > 0 )
424                 {
425                         maxhealth = (IS_MONSTER(other)) ? other.max_health : g_pickup_healthmega_max;
426                         if ( other.health < maxhealth )
427                         {
428                                 if ( self.nade_show_particles )
429                                         Send_Effect("healing_fx", other.origin, '0 0 0', 1);
430                                 other.health = min(other.health+health_factor, maxhealth);
431                         }
432                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
433                 }
434                 else if ( health_factor < 0 )
435                 {
436                         Damage(other,self,self.realowner,-health_factor,DEATH_NADE_HEAL,other.origin,'0 0 0');
437                 }
438
439         }
440
441         if ( IS_REAL_CLIENT(other) || IS_VEHICLE(other) )
442         {
443                 entity show_red = (IS_VEHICLE(other)) ? other.owner : other;
444                 show_red.stat_healing_orb = time+0.1;
445                 show_red.stat_healing_orb_alpha = 0.75 * (self.ltime - time) / self.healer_lifetime;
446         }
447 }
448
449 void nade_heal_boom()
450 {
451         entity healer;
452         healer = spawn();
453         healer.owner = self.owner;
454         healer.realowner = self.realowner;
455         setorigin(healer, self.origin);
456         healer.healer_lifetime = autocvar_g_nades_heal_time; // save the cvar
457         healer.ltime = time + healer.healer_lifetime;
458         healer.team = self.realowner.team;
459         healer.bot_dodge = false;
460         healer.solid = SOLID_TRIGGER;
461         healer.touch = nade_heal_touch;
462
463         setmodel(healer, "models/ctf/shield.md3");
464         healer.healer_radius = autocvar_g_nades_nade_radius;
465         vector size = '1 1 1' * healer.healer_radius / 2;
466         setsize(healer,-size,size);
467
468         Net_LinkEntity(healer, true, 0, healer_send);
469
470         healer.think = nade_heal_think;
471         healer.nextthink = time;
472         healer.SendFlags |= 1;
473 }
474
475 void nade_monster_boom()
476 {
477         entity e = spawnmonster(self.pokenade_type, 0, self.realowner, self.realowner, self.origin, false, false, 1);
478
479         if(autocvar_g_nades_pokenade_monster_lifetime > 0)
480                 e.monster_lifetime = time + autocvar_g_nades_pokenade_monster_lifetime;
481         e.monster_skill = MONSTER_SKILL_INSANE;
482 }
483
484 void nade_boom()
485 {
486         string expef;
487         bool nade_blast = true;
488
489         switch ( NADES[self.nade_type] )
490         {
491                 case NADE_TYPE_NAPALM:
492                         nade_blast = autocvar_g_nades_napalm_blast;
493                         expef = "explosion_medium";
494                         break;
495                 case NADE_TYPE_ICE:
496                         nade_blast = false;
497                         expef = "electro_combo"; // hookbomb_explode electro_combo bigplasma_impact
498                         break;
499                 case NADE_TYPE_TRANSLOCATE:
500                         nade_blast = false;
501                         expef = "";
502                         break;
503                 case NADE_TYPE_MONSTER:
504                 case NADE_TYPE_SPAWN:
505                         nade_blast = false;
506                         switch(self.realowner.team)
507                         {
508                                 case NUM_TEAM_1: expef = "spawn_event_red"; break;
509                                 case NUM_TEAM_2: expef = "spawn_event_blue"; break;
510                                 case NUM_TEAM_3: expef = "spawn_event_yellow"; break;
511                                 case NUM_TEAM_4: expef = "spawn_event_pink"; break;
512                                 default: expef = "spawn_event_neutral"; break;
513                         }
514                         break;
515                 case NADE_TYPE_HEAL:
516                         nade_blast = false;
517                         expef = "spawn_event_red";
518                         break;
519
520                 default:
521                 case NADE_TYPE_NORMAL:
522                         switch(self.realowner.team)
523                         {
524                                 case NUM_TEAM_1: expef = "nade_red_explode"; break;
525                                 case NUM_TEAM_2: expef = "nade_blue_explode"; break;
526                                 case NUM_TEAM_3: expef = "nade_yellow_explode"; break;
527                                 case NUM_TEAM_4: expef = "nade_pink_explode"; break;
528                                 default:                 expef = "nade_neutral_explode"; break;
529                         }
530         }
531
532         if(expef != "")
533                 Send_Effect(expef, findbetterlocation(self.origin, 8), '0 0 0', 1);
534
535         sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
536         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
537
538         self.event_damage = func_null; // prevent somehow calling damage in the next call
539
540         if(nade_blast)
541         {
542                 RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
543                                  autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
544                 Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage, autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
545         }
546
547         if(self.takedamage)
548         switch ( NADES[self.nade_type] )
549         {
550                 case NADE_TYPE_NAPALM: nade_napalm_boom(); break;
551                 case NADE_TYPE_ICE: nade_ice_boom(); break;
552                 case NADE_TYPE_TRANSLOCATE: nade_translocate_boom(); break;
553                 case NADE_TYPE_SPAWN: nade_spawn_boom(); break;
554                 case NADE_TYPE_HEAL: nade_heal_boom(); break;
555                 case NADE_TYPE_MONSTER: nade_monster_boom(); break;
556         }
557
558         remove(self);
559 }
560
561 void nade_touch()
562 {
563         /*float is_weapclip = 0;
564         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
565         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
566         if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
567                 is_weapclip = 1;*/
568         if(ITEM_TOUCH_NEEDKILL()) // || is_weapclip)
569         {
570                 remove(self);
571                 return;
572         }
573
574         PROJECTILE_TOUCH;
575
576         //setsize(self, '-2 -2 -2', '2 2 2');
577         //UpdateCSQCProjectile(self);
578         if(self.health == self.max_health)
579         {
580                 spamsound(self, CH_SHOTS, strcat("weapons/grenade_bounce", ftos(1 + rint(random() * 5)), ".wav"), VOL_BASE, ATTEN_NORM);
581                 return;
582         }
583
584         self.enemy = other;
585         nade_boom();
586 }
587
588 void nade_beep()
589 {
590         sound(self, CH_SHOTS_SINGLE, "overkill/grenadebip.ogg", VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
591         self.think = nade_boom;
592         self.nextthink = max(self.wait, time);
593 }
594
595 void nade_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
596 {
597         if(ITEM_DAMAGE_NEEDKILL(deathtype))
598         {
599                 self.takedamage = DAMAGE_NO;
600                 nade_boom();
601                 return;
602         }
603
604         if(self.nade_type == NADE_TYPE_TRANSLOCATE.m_id || self.nade_type == NADE_TYPE_SPAWN.m_id)
605                 return;
606
607         if(DEATH_ISWEAPON(deathtype, WEP_BLASTER.m_id))
608         {
609                 force *= 1.5;
610                 damage = 0;
611         }
612
613         if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER.m_id) && (deathtype & HITTYPE_SECONDARY))
614         {
615                 force *= 0.5; // too much
616                 frag_damage = 0;
617         }
618
619         if(DEATH_ISWEAPON(deathtype, WEP_VORTEX.m_id) || DEATH_ISWEAPON(deathtype, WEP_VAPORIZER.m_id))
620         {
621                 force *= 6;
622                 damage = self.max_health * 0.55;
623         }
624
625         if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN.m_id) || DEATH_ISWEAPON(deathtype, WEP_HMG.m_id))
626                 damage = self.max_health * 0.1;
627
628         if(DEATH_ISWEAPON(deathtype, WEP_SHOCKWAVE.m_id) || DEATH_ISWEAPON(deathtype, WEP_SHOTGUN.m_id)) // WEAPONTODO
629         if(deathtype & HITTYPE_SECONDARY)
630         {
631                 damage = self.max_health * 0.1;
632                 force *= 10;
633         }
634         else
635                 damage = self.max_health * 1.15;
636
637         self.velocity += force;
638         UpdateCSQCProjectile(self);
639
640         if(damage <= 0 || ((self.flags & FL_ONGROUND) && IS_PLAYER(attacker)))
641                 return;
642
643         if(self.health == self.max_health)
644         {
645                 sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
646                 self.nextthink = max(time + autocvar_g_nades_nade_lifetime, time);
647                 self.think = nade_beep;
648         }
649
650         self.health -= damage;
651
652         if ( self.nade_type != NADE_TYPE_HEAL.m_id || IS_PLAYER(attacker) )
653                 self.realowner = attacker;
654
655         if(self.health <= 0)
656                 W_PrepareExplosionByDamage(attacker, nade_boom);
657         else
658                 nade_burn_spawn(self);
659 }
660
661 void toss_nade(entity e, vector _velocity, float _time)
662 {
663         if(e.nade == world)
664                 return;
665
666         entity _nade = e.nade;
667         e.nade = world;
668
669         remove(e.fake_nade);
670         e.fake_nade = world;
671
672         makevectors(e.v_angle);
673
674         W_SetupShot(e, false, false, "", CH_WEAPON_A, 0);
675
676         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_NADES);
677
678         vector offset = (v_forward * autocvar_g_nades_throw_offset.x)
679                                   + (v_right * autocvar_g_nades_throw_offset.y)
680                                   + (v_up * autocvar_g_nades_throw_offset.z);
681         if(autocvar_g_nades_throw_offset == '0 0 0')
682                 offset = '0 0 0';
683
684         setorigin(_nade, w_shotorg + offset + (v_right * 25) * -1);
685         //setmodel(_nade, "models/weapons/v_ok_grenade.md3");
686         //setattachment(_nade, world, "");
687         PROJECTILE_MAKETRIGGER(_nade);
688         setsize(_nade, '-16 -16 -16', '16 16 16');
689         _nade.movetype = MOVETYPE_BOUNCE;
690
691         tracebox(_nade.origin, _nade.mins, _nade.maxs, _nade.origin, false, _nade);
692         if (trace_startsolid)
693                 setorigin(_nade, e.origin);
694
695         if(self.v_angle.x >= 70 && self.v_angle.x <= 110 && self.BUTTON_CROUCH)
696                 _nade.velocity = '0 0 100';
697         else if(autocvar_g_nades_nade_newton_style == 1)
698                 _nade.velocity = e.velocity + _velocity;
699         else if(autocvar_g_nades_nade_newton_style == 2)
700                 _nade.velocity = _velocity;
701         else
702                 _nade.velocity = W_CalculateProjectileVelocity(e.velocity, _velocity, true);
703
704         _nade.touch = nade_touch;
705         _nade.health = autocvar_g_nades_nade_health;
706         _nade.max_health = _nade.health;
707         _nade.takedamage = DAMAGE_AIM;
708         _nade.event_damage = nade_damage;
709         _nade.customizeentityforclient = func_null;
710         _nade.exteriormodeltoclient = world;
711         _nade.traileffectnum = 0;
712         _nade.teleportable = true;
713         _nade.pushable = true;
714         _nade.gravity = 1;
715         _nade.missile_flags = MIF_SPLASH | MIF_ARC;
716         _nade.damagedbycontents = true;
717         _nade.angles = vectoangles(_nade.velocity);
718         _nade.flags = FL_PROJECTILE;
719         _nade.projectiledeathtype = DEATH_NADE;
720         _nade.toss_time = time;
721         _nade.solid = SOLID_CORPSE; //((_nade.nade_type == NADE_TYPE_TRANSLOCATE) ? SOLID_CORPSE : SOLID_BBOX);
722
723         if(_nade.nade_type == NADE_TYPE_TRANSLOCATE.m_id || _nade.nade_type == NADE_TYPE_SPAWN.m_id)
724                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
725         else
726                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
727
728         nade_spawn(_nade);
729
730         if(_time)
731         {
732                 _nade.think = nade_boom;
733                 _nade.nextthink = _time;
734         }
735
736         e.nade_refire = time + autocvar_g_nades_nade_refire;
737         e.nade_timer = 0;
738 }
739
740 void nades_GiveBonus(entity player, float score)
741 {
742         if (autocvar_g_nades)
743         if (autocvar_g_nades_bonus)
744         if (IS_REAL_CLIENT(player))
745         if (IS_PLAYER(player) && player.bonus_nades < autocvar_g_nades_bonus_max)
746         if (player.frozen == 0)
747         if (player.deadflag == DEAD_NO)
748         {
749                 if ( player.bonus_nade_score < 1 )
750                         player.bonus_nade_score += score/autocvar_g_nades_bonus_score_max;
751
752                 if ( player.bonus_nade_score >= 1 )
753                 {
754                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_NADE_BONUS);
755                         play2(player,"kh/alarm.wav");
756                         player.bonus_nades++;
757                         player.bonus_nade_score -= 1;
758                 }
759         }
760 }
761
762 void nades_RemoveBonus(entity player)
763 {
764         player.bonus_nades = player.bonus_nade_score = 0;
765 }
766
767 float nade_customize()
768 {
769         //if(IS_SPEC(other)) { return false; }
770         if(other == self.realowner || (IS_SPEC(other) && other.enemy == self.realowner))
771         {
772                 // somewhat hide the model, but keep the glow
773                 //self.effects = 0;
774                 if(self.traileffectnum)
775                         self.traileffectnum = 0;
776                 self.alpha = -1;
777         }
778         else
779         {
780                 //self.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
781                 if(!self.traileffectnum)
782                         self.traileffectnum = particleeffectnum(Nade_TrailEffect(NADES[self.nade_type].m_projectile[false], self.team));
783                 self.alpha = 1;
784         }
785
786         return true;
787 }
788
789 void nade_prime()
790 {
791         if(self.nade)
792                 remove(self.nade);
793
794         if(self.fake_nade)
795                 remove(self.fake_nade);
796
797         entity n = spawn(), fn = spawn();
798
799         n.classname = "nade";
800         fn.classname = "fake_nade";
801
802         if(self.items & ITEM_Strength.m_itemid && autocvar_g_nades_bonus_onstrength)
803                 n.nade_type = self.nade_type;
804         else if (self.bonus_nades >= 1)
805         {
806                 n.nade_type = self.nade_type;
807                 n.pokenade_type = self.pokenade_type;
808                 self.bonus_nades -= 1;
809         }
810         else
811         {
812                 n.nade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_nade_type : autocvar_g_nades_nade_type);
813                 n.pokenade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_pokenade_type : autocvar_g_nades_pokenade_monster_type);
814         }
815
816         n.nade_type = bound(1, n.nade_type, NADES_COUNT);
817
818         setmodel(n, "models/weapons/v_ok_grenade.md3");
819         //setattachment(n, self, "bip01 l hand");
820         n.exteriormodeltoclient = self;
821         n.customizeentityforclient = nade_customize;
822         n.traileffectnum = particleeffectnum(Nade_TrailEffect(NADES[n.nade_type].m_projectile[false], self.team));
823         n.colormod = NADES[n.nade_type].m_color;
824         n.realowner = self;
825         n.colormap = self.colormap;
826         n.glowmod = self.glowmod;
827         n.wait = time + autocvar_g_nades_nade_lifetime;
828         n.lifetime = time;
829         n.think = nade_beep;
830         n.nextthink = max(n.wait - 3, time);
831         n.projectiledeathtype = DEATH_NADE;
832
833         setmodel(fn, "models/weapons/h_ok_grenade.iqm");
834         setattachment(fn, self.weaponentity, "");
835         fn.realowner = fn.owner = self;
836         fn.colormod = NADES[n.nade_type].m_color;
837         fn.colormap = self.colormap;
838         fn.glowmod = self.glowmod;
839         fn.think = SUB_Remove;
840         fn.nextthink = n.wait;
841
842         self.nade = n;
843         self.fake_nade = fn;
844 }
845
846 float CanThrowNade()
847 {
848         if(self.vehicle)
849                 return false;
850
851         if(gameover)
852                 return false;
853
854         if(self.deadflag != DEAD_NO)
855                 return false;
856
857         if (!autocvar_g_nades)
858                 return false; // allow turning them off mid match
859
860         if(forbidWeaponUse(self))
861                 return false;
862
863         if (!IS_PLAYER(self))
864                 return false;
865
866         return true;
867 }
868
869 void nades_CheckThrow()
870 {
871         if(!CanThrowNade())
872                 return;
873
874         if(!self.nade)
875         {
876                 if(self.nade_refire < time)
877                 {
878                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_NADE_THROW);
879                         nade_prime();
880                         self.nade_refire = time + autocvar_g_nades_nade_refire;
881                 }
882         }
883         else
884         {
885                 if(time - self.nade.lifetime >= 1)
886                 {
887                         makevectors(self.v_angle);
888                         float _force = time - self.nade.lifetime;
889                         _force /= autocvar_g_nades_nade_lifetime;
890                         _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
891                         toss_nade(self, (v_forward * 0.75 + v_up * 0.2 + v_right * 0.05) * _force, 0);
892                 }
893         }
894 }
895
896 void nades_Clear(entity player)
897 {
898         if(player.nade)
899                 remove(player.nade);
900         if(player.fake_nade)
901                 remove(player.fake_nade);
902
903         player.nade = player.fake_nade = world;
904         player.nade_timer = 0;
905 }
906
907 MUTATOR_HOOKFUNCTION(nades_CheckThrow)
908 {
909         if(MUTATOR_RETURNVALUE) { nades_CheckThrow(); }
910         return false;
911 }
912
913 MUTATOR_HOOKFUNCTION(nades_VehicleEnter)
914 {
915         if(vh_player.nade)
916                 toss_nade(vh_player, '0 0 100', max(vh_player.nade.wait, time + 0.05));
917
918         return false;
919 }
920
921 MUTATOR_HOOKFUNCTION(nades_PlayerPreThink)
922 {
923         if(!IS_PLAYER(self)) { return false; }
924
925         float key_pressed = self.BUTTON_HOOK;
926         float time_score;
927
928         if(g_grappling_hook || client_hasweapon(self, WEP_HOOK.m_id, false, false) || (weaponsInMap & WEPSET_HOOK))
929                 key_pressed = self.button16; // if hook is enabled, use an alternate key
930
931         if(self.nade)
932         {
933                 self.nade_timer = bound(0, (time - self.nade.lifetime) / autocvar_g_nades_nade_lifetime, 1);
934                 //print(sprintf("%d %d\n", self.nade_timer, time - self.nade.lifetime));
935                 makevectors(self.angles);
936                 self.nade.velocity = self.velocity;
937
938                 setorigin(self.nade, self.origin + self.view_ofs + v_forward * 8 + v_right * -8 + v_up * 0);
939                 self.nade.angles_y = self.angles.y;
940         }
941
942         if(self.nade)
943         if(self.nade.wait - 0.1 <= time)
944                 toss_nade(self, '0 0 0', time + 0.05);
945
946         if(CanThrowNade())
947         if(self.nade_refire < time)
948         {
949                 if(key_pressed)
950                 {
951                         if(!self.nade)
952                                 nade_prime();
953                 }
954                 else if(time - self.nade.lifetime >= 1)
955                 {
956                         if(self.nade)
957                         {
958                                 makevectors(self.v_angle);
959                                 float _force = time - self.nade.lifetime;
960                                 _force /= autocvar_g_nades_nade_lifetime;
961                                 _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
962                                 toss_nade(self, (v_forward * 0.7 + v_up * 0.2 + v_right * 0.1) * _force, 0);
963                         }
964                 }
965         }
966
967         if(IS_PLAYER(self))
968         {
969                 if ( autocvar_g_nades_bonus && autocvar_g_nades )
970                 {
971                         entity key;
972                         float key_count = 0;
973                         FOR_EACH_KH_KEY(key) if(key.owner == self) { ++key_count; }
974
975                         if(self.flagcarried || self.ballcarried) // this player is important
976                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier;
977                         else
978                                 time_score = autocvar_g_nades_bonus_score_time;
979
980                         if(key_count)
981                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier * key_count; // multiply by the number of keys the player is holding
982
983                         if(autocvar_g_nades_bonus_client_select)
984                         {
985                                 self.nade_type = self.cvar_cl_nade_type;
986                                 self.pokenade_type = self.cvar_cl_pokenade_type;
987                         }
988                         else
989                         {
990                                 self.nade_type = autocvar_g_nades_bonus_type;
991                                 self.pokenade_type = autocvar_g_nades_pokenade_monster_type;
992                         }
993
994                         self.nade_type = bound(1, self.nade_type, NADES_COUNT);
995
996                         if(self.bonus_nade_score >= 0 && autocvar_g_nades_bonus_score_max)
997                                 nades_GiveBonus(self, time_score / autocvar_g_nades_bonus_score_max);
998                 }
999                 else
1000                 {
1001                         self.bonus_nades = self.bonus_nade_score = 0;
1002                 }
1003         }
1004
1005         float n = 0;
1006         entity o = world;
1007         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
1008                 n = -1;
1009         else
1010         {
1011                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
1012                 n = 0;
1013                 FOR_EACH_PLAYER(other) if(self != other)
1014                 {
1015                         if(other.deadflag == DEAD_NO)
1016                         if(other.frozen == 0)
1017                         if(SAME_TEAM(other, self))
1018                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
1019                         {
1020                                 if(!o)
1021                                         o = other;
1022                                 if(self.frozen == 1)
1023                                         other.reviving = true;
1024                                 ++n;
1025                         }
1026                 }
1027         }
1028
1029         if(n && self.frozen == 3) // OK, there is at least one teammate reviving us
1030         {
1031                 self.revive_progress = bound(0, self.revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
1032                 self.health = max(1, self.revive_progress * start_health);
1033
1034                 if(self.revive_progress >= 1)
1035                 {
1036                         Unfreeze(self);
1037
1038                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
1039                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, self.netname);
1040                 }
1041
1042                 FOR_EACH_PLAYER(other) if(other.reviving)
1043                 {
1044                         other.revive_progress = self.revive_progress;
1045                         other.reviving = false;
1046                 }
1047         }
1048
1049         return false;
1050 }
1051
1052 MUTATOR_HOOKFUNCTION(nades_PlayerSpawn)
1053 {
1054         if(autocvar_g_nades_spawn)
1055                 self.nade_refire = time + autocvar_g_spawnshieldtime;
1056         else
1057                 self.nade_refire  = time + autocvar_g_nades_nade_refire;
1058
1059         if(autocvar_g_nades_bonus_client_select)
1060                 self.nade_type = self.cvar_cl_nade_type;
1061
1062         self.nade_timer = 0;
1063
1064         if(self.nade_spawnloc)
1065         {
1066                 setorigin(self, self.nade_spawnloc.origin);
1067                 self.nade_spawnloc.cnt -= 1;
1068
1069                 if(self.nade_spawnloc.cnt <= 0)
1070                 {
1071                         remove(self.nade_spawnloc);
1072                         self.nade_spawnloc = world;
1073                 }
1074         }
1075
1076         return false;
1077 }
1078
1079 MUTATOR_HOOKFUNCTION(nades_PlayerDies)
1080 {
1081         if(frag_target.nade)
1082         if(!frag_target.frozen || !autocvar_g_freezetag_revive_nade)
1083                 toss_nade(frag_target, '0 0 100', max(frag_target.nade.wait, time + 0.05));
1084
1085         float killcount_bonus = ((frag_attacker.killcount >= 1) ? bound(0, autocvar_g_nades_bonus_score_minor * frag_attacker.killcount, autocvar_g_nades_bonus_score_medium) : autocvar_g_nades_bonus_score_minor);
1086
1087         if(IS_PLAYER(frag_attacker))
1088         {
1089                 if (SAME_TEAM(frag_attacker, frag_target) || frag_attacker == frag_target)
1090                         nades_RemoveBonus(frag_attacker);
1091                 else if(frag_target.flagcarried)
1092                         nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_medium);
1093                 else if(autocvar_g_nades_bonus_score_spree && frag_attacker.killcount > 1)
1094                 {
1095                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
1096                                 case counta: { nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_spree); break; }
1097                         switch(frag_attacker.killcount)
1098                         {
1099                                 KILL_SPREE_LIST
1100                                 default: nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor); break;
1101                         }
1102                         #undef SPREE_ITEM
1103                 }
1104                 else
1105                         nades_GiveBonus(frag_attacker, killcount_bonus);
1106         }
1107
1108         nades_RemoveBonus(frag_target);
1109
1110         return false;
1111 }
1112
1113 MUTATOR_HOOKFUNCTION(nades_PlayerDamage)
1114 {
1115         if(frag_target.frozen)
1116         if(autocvar_g_freezetag_revive_nade)
1117         if(frag_attacker == frag_target)
1118         if(frag_deathtype == DEATH_NADE)
1119         if(time - frag_inflictor.toss_time <= 0.1)
1120         {
1121                 Unfreeze(frag_target);
1122                 frag_target.health = autocvar_g_freezetag_revive_nade_health;
1123                 Send_Effect("iceorglass", frag_target.origin, '0 0 0', 3);
1124                 frag_damage = 0;
1125                 frag_force = '0 0 0';
1126                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED_NADE, frag_target.netname);
1127                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_SELF);
1128         }
1129
1130         return false;
1131 }
1132
1133 MUTATOR_HOOKFUNCTION(nades_MonsterDies)
1134 {
1135         if(IS_PLAYER(frag_attacker))
1136         if(DIFF_TEAM(frag_attacker, self))
1137         if(!(self.spawnflags & MONSTERFLAG_SPAWNED))
1138                 nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor);
1139
1140         return false;
1141 }
1142
1143 MUTATOR_HOOKFUNCTION(nades_RemovePlayer)
1144 {
1145         nades_Clear(self);
1146         nades_RemoveBonus(self);
1147         return false;
1148 }
1149
1150 MUTATOR_HOOKFUNCTION(nades_SpectateCopy)
1151 {
1152         self.nade_timer = other.nade_timer;
1153         self.nade_type = other.nade_type;
1154         self.pokenade_type = other.pokenade_type;
1155         self.bonus_nades = other.bonus_nades;
1156         self.bonus_nade_score = other.bonus_nade_score;
1157         self.stat_healing_orb = other.stat_healing_orb;
1158         self.stat_healing_orb_alpha = other.stat_healing_orb_alpha;
1159         return false;
1160 }
1161
1162 MUTATOR_HOOKFUNCTION(nades_GetCvars)
1163 {
1164         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_nade_type, "cl_nade_type");
1165         GetCvars_handleString(get_cvars_s, get_cvars_f, cvar_cl_pokenade_type, "cl_pokenade_type");
1166
1167         return false;
1168 }
1169
1170 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsString)
1171 {
1172         ret_string = strcat(ret_string, ":Nades");
1173         return false;
1174 }
1175
1176 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsPrettyString)
1177 {
1178         ret_string = strcat(ret_string, ", Nades");
1179         return false;
1180 }
1181
1182 void nades_Initialize()
1183 {
1184         addstat(STAT_NADE_TIMER, AS_FLOAT, nade_timer);
1185         addstat(STAT_NADE_BONUS, AS_FLOAT, bonus_nades);
1186         addstat(STAT_NADE_BONUS_TYPE, AS_INT, nade_type);
1187         addstat(STAT_NADE_BONUS_SCORE, AS_FLOAT, bonus_nade_score);
1188         addstat(STAT_HEALING_ORB, AS_FLOAT, stat_healing_orb);
1189         addstat(STAT_HEALING_ORB_ALPHA, AS_FLOAT, stat_healing_orb_alpha);
1190
1191         precache_model("models/ok_nade_counter/ok_nade_counter.md3");
1192         precache_model("models/weapons/h_ok_grenade.iqm");
1193         precache_model("models/weapons/v_ok_grenade.md3");
1194         precache_model("models/ctf/shield.md3");
1195
1196         precache_sound("weapons/rocket_impact.wav");
1197         precache_sound("weapons/grenade_bounce1.wav");
1198         precache_sound("weapons/grenade_bounce2.wav");
1199         precache_sound("weapons/grenade_bounce3.wav");
1200         precache_sound("weapons/grenade_bounce4.wav");
1201         precache_sound("weapons/grenade_bounce5.wav");
1202         precache_sound("weapons/grenade_bounce6.wav");
1203         precache_sound("overkill/grenadebip.ogg");
1204 }
1205
1206 MUTATOR_DEFINITION(mutator_nades)
1207 {
1208         MUTATOR_HOOK(ForbidThrowCurrentWeapon, nades_CheckThrow, CBC_ORDER_LAST);
1209         MUTATOR_HOOK(VehicleEnter, nades_VehicleEnter, CBC_ORDER_ANY);
1210         MUTATOR_HOOK(PlayerPreThink, nades_PlayerPreThink, CBC_ORDER_ANY);
1211         MUTATOR_HOOK(PlayerSpawn, nades_PlayerSpawn, CBC_ORDER_ANY);
1212         MUTATOR_HOOK(PlayerDies, nades_PlayerDies, CBC_ORDER_LAST);
1213         MUTATOR_HOOK(PlayerDamage_Calculate, nades_PlayerDamage, CBC_ORDER_ANY);
1214         MUTATOR_HOOK(MonsterDies, nades_MonsterDies, CBC_ORDER_ANY);
1215         MUTATOR_HOOK(MakePlayerObserver, nades_RemovePlayer, CBC_ORDER_ANY);
1216         MUTATOR_HOOK(ClientDisconnect, nades_RemovePlayer, CBC_ORDER_ANY);
1217         MUTATOR_HOOK(SpectateCopy, nades_SpectateCopy, CBC_ORDER_ANY);
1218         MUTATOR_HOOK(GetCvars, nades_GetCvars, CBC_ORDER_ANY);
1219         MUTATOR_HOOK(reset_map_global, nades_RemovePlayer, CBC_ORDER_ANY);
1220         MUTATOR_HOOK(BuildMutatorsString, nades_BuildMutatorsString, CBC_ORDER_ANY);
1221         MUTATOR_HOOK(BuildMutatorsPrettyString, nades_BuildMutatorsPrettyString, CBC_ORDER_ANY);
1222
1223         MUTATOR_ONADD
1224         {
1225                 nades_Initialize();
1226         }
1227
1228         return false;
1229 }