qcsrc/server/mutators/mutator_nades.qc

   1 #include "mutator_nades.qh"
   2 #include "../_all.qh"
   3
   4 #include "mutator.qh"
   5
   6 #include "gamemode_keyhunt.qh"
   7 #include "gamemode_freezetag.qh"
   8 #include "../../common/nades.qh"
   9 #include "../../common/monsters/spawn.qh"
  10 #include "../../common/monsters/sv_monsters.qh"
  11
  12 .float lifetime;
  13
  14 .entity nade_spawnloc;
  15
  16 void nade_timer_think()
  17 {
  18         self.skin = 8 - (self.owner.wait - time) / (autocvar_g_nades_nade_lifetime / 10);
  19         self.nextthink = time;
  20         if(!self.owner || wasfreed(self.owner))
  21                 remove(self);
  22 }
  23
  24 void nade_burn_spawn(entity _nade)
  25 {
  26         CSQCProjectile(_nade, true, Nade_ProjectileFromID(_nade.nade_type, true), true);
  27 }
  28
  29 void nade_spawn(entity _nade)
  30 {
  31         entity timer = spawn();
  32         setmodel(timer, "models/ok_nade_counter/ok_nade_counter.md3");
  33         setattachment(timer, _nade, "");
  34         timer.classname = "nade_timer";
  35         timer.colormap = _nade.colormap;
  36         timer.glowmod = _nade.glowmod;
  37         timer.think = nade_timer_think;
  38         timer.nextthink = time;
  39         timer.wait = _nade.wait;
  40         timer.owner = _nade;
  41         timer.skin = 10;
  42
  43         _nade.effects |= EF_LOWPRECISION;
  44
  45         CSQCProjectile(_nade, true, Nade_ProjectileFromID(_nade.nade_type, false), true);
  46 }
  47
  48 void napalm_damage(float dist, float damage, float edgedamage, float burntime)
  49 {
  50         entity e;
  51         float d;
  52         vector p;
  53
  54         if ( damage < 0 )
  55                 return;
  56
  57         RandomSelection_Init();
  58         for(e = WarpZone_FindRadius(self.origin, dist, true); e; e = e.chain)
  59                 if(e.takedamage == DAMAGE_AIM)
  60                 if(self.realowner != e || autocvar_g_nades_napalm_selfdamage)
  61                 if(!IS_PLAYER(e) || !self.realowner || DIFF_TEAM(e, self))
  62                 if(!e.frozen)
  63                 {
  64                         p = e.origin;
  65                         p.x += e.mins.x + random() * (e.maxs.x - e.mins.x);
  66                         p.y += e.mins.y + random() * (e.maxs.y - e.mins.y);
  67                         p.z += e.mins.z + random() * (e.maxs.z - e.mins.z);
  68                         d = vlen(WarpZone_UnTransformOrigin(e, self.origin) - p);
  69                         if(d < dist)
  70                         {
  71                                 e.fireball_impactvec = p;
  72                                 RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
  73                         }
  74                 }
  75         if(RandomSelection_chosen_ent)
  76         {
  77                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, self.origin) - RandomSelection_chosen_ent.fireball_impactvec);
  78                 d = damage + (edgedamage - damage) * (d / dist);
  79                 Fire_AddDamage(RandomSelection_chosen_ent, self.realowner, d * burntime, burntime, self.projectiledeathtype | HITTYPE_BOUNCE);
  80                 //trailparticles(self, particleeffectnum("fireball_laser"), self.origin, RandomSelection_chosen_ent.fireball_impactvec);
  81                 pointparticles(particleeffectnum("fireball_laser"), self.origin, RandomSelection_chosen_ent.fireball_impactvec - self.origin, 1);
  82         }
  83 }
  84
  85
  86 void napalm_ball_think()
  87 {
  88         if(round_handler_IsActive())
  89         if(!round_handler_IsRoundStarted())
  90         {
  91                 remove(self);
  92                 return;
  93         }
  94
  95         if(time > self.pushltime)
  96         {
  97                 remove(self);
  98                 return;
  99         }
 100
 101         vector midpoint = ((self.absmin + self.absmax) * 0.5);
 102         if(pointcontents(midpoint) == CONTENT_WATER)
 103         {
 104                 self.velocity = self.velocity * 0.5;
 105
 106                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 107                         { self.velocity_z = 200; }
 108         }
 109
 110         self.angles = vectoangles(self.velocity);
 111
 112         napalm_damage(autocvar_g_nades_napalm_ball_radius,autocvar_g_nades_napalm_ball_damage,
 113                                   autocvar_g_nades_napalm_ball_damage,autocvar_g_nades_napalm_burntime);
 114
 115         self.nextthink = time + 0.1;
 116 }
 117
 118
 119 void nade_napalm_ball()
 120 {
 121         entity proj;
 122         vector kick;
 123
 124         spamsound(self, CH_SHOTS, "weapons/fireball_fire.wav", VOL_BASE, ATTEN_NORM);
 125
 126         proj = spawn ();
 127         proj.owner = self.owner;
 128         proj.realowner = self.realowner;
 129         proj.team = self.owner.team;
 130         proj.classname = "grenade";
 131         proj.bot_dodge = true;
 132         proj.bot_dodgerating = autocvar_g_nades_napalm_ball_damage;
 133         proj.movetype = MOVETYPE_BOUNCE;
 134         proj.projectiledeathtype = DEATH_NADE_NAPALM;
 135         PROJECTILE_MAKETRIGGER(proj);
 136         setmodel(proj, "null");
 137         proj.scale = 1;//0.5;
 138         setsize(proj, '-4 -4 -4', '4 4 4');
 139         setorigin(proj, self.origin);
 140         proj.think = napalm_ball_think;
 141         proj.nextthink = time;
 142         proj.damageforcescale = autocvar_g_nades_napalm_ball_damageforcescale;
 143         proj.effects = EF_LOWPRECISION | EF_FLAME;
 144
 145         kick.x =(random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 146         kick.y = (random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 147         kick.z = (random()/2+0.5) * autocvar_g_nades_napalm_ball_spread;
 148         proj.velocity = kick;
 149
 150         proj.pushltime = time + autocvar_g_nades_napalm_ball_lifetime;
 151
 152         proj.angles = vectoangles(proj.velocity);
 153         proj.flags = FL_PROJECTILE;
 154         proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
 155
 156         //CSQCProjectile(proj, true, PROJECTILE_NAPALM_FIRE, true);
 157 }
 158
 159
 160 void napalm_fountain_think()
 161 {
 162
 163         if(round_handler_IsActive())
 164         if(!round_handler_IsRoundStarted())
 165         {
 166                 remove(self);
 167                 return;
 168         }
 169
 170         if(time >= self.ltime)
 171         {
 172                 remove(self);
 173                 return;
 174         }
 175
 176         vector midpoint = ((self.absmin + self.absmax) * 0.5);
 177         if(pointcontents(midpoint) == CONTENT_WATER)
 178         {
 179                 self.velocity = self.velocity * 0.5;
 180
 181                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 182                         { self.velocity_z = 200; }
 183
 184                 UpdateCSQCProjectile(self);
 185         }
 186
 187         napalm_damage(autocvar_g_nades_napalm_fountain_radius, autocvar_g_nades_napalm_fountain_damage,
 188                 autocvar_g_nades_napalm_fountain_edgedamage, autocvar_g_nades_napalm_burntime);
 189
 190         self.nextthink = time + 0.1;
 191         if(time >= self.nade_special_time)
 192         {
 193                 self.nade_special_time = time + autocvar_g_nades_napalm_fountain_delay;
 194                 nade_napalm_ball();
 195         }
 196 }
 197
 198 void nade_napalm_boom()
 199 {
 200         entity fountain;
 201         int c;
 202         for (c = 0; c < autocvar_g_nades_napalm_ball_count; c++)
 203                 nade_napalm_ball();
 204
 205
 206         fountain = spawn();
 207         fountain.owner = self.owner;
 208         fountain.realowner = self.realowner;
 209         fountain.origin = self.origin;
 210         setorigin(fountain, fountain.origin);
 211         fountain.think = napalm_fountain_think;
 212         fountain.nextthink = time;
 213         fountain.ltime = time + autocvar_g_nades_napalm_fountain_lifetime;
 214         fountain.pushltime = fountain.ltime;
 215         fountain.team = self.team;
 216         fountain.movetype = MOVETYPE_TOSS;
 217         fountain.projectiledeathtype = DEATH_NADE_NAPALM;
 218         fountain.bot_dodge = true;
 219         fountain.bot_dodgerating = autocvar_g_nades_napalm_fountain_damage;
 220         fountain.nade_special_time = time;
 221         setsize(fountain, '-16 -16 -16', '16 16 16');
 222         CSQCProjectile(fountain, true, PROJECTILE_NAPALM_FOUNTAIN, true);
 223 }
 224
 225 void nade_ice_freeze(entity freezefield, entity frost_target, float freeze_time)
 226 {
 227         frost_target.frozen_by = freezefield.realowner;
 228         pointparticles(particleeffectnum("electro_impact"), frost_target.origin, '0 0 0', 1);
 229         Freeze(frost_target, 1/freeze_time, 3, false);
 230         if(frost_target.ballcarried)
 231         if(g_keepaway) { ka_DropEvent(frost_target); }
 232         else { DropBall(frost_target.ballcarried, frost_target.origin, frost_target.velocity);}
 233         if(frost_target.flagcarried) { ctf_Handle_Throw(frost_target, world, DROP_THROW); }
 234         if(frost_target.nade) { toss_nade(frost_target, '0 0 0', time + 0.05); }
 235
 236         kh_Key_DropAll(frost_target, false);
 237 }
 238
 239 void nade_ice_think()
 240 {
 241
 242         if(round_handler_IsActive())
 243         if(!round_handler_IsRoundStarted())
 244         {
 245                 remove(self);
 246                 return;
 247         }
 248
 249         if(time >= self.ltime)
 250         {
 251                 if ( autocvar_g_nades_ice_explode )
 252                 {
 253                         string expef;
 254                         switch(self.realowner.team)
 255                         {
 256                                 case NUM_TEAM_1: expef = "nade_red_explode"; break;
 257                                 case NUM_TEAM_2: expef = "nade_blue_explode"; break;
 258                                 case NUM_TEAM_3: expef = "nade_yellow_explode"; break;
 259                                 case NUM_TEAM_4: expef = "nade_pink_explode"; break;
 260                                 default:                 expef = "nade_neutral_explode"; break;
 261                         }
 262                         pointparticles(particleeffectnum(expef), self.origin + '0 0 1', '0 0 0', 1);
 263                         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 264
 265                         RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 266                                 autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
 267                         Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 268                                 autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
 269                 }
 270                 remove(self);
 271                 return;
 272         }
 273
 274
 275         self.nextthink = time+0.1;
 276
 277         // gaussian
 278         float randomr;
 279         randomr = random();
 280         randomr = exp(-5*randomr*randomr)*autocvar_g_nades_nade_radius;
 281         float randomw;
 282         randomw = random()*M_PI*2;
 283         vector randomp;
 284         randomp.x = randomr*cos(randomw);
 285         randomp.y = randomr*sin(randomw);
 286         randomp.z = 1;
 287         pointparticles(particleeffectnum("electro_muzzleflash"), self.origin + randomp, '0 0 0', 1);
 288
 289         if(time >= self.nade_special_time)
 290         {
 291                 self.nade_special_time = time+0.7;
 292
 293
 294                 pointparticles(particleeffectnum("electro_impact"), self.origin, '0 0 0', 1);
 295                 pointparticles(particleeffectnum("icefield"), self.origin, '0 0 0', 1);
 296         }
 297
 298
 299         float current_freeze_time = self.ltime - time - 0.1;
 300
 301         entity e;
 302         for(e = findradius(self.origin, autocvar_g_nades_nade_radius); e; e = e.chain)
 303         if(e != self)
 304         if(!autocvar_g_nades_ice_teamcheck || (DIFF_TEAM(e, self.realowner) || e == self.realowner))
 305         if(e.takedamage && e.deadflag == DEAD_NO)
 306         if(e.health > 0)
 307         if(!e.revival_time || ((time - e.revival_time) >= 1.5))
 308         if(!e.frozen)
 309         if(current_freeze_time > 0)
 310                 nade_ice_freeze(self, e, current_freeze_time);
 311 }
 312
 313 void nade_ice_boom()
 314 {
 315         entity fountain;
 316         fountain = spawn();
 317         fountain.owner = self.owner;
 318         fountain.realowner = self.realowner;
 319         fountain.origin = self.origin;
 320         setorigin(fountain, fountain.origin);
 321         fountain.think = nade_ice_think;
 322         fountain.nextthink = time;
 323         fountain.ltime = time + autocvar_g_nades_ice_freeze_time;
 324         fountain.pushltime = fountain.wait = fountain.ltime;
 325         fountain.team = self.team;
 326         fountain.movetype = MOVETYPE_TOSS;
 327         fountain.projectiledeathtype = DEATH_NADE_ICE;
 328         fountain.bot_dodge = false;
 329         setsize(fountain, '-16 -16 -16', '16 16 16');
 330         fountain.nade_special_time = time+0.3;
 331         fountain.angles = self.angles;
 332
 333         if ( autocvar_g_nades_ice_explode )
 334         {
 335                 setmodel(fountain, "models/grenademodel.md3");
 336                 entity timer = spawn();
 337                 setmodel(timer, "models/ok_nade_counter/ok_nade_counter.md3");
 338                 setattachment(timer, fountain, "");
 339                 timer.classname = "nade_timer";
 340                 timer.colormap = self.colormap;
 341                 timer.glowmod = self.glowmod;
 342                 timer.think = nade_timer_think;
 343                 timer.nextthink = time;
 344                 timer.wait = fountain.ltime;
 345                 timer.owner = fountain;
 346                 timer.skin = 10;
 347         }
 348         else
 349                 setmodel(fountain, "null");
 350 }
 351
 352 void nade_translocate_boom()
 353 {
 354         if(self.realowner.vehicle)
 355                 return;
 356
 357         vector locout = self.origin + '0 0 1' * (1 - self.realowner.mins.z - 24);
 358         tracebox(locout, self.realowner.mins, self.realowner.maxs, locout, MOVE_NOMONSTERS, self.realowner);
 359         locout = trace_endpos;
 360
 361         makevectors(self.realowner.angles);
 362
 363         entity oldself = self;
 364         self = self.realowner;
 365         MUTATOR_CALLHOOK(PortalTeleport);
 366         self.realowner = self;
 367         self = oldself;
 368
 369         TeleportPlayer(self, self.realowner, locout, self.realowner.mangle, v_forward * vlen(self.realowner.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 370 }
 371
 372 void nade_spawn_boom()
 373 {
 374         entity spawnloc = spawn();
 375         setorigin(spawnloc, self.origin);
 376         setsize(spawnloc, self.realowner.mins, self.realowner.maxs);
 377         spawnloc.movetype = MOVETYPE_NONE;
 378         spawnloc.solid = SOLID_NOT;
 379         spawnloc.drawonlytoclient = self.realowner;
 380         spawnloc.effects = EF_STARDUST;
 381         spawnloc.cnt = autocvar_g_nades_spawn_count;
 382
 383         if(self.realowner.nade_spawnloc)
 384         {
 385                 remove(self.realowner.nade_spawnloc);
 386                 self.realowner.nade_spawnloc = world;
 387         }
 388
 389         self.realowner.nade_spawnloc = spawnloc;
 390 }
 391
 392 void nade_heal_think()
 393 {
 394         if(time >= self.ltime)
 395         {
 396                 remove(self);
 397                 return;
 398         }
 399
 400         self.nextthink = time;
 401
 402         if(time >= self.nade_special_time)
 403         {
 404                 self.nade_special_time = time+0.25;
 405                 self.nade_show_particles = 1;
 406         }
 407         else
 408                 self.nade_show_particles = 0;
 409 }
 410
 411 void nade_heal_touch()
 412 {
 413         float maxhealth;
 414         float health_factor;
 415         if(IS_PLAYER(other) || (other.flags & FL_MONSTER))
 416         if(other.deadflag == DEAD_NO)
 417         if(!other.frozen)
 418         {
 419                 health_factor = autocvar_g_nades_heal_rate*frametime/2;
 420                 if ( other != self.realowner )
 421                 {
 422                         if ( SAME_TEAM(other,self) )
 423                                 health_factor *= autocvar_g_nades_heal_friend;
 424                         else
 425                                 health_factor *= autocvar_g_nades_heal_foe;
 426                 }
 427                 if ( health_factor > 0 )
 428                 {
 429                         maxhealth = (other.flags & FL_MONSTER) ? other.max_health : g_pickup_healthmega_max;
 430                         if ( other.health < maxhealth )
 431                         {
 432                                 if ( self.nade_show_particles )
 433                                         pointparticles(particleeffectnum("healing_fx"), other.origin, '0 0 0', 1);
 434                                 other.health = min(other.health+health_factor, maxhealth);
 435                         }
 436                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 437                 }
 438                 else if ( health_factor < 0 )
 439                 {
 440                         Damage(other,self,self.realowner,-health_factor,DEATH_NADE_HEAL,other.origin,'0 0 0');
 441                 }
 442
 443         }
 444
 445         if ( IS_REAL_CLIENT(other) || (other.vehicle_flags & VHF_ISVEHICLE) )
 446         {
 447                 entity show_red = (other.vehicle_flags & VHF_ISVEHICLE) ? other.owner : other;
 448                 show_red.stat_healing_orb = time+0.1;
 449                 show_red.stat_healing_orb_alpha = 0.75 * (self.ltime - time) / self.healer_lifetime;
 450         }
 451 }
 452
 453 void nade_heal_boom()
 454 {
 455         entity healer;
 456         healer = spawn();
 457         healer.owner = self.owner;
 458         healer.realowner = self.realowner;
 459         setorigin(healer, self.origin);
 460         healer.healer_lifetime = autocvar_g_nades_heal_time; // save the cvar
 461         healer.ltime = time + healer.healer_lifetime;
 462         healer.team = self.realowner.team;
 463         healer.bot_dodge = false;
 464         healer.solid = SOLID_TRIGGER;
 465         healer.touch = nade_heal_touch;
 466
 467         setmodel(healer, "models/ctf/shield.md3");
 468         healer.healer_radius = autocvar_g_nades_nade_radius;
 469         vector size = '1 1 1' * healer.healer_radius / 2;
 470         setsize(healer,-size,size);
 471
 472         Net_LinkEntity(healer, true, 0, healer_send);
 473
 474         healer.think = nade_heal_think;
 475         healer.nextthink = time;
 476         healer.SendFlags |= 1;
 477 }
 478
 479 void nade_monster_boom()
 480 {
 481         entity e = spawnmonster(self.pokenade_type, 0, self.realowner, self.realowner, self.origin, false, false, 1);
 482
 483         if(autocvar_g_nades_pokenade_monster_lifetime > 0)
 484                 e.monster_lifetime = time + autocvar_g_nades_pokenade_monster_lifetime;
 485         e.monster_skill = MONSTER_SKILL_INSANE;
 486 }
 487
 488 void nade_boom()
 489 {
 490         string expef;
 491         bool nade_blast = true;
 492
 493         switch ( self.nade_type )
 494         {
 495                 case NADE_TYPE_NAPALM:
 496                         nade_blast = autocvar_g_nades_napalm_blast;
 497                         expef = "explosion_medium";
 498                         break;
 499                 case NADE_TYPE_ICE:
 500                         nade_blast = false;
 501                         expef = "electro_combo"; // hookbomb_explode electro_combo bigplasma_impact
 502                         break;
 503                 case NADE_TYPE_TRANSLOCATE:
 504                         nade_blast = false;
 505                         expef = "";
 506                         break;
 507                 case NADE_TYPE_MONSTER:
 508                 case NADE_TYPE_SPAWN:
 509                         nade_blast = false;
 510                         switch(self.realowner.team)
 511                         {
 512                                 case NUM_TEAM_1: expef = "spawn_event_red"; break;
 513                                 case NUM_TEAM_2: expef = "spawn_event_blue"; break;
 514                                 case NUM_TEAM_3: expef = "spawn_event_yellow"; break;
 515                                 case NUM_TEAM_4: expef = "spawn_event_pink"; break;
 516                                 default: expef = "spawn_event_neutral"; break;
 517                         }
 518                         break;
 519                 case NADE_TYPE_HEAL:
 520                         nade_blast = false;
 521                         expef = "spawn_event_red";
 522                         break;
 523
 524                 default:
 525                 case NADE_TYPE_NORMAL:
 526                         switch(self.realowner.team)
 527                         {
 528                                 case NUM_TEAM_1: expef = "nade_red_explode"; break;
 529                                 case NUM_TEAM_2: expef = "nade_blue_explode"; break;
 530                                 case NUM_TEAM_3: expef = "nade_yellow_explode"; break;
 531                                 case NUM_TEAM_4: expef = "nade_pink_explode"; break;
 532                                 default:                 expef = "nade_neutral_explode"; break;
 533                         }
 534         }
 535
 536         if(expef != "")
 537                 pointparticles(particleeffectnum(expef), findbetterlocation(self.origin, 8), '0 0 0', 1);
 538
 539         sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
 540         sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
 541
 542         self.event_damage = func_null; // prevent somehow calling damage in the next call
 543
 544         if(nade_blast)
 545         {
 546                 RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 547                                  autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
 548                 Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage, autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
 549         }
 550
 551         if(self.takedamage)
 552         switch ( self.nade_type )
 553         {
 554                 case NADE_TYPE_NAPALM: nade_napalm_boom(); break;
 555                 case NADE_TYPE_ICE: nade_ice_boom(); break;
 556                 case NADE_TYPE_TRANSLOCATE: nade_translocate_boom(); break;
 557                 case NADE_TYPE_SPAWN: nade_spawn_boom(); break;
 558                 case NADE_TYPE_HEAL: nade_heal_boom(); break;
 559                 case NADE_TYPE_MONSTER: nade_monster_boom(); break;
 560         }
 561
 562         remove(self);
 563 }
 564
 565 void nade_touch()
 566 {
 567         /*float is_weapclip = 0;
 568         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 569         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 570         if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 571                 is_weapclip = 1;*/
 572         if(ITEM_TOUCH_NEEDKILL()) // || is_weapclip)
 573         {
 574                 remove(self);
 575                 return;
 576         }
 577
 578         PROJECTILE_TOUCH;
 579
 580         //setsize(self, '-2 -2 -2', '2 2 2');
 581         //UpdateCSQCProjectile(self);
 582         if(self.health == self.max_health)
 583         {
 584                 spamsound(self, CH_SHOTS, strcat("weapons/grenade_bounce", ftos(1 + rint(random() * 5)), ".wav"), VOL_BASE, ATTEN_NORM);
 585                 return;
 586         }
 587
 588         self.enemy = other;
 589         nade_boom();
 590 }
 591
 592 void nade_beep()
 593 {
 594         sound(self, CH_SHOTS_SINGLE, "overkill/grenadebip.ogg", VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 595         self.think = nade_boom;
 596         self.nextthink = max(self.wait, time);
 597 }
 598
 599 void nade_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 600 {
 601         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 602         {
 603                 self.takedamage = DAMAGE_NO;
 604                 nade_boom();
 605                 return;
 606         }
 607
 608         if(self.nade_type == NADE_TYPE_TRANSLOCATE || self.nade_type == NADE_TYPE_SPAWN)
 609                 return;
 610
 611         if(DEATH_ISWEAPON(deathtype, WEP_BLASTER))
 612         {
 613                 force *= 1.5;
 614                 damage = 0;
 615         }
 616
 617         if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER) && (deathtype & HITTYPE_SECONDARY))
 618         {
 619                 force *= 0.5; // too much
 620                 frag_damage = 0;
 621         }
 622
 623         if(DEATH_ISWEAPON(deathtype, WEP_VORTEX) || DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
 624         {
 625                 force *= 6;
 626                 damage = self.max_health * 0.55;
 627         }
 628
 629         if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN) || DEATH_ISWEAPON(deathtype, WEP_HMG))
 630                 damage = self.max_health * 0.1;
 631
 632         if(DEATH_ISWEAPON(deathtype, WEP_SHOCKWAVE) || DEATH_ISWEAPON(deathtype, WEP_SHOTGUN)) // WEAPONTODO
 633         if(deathtype & HITTYPE_SECONDARY)
 634         {
 635                 damage = self.max_health * 0.1;
 636                 force *= 10;
 637         }
 638         else
 639                 damage = self.max_health * 1.15;
 640
 641         self.velocity += force;
 642         UpdateCSQCProjectile(self);
 643
 644         if(damage <= 0 || ((self.flags & FL_ONGROUND) && IS_PLAYER(attacker)))
 645                 return;
 646
 647         if(self.health == self.max_health)
 648         {
 649                 sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 650                 self.nextthink = max(time + autocvar_g_nades_nade_lifetime, time);
 651                 self.think = nade_beep;
 652         }
 653
 654         self.health -= damage;
 655
 656         if ( self.nade_type != NADE_TYPE_HEAL || IS_PLAYER(attacker) )
 657                 self.realowner = attacker;
 658
 659         if(self.health <= 0)
 660                 W_PrepareExplosionByDamage(attacker, nade_boom);
 661         else
 662                 nade_burn_spawn(self);
 663 }
 664
 665 void toss_nade(entity e, vector _velocity, float _time)
 666 {
 667         if(e.nade == world)
 668                 return;
 669
 670         entity _nade = e.nade;
 671         e.nade = world;
 672
 673         remove(e.fake_nade);
 674         e.fake_nade = world;
 675
 676         makevectors(e.v_angle);
 677
 678         W_SetupShot(e, false, false, "", CH_WEAPON_A, 0);
 679
 680         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_NADES);
 681
 682         vector offset = (v_forward * autocvar_g_nades_throw_offset.x)
 683                                   + (v_right * autocvar_g_nades_throw_offset.y)
 684                                   + (v_up * autocvar_g_nades_throw_offset.z);
 685         if(autocvar_g_nades_throw_offset == '0 0 0')
 686                 offset = '0 0 0';
 687
 688         setorigin(_nade, w_shotorg + offset + (v_right * 25) * -1);
 689         //setmodel(_nade, "models/weapons/v_ok_grenade.md3");
 690         //setattachment(_nade, world, "");
 691         PROJECTILE_MAKETRIGGER(_nade);
 692         setsize(_nade, '-16 -16 -16', '16 16 16');
 693         _nade.movetype = MOVETYPE_BOUNCE;
 694
 695         tracebox(_nade.origin, _nade.mins, _nade.maxs, _nade.origin, false, _nade);
 696         if (trace_startsolid)
 697                 setorigin(_nade, e.origin);
 698
 699         if(self.v_angle.x >= 70 && self.v_angle.x <= 110 && self.BUTTON_CROUCH)
 700                 _nade.velocity = '0 0 100';
 701         else if(autocvar_g_nades_nade_newton_style == 1)
 702                 _nade.velocity = e.velocity + _velocity;
 703         else if(autocvar_g_nades_nade_newton_style == 2)
 704                 _nade.velocity = _velocity;
 705         else
 706                 _nade.velocity = W_CalculateProjectileVelocity(e.velocity, _velocity, true);
 707
 708         _nade.touch = nade_touch;
 709         _nade.health = autocvar_g_nades_nade_health;
 710         _nade.max_health = _nade.health;
 711         _nade.takedamage = DAMAGE_AIM;
 712         _nade.event_damage = nade_damage;
 713         _nade.customizeentityforclient = func_null;
 714         _nade.exteriormodeltoclient = world;
 715         _nade.traileffectnum = 0;
 716         _nade.teleportable = true;
 717         _nade.pushable = true;
 718         _nade.gravity = 1;
 719         _nade.missile_flags = MIF_SPLASH | MIF_ARC;
 720         _nade.damagedbycontents = true;
 721         _nade.angles = vectoangles(_nade.velocity);
 722         _nade.flags = FL_PROJECTILE;
 723         _nade.projectiledeathtype = DEATH_NADE;
 724         _nade.toss_time = time;
 725         _nade.solid = SOLID_CORPSE; //((_nade.nade_type == NADE_TYPE_TRANSLOCATE) ? SOLID_CORPSE : SOLID_BBOX);
 726
 727         if(_nade.nade_type == NADE_TYPE_TRANSLOCATE || _nade.nade_type == NADE_TYPE_SPAWN)
 728                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 729         else
 730                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 731
 732         nade_spawn(_nade);
 733
 734         if(_time)
 735         {
 736                 _nade.think = nade_boom;
 737                 _nade.nextthink = _time;
 738         }
 739
 740         e.nade_refire = time + autocvar_g_nades_nade_refire;
 741         e.nade_timer = 0;
 742 }
 743
 744 void nades_GiveBonus(entity player, float score)
 745 {
 746         if (autocvar_g_nades)
 747         if (autocvar_g_nades_bonus)
 748         if (IS_REAL_CLIENT(player))
 749         if (IS_PLAYER(player) && player.bonus_nades < autocvar_g_nades_bonus_max)
 750         if (player.frozen == 0)
 751         if (player.deadflag == DEAD_NO)
 752         {
 753                 if ( player.bonus_nade_score < 1 )
 754                         player.bonus_nade_score += score/autocvar_g_nades_bonus_score_max;
 755
 756                 if ( player.bonus_nade_score >= 1 )
 757                 {
 758                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_NADE_BONUS);
 759                         play2(player,"kh/alarm.wav");
 760                         player.bonus_nades++;
 761                         player.bonus_nade_score -= 1;
 762                 }
 763         }
 764 }
 765
 766 void nades_RemoveBonus(entity player)
 767 {
 768         player.bonus_nades = player.bonus_nade_score = 0;
 769 }
 770
 771 float nade_customize()
 772 {
 773         //if(IS_SPEC(other)) { return false; }
 774         if(other == self.realowner || (IS_SPEC(other) && other.enemy == self.realowner))
 775         {
 776                 // somewhat hide the model, but keep the glow
 777                 //self.effects = 0;
 778                 if(self.traileffectnum)
 779                         self.traileffectnum = 0;
 780                 self.alpha = -1;
 781         }
 782         else
 783         {
 784                 //self.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 785                 if(!self.traileffectnum)
 786                         self.traileffectnum = particleeffectnum(Nade_TrailEffect(Nade_ProjectileFromID(self.nade_type, false), self.team));
 787                 self.alpha = 1;
 788         }
 789
 790         return true;
 791 }
 792
 793 void nade_prime()
 794 {
 795         if(self.nade)
 796                 remove(self.nade);
 797
 798         if(self.fake_nade)
 799                 remove(self.fake_nade);
 800
 801         entity n = spawn(), fn = spawn();
 802
 803         n.classname = "nade";
 804         fn.classname = "fake_nade";
 805
 806         if(self.items & IT_STRENGTH && autocvar_g_nades_bonus_onstrength)
 807                 n.nade_type = self.nade_type;
 808         else if (self.bonus_nades >= 1)
 809         {
 810                 n.nade_type = self.nade_type;
 811                 n.pokenade_type = self.pokenade_type;
 812                 self.bonus_nades -= 1;
 813         }
 814         else
 815         {
 816                 n.nade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_nade_type : autocvar_g_nades_nade_type);
 817                 n.pokenade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_pokenade_type : autocvar_g_nades_pokenade_monster_type);
 818         }
 819
 820         n.nade_type = bound(1, n.nade_type, NADE_TYPE_LAST);
 821
 822         setmodel(n, "models/weapons/v_ok_grenade.md3");
 823         //setattachment(n, self, "bip01 l hand");
 824         n.exteriormodeltoclient = self;
 825         n.customizeentityforclient = nade_customize;
 826         n.traileffectnum = particleeffectnum(Nade_TrailEffect(Nade_ProjectileFromID(n.nade_type, false), self.team));
 827         n.colormod = Nade_Color(n.nade_type);
 828         n.realowner = self;
 829         n.colormap = self.colormap;
 830         n.glowmod = self.glowmod;
 831         n.wait = time + autocvar_g_nades_nade_lifetime;
 832         n.lifetime = time;
 833         n.think = nade_beep;
 834         n.nextthink = max(n.wait - 3, time);
 835         n.projectiledeathtype = DEATH_NADE;
 836
 837         setmodel(fn, "models/weapons/h_ok_grenade.iqm");
 838         setattachment(fn, self.weaponentity, "");
 839         fn.realowner = fn.owner = self;
 840         fn.colormod = Nade_Color(n.nade_type);
 841         fn.colormap = self.colormap;
 842         fn.glowmod = self.glowmod;
 843         fn.think = SUB_Remove;
 844         fn.nextthink = n.wait;
 845
 846         self.nade = n;
 847         self.fake_nade = fn;
 848 }
 849
 850 float CanThrowNade()
 851 {
 852         if(self.vehicle)
 853                 return false;
 854
 855         if(gameover)
 856                 return false;
 857
 858         if(self.deadflag != DEAD_NO)
 859                 return false;
 860
 861         if (!autocvar_g_nades)
 862                 return false; // allow turning them off mid match
 863
 864         if(forbidWeaponUse())
 865                 return false;
 866
 867         if (!IS_PLAYER(self))
 868                 return false;
 869
 870         return true;
 871 }
 872
 873 void nades_CheckThrow()
 874 {
 875         if(!CanThrowNade())
 876                 return;
 877
 878         if(!self.nade)
 879         {
 880                 if(self.nade_refire < time)
 881                 {
 882                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_NADE_THROW);
 883                         nade_prime();
 884                         self.nade_refire = time + autocvar_g_nades_nade_refire;
 885                 }
 886         }
 887         else
 888         {
 889                 if(time - self.nade.lifetime >= 1)
 890                 {
 891                         makevectors(self.v_angle);
 892                         float _force = time - self.nade.lifetime;
 893                         _force /= autocvar_g_nades_nade_lifetime;
 894                         _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
 895                         toss_nade(self, (v_forward * 0.75 + v_up * 0.2 + v_right * 0.05) * _force, 0);
 896                 }
 897         }
 898 }
 899
 900 void nades_Clear(entity player)
 901 {
 902         if(player.nade)
 903                 remove(player.nade);
 904         if(player.fake_nade)
 905                 remove(player.fake_nade);
 906
 907         player.nade = player.fake_nade = world;
 908         player.nade_timer = 0;
 909 }
 910
 911 MUTATOR_HOOKFUNCTION(nades_CheckThrow)
 912 {
 913         if(MUTATOR_RETURNVALUE) { nades_CheckThrow(); }
 914         return false;
 915 }
 916
 917 MUTATOR_HOOKFUNCTION(nades_VehicleEnter)
 918 {
 919         if(vh_player.nade)
 920                 toss_nade(vh_player, '0 0 100', max(vh_player.nade.wait, time + 0.05));
 921
 922         return false;
 923 }
 924
 925 MUTATOR_HOOKFUNCTION(nades_PlayerPreThink)
 926 {
 927         if(!IS_PLAYER(self)) { return false; }
 928
 929         float key_pressed = self.BUTTON_HOOK;
 930         float time_score;
 931
 932         if(g_grappling_hook || client_hasweapon(self, WEP_HOOK, false, false) || (weaponsInMap & WEPSET_HOOK))
 933                 key_pressed = self.button16; // if hook is enabled, use an alternate key
 934
 935         if(self.nade)
 936         {
 937                 self.nade_timer = bound(0, (time - self.nade.lifetime) / autocvar_g_nades_nade_lifetime, 1);
 938                 //print(sprintf("%d %d\n", self.nade_timer, time - self.nade.lifetime));
 939                 makevectors(self.angles);
 940                 self.nade.velocity = self.velocity;
 941
 942                 setorigin(self.nade, self.origin + self.view_ofs + v_forward * 8 + v_right * -8 + v_up * 0);
 943                 self.nade.angles_y = self.angles.y;
 944         }
 945
 946         if(self.nade)
 947         if(self.nade.wait - 0.1 <= time)
 948                 toss_nade(self, '0 0 0', time + 0.05);
 949
 950         if(CanThrowNade())
 951         if(self.nade_refire < time)
 952         {
 953                 if(key_pressed)
 954                 {
 955                         if(!self.nade)
 956                                 nade_prime();
 957                 }
 958                 else if(time - self.nade.lifetime >= 1)
 959                 {
 960                         if(self.nade)
 961                         {
 962                                 makevectors(self.v_angle);
 963                                 float _force = time - self.nade.lifetime;
 964                                 _force /= autocvar_g_nades_nade_lifetime;
 965                                 _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
 966                                 toss_nade(self, (v_forward * 0.7 + v_up * 0.2 + v_right * 0.1) * _force, 0);
 967                         }
 968                 }
 969         }
 970
 971         if(IS_PLAYER(self))
 972         {
 973                 if ( autocvar_g_nades_bonus && autocvar_g_nades )
 974                 {
 975                         entity key;
 976                         float key_count = 0;
 977                         FOR_EACH_KH_KEY(key) if(key.owner == self) { ++key_count; }
 978
 979                         if(self.flagcarried || self.ballcarried) // this player is important
 980                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier;
 981                         else
 982                                 time_score = autocvar_g_nades_bonus_score_time;
 983
 984                         if(key_count)
 985                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier * key_count; // multiply by the number of keys the player is holding
 986
 987                         if(autocvar_g_nades_bonus_client_select)
 988                         {
 989                                 self.nade_type = self.cvar_cl_nade_type;
 990                                 self.pokenade_type = self.cvar_cl_pokenade_type;
 991                         }
 992                         else
 993                         {
 994                                 self.nade_type = autocvar_g_nades_bonus_type;
 995                                 self.pokenade_type = autocvar_g_nades_pokenade_monster_type;
 996                         }
 997
 998                         self.nade_type = bound(1, self.nade_type, NADE_TYPE_LAST);
 999
1000                         if(self.bonus_nade_score >= 0 && autocvar_g_nades_bonus_score_max)
1001                                 nades_GiveBonus(self, time_score / autocvar_g_nades_bonus_score_max);
1002                 }
1003                 else
1004                 {
1005                         self.bonus_nades = self.bonus_nade_score = 0;
1006                 }
1007         }
1008
1009         float n = 0;
1010         entity o = world;
1011         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
1012                 n = -1;
1013         else
1014         {
1015                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
1016                 n = 0;
1017                 FOR_EACH_PLAYER(other) if(self != other)
1018                 {
1019                         if(other.deadflag == DEAD_NO)
1020                         if(other.frozen == 0)
1021                         if(SAME_TEAM(other, self))
1022                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, other.absmin, other.absmax))
1023                         {
1024                                 if(!o)
1025                                         o = other;
1026                                 if(self.frozen == 1)
1027                                         other.reviving = true;
1028                                 ++n;
1029                         }
1030                 }
1031         }
1032
1033         if(n && self.frozen == 3) // OK, there is at least one teammate reviving us
1034         {
1035                 self.revive_progress = bound(0, self.revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
1036                 self.health = max(1, self.revive_progress * start_health);
1037
1038                 if(self.revive_progress >= 1)
1039                 {
1040                         Unfreeze(self);
1041
1042                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
1043                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, self.netname);
1044                 }
1045
1046                 FOR_EACH_PLAYER(other) if(other.reviving)
1047                 {
1048                         other.revive_progress = self.revive_progress;
1049                         other.reviving = false;
1050                 }
1051         }
1052
1053         return false;
1054 }
1055
1056 MUTATOR_HOOKFUNCTION(nades_PlayerSpawn)
1057 {
1058         if(autocvar_g_nades_spawn)
1059                 self.nade_refire = time + autocvar_g_spawnshieldtime;
1060         else
1061                 self.nade_refire  = time + autocvar_g_nades_nade_refire;
1062
1063         if(autocvar_g_nades_bonus_client_select)
1064                 self.nade_type = self.cvar_cl_nade_type;
1065
1066         self.nade_timer = 0;
1067
1068         if(self.nade_spawnloc)
1069         {
1070                 setorigin(self, self.nade_spawnloc.origin);
1071                 self.nade_spawnloc.cnt -= 1;
1072
1073                 if(self.nade_spawnloc.cnt <= 0)
1074                 {
1075                         remove(self.nade_spawnloc);
1076                         self.nade_spawnloc = world;
1077                 }
1078         }
1079
1080         return false;
1081 }
1082
1083 MUTATOR_HOOKFUNCTION(nades_PlayerDies)
1084 {
1085         if(frag_target.nade)
1086         if(!frag_target.frozen || !autocvar_g_freezetag_revive_nade)
1087                 toss_nade(frag_target, '0 0 100', max(frag_target.nade.wait, time + 0.05));
1088
1089         float killcount_bonus = ((frag_attacker.killcount >= 1) ? bound(0, autocvar_g_nades_bonus_score_minor * frag_attacker.killcount, autocvar_g_nades_bonus_score_medium) : autocvar_g_nades_bonus_score_minor);
1090
1091         if(IS_PLAYER(frag_attacker))
1092         {
1093                 if (SAME_TEAM(frag_attacker, frag_target) || frag_attacker == frag_target)
1094                         nades_RemoveBonus(frag_attacker);
1095                 else if(frag_target.flagcarried)
1096                         nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_medium);
1097                 else if(autocvar_g_nades_bonus_score_spree && frag_attacker.killcount > 1)
1098                 {
1099                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
1100                                 case counta: { nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_spree); break; }
1101                         switch(frag_attacker.killcount)
1102                         {
1103                                 KILL_SPREE_LIST
1104                                 default: nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor); break;
1105                         }
1106                         #undef SPREE_ITEM
1107                 }
1108                 else
1109                         nades_GiveBonus(frag_attacker, killcount_bonus);
1110         }
1111
1112         nades_RemoveBonus(frag_target);
1113
1114         return false;
1115 }
1116
1117 MUTATOR_HOOKFUNCTION(nades_PlayerDamage)
1118 {
1119         if(frag_target.frozen)
1120         if(autocvar_g_freezetag_revive_nade)
1121         if(frag_attacker == frag_target)
1122         if(frag_deathtype == DEATH_NADE)
1123         if(time - frag_inflictor.toss_time <= 0.1)
1124         {
1125                 Unfreeze(frag_target);
1126                 frag_target.health = autocvar_g_freezetag_revive_nade_health;
1127                 pointparticles(particleeffectnum("iceorglass"), frag_target.origin, '0 0 0', 3);
1128                 frag_damage = 0;
1129                 frag_force = '0 0 0';
1130                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED_NADE, frag_target.netname);
1131                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_SELF);
1132         }
1133
1134         return false;
1135 }
1136
1137 MUTATOR_HOOKFUNCTION(nades_MonsterDies)
1138 {
1139         if(IS_PLAYER(frag_attacker))
1140         if(DIFF_TEAM(frag_attacker, self))
1141         if(!(self.spawnflags & MONSTERFLAG_SPAWNED))
1142                 nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor);
1143
1144         return false;
1145 }
1146
1147 MUTATOR_HOOKFUNCTION(nades_RemovePlayer)
1148 {
1149         nades_Clear(self);
1150         nades_RemoveBonus(self);
1151         return false;
1152 }
1153
1154 MUTATOR_HOOKFUNCTION(nades_SpectateCopy)
1155 {
1156         self.nade_timer = other.nade_timer;
1157         self.nade_type = other.nade_type;
1158         self.pokenade_type = other.pokenade_type;
1159         self.bonus_nades = other.bonus_nades;
1160         self.bonus_nade_score = other.bonus_nade_score;
1161         self.stat_healing_orb = other.stat_healing_orb;
1162         self.stat_healing_orb_alpha = other.stat_healing_orb_alpha;
1163         return false;
1164 }
1165
1166 MUTATOR_HOOKFUNCTION(nades_GetCvars)
1167 {
1168         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_nade_type, "cl_nade_type");
1169         GetCvars_handleString(get_cvars_s, get_cvars_f, cvar_cl_pokenade_type, "cl_pokenade_type");
1170
1171         return false;
1172 }
1173
1174 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsString)
1175 {
1176         ret_string = strcat(ret_string, ":Nades");
1177         return false;
1178 }
1179
1180 MUTATOR_HOOKFUNCTION(nades_BuildMutatorsPrettyString)
1181 {
1182         ret_string = strcat(ret_string, ", Nades");
1183         return false;
1184 }
1185
1186 void nades_Initialize()
1187 {
1188         addstat(STAT_NADE_TIMER, AS_FLOAT, nade_timer);
1189         addstat(STAT_NADE_BONUS, AS_FLOAT, bonus_nades);
1190         addstat(STAT_NADE_BONUS_TYPE, AS_INT, nade_type);
1191         addstat(STAT_NADE_BONUS_SCORE, AS_FLOAT, bonus_nade_score);
1192         addstat(STAT_HEALING_ORB, AS_FLOAT, stat_healing_orb);
1193         addstat(STAT_HEALING_ORB_ALPHA, AS_FLOAT, stat_healing_orb_alpha);
1194
1195         precache_model("models/ok_nade_counter/ok_nade_counter.md3");
1196         precache_model("models/weapons/h_ok_grenade.iqm");
1197         precache_model("models/weapons/v_ok_grenade.md3");
1198         precache_model("models/ctf/shield.md3");
1199
1200         precache_sound("weapons/rocket_impact.wav");
1201         precache_sound("weapons/grenade_bounce1.wav");
1202         precache_sound("weapons/grenade_bounce2.wav");
1203         precache_sound("weapons/grenade_bounce3.wav");
1204         precache_sound("weapons/grenade_bounce4.wav");
1205         precache_sound("weapons/grenade_bounce5.wav");
1206         precache_sound("weapons/grenade_bounce6.wav");
1207         precache_sound("overkill/grenadebip.ogg");
1208 }
1209
1210 MUTATOR_DEFINITION(mutator_nades)
1211 {
1212         MUTATOR_HOOK(ForbidThrowCurrentWeapon, nades_CheckThrow, CBC_ORDER_LAST);
1213         MUTATOR_HOOK(VehicleEnter, nades_VehicleEnter, CBC_ORDER_ANY);
1214         MUTATOR_HOOK(PlayerPreThink, nades_PlayerPreThink, CBC_ORDER_ANY);
1215         MUTATOR_HOOK(PlayerSpawn, nades_PlayerSpawn, CBC_ORDER_ANY);
1216         MUTATOR_HOOK(PlayerDies, nades_PlayerDies, CBC_ORDER_LAST);
1217         MUTATOR_HOOK(PlayerDamage_Calculate, nades_PlayerDamage, CBC_ORDER_ANY);
1218         MUTATOR_HOOK(MonsterDies, nades_MonsterDies, CBC_ORDER_ANY);
1219         MUTATOR_HOOK(MakePlayerObserver, nades_RemovePlayer, CBC_ORDER_ANY);
1220         MUTATOR_HOOK(ClientDisconnect, nades_RemovePlayer, CBC_ORDER_ANY);
1221         MUTATOR_HOOK(SpectateCopy, nades_SpectateCopy, CBC_ORDER_ANY);
1222         MUTATOR_HOOK(GetCvars, nades_GetCvars, CBC_ORDER_ANY);
1223         MUTATOR_HOOK(reset_map_global, nades_RemovePlayer, CBC_ORDER_ANY);
1224         MUTATOR_HOOK(BuildMutatorsString, nades_BuildMutatorsString, CBC_ORDER_ANY);
1225         MUTATOR_HOOK(BuildMutatorsPrettyString, nades_BuildMutatorsPrettyString, CBC_ORDER_ANY);
1226
1227         MUTATOR_ONADD
1228         {
1229                 nades_Initialize();
1230         }
1231
1232         return false;
1233 }