qcsrc/server/mutators/mutator_overkill.qc

   1 #include "mutator_overkill.qh"
   2 #include "../_all.qh"
   3
   4 #include "mutator.qh"
   5
   6 void W_Blaster_Attack(entity, float, float, float, float, float, float, float, float, float, float);
   7 void spawnfunc_weapon_hmg();
   8 void spawnfunc_weapon_rpc();
   9
  10 void ok_DecreaseCharge(entity ent, int wep)
  11 {
  12         if(!ent.ok_use_ammocharge) return;
  13
  14         entity wepent = get_weaponinfo(wep);
  15
  16         if(wepent.weapon == 0)
  17                 return; // dummy
  18
  19         ent.ammo_charge[wep] -= max(0, cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  20 }
  21
  22 void ok_IncreaseCharge(entity ent, int wep)
  23 {
  24         entity wepent = get_weaponinfo(wep);
  25
  26         if(wepent.weapon == 0)
  27                 return; // dummy
  28
  29         if(ent.ok_use_ammocharge)
  30         if(!ent.BUTTON_ATCK) // not while attacking?
  31                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  32 }
  33
  34 float ok_CheckWeaponCharge(entity ent, int wep)
  35 {
  36         if(!ent.ok_use_ammocharge) return true;
  37
  38         entity wepent = get_weaponinfo(wep);
  39
  40         if(wepent.weapon == 0)
  41                 return 0; // dummy
  42
  43         return (ent.ammo_charge[wep] >= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  44 }
  45
  46 MUTATOR_HOOKFUNCTION(ok_PlayerDamage_Calculate)
  47 {
  48         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target))
  49         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER.m_id))
  50         {
  51                 frag_damage = 0;
  52
  53                 if(frag_attacker != frag_target)
  54                 if(frag_target.health > 0)
  55                 if(frag_target.frozen == 0)
  56                 if(frag_target.deadflag == DEAD_NO)
  57                 {
  58                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
  59                         frag_force = '0 0 0';
  60                 }
  61         }
  62
  63         return false;
  64 }
  65
  66 MUTATOR_HOOKFUNCTION(ok_PlayerDamage_SplitHealthArmor)
  67 {SELFPARAM();
  68         if(damage_take)
  69                 self.ok_pauseregen_finished = max(self.ok_pauseregen_finished, time + 2);
  70         return false;
  71 }
  72
  73 MUTATOR_HOOKFUNCTION(ok_PlayerDies)
  74 {SELFPARAM();
  75         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
  76
  77         if(IS_MONSTER(self))
  78         {
  79                 remove(other); // remove default item
  80                 other = world;
  81         }
  82
  83         setself(spawn());
  84         self.ok_item = true;
  85         self.noalign = true;
  86         self.pickup_anyway = true;
  87         spawnfunc_item_armor_small();
  88         self.movetype = MOVETYPE_TOSS;
  89         self.gravity = 1;
  90         self.reset = SUB_Remove;
  91         setorigin(self, frag_target.origin + '0 0 32');
  92         self.velocity = '0 0 200' + normalize(targ.origin - self.origin) * 500;
  93         self.classname = "droppedweapon"; // hax
  94         SUB_SetFade(self, time + 5, 1);
  95         setself(this);
  96
  97         self.ok_lastwep = self.switchweapon;
  98
  99         return false;
 100 }
 101
 102 MUTATOR_HOOKFUNCTION(ok_PlayerRegen)
 103 {SELFPARAM();
 104         // overkill's values are different, so use custom regen
 105         if(!self.frozen)
 106         {
 107                 self.armorvalue = CalcRotRegen(self.armorvalue, autocvar_g_balance_armor_regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 1 * frametime * (time > self.ok_pauseregen_finished), 0, 0, 1, 1 * frametime * (time > self.pauserotarmor_finished), autocvar_g_balance_armor_limit);
 108                 self.health = CalcRotRegen(self.health, autocvar_g_balance_health_regenstable, 0, 100, 1 * frametime * (time > self.ok_pauseregen_finished), 200, 0, autocvar_g_balance_health_rotlinear, 1 * frametime * (time > self.pauserothealth_finished), autocvar_g_balance_health_limit);
 109
 110                 float minf, maxf, limitf;
 111
 112                 maxf = autocvar_g_balance_fuel_rotstable;
 113                 minf = autocvar_g_balance_fuel_regenstable;
 114                 limitf = autocvar_g_balance_fuel_limit;
 115
 116                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
 117         }
 118         return true; // return true anyway, as frozen uses no regen
 119 }
 120
 121 MUTATOR_HOOKFUNCTION(ok_ForbidThrowCurrentWeapon)
 122 {
 123         return true;
 124 }
 125
 126 MUTATOR_HOOKFUNCTION(ok_PlayerPreThink)
 127 {SELFPARAM();
 128         if(intermission_running || gameover)
 129                 return false;
 130
 131         if(self.deadflag != DEAD_NO || !IS_PLAYER(self) || self.frozen)
 132                 return false;
 133
 134         if(self.ok_lastwep)
 135         {
 136                 self.switchweapon = self.ok_lastwep;
 137                 self.ok_lastwep = 0;
 138         }
 139
 140         ok_IncreaseCharge(self, self.weapon);
 141
 142         if(self.BUTTON_ATCK2)
 143         if(!forbidWeaponUse(self) || self.weapon_blocked) // allow if weapon is blocked
 144         if(time >= self.jump_interval)
 145         {
 146                 self.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor();
 147                 makevectors(self.v_angle);
 148
 149                 int oldwep = self.weapon;
 150                 self.weapon = WEP_BLASTER.m_id;
 151                 W_Blaster_Attack(
 152                         self,
 153                         WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 154                         WEP_CVAR_SEC(vaporizer, shotangle),
 155                         WEP_CVAR_SEC(vaporizer, damage),
 156                         WEP_CVAR_SEC(vaporizer, edgedamage),
 157                         WEP_CVAR_SEC(vaporizer, radius),
 158                         WEP_CVAR_SEC(vaporizer, force),
 159                         WEP_CVAR_SEC(vaporizer, speed),
 160                         WEP_CVAR_SEC(vaporizer, spread),
 161                         WEP_CVAR_SEC(vaporizer, delay),
 162                         WEP_CVAR_SEC(vaporizer, lifetime)
 163                 );
 164                 self.weapon = oldwep;
 165         }
 166
 167         self.weapon_blocked = false;
 168
 169         self.ok_ammo_charge = self.ammo_charge[self.weapon];
 170
 171         if(self.ok_use_ammocharge)
 172         if(!ok_CheckWeaponCharge(self, self.weapon))
 173         {
 174                 if(autocvar_g_overkill_ammo_charge_notice && time > self.ok_notice_time && self.BUTTON_ATCK && IS_REAL_CLIENT(self) && self.weapon == self.switchweapon)
 175                 {
 176                         //Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 177                         self.ok_notice_time = time + 2;
 178                         play2(self, SND(DRYFIRE));
 179                 }
 180                 Weapon wpn = get_weaponinfo(self.weapon);
 181                 if(self.weaponentity.state != WS_CLEAR)
 182                         w_ready(wpn, self, self.BUTTON_ATCK, self.BUTTON_ATCK2);
 183
 184                 self.weapon_blocked = true;
 185         }
 186
 187         self.BUTTON_ATCK2 = 0;
 188
 189         return false;
 190 }
 191
 192 MUTATOR_HOOKFUNCTION(ok_PlayerSpawn)
 193 {SELFPARAM();
 194         if(autocvar_g_overkill_ammo_charge)
 195         {
 196                 for(int i = WEP_FIRST; i <= WEP_LAST; ++i)
 197                         self.ammo_charge[i] = autocvar_g_overkill_ammo_charge_limit;
 198
 199                 self.ok_use_ammocharge = 1;
 200                 self.ok_notice_time = time;
 201         }
 202         else
 203                 self.ok_use_ammocharge = 0;
 204
 205         self.ok_pauseregen_finished = time + 2;
 206
 207         return false;
 208 }
 209
 210 MUTATOR_HOOKFUNCTION(ok_OnEntityPreSpawn)
 211 {SELFPARAM();
 212         if(autocvar_g_powerups)
 213         if(autocvar_g_overkill_powerups_replace)
 214         {
 215                 if(self.classname == "item_strength")
 216                 {
 217                         entity wep = spawn();
 218                         setorigin(wep, self.origin);
 219                         setmodel(wep, MDL_OK_HMG);
 220                         wep.classname = "weapon_hmg";
 221                         wep.ok_item = true;
 222                         wep.noalign = self.noalign;
 223                         wep.cnt = self.cnt;
 224                         wep.team = self.team;
 225                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 226                         wep.pickup_anyway = true;
 227                         wep.think = spawnfunc_weapon_hmg;
 228                         wep.nextthink = time + 0.1;
 229                         return true;
 230                 }
 231
 232                 if(self.classname == "item_invincible")
 233                 {
 234                         entity wep = spawn();
 235                         setorigin(wep, self.origin);
 236                         setmodel(wep, MDL_OK_RPC);
 237                         wep.classname = "weapon_rpc";
 238                         wep.ok_item = true;
 239                         wep.noalign = self.noalign;
 240                         wep.cnt = self.cnt;
 241                         wep.team = self.team;
 242                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 243                         wep.pickup_anyway = true;
 244                         wep.think = spawnfunc_weapon_rpc;
 245                         wep.nextthink = time + 0.1;
 246                         return true;
 247                 }
 248         }
 249
 250         return false;
 251 }
 252
 253 MUTATOR_HOOKFUNCTION(ok_ItemRemove)
 254 {SELFPARAM();
 255         if(self.ok_item)
 256                 return false;
 257
 258         switch(self.items)
 259         {
 260                 case ITEM_HealthMega.m_itemid: return !(autocvar_g_overkill_100h_anyway);
 261                 case ITEM_ArmorMega.m_itemid: return !(autocvar_g_overkill_100a_anyway);
 262         }
 263
 264         return true;
 265 }
 266
 267 MUTATOR_HOOKFUNCTION(ok_SpectateCopy)
 268 {SELFPARAM();
 269         self.ammo_charge[self.weapon] = other.ammo_charge[other.weapon];
 270         self.ok_use_ammocharge = other.ok_use_ammocharge;
 271
 272         return false;
 273 }
 274
 275 MUTATOR_HOOKFUNCTION(ok_StartItems)
 276 {
 277         WepSet ok_start_items = (WEPSET_MACHINEGUN | WEPSET_VORTEX | WEPSET_SHOTGUN);
 278
 279         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET_RPC; }
 280         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET_HMG; }
 281
 282         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 283         start_weapons = warmup_start_weapons = ok_start_items;
 284
 285         return false;
 286 }
 287
 288 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsString)
 289 {
 290         ret_string = strcat(ret_string, ":OK");
 291         return false;
 292 }
 293
 294 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsPrettyString)
 295 {
 296         ret_string = strcat(ret_string, ", Overkill");
 297         return false;
 298 }
 299
 300 MUTATOR_HOOKFUNCTION(ok_SetModname)
 301 {
 302         modname = "Overkill";
 303         return true;
 304 }
 305
 306 void ok_SetCvars()
 307 {
 308         // hack to force overkill playermodels
 309         cvar_settemp("sv_defaultcharacter", "1");
 310         cvar_settemp("sv_defaultplayermodel", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 311         cvar_settemp("sv_defaultplayermodel_red", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm");
 312         cvar_settemp("sv_defaultplayermodel_blue", "models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 313 }
 314
 315 void ok_Initialize()
 316 {
 317         ok_SetCvars();
 318
 319         precache_all_playermodels("models/ok_player/*.dpm");
 320
 321         addstat(STAT_OK_AMMO_CHARGE, AS_FLOAT, ok_use_ammocharge);
 322         addstat(STAT_OK_AMMO_CHARGEPOOL, AS_FLOAT, ok_ammo_charge);
 323
 324         WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 325         WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 326
 327         WEP_SHOTGUN.mdl = "ok_shotgun";
 328         WEP_MACHINEGUN.mdl = "ok_mg";
 329         WEP_VORTEX.mdl = "ok_sniper";
 330 }
 331
 332 MUTATOR_DEFINITION(mutator_overkill)
 333 {
 334         MUTATOR_HOOK(ForbidThrowCurrentWeapon, ok_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 335         MUTATOR_HOOK(PlayerPreThink, ok_PlayerPreThink, CBC_ORDER_LAST);
 336         MUTATOR_HOOK(PlayerSpawn, ok_PlayerSpawn, CBC_ORDER_ANY);
 337         MUTATOR_HOOK(PlayerDamage_Calculate, ok_PlayerDamage_Calculate, CBC_ORDER_LAST);
 338         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, ok_PlayerDamage_SplitHealthArmor, CBC_ORDER_ANY);
 339         MUTATOR_HOOK(PlayerDies, ok_PlayerDies, CBC_ORDER_ANY);
 340         MUTATOR_HOOK(PlayerRegen, ok_PlayerRegen, CBC_ORDER_ANY);
 341         MUTATOR_HOOK(OnEntityPreSpawn, ok_OnEntityPreSpawn, CBC_ORDER_ANY);
 342         MUTATOR_HOOK(FilterItem, ok_ItemRemove, CBC_ORDER_ANY);
 343         MUTATOR_HOOK(MonsterDropItem, ok_PlayerDies, CBC_ORDER_ANY);
 344         MUTATOR_HOOK(SpectateCopy, ok_SpectateCopy, CBC_ORDER_ANY);
 345         MUTATOR_HOOK(SetStartItems, ok_StartItems, CBC_ORDER_ANY);
 346         MUTATOR_HOOK(BuildMutatorsString, ok_BuildMutatorsString, CBC_ORDER_ANY);
 347         MUTATOR_HOOK(BuildMutatorsPrettyString, ok_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 348         MUTATOR_HOOK(SetModname, ok_SetModname, CBC_ORDER_ANY);
 349
 350         MUTATOR_ONADD
 351         {
 352                 ok_Initialize();
 353         }
 354
 355         MUTATOR_ONREMOVE
 356         {
 357                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 358                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 359         }
 360
 361         return false;
 362 }