qcsrc/server/mutators/mutator_overkill.qc

   1 void ok_DecreaseCharge(entity ent, float wep)
   2 {
   3         if(!ent.ok_use_ammocharge) return;
   4
   5         entity wepent = get_weaponinfo(wep);
   6
   7         if(wepent.weapon == 0)
   8                 return; // dummy
   9
  10         ent.ammo_charge[wep] -= max(0, cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  11 }
  12
  13 void ok_IncreaseCharge(entity ent, float wep)
  14 {
  15         entity wepent = get_weaponinfo(wep);
  16
  17         if(wepent.weapon == 0)
  18                 return; // dummy
  19
  20         if(ent.ok_use_ammocharge)
  21         if(!ent.BUTTON_ATCK) // not while attacking?
  22                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  23 }
  24
  25 float ok_CheckWeaponCharge(entity ent, float wep)
  26 {
  27         if(!ent.ok_use_ammocharge) return TRUE;
  28
  29         entity wepent = get_weaponinfo(wep);
  30
  31         if(wepent.weapon == 0)
  32                 return 0; // dummy
  33
  34         return (ent.ammo_charge[wep] >= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  35 }
  36
  37 void start_hmg()
  38 {
  39         self.classname = "weapon_hmg";
  40         self.respawntime = autocvar_g_overkill_superguns_respawn_time;
  41         self.ok_item = TRUE;
  42         setmodel(self, "models/weapons/g_ok_hmg.md3");
  43         self.pickup_anyway = TRUE;
  44         spawnfunc_weapon_hmg();
  45 }
  46
  47 void start_rpc()
  48 {
  49         self.classname = "weapon_rpc";
  50         self.respawntime = autocvar_g_overkill_superguns_respawn_time;
  51         self.ok_item = TRUE;
  52         self.pickup_anyway = TRUE;
  53         setmodel(self, "models/weapons/g_ok_rl.md3");
  54         spawnfunc_weapon_rpc();
  55 }
  56
  57 MUTATOR_HOOKFUNCTION(ok_PlayerDamage_Calculate)
  58 {
  59         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target))
  60         if(DEATH_ISWEAPON(frag_deathtype, WEP_LASER))
  61         {
  62                 frag_damage = 0;
  63
  64                 if(frag_attacker != frag_target)
  65                 if(frag_target.health > 0)
  66                 if(frag_target.freezetag_frozen == 0)
  67                 if(frag_target.deadflag == DEAD_NO)
  68                 {
  69                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
  70                         frag_force = '0 0 0';
  71                 }
  72         }
  73
  74         return FALSE;
  75 }
  76
  77 MUTATOR_HOOKFUNCTION(ok_PlayerDies)
  78 {
  79         entity oldself = self;
  80
  81         self.ok_lastwep = self.weapon;
  82         self.ok_deathloc = self.origin;
  83         self = spawn();
  84         self.ok_item = TRUE;
  85         self.noalign = TRUE;
  86         self.pickup_anyway = TRUE;
  87         spawnfunc_item_armor_small();
  88         self.movetype = MOVETYPE_TOSS;
  89         self.gravity = 1;
  90         self.reset = SUB_Remove;
  91         setorigin(self, frag_target.origin + '0 0 32');
  92         self.velocity = '0 0 200' + normalize(frag_attacker.origin - self.origin) * 500;
  93         self.classname = "droppedweapon"; // hax
  94         SUB_SetFade(self, time + 5, 1);
  95         self = oldself;
  96
  97         return FALSE;
  98 }
  99
 100 MUTATOR_HOOKFUNCTION(ok_MonsterSpawn)
 101 {
 102         self.candrop = FALSE; // no default item drops
 103         return FALSE;
 104 }
 105
 106 MUTATOR_HOOKFUNCTION(ok_ForbidThrowCurrentWeapon)
 107 {
 108         return TRUE;
 109 }
 110
 111 MUTATOR_HOOKFUNCTION(ok_PlayerPreThink)
 112 {
 113         if(intermission_running || gameover)
 114                 return FALSE;
 115
 116         if(self.deadflag != DEAD_NO || !IS_PLAYER(self) || self.freezetag_frozen)
 117                 return FALSE;
 118
 119         ok_IncreaseCharge(self, self.weapon);
 120
 121         if(self.BUTTON_ATCK2)
 122         if(!forbidWeaponUse() || self.weapon_blocked) // allow if weapon is blocked
 123         if(time >= self.jump_interval)
 124         {
 125                 self.jump_interval = time + autocvar_g_balance_laser_primary_refire * W_WeaponRateFactor();
 126                 makevectors(self.v_angle);
 127                 float w = self.weapon;
 128                 self.weapon = WEP_LASER;
 129                 W_Laser_Attack(3);
 130                 self.weapon = w;
 131         }
 132
 133         self.weapon_blocked = FALSE;
 134
 135         self.ok_ammo_charge = self.ammo_charge[self.weapon];
 136
 137         if(self.ok_use_ammocharge)
 138         if(!ok_CheckWeaponCharge(self, self.weapon))
 139         {
 140                 if(autocvar_g_overkill_ammo_charge_notice && time > self.ok_notice_time && self.BUTTON_ATCK && IS_REAL_CLIENT(self))
 141                 {
 142                         //Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 143                         self.ok_notice_time = time + 2;
 144                         play2(self, "weapons/dryfire.wav");
 145                 }
 146                 if(self.weaponentity.state != WS_CLEAR)
 147                         w_ready();
 148
 149                 self.weapon_blocked = TRUE;
 150         }
 151
 152         self.BUTTON_ATCK2 = 0;
 153
 154         return FALSE;
 155 }
 156
 157 MUTATOR_HOOKFUNCTION(ok_PlayerSpawn)
 158 {
 159         if(autocvar_g_overkill_ammo_charge)
 160         {
 161                 float i;
 162
 163                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 164                         self.ammo_charge[i] = autocvar_g_overkill_ammo_charge_limit;
 165
 166                 self.ok_use_ammocharge = 1;
 167                 self.ok_notice_time = time;
 168         }
 169         else
 170                 self.ok_use_ammocharge = 0;
 171
 172         return FALSE;
 173 }
 174
 175 MUTATOR_HOOKFUNCTION(ok_OnEntityPreSpawn)
 176 {
 177         if(autocvar_g_powerups)
 178         if(autocvar_g_overkill_powerups_replace)
 179         {
 180                 if(self.classname == "item_strength")
 181                 {
 182                         entity wep = spawn();
 183                         setorigin(wep, self.origin);
 184                         setmodel(wep, "models/weapons/g_ok_hmg.md3");
 185                         wep.classname = "weapon_hmg";
 186                         wep.ok_item = TRUE;
 187                         wep.noalign = self.noalign;
 188                         wep.cnt = self.cnt;
 189                         wep.team = self.team;
 190                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 191                         wep.pickup_anyway = TRUE;
 192                         wep.think = spawnfunc_weapon_hmg;
 193                         wep.nextthink = time + 0.1;
 194                         return TRUE;
 195                 }
 196
 197                 if(self.classname == "item_invincible")
 198                 {
 199                         entity wep = spawn();
 200                         setorigin(wep, self.origin);
 201                         setmodel(wep, "models/weapons/g_ok_rl.md3");
 202                         wep.classname = "weapon_rpc";
 203                         wep.ok_item = TRUE;
 204                         wep.noalign = self.noalign;
 205                         wep.cnt = self.cnt;
 206                         wep.team = self.team;
 207                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 208                         wep.pickup_anyway = TRUE;
 209                         wep.think = spawnfunc_weapon_rpc;
 210                         wep.nextthink = time + 0.1;
 211                         return TRUE;
 212                 }
 213         }
 214
 215         return FALSE;
 216 }
 217
 218 MUTATOR_HOOKFUNCTION(ok_ItemRemove)
 219 {
 220         if(self.ok_item)
 221                 return FALSE;
 222
 223         switch(self.items)
 224         {
 225                 case IT_HEALTH: return !(autocvar_g_overkill_100h_anyway);
 226                 case IT_ARMOR: return !(autocvar_g_overkill_100a_anyway);
 227         }
 228
 229         return TRUE;
 230 }
 231
 232 MUTATOR_HOOKFUNCTION(ok_SpectateCopy)
 233 {
 234         self.ammo_charge[self.weapon] = other.ammo_charge[other.weapon];
 235         self.ok_use_ammocharge = other.ok_use_ammocharge;
 236
 237         return FALSE;
 238 }
 239
 240 MUTATOR_HOOKFUNCTION(ok_StartItems)
 241 {
 242         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 243         start_weapons = warmup_start_weapons = (WEPSET_UZI | WEPSET_NEX | WEPSET_SHOTGUN);
 244
 245         start_ammo_nails = start_ammo_cells = start_ammo_shells = start_ammo_rockets =
 246         warmup_start_ammo_nails = warmup_start_ammo_cells = warmup_start_ammo_shells = warmup_start_ammo_rockets = autocvar_g_overkill_ammo_start;
 247
 248         return FALSE;
 249 }
 250
 251 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsString)
 252 {
 253         ret_string = strcat(ret_string, ":OK");
 254         return FALSE;
 255 }
 256
 257 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsPrettyString)
 258 {
 259         ret_string = strcat(ret_string, ", Overkill");
 260         return FALSE;
 261 }
 262
 263 MUTATOR_HOOKFUNCTION(ok_SetModname)
 264 {
 265         modname = "Overkill";
 266         return TRUE;
 267 }
 268
 269 void ok_Initialize()
 270 {
 271         precache_all_playermodels("models/ok_player/*.dpm");
 272
 273         precache_model("models/weapons/h_ok_rl.iqm");
 274         precache_model("models/weapons/v_ok_rl.md3");
 275         precache_model("models/weapons/g_ok_rl.md3");
 276         precache_model("models/weapons/ok_rocket.md3");
 277
 278         precache_model("models/weapons/h_ok_mg.iqm");
 279         precache_model("models/weapons/v_ok_mg.md3");
 280         precache_model("models/weapons/g_ok_mg.md3");
 281
 282         precache_model("models/weapons/h_ok_hmg.iqm");
 283         precache_model("models/weapons/v_ok_hmg.md3");
 284         precache_model("models/weapons/g_ok_hmg.md3");
 285
 286         precache_model("models/weapons/h_ok_shotgun.iqm");
 287         precache_model("models/weapons/v_ok_shotgun.md3");
 288         precache_model("models/weapons/g_ok_shotgun.md3");
 289
 290         precache_model("models/weapons/h_ok_sniper.iqm");
 291         precache_model("models/weapons/v_ok_sniper.md3");
 292         precache_model("models/weapons/g_ok_sniper.md3");
 293
 294         precache_sound("weapons/dryfire.wav");
 295
 296         addstat(STAT_OK_AMMO_CHARGE, AS_FLOAT, ok_use_ammocharge);
 297         addstat(STAT_OK_AMMO_CHARGEPOOl, AS_FLOAT, ok_ammo_charge);
 298
 299         w_uzi(WR_PRECACHE);
 300         w_nex(WR_PRECACHE);
 301         w_shotgun(WR_PRECACHE);
 302         w_laser(WR_PRECACHE);
 303
 304         (get_weaponinfo(WEP_RPC)).spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 305         (get_weaponinfo(WEP_HMG)).spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 306
 307         (get_weaponinfo(WEP_SHOTGUN)).mdl = "ok_shotgun";
 308         (get_weaponinfo(WEP_UZI)).mdl = "ok_mg";
 309         (get_weaponinfo(WEP_NEX)).mdl = "ok_sniper";
 310
 311         string s;
 312         float fh = fopen("overkill.cfg", FILE_READ);
 313         if(fh >= 0)
 314         {
 315                 while((s = fgets(fh)))
 316                 {
 317                         tokenize_console(s);
 318                         if(!(argv(0) == "" || argv(1) == "//" || argv(1) == ""))
 319                                 cvar_settemp(argv(0), argv(1));
 320                 }
 321                 fclose(fh);
 322         }
 323         else
 324                 dprint("^1Mutator Overkill: WARNING! overkill.cfg NOT found, things will be strange!\n");
 325 }
 326
 327 MUTATOR_DEFINITION(mutator_overkill)
 328 {
 329         MUTATOR_HOOK(ForbidThrowCurrentWeapon, ok_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 330         MUTATOR_HOOK(PlayerPreThink, ok_PlayerPreThink, CBC_ORDER_LAST);
 331         MUTATOR_HOOK(PlayerSpawn, ok_PlayerSpawn, CBC_ORDER_ANY);
 332         MUTATOR_HOOK(PlayerDamage_Calculate, ok_PlayerDamage_Calculate, CBC_ORDER_LAST);
 333         MUTATOR_HOOK(PlayerDies, ok_PlayerDies, CBC_ORDER_ANY);
 334         MUTATOR_HOOK(MonsterDies, ok_PlayerDies, CBC_ORDER_ANY);
 335         MUTATOR_HOOK(MonsterSpawn, ok_MonsterSpawn, CBC_ORDER_ANY);
 336         MUTATOR_HOOK(OnEntityPreSpawn, ok_OnEntityPreSpawn, CBC_ORDER_ANY);
 337         MUTATOR_HOOK(FilterItem, ok_ItemRemove, CBC_ORDER_ANY);
 338         MUTATOR_HOOK(SpectateCopy, ok_SpectateCopy, CBC_ORDER_ANY);
 339         MUTATOR_HOOK(SetStartItems, ok_StartItems, CBC_ORDER_ANY);
 340         MUTATOR_HOOK(BuildMutatorsString, ok_BuildMutatorsString, CBC_ORDER_ANY);
 341         MUTATOR_HOOK(BuildMutatorsPrettyString, ok_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 342         MUTATOR_HOOK(SetModname, ok_SetModname, CBC_ORDER_ANY);
 343
 344         MUTATOR_ONADD
 345         {
 346                 ok_Initialize();
 347         }
 348
 349         MUTATOR_ONREMOVE
 350         {
 351                 (get_weaponinfo(WEP_RPC)).spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 352                 (get_weaponinfo(WEP_HMG)).spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 353         }
 354
 355         return FALSE;
 356 }