qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .entity object_attach;
   4 .string material;
   5
   6 .float touch_timer;
   7 void sandbox_ObjectFunction_Touch()
   8 {
   9         // apply material impact effects
  10
  11         if(!self.material)
  12                 return;
  13         if(self.touch_timer > time)
  14                 return; // don't execute each frame
  15         self.touch_timer = time + 0.1;
  16
  17         // make particle count and sound volume depend on impact speed
  18         float intensity;
  19         intensity = vlen(self.velocity) + vlen(other.velocity);
  20         if(intensity) // avoid divisions by 0
  21                 intensity /= 2; // average the two velocities
  22         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  23                 return; // impact not strong enough to do anything
  24         // now offset intensity and apply it to the effects
  25         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  26         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  27
  28         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  29         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  30 }
  31
  32 entity sandbox_ObjectEdit_Get(float permissions)
  33 {
  34         // returns the traced entity if the player can edit it, and world if not
  35         // if permissions if FALSE, the object is returned regardless of editing rights
  36         // attached objects are SOLID_NOT and don't risk getting traced
  37
  38         makevectors(self.v_angle);
  39         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  40
  41         if(trace_ent.classname != "object")
  42                 return world; // entity is not an object
  43         if(!permissions)
  44                 return trace_ent; // don't check permissions, anyone can edit this object
  45         if(!trace_ent.crypto_idfp)
  46                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  47         if not(trace_ent.crypto_idfp != self.crypto_idfp && autocvar_g_sandbox_editor_free < 2)
  48                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  49         return world;
  50 }
  51
  52 void sandbox_ObjectEdit_Scale(entity e, float f)
  53 {
  54         e.scale = f;
  55         if(e.scale)
  56         {
  57                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  58                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  59         }
  60 }
  61
  62 .float old_movetype;
  63 void sandbox_ObjectAttach_Remove(entity e);
  64 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  65 {
  66         // attaches e to parent on string s
  67
  68         // we can't attach to an attachment, for obvious reasons
  69         sandbox_ObjectAttach_Remove(e);
  70
  71         e.old_movetype = e.movetype; // persist physics
  72         e.movetype = MOVETYPE_FOLLOW;
  73         e.solid = SOLID_NOT;
  74         e.takedamage = DAMAGE_NO;
  75
  76         setattachment(e, parent, s);
  77         e.owner = parent;
  78 }
  79
  80 void sandbox_ObjectAttach_Remove(entity e)
  81 {
  82         // detaches any object attached to e
  83
  84         entity head;
  85         for(head = world; (head = find(head, classname, "object")); )
  86         {
  87                 if(head.owner == e)
  88                 {
  89                         vector org;
  90                         head.movetype = head.old_movetype; // restore persisted physics
  91                         head.solid = SOLID_BBOX;
  92                         head.takedamage = DAMAGE_AIM;
  93
  94                         org = gettaginfo(head, 0);
  95                         setattachment(head, world, "");
  96                         head.owner = world;
  97
  98                         // objects change origin and angles when detached, so apply previous position
  99                         setorigin(head, org);
 100                         head.angles = e.angles; // don't allow detached objects to spin or roll
 101                 }
 102         }
 103 }
 104
 105 entity sandbox_ObjectSpawn(float database)
 106 {
 107         // spawn a new object with default properties
 108
 109         entity e;
 110         e = spawn();
 111         e.classname = "object";
 112         e.takedamage = DAMAGE_AIM;
 113         e.damageforcescale = 1;
 114         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 115         e.movetype = MOVETYPE_TOSS;
 116         e.frame = 0;
 117         e.skin = 0;
 118         e.material = string_null;
 119         e.touch = sandbox_ObjectFunction_Touch;
 120         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
 121
 122         if(!database)
 123         {
 124                 // set the object's owner via player UID
 125                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 126                 if(self.crypto_idfp != "")
 127                         e.crypto_idfp = strzone(self.crypto_idfp);
 128                 else
 129                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 130
 131                 // set public object information
 132                 e.netname = strzone(self.netname); // name of the owner
 133                 e.message = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // creation time
 134                 e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // last editing time
 135
 136                 // set origin and direction based on player position and view angle
 137                 makevectors(self.v_angle);
 138                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 139                 setorigin(e, trace_endpos);
 140                 e.angles_y = self.v_angle_y;
 141         }
 142
 143         object_count += 1;
 144         return e;
 145 }
 146
 147 void sandbox_ObjectRemove(entity e)
 148 {
 149         sandbox_ObjectAttach_Remove(e); // detach child objects
 150
 151         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
 152         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
 153         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
 154         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
 155         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
 156         remove(e);
 157         e = world;
 158
 159         object_count -= 1;
 160 }
 161
 162 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 163
 164 string sandbox_ObjectPort_Save(entity e, float database)
 165 {
 166         // save object properties, and return them as a string
 167         float i;
 168         string s;
 169         entity head;
 170
 171         for(head = world; (head = find(head, classname, "object")); )
 172         {
 173                 // the main object needs to be first in the array [0] with attached objects following
 174                 float slot, physics;
 175                 if(head == e) // this is the main object, place it first
 176                 {
 177                         slot = 0;
 178                         physics = head.movetype; // applied physics are normal physics for parents
 179                 }
 180                 else if(head.owner == e) // child object, list them in order
 181                 {
 182                         i += 1; // children start from 1
 183                         slot = i;
 184                         physics = head.old_movetype; // persisted physics are normal physics for children
 185                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 186                 }
 187                 else
 188                         continue;
 189
 190                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 191                 if(slot)
 192                 {
 193                         // properties stored only for child objects
 194                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "- "); // none
 195                 }
 196                 else
 197                 {
 198                         // properties stored only for parent objects
 199                         if(database)
 200                         {
 201                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 202                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 203                         }
 204                 }
 205                 // properties stored for all objects
 206                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 207                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 208                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 209                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 210                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 211                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 212                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 213                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 214                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 215                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 216                 if(database)
 217                 {
 218                         // properties stored only for the database
 219                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 220                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
 221                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
 222                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
 223                 }
 224         }
 225
 226         // now apply the array to a simple string, with the ; symbol separating objects
 227         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 228         {
 229                 if(port_string[i])
 230                         s = strcat(s, port_string[i], "; ");
 231                 port_string[i] = string_null; // fully clear the string
 232         }
 233
 234         return s;
 235 }
 236
 237 entity sandbox_ObjectPort_Load(string s, float database)
 238 {
 239         // load object properties, and spawn a new object with them
 240         float n, i;
 241         entity e, parent;
 242
 243         // separate objects between the ; symbols
 244         n = tokenizebyseparator(s, "; ");
 245         for(i = 0; i < n; ++i)
 246                 port_string[i] = argv(i);
 247
 248         // now separate and apply the properties of each object
 249         for(i = 0; i < n; ++i)
 250         {
 251                 float argv_num;
 252                 string tagname;
 253                 argv_num = 0;
 254                 tokenize_console(port_string[i]);
 255                 e = sandbox_ObjectSpawn(database);
 256
 257                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 258                 if(i)
 259                 {
 260                         // properties stored only for child objects
 261                         if(argv(argv_num) != "-")       tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 262                 }
 263                 else
 264                 {
 265                         // properties stored only for parent objects
 266                         if(database)
 267                         {
 268                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 269                                 e.angles = stov(argv(argv_num));        ++argv_num;
 270                         }
 271                         parent = e; // mark parent objects as such
 272                 }
 273                 // properties stored for all objects
 274                 setmodel(e, argv(argv_num));    ++argv_num;
 275                 e.skin = stof(argv(argv_num));  ++argv_num;
 276                 e.alpha = stof(argv(argv_num)); ++argv_num;
 277                 e.colormod = stov(argv(argv_num));      ++argv_num;
 278                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 279                 e.frame = stof(argv(argv_num)); ++argv_num;
 280                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 281                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 282                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 283                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "-")       e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 284                 if(database)
 285                 {
 286                         // properties stored only for the database
 287                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "-")       e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 288                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
 289                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
 290                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
 291                 }
 292
 293                 // attach last
 294                 if(i)
 295                         sandbox_ObjectAttach_Set(e, parent, tagname);
 296         }
 297
 298         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 299                 port_string[i] = string_null; // fully clear the string
 300
 301         return e;
 302 }
 303
 304 void sandbox_Database_Save()
 305 {
 306         // saves all objects to the database file
 307         entity head;
 308         string file_name;
 309         float file_get;
 310
 311         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 312         file_get = fopen(file_name, FILE_WRITE);
 313         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 314         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 315
 316         for(head = world; (head = find(head, classname, "object")); )
 317         {
 318                 // attached objects are persisted separately, ignore them here
 319                 if(head.owner != world)
 320                         continue;
 321
 322                 // use a line of text for each object, listing all properties
 323                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 324         }
 325         fclose(file_get);
 326 }
 327
 328 void sandbox_Database_Load()
 329 {
 330         // loads all objects from the database file
 331         string file_read, file_name;
 332         float file_get, i;
 333
 334         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 335         file_get = fopen(file_name, FILE_READ);
 336         if(file_get < 0)
 337         {
 338                 if(autocvar_g_sandbox_info > 0)
 339                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 340         }
 341         else
 342         {
 343                 for(;;)
 344                 {
 345                         file_read = fgets(file_get);
 346                         if(!file_read)
 347                                 break;
 348                         if(substring(file_read, 0, 2) == "//")
 349                                 continue;
 350                         if(substring(file_read, 0, 1) == "#")
 351                                 continue;
 352
 353                         entity e;
 354                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 355
 356                         if(e.material)
 357                         {
 358                                 // since objects are being loaded for the first time, precache material sounds for each
 359                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 360                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 361                         }
 362                 }
 363                 if(autocvar_g_sandbox_info > 0)
 364                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 365         }
 366 }
 367
 368 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 369 {
 370         if(MUTATOR_RETURNVALUE) // command was already handled?
 371                 return FALSE;
 372         if(cmd_name == "g_sandbox")
 373         {
 374                 if(cmd_argc < 2)
 375                 {
 376                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 377                         return TRUE;
 378                 }
 379
 380                 switch(argv(1))
 381                 {
 382                         entity e;
 383                         float i;
 384                         string s;
 385
 386                         // ---------------- COMMAND: HELP ----------------
 387                         case "help":
 388                                 print_to(self, "You can use the following sandbox commands:");
 389                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 390                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 391                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
 392                                 print_to(self, "^3copy value ^7- copies the properties of the object to the specified client cvar");
 393                                 print_to(self, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
 394                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 395                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 396                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 397                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 398                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 399                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 400                                 print_to(self, "^3alpha value ^7- sets object transparency");
 401                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 402                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 403                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 404                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 405                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 406                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 407                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 408                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 409                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object");
 410                                 print_to(self, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
 411                                 print_to(self, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
 412                                 print_to(self, "^3attachments ^7- prints information about the object's attachments");
 413                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 414                                 return TRUE;
 415
 416                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 417                         case "object_spawn":
 418                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 419                                 {
 420                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 421                                         return TRUE;
 422                                 }
 423                                 if(cmd_argc < 3)
 424                                 {
 425                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 426                                         return TRUE;
 427                                 }
 428                                 else if not(fexists(argv(2)))
 429                                 {
 430                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 431                                         return TRUE;
 432                                 }
 433
 434                                 e = sandbox_ObjectSpawn(FALSE);
 435                                 setmodel(e, argv(2));
 436
 437                                 if(autocvar_g_sandbox_info > 0)
 438                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 439                                 return TRUE;
 440
 441                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 442                         case "object_remove":
 443                                 e = sandbox_ObjectEdit_Get(TRUE);
 444                                 if(e != world)
 445                                 {
 446                                         if(autocvar_g_sandbox_info > 0)
 447                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 448                                         sandbox_ObjectRemove(e);
 449                                         return TRUE;
 450                                 }
 451
 452                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 453                                 return TRUE;
 454
 455                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 456                         case "object_duplicate":
 457                                 switch(argv(2))
 458                                 {
 459                                         case "copy":
 460                                                 // copies customizable properties of the selected object to the clipboard cvar
 461                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 462                                                 if(e != world)
 463                                                 {
 464                                                         s = sandbox_ObjectPort_Save(e, FALSE);
 465                                                         s = strreplace("\"", "\\\"", s);
 466                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
 467
 468                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 469                                                         return TRUE;
 470                                                 }
 471                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 472                                                 return TRUE;
 473
 474                                         case "paste":
 475                                                 // spawns a new object using the properties in the player's clipboard cvar
 476                                                 if(!argv(3)) // no object in clipboard
 477                                                 {
 478                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 479                                                         return TRUE;
 480                                                 }
 481                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 482                                                 {
 483                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 484                                                         return TRUE;
 485                                                 }
 486                                                 e = sandbox_ObjectPort_Load(argv(3), FALSE);
 487
 488                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 489                                                 if(autocvar_g_sandbox_info > 0)
 490                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 491                                                 return TRUE;
 492                                 }
 493                                 return TRUE;
 494
 495                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 496                         case "object_attach":
 497                                 switch(argv(2))
 498                                 {
 499                                         case "get":
 500                                                 // select e as the object as meant to be attached
 501                                                 e = sandbox_ObjectEdit_Get(TRUE);
 502                                                 if(e != world)
 503                                                 {
 504                                                         self.object_attach = e;
 505                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 506                                                         return TRUE;
 507                                                 }
 508                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 509                                                 return TRUE;
 510                                         case "set":
 511                                                 if(self.object_attach == world)
 512                                                 {
 513                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 514                                                         return TRUE;
 515                                                 }
 516
 517                                                 // attaches the previously selected object to e
 518                                                 e = sandbox_ObjectEdit_Get(TRUE);
 519                                                 if(e != world)
 520                                                 {
 521                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 522                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 523                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 524                                                         if(autocvar_g_sandbox_info > 1)
 525                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 526                                                         return TRUE;
 527                                                 }
 528                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 529                                                 return TRUE;
 530                                         case "remove":
 531                                                 // removes e if it was attached
 532                                                 e = sandbox_ObjectEdit_Get(TRUE);
 533                                                 if(e != world)
 534                                                 {
 535                                                         sandbox_ObjectAttach_Remove(e);
 536                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 537                                                         if(autocvar_g_sandbox_info > 1)
 538                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 539                                                         return TRUE;
 540                                                 }
 541                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 542                                                 return TRUE;
 543                                 }
 544                                 return TRUE;
 545
 546                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 547                         case "object_edit":
 548                                 if(!argv(2))
 549                                 {
 550                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 551                                         return TRUE;
 552                                 }
 553
 554                                 e = sandbox_ObjectEdit_Get(TRUE);
 555                                 if(e != world)
 556                                 {
 557                                         switch(argv(2))
 558                                         {
 559                                                 case "skin":
 560                                                         e.skin = stof(argv(3));
 561                                                         break;
 562                                                 case "alpha":
 563                                                         e.alpha = stof(argv(3));
 564                                                         break;
 565                                                 case "color_main":
 566                                                         e.colormod = stov(argv(3));
 567                                                         break;
 568                                                 case "color_glow":
 569                                                         e.glowmod = stov(argv(3));
 570                                                         break;
 571                                                 case "frame":
 572                                                         e.frame = stof(argv(3));
 573                                                         break;
 574                                                 case "scale":
 575                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 576                                                         break;
 577                                                 case "physics":
 578                                                         switch(argv(3))
 579                                                         {
 580                                                                 case "0": // static
 581                                                                         e.movetype = MOVETYPE_NONE;
 582                                                                         break;
 583                                                                 case "1": // movable
 584                                                                         e.movetype = MOVETYPE_TOSS;
 585                                                                         break;
 586                                                                 case "2": // physical
 587                                                                         e.movetype = MOVETYPE_PHYSICS;
 588                                                                         break;
 589                                                                 default:
 590                                                                         break;
 591                                                         }
 592                                                         break;
 593                                                 case "force":
 594                                                         e.damageforcescale = stof(argv(3));
 595                                                         break;
 596                                                 case "material":
 597                                                         if(e.material)  strunzone(e.material);
 598                                                         if(argv(3))
 599                                                         {
 600                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 601                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 602                                                                 e.material = strzone(argv(3));
 603                                                         }
 604                                                         else
 605                                                                 e.material = string_null; // no material
 606                                                         break;
 607                                                 default:
 608                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 609                                                         return TRUE;
 610                                         }
 611
 612                                         // update last editing time
 613                                         if(e.message2)  strunzone(e.message2);
 614                                         e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S"));
 615
 616                                         if(autocvar_g_sandbox_info > 1)
 617                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 618                                         return TRUE;
 619                                 }
 620
 621                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 622                                 return TRUE;
 623
 624                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 625                         case "object_claim":
 626                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 627                                 if(self.crypto_idfp == "")
 628                                 {
 629                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 630                                         return TRUE;
 631                                 }
 632                                 e = sandbox_ObjectEdit_Get(TRUE);
 633                                 if(e != world)
 634                                 {
 635                                         // update the owner's name
 636                                         // Do this before checking if you're already the owner and skipping if such, so we
 637                                         // also update the player's nickname if he changed it (but has the same player UID)
 638                                         if(e.netname != self.netname)
 639                                         {
 640                                                 if(e.netname)   strunzone(e.netname);
 641                                                 e.netname = strzone(self.netname);
 642                                                 print_to(self, "^2SANDBOX - INFO: ^7Object owner name updated");
 643                                         }
 644
 645                                         if(e.crypto_idfp == self.crypto_idfp)
 646                                         {
 647                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 648                                                 return TRUE;
 649                                         }
 650
 651                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
 652                                         e.crypto_idfp = strzone(self.crypto_idfp);
 653
 654                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 655                                 }
 656                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 657                                 return TRUE;
 658
 659                         // ---------------- COMMAND: OBJECT, INFO ----------------
 660                         case "object_info":
 661                                 // prints public information about the object to the player
 662                                 e = sandbox_ObjectEdit_Get(FALSE);
 663                                 if(e != world)
 664                                 {
 665                                         switch(argv(2))
 666                                         {
 667                                                 case "object":
 668                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
 669                                                         return TRUE;
 670                                                 case "mesh":
 671                                                         for(i = 1; gettaginfo(e, i); i++)
 672                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
 673                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
 674                                                         return TRUE;
 675                                                 case "attachments":
 676                                                         // this should show the same info as 'mesh' but for attachments
 677                                                         entity head;
 678                                                         for(head = world; (head = find(head, classname, "object")); )
 679                                                         {
 680                                                                 if(head.owner == e)
 681                                                                 {
 682                                                                         ++i; // start from 1
 683                                                                         gettaginfo(e, head.tag_index);
 684                                                                         s = strcat(s, "^1attachment ", ftos(i), "^7 has mesh \"^3", head.model, "^7\" at animation frame ^3", ftos(head.frame));
 685                                                                         s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
 686                                                                 }
 687                                                         }
 688                                                         if(i) // object contains attachments
 689                                                                 print_to(self, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(i), "^7 attachment(s): ", s));
 690                                                         else
 691                                                                 print_to(self, "^2SANDBOX - INFO: ^7Object contains no attachments");
 692                                                         return TRUE;
 693                                         }
 694                                 }
 695                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
 696                                 return TRUE;
 697
 698                         // ---------------- COMMAND: DEFAULT ----------------
 699                         default:
 700                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 701                                 return TRUE;
 702                 }
 703         }
 704         return FALSE;
 705 }
 706
 707 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 708 {
 709         // if the player is close enough to their object, they can drag it
 710
 711         if(autocvar_sv_cheats)
 712                 return FALSE; // cheat dragging is used instead
 713
 714         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 715         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 716         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 717         // it goes out of range while slinging it around.
 718
 719         entity e;
 720         float grab;
 721
 722         e = sandbox_ObjectEdit_Get(TRUE);
 723         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 724                 grab = TRUE;
 725
 726         if(Drag(e, grab)) // execute dragging
 727                 return TRUE;
 728
 729         return FALSE;
 730 }
 731
 732 float autosave_time;
 733 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 734 {
 735         if(!autocvar_g_sandbox_storage_autosave)
 736                 return FALSE;
 737         if(time < autosave_time)
 738                 return FALSE;
 739         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 740
 741         sandbox_Database_Save();
 742
 743         return TRUE;
 744 }
 745
 746 MUTATOR_DEFINITION(sandbox)
 747 {
 748         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 749         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 750         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 751
 752         MUTATOR_ONADD
 753         {
 754                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 755                 if(autocvar_g_sandbox_storage_autoload)
 756                         sandbox_Database_Load();
 757         }
 758
 759         return FALSE;
 760 }
 761