Read-only mode. When enabled, no sandbox commands can be used, and objects cannot...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / mutators / sandbox.qc
1 const float MAX_STORAGE_ATTACHMENTS = 16;
2 float object_count;
3 .float object_flood;
4 .entity object_attach;
5 .string material;
6
7 .float touch_timer;
8 void sandbox_ObjectFunction_Touch()
9 {
10         // apply material impact effects
11
12         if(!self.material)
13                 return;
14         if(self.touch_timer > time)
15                 return; // don't execute each frame
16         self.touch_timer = time + 0.1;
17
18         // make particle count and sound volume depend on impact speed
19         float intensity;
20         intensity = vlen(self.velocity) + vlen(other.velocity);
21         if(intensity) // avoid divisions by 0
22                 intensity /= 2; // average the two velocities
23         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
24                 return; // impact not strong enough to do anything
25         // now offset intensity and apply it to the effects
26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
28
29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
31 }
32
33 void sandbox_ObjectFunction_Think()
34 {
35         entity e;
36
37         // decide if and how this object can be grabbed
38         if(autocvar_g_sandbox_readonly)
39                 self.grab = 0; // no grabbing
40         else if(autocvar_g_sandbox_editor_free < 2 && self.crypto_idfp)
41                 self.grab = 1; // owner only
42         else
43                 self.grab = 3; // anyone
44
45         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
46         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
47         // since if the owning player disconnects, the object's owner should also be reset.
48         FOR_EACH_REALPLAYER(e) // bots can't have objects
49         {
50                 if(self.crypto_idfp == e.crypto_idfp)
51                 {
52                         self.realowner = e;
53                         break;
54                 }
55                 self.realowner = world;
56         }
57
58         self.nextthink = time;
59 }
60
61 entity sandbox_ObjectEdit_Get(float permissions)
62 {
63         // returns the traced entity if the player can edit it, and world if not
64         // if permissions if FALSE, the object is returned regardless of editing rights
65         // attached objects are SOLID_NOT and don't risk getting traced
66
67         makevectors(self.v_angle);
68         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
69
70         if(trace_ent.classname != "object")
71                 return world; // entity is not an object
72         if(!permissions)
73                 return trace_ent; // don't check permissions, anyone can edit this object
74         if(!trace_ent.crypto_idfp)
75                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
76         if not(trace_ent.realowner != self && autocvar_g_sandbox_editor_free < 2)
77                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
78         return world;
79 }
80
81 void sandbox_ObjectEdit_Scale(entity e, float f)
82 {
83         e.scale = f;
84         if(e.scale)
85         {
86                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
87                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
88         }
89 }
90
91 .float old_movetype;
92 void sandbox_ObjectAttach_Remove(entity e);
93 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
94 {
95         // attaches e to parent on string s
96
97         // we can't attach to an attachment, for obvious reasons
98         sandbox_ObjectAttach_Remove(e);
99
100         e.old_movetype = e.movetype; // persist physics
101         e.movetype = MOVETYPE_FOLLOW;
102         e.solid = SOLID_NOT;
103         e.takedamage = DAMAGE_NO;
104
105         setattachment(e, parent, s);
106         e.owner = parent;
107 }
108
109 void sandbox_ObjectAttach_Remove(entity e)
110 {
111         // detaches any object attached to e
112
113         entity head;
114         for(head = world; (head = find(head, classname, "object")); )
115         {
116                 if(head.owner == e)
117                 {
118                         vector org;
119                         head.movetype = head.old_movetype; // restore persisted physics
120                         head.solid = SOLID_BBOX;
121                         head.takedamage = DAMAGE_AIM;
122
123                         org = gettaginfo(head, 0);
124                         setattachment(head, world, "");
125                         head.owner = world;
126
127                         // objects change origin and angles when detached, so apply previous position
128                         setorigin(head, org);
129                         head.angles = e.angles; // don't allow detached objects to spin or roll
130                 }
131         }
132 }
133
134 entity sandbox_ObjectSpawn(float database)
135 {
136         // spawn a new object with default properties
137
138         entity e;
139         e = spawn();
140         e.classname = "object";
141         e.takedamage = DAMAGE_AIM;
142         e.damageforcescale = 1;
143         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
144         e.movetype = MOVETYPE_TOSS;
145         e.frame = 0;
146         e.skin = 0;
147         e.material = string_null;
148         e.touch = sandbox_ObjectFunction_Touch;
149         e.think = sandbox_ObjectFunction_Think;
150         e.nextthink = time;
151         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
152
153         if(!database)
154         {
155                 // set the object's owner via player UID
156                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
157                 if(self.crypto_idfp != "")
158                         e.crypto_idfp = strzone(self.crypto_idfp);
159                 else
160                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
161
162                 // set public object information
163                 e.netname = strzone(self.netname); // name of the owner
164                 e.message = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // creation time
165                 e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // last editing time
166
167                 // set origin and direction based on player position and view angle
168                 makevectors(self.v_angle);
169                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
170                 setorigin(e, trace_endpos);
171                 e.angles_y = self.v_angle_y;
172         }
173
174         object_count += 1;
175         return e;
176 }
177
178 void sandbox_ObjectRemove(entity e)
179 {
180         sandbox_ObjectAttach_Remove(e); // detach child objects
181
182         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
183         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
184         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
185         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
186         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
187         remove(e);
188         e = world;
189
190         object_count -= 1;
191 }
192
193 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
194
195 string sandbox_ObjectPort_Save(entity e, float database)
196 {
197         // save object properties, and return them as a string
198         float i;
199         string s;
200         entity head;
201
202         for(head = world; (head = find(head, classname, "object")); )
203         {
204                 // the main object needs to be first in the array [0] with attached objects following
205                 float slot, physics;
206                 if(head == e) // this is the main object, place it first
207                 {
208                         slot = 0;
209                         physics = head.movetype; // applied physics are normal physics for parents
210                 }
211                 else if(head.owner == e) // child object, list them in order
212                 {
213                         i += 1; // children start from 1
214                         slot = i;
215                         physics = head.old_movetype; // persisted physics are normal physics for children
216                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
217                 }
218                 else
219                         continue;
220
221                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
222                 if(slot)
223                 {
224                         // properties stored only for child objects
225                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "- "); // none
226                 }
227                 else
228                 {
229                         // properties stored only for parent objects
230                         if(database)
231                         {
232                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
233                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
234                         }
235                 }
236                 // properties stored for all objects
237                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
238                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
239                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
240                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
241                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
242                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
243                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
244                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
245                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
246                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
247                 if(database)
248                 {
249                         // properties stored only for the database
250                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
251                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
252                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
253                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
254                 }
255         }
256
257         // now apply the array to a simple string, with the ; symbol separating objects
258         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
259         {
260                 if(port_string[i])
261                         s = strcat(s, port_string[i], "; ");
262                 port_string[i] = string_null; // fully clear the string
263         }
264
265         return s;
266 }
267
268 entity sandbox_ObjectPort_Load(string s, float database)
269 {
270         // load object properties, and spawn a new object with them
271         float n, i;
272         entity e, parent;
273
274         // separate objects between the ; symbols
275         n = tokenizebyseparator(s, "; ");
276         for(i = 0; i < n; ++i)
277                 port_string[i] = argv(i);
278
279         // now separate and apply the properties of each object
280         for(i = 0; i < n; ++i)
281         {
282                 float argv_num;
283                 string tagname;
284                 argv_num = 0;
285                 tokenize_console(port_string[i]);
286                 e = sandbox_ObjectSpawn(database);
287
288                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
289                 if(i)
290                 {
291                         // properties stored only for child objects
292                         if(argv(argv_num) != "-")       tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
293                 }
294                 else
295                 {
296                         // properties stored only for parent objects
297                         if(database)
298                         {
299                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
300                                 e.angles = stov(argv(argv_num));        ++argv_num;
301                         }
302                         parent = e; // mark parent objects as such
303                 }
304                 // properties stored for all objects
305                 setmodel(e, argv(argv_num));    ++argv_num;
306                 e.skin = stof(argv(argv_num));  ++argv_num;
307                 e.alpha = stof(argv(argv_num)); ++argv_num;
308                 e.colormod = stov(argv(argv_num));      ++argv_num;
309                 e.glowmod = stov(argv(argv_num));       ++argv_num;
310                 e.frame = stof(argv(argv_num)); ++argv_num;
311                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
312                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
313                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
314                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "-")       e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
315                 if(database)
316                 {
317                         // properties stored only for the database
318                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "-")       e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
319                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
320                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
321                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
322                 }
323
324                 // attach last
325                 if(i)
326                         sandbox_ObjectAttach_Set(e, parent, tagname);
327         }
328
329         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
330                 port_string[i] = string_null; // fully clear the string
331
332         return e;
333 }
334
335 void sandbox_Database_Save()
336 {
337         // saves all objects to the database file
338         entity head;
339         string file_name;
340         float file_get;
341
342         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
343         file_get = fopen(file_name, FILE_WRITE);
344         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
345         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
346
347         for(head = world; (head = find(head, classname, "object")); )
348         {
349                 // attached objects are persisted separately, ignore them here
350                 if(head.owner != world)
351                         continue;
352
353                 // use a line of text for each object, listing all properties
354                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
355         }
356         fclose(file_get);
357 }
358
359 void sandbox_Database_Load()
360 {
361         // loads all objects from the database file
362         string file_read, file_name;
363         float file_get, i;
364
365         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
366         file_get = fopen(file_name, FILE_READ);
367         if(file_get < 0)
368         {
369                 if(autocvar_g_sandbox_info > 0)
370                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
371         }
372         else
373         {
374                 for(;;)
375                 {
376                         file_read = fgets(file_get);
377                         if(!file_read)
378                                 break;
379                         if(substring(file_read, 0, 2) == "//")
380                                 continue;
381                         if(substring(file_read, 0, 1) == "#")
382                                 continue;
383
384                         entity e;
385                         e = sandbox_ObjectPort_Load(file_read, TRUE);
386
387                         if(e.material)
388                         {
389                                 // since objects are being loaded for the first time, precache material sounds for each
390                                 for (i = 1; i <= 5; i++) // 5 sounds in total
391                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
392                         }
393                 }
394                 if(autocvar_g_sandbox_info > 0)
395                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
396         }
397 }
398
399 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
400 {
401         if(MUTATOR_RETURNVALUE) // command was already handled?
402                 return FALSE;
403         if(cmd_name == "g_sandbox")
404         {
405                 if(autocvar_g_sandbox_readonly)
406                 {
407                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active, but in read-only mode. Sandbox commands cannot be used");
408                         return TRUE;
409                 }
410                 if(cmd_argc < 2)
411                 {
412                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active. For usage information, type 'sandbox help'");
413                         return TRUE;
414                 }
415
416                 switch(argv(1))
417                 {
418                         entity e;
419                         float i;
420                         string s;
421
422                         // ---------------- COMMAND: HELP ----------------
423                         case "help":
424                                 print_to(self, "You can use the following sandbox commands:");
425                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
426                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
427                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
428                                 print_to(self, "^3copy value ^7- copies the properties of the object to the specified client cvar");
429                                 print_to(self, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
430                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
431                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
432                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
433                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
434                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
435                                 print_to(self, "^3skin value ^7- changes the skin of the object");
436                                 print_to(self, "^3alpha value ^7- sets object transparency");
437                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
438                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
439                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
440                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
441                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
442                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
443                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
444                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
445                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object");
446                                 print_to(self, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
447                                 print_to(self, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
448                                 print_to(self, "^3attachments ^7- prints information about the object's attachments");
449                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
450                                 return TRUE;
451
452                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
453                         case "object_spawn":
454                                 if(time < self.object_flood)
455                                 {
456                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
457                                         return TRUE;
458                                 }
459                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
460                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
461                                 {
462                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
463                                         return TRUE;
464                                 }
465                                 if(cmd_argc < 3)
466                                 {
467                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
468                                         return TRUE;
469                                 }
470                                 if not(fexists(argv(2)))
471                                 {
472                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
473                                         return TRUE;
474                                 }
475
476                                 e = sandbox_ObjectSpawn(FALSE);
477                                 setmodel(e, argv(2));
478
479                                 if(autocvar_g_sandbox_info > 0)
480                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
481                                 return TRUE;
482
483                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
484                         case "object_remove":
485                                 e = sandbox_ObjectEdit_Get(TRUE);
486                                 if(e != world)
487                                 {
488                                         if(autocvar_g_sandbox_info > 0)
489                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
490                                         sandbox_ObjectRemove(e);
491                                         return TRUE;
492                                 }
493
494                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
495                                 return TRUE;
496
497                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
498                         case "object_duplicate":
499                                 switch(argv(2))
500                                 {
501                                         case "copy":
502                                                 // copies customizable properties of the selected object to the clipboard cvar
503                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
504                                                 if(e != world)
505                                                 {
506                                                         s = sandbox_ObjectPort_Save(e, FALSE);
507                                                         s = strreplace("\"", "\\\"", s);
508                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
509
510                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
511                                                         return TRUE;
512                                                 }
513                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
514                                                 return TRUE;
515
516                                         case "paste":
517                                                 // spawns a new object using the properties in the player's clipboard cvar
518                                                 if(time < self.object_flood)
519                                                 {
520                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
521                                                         return TRUE;
522                                                 }
523                                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
524                                                 if(!argv(3)) // no object in clipboard
525                                                 {
526                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
527                                                         return TRUE;
528                                                 }
529                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
530                                                 {
531                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
532                                                         return TRUE;
533                                                 }
534                                                 e = sandbox_ObjectPort_Load(argv(3), FALSE);
535
536                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
537                                                 if(autocvar_g_sandbox_info > 0)
538                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
539                                                 return TRUE;
540                                 }
541                                 return TRUE;
542
543                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
544                         case "object_attach":
545                                 switch(argv(2))
546                                 {
547                                         case "get":
548                                                 // select e as the object as meant to be attached
549                                                 e = sandbox_ObjectEdit_Get(TRUE);
550                                                 if(e != world)
551                                                 {
552                                                         self.object_attach = e;
553                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
554                                                         return TRUE;
555                                                 }
556                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
557                                                 return TRUE;
558                                         case "set":
559                                                 if(self.object_attach == world)
560                                                 {
561                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
562                                                         return TRUE;
563                                                 }
564
565                                                 // attaches the previously selected object to e
566                                                 e = sandbox_ObjectEdit_Get(TRUE);
567                                                 if(e != world)
568                                                 {
569                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
570                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
571                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
572                                                         if(autocvar_g_sandbox_info > 1)
573                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
574                                                         return TRUE;
575                                                 }
576                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
577                                                 return TRUE;
578                                         case "remove":
579                                                 // removes e if it was attached
580                                                 e = sandbox_ObjectEdit_Get(TRUE);
581                                                 if(e != world)
582                                                 {
583                                                         sandbox_ObjectAttach_Remove(e);
584                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
585                                                         if(autocvar_g_sandbox_info > 1)
586                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
587                                                         return TRUE;
588                                                 }
589                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
590                                                 return TRUE;
591                                 }
592                                 return TRUE;
593
594                         // ---------------- COMMAND: OBJECT, EDIT ----------------
595                         case "object_edit":
596                                 if(!argv(2))
597                                 {
598                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
599                                         return TRUE;
600                                 }
601
602                                 e = sandbox_ObjectEdit_Get(TRUE);
603                                 if(e != world)
604                                 {
605                                         switch(argv(2))
606                                         {
607                                                 case "skin":
608                                                         e.skin = stof(argv(3));
609                                                         break;
610                                                 case "alpha":
611                                                         e.alpha = stof(argv(3));
612                                                         break;
613                                                 case "color_main":
614                                                         e.colormod = stov(argv(3));
615                                                         break;
616                                                 case "color_glow":
617                                                         e.glowmod = stov(argv(3));
618                                                         break;
619                                                 case "frame":
620                                                         e.frame = stof(argv(3));
621                                                         break;
622                                                 case "scale":
623                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
624                                                         break;
625                                                 case "physics":
626                                                         switch(argv(3))
627                                                         {
628                                                                 case "0": // static
629                                                                         e.movetype = MOVETYPE_NONE;
630                                                                         break;
631                                                                 case "1": // movable
632                                                                         e.movetype = MOVETYPE_TOSS;
633                                                                         break;
634                                                                 case "2": // physical
635                                                                         e.movetype = MOVETYPE_PHYSICS;
636                                                                         break;
637                                                                 default:
638                                                                         break;
639                                                         }
640                                                         break;
641                                                 case "force":
642                                                         e.damageforcescale = stof(argv(3));
643                                                         break;
644                                                 case "material":
645                                                         if(e.material)  strunzone(e.material);
646                                                         if(argv(3))
647                                                         {
648                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
649                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
650                                                                 e.material = strzone(argv(3));
651                                                         }
652                                                         else
653                                                                 e.material = string_null; // no material
654                                                         break;
655                                                 default:
656                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
657                                                         return TRUE;
658                                         }
659
660                                         // update last editing time
661                                         if(e.message2)  strunzone(e.message2);
662                                         e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S"));
663
664                                         if(autocvar_g_sandbox_info > 1)
665                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
666                                         return TRUE;
667                                 }
668
669                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
670                                 return TRUE;
671
672                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
673                         case "object_claim":
674                                 // if the player can edit an object but is not its owner, this can be used to claim that object
675                                 if(self.crypto_idfp == "")
676                                 {
677                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
678                                         return TRUE;
679                                 }
680                                 e = sandbox_ObjectEdit_Get(TRUE);
681                                 if(e != world)
682                                 {
683                                         // update the owner's name
684                                         // Do this before checking if you're already the owner and skipping if such, so we
685                                         // also update the player's nickname if he changed it (but has the same player UID)
686                                         if(e.netname != self.netname)
687                                         {
688                                                 if(e.netname)   strunzone(e.netname);
689                                                 e.netname = strzone(self.netname);
690                                                 print_to(self, "^2SANDBOX - INFO: ^7Object owner name updated");
691                                         }
692
693                                         if(e.crypto_idfp == self.crypto_idfp)
694                                         {
695                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
696                                                 return TRUE;
697                                         }
698
699                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
700                                         e.crypto_idfp = strzone(self.crypto_idfp);
701
702                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
703                                 }
704                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
705                                 return TRUE;
706
707                         // ---------------- COMMAND: OBJECT, INFO ----------------
708                         case "object_info":
709                                 // prints public information about the object to the player
710                                 e = sandbox_ObjectEdit_Get(FALSE);
711                                 if(e != world)
712                                 {
713                                         switch(argv(2))
714                                         {
715                                                 case "object":
716                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
717                                                         return TRUE;
718                                                 case "mesh":
719                                                         for(i = 1; gettaginfo(e, i); i++)
720                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
721                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
722                                                         return TRUE;
723                                                 case "attachments":
724                                                         // this should show the same info as 'mesh' but for attachments
725                                                         entity head;
726                                                         for(head = world; (head = find(head, classname, "object")); )
727                                                         {
728                                                                 if(head.owner == e)
729                                                                 {
730                                                                         ++i; // start from 1
731                                                                         gettaginfo(e, head.tag_index);
732                                                                         s = strcat(s, "^1attachment ", ftos(i), "^7 has mesh \"^3", head.model, "^7\" at animation frame ^3", ftos(head.frame));
733                                                                         s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
734                                                                 }
735                                                         }
736                                                         if(i) // object contains attachments
737                                                                 print_to(self, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(i), "^7 attachment(s): ", s));
738                                                         else
739                                                                 print_to(self, "^2SANDBOX - INFO: ^7Object contains no attachments");
740                                                         return TRUE;
741                                         }
742                                 }
743                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
744                                 return TRUE;
745
746                         // ---------------- COMMAND: DEFAULT ----------------
747                         default:
748                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
749                                 return TRUE;
750                 }
751         }
752         return FALSE;
753 }
754
755 float autosave_time;
756 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
757 {
758         if(!autocvar_g_sandbox_storage_autosave)
759                 return FALSE;
760         if(time < autosave_time)
761                 return FALSE;
762         autosave_time = time + autocvar_g_sandbox_storage_autosave;
763
764         sandbox_Database_Save();
765
766         return TRUE;
767 }
768
769 MUTATOR_DEFINITION(sandbox)
770 {
771         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
772         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
773
774         MUTATOR_ONADD
775         {
776                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
777                 if(autocvar_g_sandbox_storage_autoload)
778                         sandbox_Database_Load();
779         }
780
781         return FALSE;
782 }
783