qcsrc/server/mutators/mutator_spawn_near_teammate.qc

   1 #include "../_all.qh"
   2
   3 #include "mutator.qh"
   4
   5 .entity msnt_lookat;
   6
   7 .float msnt_timer;
   8 .vector msnt_deathloc;
   9
  10 MUTATOR_HOOKFUNCTION(msnt_Spawn_Score)
  11 {
  12         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint)
  13                 return 0;
  14
  15         entity p;
  16
  17         spawn_spot.msnt_lookat = world;
  18
  19         if(!teamplay)
  20                 return 0;
  21
  22         RandomSelection_Init();
  23         FOR_EACH_PLAYER(p) if(p != self) if(p.team == self.team) if(!p.deadflag)
  24         {
  25                 float l = vlen(spawn_spot.origin - p.origin);
  26                 if(l > autocvar_g_spawn_near_teammate_distance)
  27                         continue;
  28                 if(l < 48)
  29                         continue;
  30                 if(!checkpvs(spawn_spot.origin, p))
  31                         continue;
  32                 RandomSelection_Add(p, 0, string_null, 1, 1);
  33         }
  34
  35         if(RandomSelection_chosen_ent)
  36         {
  37                 spawn_spot.msnt_lookat = RandomSelection_chosen_ent;
  38                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_FOUND;
  39         }
  40         else if(self.team == spawn_spot.team)
  41                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_SAMETEAM; // prefer same team, if we can't find a spawn near teammate
  42
  43         return 0;
  44 }
  45
  46 MUTATOR_HOOKFUNCTION(msnt_PlayerSpawn)
  47 {
  48         // Note: when entering this, fixangle is already set.
  49         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint)
  50         {
  51                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death)
  52                         self.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
  53
  54                 entity team_mate, best_mate = world;
  55                 vector best_spot = '0 0 0';
  56                 float pc = 0, best_dist = 0, dist = 0;
  57                 FOR_EACH_PLAYER(team_mate)
  58                 {
  59                         if((autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health >= 0 && team_mate.health >= autocvar_g_balance_health_regenstable) || autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health == 0)
  60                         if(team_mate.deadflag == DEAD_NO)
  61                         if(team_mate.msnt_timer < time)
  62                         if(SAME_TEAM(self, team_mate))
  63                         if(time > team_mate.spawnshieldtime) // spawn shielding
  64                         if(team_mate.frozen == 0)
  65                         if(team_mate != self)
  66                         {
  67                                 tracebox(team_mate.origin, PL_MIN, PL_MAX, team_mate.origin - '0 0 100', MOVE_WORLDONLY, team_mate);
  68                                 if(trace_fraction != 1.0)
  69                                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
  70                                 {
  71                                         pc = pointcontents(trace_endpos + '0 0 1');
  72                                         if(pc == CONTENT_EMPTY)
  73                                         {
  74                                                 if(vlen(team_mate.velocity) > 5)
  75                                                         fixedmakevectors(vectoangles(team_mate.velocity));
  76                                                 else
  77                                                         fixedmakevectors(team_mate.angles);
  78
  79                                                 for(pc = 0; pc != 5; ++pc) // test 5 diffrent spots close to mate
  80                                                 {
  81                                                         switch(pc)
  82                                                         {
  83                                                                 case 0:
  84                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin + v_right * 128, MOVE_NORMAL, team_mate);
  85                                                                         break;
  86                                                                 case 1:
  87                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_right * 128 , MOVE_NORMAL, team_mate);
  88                                                                         break;
  89                                                                 case 2:
  90                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin + v_right * 64 - v_forward * 64, MOVE_NORMAL, team_mate);
  91                                                                         break;
  92                                                                 case 3:
  93                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_right * 64 - v_forward * 64, MOVE_NORMAL, team_mate);
  94                                                                         break;
  95                                                                 case 4:
  96                                                                         tracebox(team_mate.origin , PL_MIN, PL_MAX, team_mate.origin - v_forward * 128, MOVE_NORMAL, team_mate);
  97                                                                         break;
  98                                                         }
  99
 100                                                         if(trace_fraction == 1.0)
 101                                                         {
 102                                                                 traceline(trace_endpos + '0 0 4', trace_endpos - '0 0 100', MOVE_NORMAL, team_mate);
 103                                                                 if(trace_fraction != 1.0)
 104                                                                 {
 105                                                                         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 106                                                                         {
 107                                                                                 dist = vlen(trace_endpos - self.msnt_deathloc);
 108                                                                                 if(dist < best_dist || best_dist == 0)
 109                                                                                 {
 110                                                                                         best_dist = dist;
 111                                                                                         best_spot = trace_endpos;
 112                                                                                         best_mate = team_mate;
 113                                                                                 }
 114                                                                         }
 115                                                                         else
 116                                                                         {
 117                                                                                 setorigin(self, trace_endpos);
 118                                                                                 self.angles = team_mate.angles;
 119                                                                                 self.angles_z = 0; // never spawn tilted even if the spot says to
 120                                                                                 team_mate.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 121                                                                                 return 0;
 122                                                                         }
 123                                                                 }
 124                                                         }
 125                                                 }
 126                                         }
 127                                 }
 128                         }
 129                 }
 130
 131                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 132                 if(best_dist)
 133                 {
 134                         setorigin(self, best_spot);
 135                         self.angles = best_mate.angles;
 136                         self.angles_z = 0; // never spawn tilted even if the spot says to
 137                         best_mate.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 138                 }
 139         }
 140         else if(spawn_spot.msnt_lookat)
 141         {
 142                 self.angles = vectoangles(spawn_spot.msnt_lookat.origin - self.origin);
 143                 self.angles_x = -self.angles.x;
 144                 self.angles_z = 0; // never spawn tilted even if the spot says to
 145                 /*
 146                 sprint(self, "You should be looking at ", spawn_spot.msnt_lookat.netname, "^7.\n");
 147                 sprint(self, "distance: ", vtos(spawn_spot.msnt_lookat.origin - self.origin), "\n");
 148                 sprint(self, "angles: ", vtos(self.angles), "\n");
 149                 */
 150         }
 151
 152         return 0;
 153 }
 154
 155 MUTATOR_HOOKFUNCTION(msnt_PlayerDies)
 156 {
 157         self.msnt_deathloc = self.origin;
 158         return 0;
 159 }
 160
 161 MUTATOR_DEFINITION(mutator_spawn_near_teammate)
 162 {
 163         MUTATOR_HOOK(Spawn_Score, msnt_Spawn_Score, CBC_ORDER_ANY);
 164         MUTATOR_HOOK(PlayerSpawn, msnt_PlayerSpawn, CBC_ORDER_ANY);
 165         MUTATOR_HOOK(PlayerDies, msnt_PlayerDies, CBC_ORDER_ANY);
 166
 167         return 0;
 168 }