qcsrc/server/mutators/mutator_spawn_near_teammate.qc

   1
   2 #include "mutator.qh"
   3
   4 REGISTER_MUTATOR(spawn_near_teammate, cvar("g_spawn_near_teammate") && teamplay);
   5
   6 .entity msnt_lookat;
   7
   8 .float msnt_timer;
   9 .vector msnt_deathloc;
  10
  11 .float cvar_cl_spawn_near_teammate;
  12
  13 MUTATOR_HOOKFUNCTION(spawn_near_teammate, Spawn_Score)
  14 {SELFPARAM();
  15         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && self.cvar_cl_spawn_near_teammate))
  16                 return 0;
  17
  18         entity p;
  19
  20         spawn_spot.msnt_lookat = world;
  21
  22         if(!teamplay)
  23                 return 0;
  24
  25         RandomSelection_Init();
  26         FOR_EACH_PLAYER(p) if(p != self) if(p.team == self.team) if(!p.deadflag)
  27         {
  28                 float l = vlen(spawn_spot.origin - p.origin);
  29                 if(l > autocvar_g_spawn_near_teammate_distance)
  30                         continue;
  31                 if(l < 48)
  32                         continue;
  33                 if(!checkpvs(spawn_spot.origin, p))
  34                         continue;
  35                 RandomSelection_Add(p, 0, string_null, 1, 1);
  36         }
  37
  38         if(RandomSelection_chosen_ent)
  39         {
  40                 spawn_spot.msnt_lookat = RandomSelection_chosen_ent;
  41                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_FOUND;
  42         }
  43         else if(self.team == spawn_spot.team)
  44                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_SAMETEAM; // prefer same team, if we can't find a spawn near teammate
  45
  46         return 0;
  47 }
  48
  49 MUTATOR_HOOKFUNCTION(spawn_near_teammate, PlayerSpawn)
  50 {SELFPARAM();
  51         // Note: when entering this, fixangle is already set.
  52         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && self.cvar_cl_spawn_near_teammate))
  53         {
  54                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death)
  55                         self.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
  56
  57                 entity team_mate, best_mate = world;
  58                 vector best_spot = '0 0 0';
  59                 float pc = 0, best_dist = 0, dist = 0;
  60                 FOR_EACH_PLAYER(team_mate)
  61                 {
  62                         if((autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health >= 0 && team_mate.health >= autocvar_g_balance_health_regenstable) || autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health == 0)
  63                         if(team_mate.deadflag == DEAD_NO)
  64                         if(team_mate.msnt_timer < time)
  65                         if(SAME_TEAM(self, team_mate))
  66                         if(time > team_mate.spawnshieldtime) // spawn shielding
  67                         if(team_mate.frozen == 0)
  68                         if(team_mate != self)
  69                         {
  70                                 tracebox(team_mate.origin, PL_MIN, PL_MAX, team_mate.origin - '0 0 100', MOVE_WORLDONLY, team_mate);
  71                                 if(trace_fraction != 1.0)
  72                                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
  73                                 {
  74                                         pc = pointcontents(trace_endpos + '0 0 1');
  75                                         if(pc == CONTENT_EMPTY)
  76                                         {
  77                                                 if(vlen(team_mate.velocity) > 5)
  78                                                         fixedmakevectors(vectoangles(team_mate.velocity));
  79                                                 else
  80                                                         fixedmakevectors(team_mate.angles);
  81
  82                                                 for(pc = 0; pc != 5; ++pc) // test 5 diffrent spots close to mate
  83                                                 {
  84                                                         switch(pc)
  85                                                         {
  86                                                                 case 0:
  87                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin + v_right * 128, MOVE_NORMAL, team_mate);
  88                                                                         break;
  89                                                                 case 1:
  90                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_right * 128 , MOVE_NORMAL, team_mate);
  91                                                                         break;
  92                                                                 case 2:
  93                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin + v_right * 64 - v_forward * 64, MOVE_NORMAL, team_mate);
  94                                                                         break;
  95                                                                 case 3:
  96                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_right * 64 - v_forward * 64, MOVE_NORMAL, team_mate);
  97                                                                         break;
  98                                                                 case 4:
  99                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_forward * 128, MOVE_NORMAL, team_mate);
 100                                                                         break;
 101                                                         }
 102
 103                                                         if(trace_fraction == 1.0)
 104                                                         {
 105                                                                 traceline(trace_endpos + '0 0 4', trace_endpos - '0 0 100', MOVE_NORMAL, team_mate);
 106                                                                 if(trace_fraction != 1.0)
 107                                                                 {
 108                                                                         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 109                                                                         {
 110                                                                                 dist = vlen(trace_endpos - self.msnt_deathloc);
 111                                                                                 if(dist < best_dist || best_dist == 0)
 112                                                                                 {
 113                                                                                         best_dist = dist;
 114                                                                                         best_spot = trace_endpos;
 115                                                                                         best_mate = team_mate;
 116                                                                                 }
 117                                                                         }
 118                                                                         else
 119                                                                         {
 120                                                                                 setorigin(self, trace_endpos);
 121                                                                                 self.angles = team_mate.angles;
 122                                                                                 self.angles_z = 0; // never spawn tilted even if the spot says to
 123                                                                                 team_mate.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 124                                                                                 return 0;
 125                                                                         }
 126                                                                 }
 127                                                         }
 128                                                 }
 129                                         }
 130                                 }
 131                         }
 132                 }
 133
 134                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 135                 if(best_dist)
 136                 {
 137                         setorigin(self, best_spot);
 138                         self.angles = best_mate.angles;
 139                         self.angles_z = 0; // never spawn tilted even if the spot says to
 140                         best_mate.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 141                 }
 142         }
 143         else if(spawn_spot.msnt_lookat)
 144         {
 145                 self.angles = vectoangles(spawn_spot.msnt_lookat.origin - self.origin);
 146                 self.angles_x = -self.angles.x;
 147                 self.angles_z = 0; // never spawn tilted even if the spot says to
 148                 /*
 149                 sprint(self, "You should be looking at ", spawn_spot.msnt_lookat.netname, "^7.\n");
 150                 sprint(self, "distance: ", vtos(spawn_spot.msnt_lookat.origin - self.origin), "\n");
 151                 sprint(self, "angles: ", vtos(self.angles), "\n");
 152                 */
 153         }
 154
 155         return 0;
 156 }
 157
 158 MUTATOR_HOOKFUNCTION(spawn_near_teammate, PlayerDies)
 159 {SELFPARAM();
 160         self.msnt_deathloc = self.origin;
 161         return 0;
 162 }
 163
 164 MUTATOR_HOOKFUNCTION(spawn_near_teammate, GetCvars)
 165 {
 166         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_spawn_near_teammate, "cl_spawn_near_teammate");
 167         return false;
 168 }