qcsrc/server/mutators/mutator_spawn_near_teammate.qc

   1 .entity msnt_lookat;
   2
   3 .float msnt_timer;
   4 .vector msnt_deathloc;
   5
   6 MUTATOR_HOOKFUNCTION(msnt_Spawn_Score)
   7 {
   8         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint)
   9                 return 0;
  10
  11         entity p;
  12
  13         spawn_spot.msnt_lookat = world;
  14
  15         if(!teamplay)
  16                 return 0;
  17
  18         RandomSelection_Init();
  19         FOR_EACH_PLAYER(p) if(p != self) if(p.team == self.team) if(!p.deadflag)
  20         {
  21                 float l = vlen(spawn_spot.origin - p.origin);
  22                 if(l > autocvar_g_spawn_near_teammate_distance)
  23                         continue;
  24                 if(l < 48)
  25                         continue;
  26                 if(!checkpvs(spawn_spot.origin, p))
  27                         continue;
  28                 RandomSelection_Add(p, 0, string_null, 1, 1);
  29         }
  30
  31         if(RandomSelection_chosen_ent)
  32         {
  33                 spawn_spot.msnt_lookat = RandomSelection_chosen_ent;
  34                 spawn_score_x += SPAWN_PRIO_NEAR_TEAMMATE_FOUND;
  35         }
  36         else if(self.team == spawn_spot.team)
  37                 spawn_score_x += SPAWN_PRIO_NEAR_TEAMMATE_SAMETEAM; // prefer same team, if we can't find a spawn near teammate
  38
  39         return 0;
  40 }
  41
  42 MUTATOR_HOOKFUNCTION(msnt_PlayerSpawn)
  43 {
  44         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint)
  45         {
  46                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death)
  47                         self.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
  48
  49                 entity team_mate, best_mate = world;
  50                 vector best_spot = '0 0 0';
  51                 float pc = 0, best_dist = 0, dist = 0;
  52                 FOR_EACH_PLAYER(team_mate)
  53                 {
  54                         if((autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health >= 0 && team_mate.health >= autocvar_g_balance_health_regenstable) || autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health == 0)
  55                         if(team_mate.deadflag == DEAD_NO)
  56                         if(team_mate.msnt_timer < time)
  57                         if(SAME_TEAM(self, team_mate))
  58                         if(time > team_mate.spawnshieldtime) // spawn shielding
  59                         if(team_mate.freezetag_frozen == 0)
  60                         if(team_mate != self)
  61                         {
  62                                 tracebox(team_mate.origin, PL_MIN, PL_MAX, team_mate.origin - '0 0 100', MOVE_WORLDONLY, team_mate);
  63                                 if(trace_fraction != 1.0)
  64                                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
  65                                 {
  66                                         pc = pointcontents(trace_endpos + '0 0 1');
  67                                         if(pc == CONTENT_EMPTY)
  68                                         {
  69                                                 if(vlen(team_mate.velocity) > 5)
  70                                                         fixedmakevectors(vectoangles(team_mate.velocity));
  71                                                 else
  72                                                         fixedmakevectors(team_mate.angles);
  73
  74                                                 for(pc = 0; pc != 5; ++pc) // test 5 diffrent spots close to mate
  75                                                 {
  76                                                         switch(pc)
  77                                                         {
  78                                                                 case 0:
  79                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin + v_right * 128, MOVE_NORMAL, team_mate);
  80                                                                         break;
  81                                                                 case 1:
  82                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_right * 128 , MOVE_NORMAL, team_mate);
  83                                                                         break;
  84                                                                 case 2:
  85                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin + v_right * 64 - v_forward * 64, MOVE_NORMAL, team_mate);
  86                                                                         break;
  87                                                                 case 3:
  88                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_right * 64 - v_forward * 64, MOVE_NORMAL, team_mate);
  89                                                                         break;
  90                                                                 case 4:
  91                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_forward * 128, MOVE_NORMAL, team_mate);
  92                                                                         break;
  93                                                         }
  94
  95                                                         if(trace_fraction == 1.0)
  96                                                         {
  97                                                                 traceline(trace_endpos + '0 0 4', trace_endpos - '0 0 100', MOVE_NORMAL, team_mate);
  98                                                                 if(trace_fraction != 1.0)
  99                                                                 {
 100                                                                         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 101                                                                         {
 102                                                                                 dist = vlen(trace_endpos - self.msnt_deathloc);
 103                                                                                 if(dist < best_dist || best_dist == 0)
 104                                                                                 {
 105                                                                                         best_dist = dist;
 106                                                                                         best_spot = trace_endpos;
 107                                                                                         best_mate = team_mate;
 108                                                                                 }
 109                                                                         }
 110                                                                         else
 111                                                                         {
 112                                                                                 setorigin(self, trace_endpos);
 113                                                                                 self.angles = team_mate.angles;
 114                                                                                 self.angles_z = 0; // never spawn tilted even if the spot says to
 115                                                                                 self.fixangle = TRUE; // turn this way immediately
 116                                                                                 team_mate.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 117                                                                                 return 0;
 118                                                                         }
 119                                                                 }
 120                                                         }
 121                                                 }
 122                                         }
 123                                 }
 124                         }
 125                 }
 126
 127                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 128                 if(best_dist)
 129                 {
 130                         setorigin(self, best_spot);
 131                         self.angles = best_mate.angles;
 132                         self.angles_z = 0; // never spawn tilted even if the spot says to
 133                         self.fixangle = TRUE; // turn this way immediately
 134                         best_mate.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 135                 }
 136         }
 137         else if(spawn_spot.msnt_lookat)
 138         {
 139                 self.angles = vectoangles(spawn_spot.msnt_lookat.origin - self.origin);
 140                 self.angles_x = -self.angles_x;
 141                 self.angles_z = 0; // never spawn tilted even if the spot says to
 142                 self.fixangle = TRUE; // turn this way immediately
 143                 /*
 144                 sprint(self, "You should be looking at ", spawn_spot.msnt_lookat.netname, "^7.\n");
 145                 sprint(self, "distance: ", vtos(spawn_spot.msnt_lookat.origin - self.origin), "\n");
 146                 sprint(self, "angles: ", vtos(self.angles), "\n");
 147                 */
 148         }
 149
 150         return 0;
 151 }
 152
 153 MUTATOR_HOOKFUNCTION(msnt_PlayerDies)
 154 {
 155         self.msnt_deathloc = self.origin;
 156         return 0;
 157 }
 158
 159 MUTATOR_DEFINITION(mutator_spawn_near_teammate)
 160 {
 161         MUTATOR_HOOK(Spawn_Score, msnt_Spawn_Score, CBC_ORDER_ANY);
 162         MUTATOR_HOOK(PlayerSpawn, msnt_PlayerSpawn, CBC_ORDER_ANY);
 163         MUTATOR_HOOK(PlayerDies, msnt_PlayerDies, CBC_ORDER_ANY);
 164
 165         return 0;
 166 }