qcsrc/server/mutators/mutator_nades.qc

   1 #include "mutator_nades.qh"
   2 #include "../_all.qh"
   3
   4 #include "mutator.qh"
   5
   6 #include "gamemode_keyhunt.qh"
   7 #include "gamemode_freezetag.qh"
   8 #include "../../common/nades.qh"
   9 #include "../../common/monsters/spawn.qh"
  10 #include "../../common/monsters/sv_monsters.qh"
  11
  12 .float lifetime;
  13
  14 .entity nade_spawnloc;
  15
  16 void nade_timer_think()
  17 {SELFPARAM();
  18         self.skin = 8 - (self.owner.wait - time) / (autocvar_g_nades_nade_lifetime / 10);
  19         self.nextthink = time;
  20         if(!self.owner || wasfreed(self.owner))
  21                 remove(self);
  22 }
  23
  24 void nade_burn_spawn(entity _nade)
  25 {
  26         CSQCProjectile(_nade, true, NADES[_nade.nade_type].m_projectile[true], true);
  27 }
  28
  29 void nade_spawn(entity _nade)
  30 {
  31         entity timer = spawn();
  32         setmodel(timer, MDL_NADE_TIMER);
  33         setattachment(timer, _nade, "");
  34         timer.classname = "nade_timer";
  35         timer.colormap = _nade.colormap;
  36         timer.glowmod = _nade.glowmod;
  37         timer.think = nade_timer_think;
  38         timer.nextthink = time;
  39         timer.wait = _nade.wait;
  40         timer.owner = _nade;
  41         timer.skin = 10;
  42
  43         _nade.effects |= EF_LOWPRECISION;
  44
  45         CSQCProjectile(_nade, true, NADES[_nade.nade_type].m_projectile[false], true);
  46 }
  47
  48 void napalm_damage(float dist, float damage, float edgedamage, float burntime)
  49 {SELFPARAM();
  50         entity e;
  51         float d;
  52         vector p;
  53
  54         if ( damage < 0 )
  55                 return;
  56
  57         RandomSelection_Init();
  58         for(e = WarpZone_FindRadius(self.origin, dist, true); e; e = e.chain)
  59                 if(e.takedamage == DAMAGE_AIM)
  60                 if(self.realowner != e || autocvar_g_nades_napalm_selfdamage)
  61                 if(!IS_PLAYER(e) || !self.realowner || DIFF_TEAM(e, self))
  62                 if(!e.frozen)
  63                 {
  64                         p = e.origin;
  65                         p.x += e.mins.x + random() * (e.maxs.x - e.mins.x);
  66                         p.y += e.mins.y + random() * (e.maxs.y - e.mins.y);
  67                         p.z += e.mins.z + random() * (e.maxs.z - e.mins.z);
  68                         d = vlen(WarpZone_UnTransformOrigin(e, self.origin) - p);
  69                         if(d < dist)
  70                         {
  71                                 e.fireball_impactvec = p;
  72                                 RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
  73                         }
  74                 }
  75         if(RandomSelection_chosen_ent)
  76         {
  77                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, self.origin) - RandomSelection_chosen_ent.fireball_impactvec);
  78                 d = damage + (edgedamage - damage) * (d / dist);
  79                 Fire_AddDamage(RandomSelection_chosen_ent, self.realowner, d * burntime, burntime, self.projectiledeathtype | HITTYPE_BOUNCE);
  80                 //trailparticles(self, particleeffectnum(EFFECT_FIREBALL_LASER), self.origin, RandomSelection_chosen_ent.fireball_impactvec);
  81                 Send_Effect(EFFECT_FIREBALL_LASER, self.origin, RandomSelection_chosen_ent.fireball_impactvec - self.origin, 1);
  82         }
  83 }
  84
  85
  86 void napalm_ball_think()
  87 {SELFPARAM();
  88         if(round_handler_IsActive())
  89         if(!round_handler_IsRoundStarted())
  90         {
  91                 remove(self);
  92                 return;
  93         }
  94
  95         if(time > self.pushltime)
  96         {
  97                 remove(self);
  98                 return;
  99         }
 100
 101         vector midpoint = ((self.absmin + self.absmax) * 0.5);
 102         if(pointcontents(midpoint) == CONTENT_WATER)
 103         {
 104                 self.velocity = self.velocity * 0.5;
 105
 106                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 107                         { self.velocity_z = 200; }
 108         }
 109
 110         self.angles = vectoangles(self.velocity);
 111
 112         napalm_damage(autocvar_g_nades_napalm_ball_radius,autocvar_g_nades_napalm_ball_damage,
 113                                   autocvar_g_nades_napalm_ball_damage,autocvar_g_nades_napalm_burntime);
 114
 115         self.nextthink = time + 0.1;
 116 }
 117
 118
 119 void nade_napalm_ball()
 120 {SELFPARAM();
 121         entity proj;
 122         vector kick;
 123
 124         spamsound(self, CH_SHOTS, SND(FIREBALL_FIRE), VOL_BASE, ATTEN_NORM);
 125
 126         proj = spawn ();
 127         proj.owner = self.owner;
 128         proj.realowner = self.realowner;
 129         proj.team = self.owner.team;
 130         proj.classname = "grenade";
 131         proj.bot_dodge = true;
 132         proj.bot_dodgerating = autocvar_g_nades_napalm_ball_damage;
 133         proj.movetype = MOVETYPE_BOUNCE;
 134         proj.projectiledeathtype = DEATH_NADE_NAPALM;
 135         PROJECTILE_MAKETRIGGER(proj);
 136         setmodel(proj, MDL_Null);
 137         proj.scale = 1;//0.5;
 138         setsize(proj, '-4 -4 -4', '4 4 4');
 139         setorigin(proj, self.origin);
 140         proj.think = napalm_ball_think;
 141         proj.nextthink = time;
 142         proj.damageforcescale = autocvar_g_nades_napalm_ball_damageforcescale;
 143         proj.effects = EF_LOWPRECISION | EF_FLAME;
 144
 145         kick.x =(random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 146         kick.y = (random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 147         kick.z = (random()/2+0.5) * autocvar_g_nades_napalm_ball_spread;
 148         proj.velocity = kick;
 149
 150         proj.pushltime = time + autocvar_g_nades_napalm_ball_lifetime;
 151
 152         proj.angles = vectoangles(proj.velocity);
 153         proj.flags = FL_PROJECTILE;
 154         proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
 155
 156         //CSQCProjectile(proj, true, PROJECTILE_NAPALM_FIRE, true);
 157 }
 158
 159
 160 void napalm_fountain_think()
 161 {SELFPARAM();
 162
 163         if(round_handler_IsActive())
 164         if(!round_handler_IsRoundStarted())
 165         {
 166                 remove(self);
 167                 return;
 168         }
 169
 170         if(time >= self.ltime)
 171         {
 172                 remove(self);
 173                 return;
 174         }
 175
 176         vector midpoint = ((self.absmin + self.absmax) * 0.5);
 177         if(pointcontents(midpoint) == CONTENT_WATER)
 178         {
 179                 self.velocity = self.velocity * 0.5;
 180
 181                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 182                         { self.velocity_z = 200; }
 183
 184                 UpdateCSQCProjectile(self);
 185         }
 186
 187         napalm_damage(autocvar_g_nades_napalm_fountain_radius, autocvar_g_nades_napalm_fountain_damage,
 188                 autocvar_g_nades_napalm_fountain_edgedamage, autocvar_g_nades_napalm_burntime);
 189
 190         self.nextthink = time + 0.1;
 191         if(time >= self.nade_special_time)
 192         {
 193                 self.nade_special_time = time + autocvar_g_nades_napalm_fountain_delay;
 194                 nade_napalm_ball();
 195         }
 196 }
 197
 198 void nade_napalm_boom()
 199 {SELFPARAM();
 200         entity fountain;
 201         int c;
 202         for (c = 0; c < autocvar_g_nades_napalm_ball_count; c++)
 203                 nade_napalm_ball();
 204
 205
 206         fountain = spawn();
 207         fountain.owner = self.owner;
 208         fountain.realowner = self.realowner;
 209         fountain.origin = self.origin;
 210         setorigin(fountain, fountain.origin);
 211         fountain.think = napalm_fountain_think;
 212         fountain.nextthink = time;
 213         fountain.ltime = time + autocvar_g_nades_napalm_fountain_lifetime;
 214         fountain.pushltime = fountain.ltime;
 215         fountain.team = self.team;
 216         fountain.movetype = MOVETYPE_TOSS;
 217         fountain.projectiledeathtype = DEATH_NADE_NAPALM;
 218         fountain.bot_dodge = true;
 219         fountain.bot_dodgerating = autocvar_g_nades_napalm_fountain_damage;
 220         fountain.nade_special_time = time;
 221         setsize(fountain, '-16 -16 -16', '16 16 16');
 222         CSQCProjectile(fountain, true, PROJECTILE_NAPALM_FOUNTAIN, true);
 223 }
 224
 225 void nade_ice_freeze(entity freezefield, entity frost_target, float freeze_time)
 226 {
 227         frost_target.frozen_by = freezefield.realowner;
 228         Send_Effect(EFFECT_ELECTRO_IMPACT, frost_target.origin, '0 0 0', 1);
 229         Freeze(frost_target, 1/freeze_time, 3, false);
 230         if(frost_target.ballcarried)
 231         if(g_keepaway) { ka_DropEvent(frost_target); }
 232         else { DropBall(frost_target.ballcarried, frost_target.origin, frost_target.velocity);}
 233         if(frost_target.flagcarried) { ctf_Handle_Throw(frost_target, world, DROP_THROW); }
 234         if(frost_target.nade) { toss_nade(frost_target, '0 0 0', time + 0.05); }
 235
 236         kh_Key_DropAll(frost_target, false);
 237 }
 238
 239 void nade_ice_think()
 240 {SELFPARAM();
 241
 242         if(round_handler_IsActive())
 243         if(!round_handler_IsRoundStarted())
 244         {
 245                 remove(self);
 246                 return;
 247         }
 248
 249         if(time >= self.ltime)
 250         {
 251                 if ( autocvar_g_nades_ice_explode )
 252                 {
 253                         entity expef = EFFECT_NADE_EXPLODE(self.realowner.team);
 254                         Send_Effect(expef, self.origin + '0 0 1', '0 0 0', 1);
 255                         sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 256
 257                         RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 258                                 autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
 259                         Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 260                                 autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
 261                 }
 262                 remove(self);
 263                 return;
 264         }
 265
 266
 267         self.nextthink = time+0.1;
 268
 269         // gaussian
 270         float randomr;
 271         randomr = random();
 272         randomr = exp(-5*randomr*randomr)*autocvar_g_nades_nade_radius;
 273         float randomw;
 274         randomw = random()*M_PI*2;
 275         vector randomp;
 276         randomp.x = randomr*cos(randomw);
 277         randomp.y = randomr*sin(randomw);
 278         randomp.z = 1;
 279         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, self.origin + randomp, '0 0 0', 1);
 280
 281         if(time >= self.nade_special_time)
 282         {
 283                 self.nade_special_time = time+0.7;
 284
 285                 Send_Effect(EFFECT_ELECTRO_IMPACT, self.origin, '0 0 0', 1);
 286                 Send_Effect(EFFECT_ICEFIELD, self.origin, '0 0 0', 1);
 287         }
 288
 289
 290         float current_freeze_time = self.ltime - time - 0.1;
 291
 292         entity e;
 293         for(e = findradius(self.origin, autocvar_g_nades_nade_radius); e; e = e.chain)
 294         if(e != self)
 295         if(!autocvar_g_nades_ice_teamcheck || (DIFF_TEAM(e, self.realowner) || e == self.realowner))
 296         if(e.takedamage && e.deadflag == DEAD_NO)
 297         if(e.health > 0)
 298         if(!e.revival_time || ((time - e.revival_time) >= 1.5))
 299         if(!e.frozen)
 300         if(current_freeze_time > 0)
 301                 nade_ice_freeze(self, e, current_freeze_time);
 302 }
 303
 304 void nade_ice_boom()
 305 {SELFPARAM();
 306         entity fountain;
 307         fountain = spawn();
 308         fountain.owner = self.owner;
 309         fountain.realowner = self.realowner;
 310         fountain.origin = self.origin;
 311         setorigin(fountain, fountain.origin);
 312         fountain.think = nade_ice_think;
 313         fountain.nextthink = time;
 314         fountain.ltime = time + autocvar_g_nades_ice_freeze_time;
 315         fountain.pushltime = fountain.wait = fountain.ltime;
 316         fountain.team = self.team;
 317         fountain.movetype = MOVETYPE_TOSS;
 318         fountain.projectiledeathtype = DEATH_NADE_ICE;
 319         fountain.bot_dodge = false;
 320         setsize(fountain, '-16 -16 -16', '16 16 16');
 321         fountain.nade_special_time = time+0.3;
 322         fountain.angles = self.angles;
 323
 324         if ( autocvar_g_nades_ice_explode )
 325         {
 326                 setmodel(fountain, MDL_PROJECTILE_GRENADE);
 327                 entity timer = spawn();
 328                 setmodel(timer, MDL_NADE_TIMER);
 329                 setattachment(timer, fountain, "");
 330                 timer.classname = "nade_timer";
 331                 timer.colormap = self.colormap;
 332                 timer.glowmod = self.glowmod;
 333                 timer.think = nade_timer_think;
 334                 timer.nextthink = time;
 335                 timer.wait = fountain.ltime;
 336                 timer.owner = fountain;
 337                 timer.skin = 10;
 338         }
 339         else
 340                 setmodel(fountain, MDL_Null);
 341 }
 342
 343 void nade_translocate_boom()
 344 {SELFPARAM();
 345         if(self.realowner.vehicle)
 346                 return;
 347
 348         vector locout = self.origin + '0 0 1' * (1 - self.realowner.mins.z - 24);
 349         tracebox(locout, self.realowner.mins, self.realowner.maxs, locout, MOVE_NOMONSTERS, self.realowner);
 350         locout = trace_endpos;
 351
 352         makevectors(self.realowner.angles);
 353
 354         MUTATOR_CALLHOOK(PortalTeleport, self.realowner);
 355
 356         TeleportPlayer(self, self.realowner, locout, self.realowner.angles, v_forward * vlen(self.realowner.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 357 }
 358
 359 void nade_spawn_boom()
 360 {SELFPARAM();
 361         entity spawnloc = spawn();
 362         setorigin(spawnloc, self.origin);
 363         setsize(spawnloc, self.realowner.mins, self.realowner.maxs);
 364         spawnloc.movetype = MOVETYPE_NONE;
 365         spawnloc.solid = SOLID_NOT;
 366         spawnloc.drawonlytoclient = self.realowner;
 367         spawnloc.effects = EF_STARDUST;
 368         spawnloc.cnt = autocvar_g_nades_spawn_count;
 369
 370         if(self.realowner.nade_spawnloc)
 371         {
 372                 remove(self.realowner.nade_spawnloc);
 373                 self.realowner.nade_spawnloc = world;
 374         }
 375
 376         self.realowner.nade_spawnloc = spawnloc;
 377 }
 378
 379 void nade_heal_think()
 380 {SELFPARAM();
 381         if(time >= self.ltime)
 382         {
 383                 remove(self);
 384                 return;
 385         }
 386
 387         self.nextthink = time;
 388
 389         if(time >= self.nade_special_time)
 390         {
 391                 self.nade_special_time = time+0.25;
 392                 self.nade_show_particles = 1;
 393         }
 394         else
 395                 self.nade_show_particles = 0;
 396 }
 397
 398 void nade_heal_touch()
 399 {SELFPARAM();
 400         float maxhealth;
 401         float health_factor;
 402         if(IS_PLAYER(other) || IS_MONSTER(other))
 403         if(other.deadflag == DEAD_NO)
 404         if(!other.frozen)
 405         {
 406                 health_factor = autocvar_g_nades_heal_rate*frametime/2;
 407                 if ( other != self.realowner )
 408                 {
 409                         if ( SAME_TEAM(other,self) )
 410                                 health_factor *= autocvar_g_nades_heal_friend;
 411                         else
 412                                 health_factor *= autocvar_g_nades_heal_foe;
 413                 }
 414                 if ( health_factor > 0 )
 415                 {
 416                         maxhealth = (IS_MONSTER(other)) ? other.max_health : g_pickup_healthmega_max;
 417                         if ( other.health < maxhealth )
 418                         {
 419                                 if ( self.nade_show_particles )
 420                                         Send_Effect(EFFECT_HEALING, other.origin, '0 0 0', 1);
 421                                 other.health = min(other.health+health_factor, maxhealth);
 422                         }
 423                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 424                 }
 425                 else if ( health_factor < 0 )
 426                 {
 427                         Damage(other,self,self.realowner,-health_factor,DEATH_NADE_HEAL,other.origin,'0 0 0');
 428                 }
 429
 430         }
 431
 432         if ( IS_REAL_CLIENT(other) || IS_VEHICLE(other) )
 433         {
 434                 entity show_red = (IS_VEHICLE(other)) ? other.owner : other;
 435                 show_red.stat_healing_orb = time+0.1;
 436                 show_red.stat_healing_orb_alpha = 0.75 * (self.ltime - time) / self.healer_lifetime;
 437         }
 438 }
 439
 440 void nade_heal_boom()
 441 {SELFPARAM();
 442         entity healer;
 443         healer = spawn();
 444         healer.owner = self.owner;
 445         healer.realowner = self.realowner;
 446         setorigin(healer, self.origin);
 447         healer.healer_lifetime = autocvar_g_nades_heal_time; // save the cvar
 448         healer.ltime = time + healer.healer_lifetime;
 449         healer.team = self.realowner.team;
 450         healer.bot_dodge = false;
 451         healer.solid = SOLID_TRIGGER;
 452         healer.touch = nade_heal_touch;
 453
 454         setmodel(healer, MDL_NADE_HEAL);
 455         healer.healer_radius = autocvar_g_nades_nade_radius;
 456         vector size = '1 1 1' * healer.healer_radius / 2;
 457         setsize(healer,-size,size);
 458
 459         Net_LinkEntity(healer, true, 0, healer_send);
 460
 461         healer.think = nade_heal_think;
 462         healer.nextthink = time;
 463         healer.SendFlags |= 1;
 464 }
 465
 466 void nade_monster_boom()
 467 {SELFPARAM();
 468         entity e = spawnmonster(self.pokenade_type, 0, self.realowner, self.realowner, self.origin, false, false, 1);
 469
 470         if(autocvar_g_nades_pokenade_monster_lifetime > 0)
 471                 e.monster_lifetime = time + autocvar_g_nades_pokenade_monster_lifetime;
 472         e.monster_skill = MONSTER_SKILL_INSANE;
 473 }
 474
 475 void nade_boom()
 476 {SELFPARAM();
 477         entity expef = NULL;
 478         bool nade_blast = true;
 479
 480         switch ( NADES[self.nade_type] )
 481         {
 482                 case NADE_TYPE_NAPALM:
 483                         nade_blast = autocvar_g_nades_napalm_blast;
 484                         expef = EFFECT_EXPLOSION_MEDIUM;
 485                         break;
 486                 case NADE_TYPE_ICE:
 487                         nade_blast = false;
 488                         expef = EFFECT_ELECTRO_COMBO; // hookbomb_explode electro_combo bigplasma_impact
 489                         break;
 490                 case NADE_TYPE_TRANSLOCATE:
 491                         nade_blast = false;
 492                         break;
 493                 case NADE_TYPE_MONSTER:
 494                 case NADE_TYPE_SPAWN:
 495                         nade_blast = false;
 496                         switch(self.realowner.team)
 497                         {
 498                                 case NUM_TEAM_1: expef = EFFECT_SPAWN_RED; break;
 499                                 case NUM_TEAM_2: expef = EFFECT_SPAWN_BLUE; break;
 500                                 case NUM_TEAM_3: expef = EFFECT_SPAWN_YELLOW; break;
 501                                 case NUM_TEAM_4: expef = EFFECT_SPAWN_PINK; break;
 502                                 default: expef = EFFECT_SPAWN_NEUTRAL; break;
 503                         }
 504                         break;
 505                 case NADE_TYPE_HEAL:
 506                         nade_blast = false;
 507                         expef = EFFECT_SPAWN_RED;
 508                         break;
 509
 510                 default:
 511                 case NADE_TYPE_NORMAL:
 512                         expef = EFFECT_NADE_EXPLODE(self.realowner.team);
 513                         break;
 514         }
 515
 516         if(expef)
 517                 Send_Effect(expef, findbetterlocation(self.origin, 8), '0 0 0', 1);
 518
 519         sound(self, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 520         sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 521
 522         self.event_damage = func_null; // prevent somehow calling damage in the next call
 523
 524         if(nade_blast)
 525         {
 526                 RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 527                                  autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
 528                 Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage, autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
 529         }
 530
 531         if(self.takedamage)
 532         switch ( NADES[self.nade_type] )
 533         {
 534                 case NADE_TYPE_NAPALM: nade_napalm_boom(); break;
 535                 case NADE_TYPE_ICE: nade_ice_boom(); break;
 536                 case NADE_TYPE_TRANSLOCATE: nade_translocate_boom(); break;
 537                 case NADE_TYPE_SPAWN: nade_spawn_boom(); break;
 538                 case NADE_TYPE_HEAL: nade_heal_boom(); break;
 539                 case NADE_TYPE_MONSTER: nade_monster_boom(); break;
 540         }
 541
 542         entity head;
 543         for(head = world; (head = find(head, classname, "grapplinghook")); )
 544         if(head.aiment == self)
 545                 RemoveGrapplingHook(head.realowner);
 546
 547         remove(self);
 548 }
 549
 550 void nade_touch()
 551 {SELFPARAM();
 552         /*float is_weapclip = 0;
 553         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 554         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 555         if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 556                 is_weapclip = 1;*/
 557         if(ITEM_TOUCH_NEEDKILL()) // || is_weapclip)
 558         {
 559                 entity head;
 560                 for(head = world; (head = find(head, classname, "grapplinghook")); )
 561                 if(head.aiment == self)
 562                         RemoveGrapplingHook(head.realowner);
 563                 remove(self);
 564                 return;
 565         }
 566
 567         PROJECTILE_TOUCH;
 568
 569         //setsize(self, '-2 -2 -2', '2 2 2');
 570         //UpdateCSQCProjectile(self);
 571         if(self.health == self.max_health)
 572         {
 573                 spamsound(self, CH_SHOTS, SND(GRENADE_BOUNCE_RANDOM()), VOL_BASE, ATTEN_NORM);
 574                 return;
 575         }
 576
 577         self.enemy = other;
 578         nade_boom();
 579 }
 580
 581 void nade_beep()
 582 {SELFPARAM();
 583         sound(self, CH_SHOTS_SINGLE, SND_NADE_BEEP, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 584         self.think = nade_boom;
 585         self.nextthink = max(self.wait, time);
 586 }
 587
 588 void nade_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 589 {SELFPARAM();
 590         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 591         {
 592                 self.takedamage = DAMAGE_NO;
 593                 nade_boom();
 594                 return;
 595         }
 596
 597         if(self.nade_type == NADE_TYPE_TRANSLOCATE.m_id || self.nade_type == NADE_TYPE_SPAWN.m_id)
 598                 return;
 599
 600         if(DEATH_ISWEAPON(deathtype, WEP_BLASTER.m_id))
 601         {
 602                 force *= 1.5;
 603                 damage = 0;
 604         }
 605
 606         if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER.m_id) && (deathtype & HITTYPE_SECONDARY))
 607         {
 608                 force *= 0.5; // too much
 609                 frag_damage = 0;
 610         }
 611
 612         if(DEATH_ISWEAPON(deathtype, WEP_VORTEX.m_id) || DEATH_ISWEAPON(deathtype, WEP_VAPORIZER.m_id))
 613         {
 614                 force *= 6;
 615                 damage = self.max_health * 0.55;
 616         }
 617
 618         if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN.m_id) || DEATH_ISWEAPON(deathtype, WEP_HMG.m_id))
 619                 damage = self.max_health * 0.1;
 620
 621         if(DEATH_ISWEAPON(deathtype, WEP_SHOCKWAVE.m_id) || DEATH_ISWEAPON(deathtype, WEP_SHOTGUN.m_id)) // WEAPONTODO
 622         if(deathtype & HITTYPE_SECONDARY)
 623         {
 624                 damage = self.max_health * 0.1;
 625                 force *= 10;
 626         }
 627         else
 628                 damage = self.max_health * 1.15;
 629
 630         self.velocity += force;
 631         UpdateCSQCProjectile(self);
 632
 633         if(damage <= 0 || ((self.flags & FL_ONGROUND) && IS_PLAYER(attacker)))
 634                 return;
 635
 636         if(self.health == self.max_health)
 637         {
 638                 sound(self, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 639                 self.nextthink = max(time + autocvar_g_nades_nade_lifetime, time);
 640                 self.think = nade_beep;
 641         }
 642
 643         self.health -= damage;
 644
 645         if ( self.nade_type != NADE_TYPE_HEAL.m_id || IS_PLAYER(attacker) )
 646                 self.realowner = attacker;
 647
 648         if(self.health <= 0)
 649                 W_PrepareExplosionByDamage(attacker, nade_boom);
 650         else
 651                 nade_burn_spawn(self);
 652 }
 653
 654 void toss_nade(entity e, vector _velocity, float _time)
 655 {SELFPARAM();
 656         if(e.nade == world)
 657                 return;
 658
 659         entity _nade = e.nade;
 660         e.nade = world;
 661
 662         remove(e.fake_nade);
 663         e.fake_nade = world;
 664
 665         makevectors(e.v_angle);
 666
 667         W_SetupShot(e, false, false, "", CH_WEAPON_A, 0);
 668
 669         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_NADES);
 670
 671         vector offset = (v_forward * autocvar_g_nades_throw_offset.x)
 672                                   + (v_right * autocvar_g_nades_throw_offset.y)
 673                                   + (v_up * autocvar_g_nades_throw_offset.z);
 674         if(autocvar_g_nades_throw_offset == '0 0 0')
 675                 offset = '0 0 0';
 676
 677         setorigin(_nade, w_shotorg + offset + (v_right * 25) * -1);
 678         //setmodel(_nade, MDL_PROJECTILE_NADE);
 679         //setattachment(_nade, world, "");
 680         PROJECTILE_MAKETRIGGER(_nade);
 681         setsize(_nade, '-16 -16 -16', '16 16 16');
 682         _nade.movetype = MOVETYPE_BOUNCE;
 683
 684         tracebox(_nade.origin, _nade.mins, _nade.maxs, _nade.origin, false, _nade);
 685         if (trace_startsolid)
 686                 setorigin(_nade, e.origin);
 687
 688         if(self.v_angle.x >= 70 && self.v_angle.x <= 110 && self.BUTTON_CROUCH)
 689                 _nade.velocity = '0 0 100';
 690         else if(autocvar_g_nades_nade_newton_style == 1)
 691                 _nade.velocity = e.velocity + _velocity;
 692         else if(autocvar_g_nades_nade_newton_style == 2)
 693                 _nade.velocity = _velocity;
 694         else
 695                 _nade.velocity = W_CalculateProjectileVelocity(e.velocity, _velocity, true);
 696
 697         _nade.touch = nade_touch;
 698         _nade.health = autocvar_g_nades_nade_health;
 699         _nade.max_health = _nade.health;
 700         _nade.takedamage = DAMAGE_AIM;
 701         _nade.event_damage = nade_damage;
 702         _nade.customizeentityforclient = func_null;
 703         _nade.exteriormodeltoclient = world;
 704         _nade.traileffectnum = 0;
 705         _nade.teleportable = true;
 706         _nade.pushable = true;
 707         _nade.gravity = 1;
 708         _nade.missile_flags = MIF_SPLASH | MIF_ARC;
 709         _nade.damagedbycontents = true;
 710         _nade.angles = vectoangles(_nade.velocity);
 711         _nade.flags = FL_PROJECTILE;
 712         _nade.projectiledeathtype = DEATH_NADE;
 713         _nade.toss_time = time;
 714         _nade.solid = SOLID_CORPSE; //((_nade.nade_type == NADE_TYPE_TRANSLOCATE) ? SOLID_CORPSE : SOLID_BBOX);
 715
 716         if(_nade.nade_type == NADE_TYPE_TRANSLOCATE.m_id || _nade.nade_type == NADE_TYPE_SPAWN.m_id)
 717                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 718         else
 719                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 720
 721         nade_spawn(_nade);
 722
 723         if(_time)
 724         {
 725                 _nade.think = nade_boom;
 726                 _nade.nextthink = _time;
 727         }
 728
 729         e.nade_refire = time + autocvar_g_nades_nade_refire;
 730         e.nade_timer = 0;
 731 }
 732
 733 void nades_GiveBonus(entity player, float score)
 734 {
 735         if (autocvar_g_nades)
 736         if (autocvar_g_nades_bonus)
 737         if (IS_REAL_CLIENT(player))
 738         if (IS_PLAYER(player) && player.bonus_nades < autocvar_g_nades_bonus_max)
 739         if (player.frozen == 0)
 740         if (player.deadflag == DEAD_NO)
 741         {
 742                 if ( player.bonus_nade_score < 1 )
 743                         player.bonus_nade_score += score/autocvar_g_nades_bonus_score_max;
 744
 745                 if ( player.bonus_nade_score >= 1 )
 746                 {
 747                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_NADE_BONUS);
 748                         play2(player, SND(KH_ALARM));
 749                         player.bonus_nades++;
 750                         player.bonus_nade_score -= 1;
 751                 }
 752         }
 753 }
 754
 755 void nades_RemoveBonus(entity player)
 756 {
 757         player.bonus_nades = player.bonus_nade_score = 0;
 758 }
 759
 760 float nade_customize()
 761 {SELFPARAM();
 762         //if(IS_SPEC(other)) { return false; }
 763         if(other == self.realowner || (IS_SPEC(other) && other.enemy == self.realowner))
 764         {
 765                 // somewhat hide the model, but keep the glow
 766                 //self.effects = 0;
 767                 if(self.traileffectnum)
 768                         self.traileffectnum = 0;
 769                 self.alpha = -1;
 770         }
 771         else
 772         {
 773                 //self.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 774                 if(!self.traileffectnum)
 775                         self.traileffectnum = _particleeffectnum(Nade_TrailEffect(NADES[self.nade_type].m_projectile[false], self.team));
 776                 self.alpha = 1;
 777         }
 778
 779         return true;
 780 }
 781
 782 void nade_prime()
 783 {SELFPARAM();
 784         if(autocvar_g_nades_bonus_only)
 785         if(!self.bonus_nades)
 786                 return; // only allow bonus nades
 787
 788         if(self.nade)
 789                 remove(self.nade);
 790
 791         if(self.fake_nade)
 792                 remove(self.fake_nade);
 793
 794         entity n = spawn(), fn = spawn();
 795
 796         n.classname = "nade";
 797         fn.classname = "fake_nade";
 798
 799         if(self.items & ITEM_Strength.m_itemid && autocvar_g_nades_bonus_onstrength)
 800                 n.nade_type = self.nade_type;
 801         else if (self.bonus_nades >= 1)
 802         {
 803                 n.nade_type = self.nade_type;
 804                 n.pokenade_type = self.pokenade_type;
 805                 self.bonus_nades -= 1;
 806         }
 807         else
 808         {
 809                 n.nade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_nade_type : autocvar_g_nades_nade_type);
 810                 n.pokenade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_pokenade_type : autocvar_g_nades_pokenade_monster_type);
 811         }
 812
 813         n.nade_type = bound(1, n.nade_type, NADES_COUNT);
 814
 815         setmodel(n, MDL_PROJECTILE_NADE);
 816         //setattachment(n, self, "bip01 l hand");
 817         n.exteriormodeltoclient = self;
 818         n.customizeentityforclient = nade_customize;
 819         n.traileffectnum = _particleeffectnum(Nade_TrailEffect(NADES[n.nade_type].m_projectile[false], self.team));
 820         n.colormod = NADES[n.nade_type].m_color;
 821         n.realowner = self;
 822         n.colormap = self.colormap;
 823         n.glowmod = self.glowmod;
 824         n.wait = time + autocvar_g_nades_nade_lifetime;
 825         n.lifetime = time;
 826         n.think = nade_beep;
 827         n.nextthink = max(n.wait - 3, time);
 828         n.projectiledeathtype = DEATH_NADE;
 829
 830         setmodel(fn, MDL_NADE_VIEW);
 831         setattachment(fn, self.weaponentity, "");
 832         fn.realowner = fn.owner = self;
 833         fn.colormod = NADES[n.nade_type].m_color;
 834         fn.colormap = self.colormap;
 835         fn.glowmod = self.glowmod;
 836         fn.think = SUB_Remove;
 837         fn.nextthink = n.wait;
 838
 839         self.nade = n;
 840         self.fake_nade = fn;
 841 }
 842
 843 float CanThrowNade()
 844 {SELFPARAM();
 845         if(self.vehicle)
 846                 return false;
 847
 848         if(gameover)
 849                 return false;
 850
 851         if(self.deadflag != DEAD_NO)
 852                 return false;
 853
 854         if (!autocvar_g_nades)
 855                 return false; // allow turning them off mid match
 856
 857         if(forbidWeaponUse(self))
 858                 return false;
 859
 860         if (!IS_PLAYER(self))
 861                 return false;
 862
 863         return true;
 864 }
 865
 866 void nades_CheckThrow()
 867 {SELFPARAM();
 868         if(!CanThrowNade())
 869                 return;
 870
 871         if(!self.nade)
 872         {
 873                 if(self.nade_refire < time)
 874                 {
 875                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_NADE_THROW);
 876                         nade_prime();
 877                         self.nade_refire = time + autocvar_g_nades_nade_refire;
 878                 }
 879         }
 880         else
 881         {
 882                 if(time - self.nade.lifetime >= 1)
 883                 {
 884                         makevectors(self.v_angle);
 885                         float _force = time - self.nade.lifetime;
 886                         _force /= autocvar_g_nades_nade_lifetime;
 887                         _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
 888                         toss_nade(self, (v_forward * 0.75 + v_up * 0.2 + v_right * 0.05) * _force, 0);
 889                 }
 890         }
 891 }
 892
 893 void nades_Clear(entity player)
 894 {
 895         if(player.nade)
 896                 remove(player.nade);
 897         if(player.fake_nade)
 898                 remove(player.fake_nade);
 899
 900         player.nade = player.fake_nade = world;
 901         player.nade_timer = 0;
 902 }
 903
 904 MUTATOR_HOOKFUNCTION(nades_CheckThrow)
 905 {
 906         if(MUTATOR_RETURNVALUE) { nades_CheckThrow(); }
 907         return false;
 908 }
 909
 910 MUTATOR_HOOKFUNCTION(nades_VehicleEnter)
 911 {
 912         if(vh_player.nade)
 913                 toss_nade(vh_player, '0 0 100', max(vh_player.nade.wait, time + 0.05));
 914
 915         return false;
 916 }
 917
 918 MUTATOR_HOOKFUNCTION(nades_PlayerPreThink)
 919 {SELFPARAM();
 920         if(!IS_PLAYER(self)) { return false; }
 921
 922         float key_pressed = self.BUTTON_HOOK;
 923         float time_score;
 924
 925         if(g_grappling_hook || client_hasweapon(self, WEP_HOOK.m_id, false, false) || (weaponsInMap & WEPSET_HOOK))
 926                 key_pressed = self.button16; // if hook is enabled, use an alternate key
 927
 928         if(self.nade)
 929         {
 930                 self.nade_timer = bound(0, (time - self.nade.lifetime) / autocvar_g_nades_nade_lifetime, 1);
 931                 //print(sprintf("%d %d\n", self.nade_timer, time - self.nade.lifetime));
 932                 makevectors(self.angles);
 933                 self.nade.velocity = self.velocity;
 934
 935                 setorigin(self.nade, self.origin + self.view_ofs + v_forward * 8 + v_right * -8 + v_up * 0);
 936                 self.nade.angles_y = self.angles.y;
 937         }
 938
 939         if(self.nade)
 940         if(self.nade.wait - 0.1 <= time)
 941                 toss_nade(self, '0 0 0', time + 0.05);
 942
 943         if(CanThrowNade())
 944         if(self.nade_refire < time)
 945         {
 946                 if(key_pressed)
 947                 {
 948                         if(!self.nade)
 949                                 nade_prime();
 950                 }
 951                 else if(time - self.nade.lifetime >= 1)
 952                 {
 953                         if(self.nade)
 954                         {
 955                                 makevectors(self.v_angle);
 956                                 float _force = time - self.nade.lifetime;
 957                                 _force /= autocvar_g_nades_nade_lifetime;
 958                                 _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
 959                                 toss_nade(self, (v_forward * 0.7 + v_up * 0.2 + v_right * 0.1) * _force, 0);
 960                         }
 961                 }
 962         }
 963
 964         if(IS_PLAYER(self))
 965         {
 966                 if ( autocvar_g_nades_bonus && autocvar_g_nades )
 967                 {
 968                         entity key;
 969                         float key_count = 0;
 970                         FOR_EACH_KH_KEY(key) if(key.owner == self) { ++key_count; }
 971
 972                         if(self.flagcarried || self.ballcarried) // this player is important
 973                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier;
 974                         else
 975                                 time_score = autocvar_g_nades_bonus_score_time;
 976
 977                         if(key_count)
 978                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier * key_count; // multiply by the number of keys the player is holding
 979
 980                         if(autocvar_g_nades_bonus_client_select)
 981                         {
 982                                 self.nade_type = self.cvar_cl_nade_type;
 983                                 self.pokenade_type = self.cvar_cl_pokenade_type;
 984                         }
 985                         else
 986                         {
 987                                 self.nade_type = autocvar_g_nades_bonus_type;
 988                                 self.pokenade_type = autocvar_g_nades_pokenade_monster_type;
 989                         }
 990
 991                         self.nade_type = bound(1, self.nade_type, NADES_COUNT);
 992
 993                         if(self.bonus_nade_score >= 0 && autocvar_g_nades_bonus_score_max)
 994                                 nades_GiveBonus(self, time_score / autocvar_g_nades_bonus_score_max);
 995                 }
 996                 else
 997                 {
 998                         self.bonus_nades = self.bonus_nade_score = 0;
 999                 }
1000         }
1001
1002         float n = 0;
1003         entity o = world;
1004         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
1005                 n = -1;
1006         else
1007         {
1008                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
1009                 n = 0;
1010                 FOR_EACH_PLAYER(other) if(self != other)
1011                 {
1012                         if(other.deadflag == DEAD_NO)
1013                         if(other.frozen == 0)
1014                         if(SAME_TEAM(other, self))
1015                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
1016                         {
1017                                 if(!o)
1018                                         o = other;
1019                                 if(self.frozen == 1)
1020                                         other.reviving = true;
1021                                 ++n;
1022                         }
1023                 }
1024         }
1025
1026         if(n && self.frozen == 3) // OK, there is at least one teammate reviving us
1027         {
1028                 self.revive_progress = bound(0, self.revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
1029                 self.health = max(1, self.revive_progress * start_health);
1030
1031                 if(self.revive_progress >= 1)
1032                 {
1033                         Unfreeze(self);
1034
1035                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
1036                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, self.netname);
1037                 }
1038
1039                 FOR_EACH_PLAYER(other) if(other.reviving)
1040                 {
1041                         other.revive_progress = self.revive_progress;
1042                         other.reviving = false;
1043                 }
1044         }
1045
1046         return false;
1047 }
1048
1049 MUTATOR_HOOKFUNCTION(nades_PlayerSpawn)
1050 {SELFPARAM();
1051         if(autocvar_g_nades_spawn)
1052                 self.nade_refire = time + autocvar_g_spawnshieldtime;
1053         else
1054                 self.nade_refire  = time + autocvar_g_nades_nade_refire;
1055
1056         if(autocvar_g_nades_bonus_client_select)
1057                 self.nade_type = self.cvar_cl_nade_type;
1058
1059         self.nade_timer = 0;
1060
1061         if(self.nade_spawnloc)
1062         {
1063                 setorigin(self, self.nade_spawnloc.origin);
1064                 self.nade_spawnloc.cnt -= 1;
1065
1066                 if(self.nade_spawnloc.cnt <= 0)
1067                 {
1068                         remove(self.nade_spawnloc);
1069                         self.nade_spawnloc = world;
1070                 }
1071         }
1072
1073         return false;
1074 }
1075
1076 MUTATOR_HOOKFUNCTION(nades_PlayerDies)
1077 {
1078         if(frag_target.nade)
1079         if(!frag_target.frozen || !autocvar_g_freezetag_revive_nade)
1080                 toss_nade(frag_target, '0 0 100', max(frag_target.nade.wait, time + 0.05));
1081
1082         float killcount_bonus = ((frag_attacker.killcount >= 1) ? bound(0, autocvar_g_nades_bonus_score_minor * frag_attacker.killcount, autocvar_g_nades_bonus_score_medium) : autocvar_g_nades_bonus_score_minor);
1083
1084         if(IS_PLAYER(frag_attacker))
1085         {
1086                 if (SAME_TEAM(frag_attacker, frag_target) || frag_attacker == frag_target)
1087                         nades_RemoveBonus(frag_attacker);
1088                 else if(frag_target.flagcarried)
1089                         nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_medium);
1090                 else if(autocvar_g_nades_bonus_score_spree && frag_attacker.killcount > 1)
1091                 {
1092                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
1093                                 case counta: { nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_spree); break; }
1094                         switch(frag_attacker.killcount)
1095                         {
1096                                 KILL_SPREE_LIST
1097                                 default: nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor); break;
1098                         }
1099                         #undef SPREE_ITEM
1100                 }
1101                 else
1102                         nades_GiveBonus(frag_attacker, killcount_bonus);
1103         }
1104
1105         nades_RemoveBonus(frag_target);
1106
1107         return false;
1108 }
1109
1110 MUTATOR_HOOKFUNCTION(nades_PlayerDamage)
1111 {
1112         if(frag_target.frozen)
1113         if(autocvar_g_freezetag_revive_nade)
1114         if(frag_attacker == frag_target)
1115         if(frag_deathtype == DEATH_NADE)
1116         if(time - frag_inflictor.toss_time <= 0.1)
1117         {
1118                 Unfreeze(frag_target);
1119                 frag_target.health = autocvar_g_freezetag_revive_nade_health;
1120                 Send_Effect(EFFECT_ICEORGLASS, frag_target.origin, '0 0 0', 3);
1121                 frag_damage = 0;
1122                 frag_force = '0 0 0';
1123                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED_NADE, frag_target.netname);
1124                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_SELF);
1125         }
1126
1127         return false;
1128 }
1129
1130 MUTATOR_HOOKFUNCTION(nades_MonsterDies)
1131 {SELFPARAM();
1132         if(IS_PLAYER(frag_attacker))
1133         if(DIFF_TEAM(frag_attacker, self))
1134         if(!(self.spawnflags & MONSTERFLAG_SPAWNED))
1135                 nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor);
1136
1137         return false;
1138 }
1139
1140 MUTATOR_HOOKFUNCTION(nades_RemovePlayer)
1141 {SELFPARAM();
1142         nades_Clear(self);
1143         nades_RemoveBonus(self);
1144         return false;
1145 }
1146
1147 MUTATOR_HOOKFUNCTION(nades_SpectateCopy)
1148 {SELFPARAM();
1149         self.nade_timer = other.nade_timer;
1150         self.nade_type = other.nade_type;
1151         self.pokenade_type = other.pokenade_type;
1152         self.bonus_nades = other.bonus_nades;
1153         self.bonus_nade_score = other.bonus_nade_score;
1154         self.stat_healing_orb = other.stat_healing_orb;
1155         self.stat_healing_orb_alpha = other.stat_healing_orb_alpha;
1156         return false;
1157 }
1158
1159 MUTATOR_HOOKFUNCTION(nades_GetCvars)
1160 {
1161         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_nade_type, "cl_nade_type");
1162         GetCvars_handleString(get_cvars_s, get_cvars_f, cvar_cl_pokenade_type, "cl_pokenade_type");
1163
1164         return false;
1165 }
1166
1167 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsString)
1168 {
1169         ret_string = strcat(ret_string, ":Nades");
1170         return false;
1171 }
1172
1173 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsPrettyString)
1174 {
1175         ret_string = strcat(ret_string, ", Nades");
1176         return false;
1177 }
1178
1179 void nades_Initialize()
1180 {
1181         addstat(STAT_NADE_TIMER, AS_FLOAT, nade_timer);
1182         addstat(STAT_NADE_BONUS, AS_FLOAT, bonus_nades);
1183         addstat(STAT_NADE_BONUS_TYPE, AS_INT, nade_type);
1184         addstat(STAT_NADE_BONUS_SCORE, AS_FLOAT, bonus_nade_score);
1185         addstat(STAT_HEALING_ORB, AS_FLOAT, stat_healing_orb);
1186         addstat(STAT_HEALING_ORB_ALPHA, AS_FLOAT, stat_healing_orb_alpha);
1187 }
1188
1189 MUTATOR_DEFINITION(mutator_nades)
1190 {
1191         MUTATOR_HOOK(ForbidThrowCurrentWeapon, nades_CheckThrow, CBC_ORDER_LAST);
1192         MUTATOR_HOOK(VehicleEnter, nades_VehicleEnter, CBC_ORDER_ANY);
1193         MUTATOR_HOOK(PlayerPreThink, nades_PlayerPreThink, CBC_ORDER_ANY);
1194         MUTATOR_HOOK(PlayerSpawn, nades_PlayerSpawn, CBC_ORDER_ANY);
1195         MUTATOR_HOOK(PlayerDies, nades_PlayerDies, CBC_ORDER_LAST);
1196         MUTATOR_HOOK(PlayerDamage_Calculate, nades_PlayerDamage, CBC_ORDER_ANY);
1197         MUTATOR_HOOK(MonsterDies, nades_MonsterDies, CBC_ORDER_ANY);
1198         MUTATOR_HOOK(MakePlayerObserver, nades_RemovePlayer, CBC_ORDER_ANY);
1199         MUTATOR_HOOK(ClientDisconnect, nades_RemovePlayer, CBC_ORDER_ANY);
1200         MUTATOR_HOOK(SpectateCopy, nades_SpectateCopy, CBC_ORDER_ANY);
1201         MUTATOR_HOOK(GetCvars, nades_GetCvars, CBC_ORDER_ANY);
1202         MUTATOR_HOOK(reset_map_global, nades_RemovePlayer, CBC_ORDER_ANY);
1203         MUTATOR_HOOK(BuildMutatorsString, nades_BuildMutatorsString, CBC_ORDER_ANY);
1204         MUTATOR_HOOK(BuildMutatorsPrettyString, nades_BuildMutatorsPrettyString, CBC_ORDER_ANY);
1205
1206         MUTATOR_ONADD
1207         {
1208                 nades_Initialize();
1209         }
1210
1211         return false;
1212 }