qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .float object_flood;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if (!(intensity >= autocvar_g_sandbox_object_material_velocity_min))
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".wav"), VOL_BASE * intensity, ATTEN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 void sandbox_ObjectFunction_Think()
  34 {
  35         entity e;
  36
  37         // decide if and how this object can be grabbed
  38         if(autocvar_g_sandbox_readonly)
  39                 self.grab = 0; // no grabbing
  40         else if(autocvar_g_sandbox_editor_free < 2 && self.crypto_idfp)
  41                 self.grab = 1; // owner only
  42         else
  43                 self.grab = 3; // anyone
  44
  45         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
  46         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
  47         // since if the owning player disconnects, the object's owner should also be reset.
  48         FOR_EACH_REALPLAYER(e) // bots can't have objects
  49         {
  50                 if(self.crypto_idfp == e.crypto_idfp)
  51                 {
  52                         self.realowner = e;
  53                         break;
  54                 }
  55                 self.realowner = world;
  56         }
  57
  58         self.nextthink = time;
  59 }
  60
  61 .float old_solid, old_movetype;
  62 entity sandbox_ObjectEdit_Get(float permissions)
  63 {
  64         // Returns the traced entity if the player can edit it, and world if not.
  65         // If permissions if FALSE, the object is returned regardless of editing rights.
  66         // Attached objects are SOLID_NOT and do not get traced.
  67
  68         crosshair_trace_plusvisibletriggers(self);
  69         if(vlen(self.origin - trace_ent.origin) > autocvar_g_sandbox_editor_distance_edit)
  70                 return world; // out of trace range
  71         if(trace_ent.classname != "object")
  72                 return world; // entity is not an object
  73         if(!permissions)
  74                 return trace_ent; // don't check permissions, anyone can edit this object
  75         if(trace_ent.crypto_idfp == "")
  76                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  77         if (!(trace_ent.realowner != self && autocvar_g_sandbox_editor_free < 2))
  78                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  79         return world;
  80 }
  81
  82 void sandbox_ObjectEdit_Scale(entity e, float f)
  83 {
  84         e.scale = f;
  85         if(e.scale)
  86         {
  87                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  88                 setmodel(e, e.model); // reset mins and maxs based on mesh
  89                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  90         }
  91 }
  92
  93 void sandbox_ObjectAttach_Remove(entity e);
  94 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  95 {
  96         // attaches e to parent on string s
  97
  98         // we can't attach to an attachment, for obvious reasons
  99         sandbox_ObjectAttach_Remove(e);
 100
 101         e.old_solid = e.solid; // persist solidity
 102         e.old_movetype = e.movetype; // persist physics
 103         e.movetype = MOVETYPE_FOLLOW;
 104         e.solid = SOLID_NOT;
 105         e.takedamage = DAMAGE_NO;
 106
 107         setattachment(e, parent, s);
 108         e.owner = parent;
 109 }
 110
 111 void sandbox_ObjectAttach_Remove(entity e)
 112 {
 113         // detaches any object attached to e
 114
 115         entity head;
 116         for(head = world; (head = find(head, classname, "object")); )
 117         {
 118                 if(head.owner == e)
 119                 {
 120                         vector org;
 121                         org = gettaginfo(head, 0);
 122                         setattachment(head, world, "");
 123                         head.owner = world;
 124
 125                         // objects change origin and angles when detached, so apply previous position
 126                         setorigin(head, org);
 127                         head.angles = e.angles; // don't allow detached objects to spin or roll
 128
 129                         head.solid = head.old_solid; // restore persisted solidity
 130                         head.movetype = head.old_movetype; // restore persisted physics
 131                         head.takedamage = DAMAGE_AIM;
 132                 }
 133         }
 134 }
 135
 136 entity sandbox_ObjectSpawn(float database)
 137 {
 138         // spawn a new object with default properties
 139
 140         entity e;
 141         e = spawn();
 142         e.classname = "object";
 143         e.takedamage = DAMAGE_AIM;
 144         e.damageforcescale = 1;
 145         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 146         e.movetype = MOVETYPE_TOSS;
 147         e.frame = 0;
 148         e.skin = 0;
 149         e.material = string_null;
 150         e.touch = sandbox_ObjectFunction_Touch;
 151         e.think = sandbox_ObjectFunction_Think;
 152         e.nextthink = time;
 153         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
 154
 155         if(!database)
 156         {
 157                 // set the object's owner via player UID
 158                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 159                 if(self.crypto_idfp != "")
 160                         e.crypto_idfp = strzone(self.crypto_idfp);
 161                 else
 162                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 163
 164                 // set public object information
 165                 e.netname = strzone(self.netname); // name of the owner
 166                 e.message = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // creation time
 167                 e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // last editing time
 168
 169                 // set origin and direction based on player position and view angle
 170                 makevectors(self.v_angle);
 171                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 172                 setorigin(e, trace_endpos);
 173                 e.angles_y = self.v_angle_y;
 174         }
 175
 176         object_count += 1;
 177         return e;
 178 }
 179
 180 void sandbox_ObjectRemove(entity e)
 181 {
 182         sandbox_ObjectAttach_Remove(e); // detach child objects
 183
 184         // if the object being removed has been selected for attachment by a player, unset it
 185         entity head;
 186         FOR_EACH_REALPLAYER(head) // bots can't have objects
 187         {
 188                 if(head.object_attach == e)
 189                         head.object_attach = world;
 190         }
 191
 192         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
 193         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
 194         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
 195         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
 196         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
 197         remove(e);
 198         e = world;
 199
 200         object_count -= 1;
 201 }
 202
 203 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 204
 205 string sandbox_ObjectPort_Save(entity e, float database)
 206 {
 207         // save object properties, and return them as a string
 208         float i = 0;
 209         string s;
 210         entity head;
 211
 212         for(head = world; (head = find(head, classname, "object")); )
 213         {
 214                 // the main object needs to be first in the array [0] with attached objects following
 215                 float slot, physics, solidity;
 216                 if(head == e) // this is the main object, place it first
 217                 {
 218                         slot = 0;
 219                         solidity = head.solid; // applied solidity is normal solidity for children
 220                         physics = head.movetype; // applied physics are normal physics for parents
 221                 }
 222                 else if(head.owner == e) // child object, list them in order
 223                 {
 224                         i += 1; // children start from 1
 225                         slot = i;
 226                         solidity = head.old_solid; // persisted solidity is normal solidity for children
 227                         physics = head.old_movetype; // persisted physics are normal physics for children
 228                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 229                 }
 230                 else
 231                         continue;
 232
 233                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 234                 if(slot)
 235                 {
 236                         // properties stored only for child objects
 237                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 238                 }
 239                 else
 240                 {
 241                         // properties stored only for parent objects
 242                         if(database)
 243                         {
 244                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 245                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 246                         }
 247                 }
 248                 // properties stored for all objects
 249                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 250                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 251                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 252                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 253                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 254                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 255                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 256                 port_string[slot] = strcat(port_string[slot], ftos(solidity), " ");
 257                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 258                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 259                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 260                 if(database)
 261                 {
 262                         // properties stored only for the database
 263                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 264                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
 265                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
 266                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
 267                 }
 268         }
 269
 270         // now apply the array to a simple string, with the ; symbol separating objects
 271         s = "";
 272         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 273         {
 274                 if(port_string[i])
 275                         s = strcat(s, port_string[i], "; ");
 276                 port_string[i] = string_null; // fully clear the string
 277         }
 278
 279         return s;
 280 }
 281
 282 entity sandbox_ObjectPort_Load(string s, float database)
 283 {
 284         // load object properties, and spawn a new object with them
 285         float n, i;
 286         entity e = world, parent = world;
 287
 288         // separate objects between the ; symbols
 289         n = tokenizebyseparator(s, "; ");
 290         for(i = 0; i < n; ++i)
 291                 port_string[i] = argv(i);
 292
 293         // now separate and apply the properties of each object
 294         for(i = 0; i < n; ++i)
 295         {
 296                 float argv_num;
 297                 string tagname = string_null;
 298                 argv_num = 0;
 299                 tokenize_console(port_string[i]);
 300                 e = sandbox_ObjectSpawn(database);
 301
 302                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 303                 if(i)
 304                 {
 305                         // properties stored only for child objects
 306                         if(argv(argv_num) != "")        tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 307                 }
 308                 else
 309                 {
 310                         // properties stored only for parent objects
 311                         if(database)
 312                         {
 313                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 314                                 e.angles = stov(argv(argv_num));        ++argv_num;
 315                         }
 316                         parent = e; // mark parent objects as such
 317                 }
 318                 // properties stored for all objects
 319                 setmodel(e, argv(argv_num));    ++argv_num;
 320                 e.skin = stof(argv(argv_num));  ++argv_num;
 321                 e.alpha = stof(argv(argv_num)); ++argv_num;
 322                 e.colormod = stov(argv(argv_num));      ++argv_num;
 323                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 324                 e.frame = stof(argv(argv_num)); ++argv_num;
 325                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 326                 e.solid = e.old_solid = stof(argv(argv_num));   ++argv_num;
 327                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 328                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 329                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "")        e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 330                 if(database)
 331                 {
 332                         // properties stored only for the database
 333                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "")        e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 334                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
 335                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
 336                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
 337                 }
 338
 339                 // attach last
 340                 if(i)
 341                         sandbox_ObjectAttach_Set(e, parent, tagname);
 342         }
 343
 344         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 345                 port_string[i] = string_null; // fully clear the string
 346
 347         return e;
 348 }
 349
 350 void sandbox_Database_Save()
 351 {
 352         // saves all objects to the database file
 353         entity head;
 354         string file_name;
 355         float file_get;
 356
 357         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 358         file_get = fopen(file_name, FILE_WRITE);
 359         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 360         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 361
 362         for(head = world; (head = find(head, classname, "object")); )
 363         {
 364                 // attached objects are persisted separately, ignore them here
 365                 if(head.owner != world)
 366                         continue;
 367
 368                 // use a line of text for each object, listing all properties
 369                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 370         }
 371         fclose(file_get);
 372 }
 373
 374 void sandbox_Database_Load()
 375 {
 376         // loads all objects from the database file
 377         string file_read, file_name;
 378         float file_get, i;
 379
 380         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 381         file_get = fopen(file_name, FILE_READ);
 382         if(file_get < 0)
 383         {
 384                 if(autocvar_g_sandbox_info > 0)
 385                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 386         }
 387         else
 388         {
 389                 for(;;)
 390                 {
 391                         file_read = fgets(file_get);
 392                         if(file_read == "")
 393                                 break;
 394                         if(substring(file_read, 0, 2) == "//")
 395                                 continue;
 396                         if(substring(file_read, 0, 1) == "#")
 397                                 continue;
 398
 399                         entity e;
 400                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 401
 402                         if(e.material)
 403                         {
 404                                 // since objects are being loaded for the first time, precache material sounds for each
 405                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 406                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".wav"));
 407                         }
 408                 }
 409                 if(autocvar_g_sandbox_info > 0)
 410                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 411         }
 412         fclose(file_get);
 413 }
 414
 415 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 416 {
 417         if(MUTATOR_RETURNVALUE) // command was already handled?
 418                 return FALSE;
 419         if(cmd_name == "g_sandbox")
 420         {
 421                 if(autocvar_g_sandbox_readonly)
 422                 {
 423                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active, but in read-only mode. Sandbox commands cannot be used");
 424                         return TRUE;
 425                 }
 426                 if(cmd_argc < 2)
 427                 {
 428                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active. For usage information, type 'sandbox help'");
 429                         return TRUE;
 430                 }
 431
 432                 switch(argv(1))
 433                 {
 434                         entity e;
 435                         float i;
 436                         string s;
 437
 438                         // ---------------- COMMAND: HELP ----------------
 439                         case "help":
 440                                 print_to(self, "You can use the following sandbox commands:");
 441                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 442                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 443                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
 444                                 print_to(self, "^3copy value ^7- copies the properties of the object to the specified client cvar");
 445                                 print_to(self, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
 446                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 447                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 448                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 449                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 450                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 451                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 452                                 print_to(self, "^3alpha value ^7- sets object transparency");
 453                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 454                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 455                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 456                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 457                                 print_to(self, "^3solidity value ^7- object collisions, 0 = non-solid, 1 = solid");
 458                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 459                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 460                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 461                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 462                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object");
 463                                 print_to(self, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
 464                                 print_to(self, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
 465                                 print_to(self, "^3attachments ^7- prints information about the object's attachments");
 466                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 467                                 return TRUE;
 468
 469                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 470                         case "object_spawn":
 471                                 if(time < self.object_flood)
 472                                 {
 473                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 474                                         return TRUE;
 475                                 }
 476                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 477                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 478                                 {
 479                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 480                                         return TRUE;
 481                                 }
 482                                 if(cmd_argc < 3)
 483                                 {
 484                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 485                                         return TRUE;
 486                                 }
 487                                 if (!(fexists(argv(2))))
 488                                 {
 489                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 490                                         return TRUE;
 491                                 }
 492
 493                                 e = sandbox_ObjectSpawn(FALSE);
 494                                 setmodel(e, argv(2));
 495
 496                                 if(autocvar_g_sandbox_info > 0)
 497                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 498                                 return TRUE;
 499
 500                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 501                         case "object_remove":
 502                                 e = sandbox_ObjectEdit_Get(TRUE);
 503                                 if(e != world)
 504                                 {
 505                                         if(autocvar_g_sandbox_info > 0)
 506                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 507                                         sandbox_ObjectRemove(e);
 508                                         return TRUE;
 509                                 }
 510
 511                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 512                                 return TRUE;
 513
 514                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 515                         case "object_duplicate":
 516                                 switch(argv(2))
 517                                 {
 518                                         case "copy":
 519                                                 // copies customizable properties of the selected object to the clipboard cvar
 520                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 521                                                 if(e != world)
 522                                                 {
 523                                                         s = sandbox_ObjectPort_Save(e, FALSE);
 524                                                         s = strreplace("\"", "\\\"", s);
 525                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
 526
 527                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 528                                                         return TRUE;
 529                                                 }
 530                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 531                                                 return TRUE;
 532
 533                                         case "paste":
 534                                                 // spawns a new object using the properties in the player's clipboard cvar
 535                                                 if(time < self.object_flood)
 536                                                 {
 537                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 538                                                         return TRUE;
 539                                                 }
 540                                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 541                                                 if(argv(3) == "") // no object in clipboard
 542                                                 {
 543                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 544                                                         return TRUE;
 545                                                 }
 546                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 547                                                 {
 548                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 549                                                         return TRUE;
 550                                                 }
 551                                                 e = sandbox_ObjectPort_Load(argv(3), FALSE);
 552
 553                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 554                                                 if(autocvar_g_sandbox_info > 0)
 555                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 556                                                 return TRUE;
 557                                 }
 558                                 return TRUE;
 559
 560                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 561                         case "object_attach":
 562                                 switch(argv(2))
 563                                 {
 564                                         case "get":
 565                                                 // select e as the object as meant to be attached
 566                                                 e = sandbox_ObjectEdit_Get(TRUE);
 567                                                 if(e != world)
 568                                                 {
 569                                                         self.object_attach = e;
 570                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 571                                                         return TRUE;
 572                                                 }
 573                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 574                                                 return TRUE;
 575                                         case "set":
 576                                                 if(self.object_attach == world)
 577                                                 {
 578                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 579                                                         return TRUE;
 580                                                 }
 581
 582                                                 // attaches the previously selected object to e
 583                                                 e = sandbox_ObjectEdit_Get(TRUE);
 584                                                 if(e != world)
 585                                                 {
 586                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 587                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 588                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 589                                                         if(autocvar_g_sandbox_info > 1)
 590                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 591                                                         return TRUE;
 592                                                 }
 593                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 594                                                 return TRUE;
 595                                         case "remove":
 596                                                 // removes e if it was attached
 597                                                 e = sandbox_ObjectEdit_Get(TRUE);
 598                                                 if(e != world)
 599                                                 {
 600                                                         sandbox_ObjectAttach_Remove(e);
 601                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 602                                                         if(autocvar_g_sandbox_info > 1)
 603                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 604                                                         return TRUE;
 605                                                 }
 606                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 607                                                 return TRUE;
 608                                 }
 609                                 return TRUE;
 610
 611                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 612                         case "object_edit":
 613                                 if(argv(2) == "")
 614                                 {
 615                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 616                                         return TRUE;
 617                                 }
 618
 619                                 e = sandbox_ObjectEdit_Get(TRUE);
 620                                 if(e != world)
 621                                 {
 622                                         switch(argv(2))
 623                                         {
 624                                                 case "skin":
 625                                                         e.skin = stof(argv(3));
 626                                                         break;
 627                                                 case "alpha":
 628                                                         e.alpha = stof(argv(3));
 629                                                         break;
 630                                                 case "color_main":
 631                                                         e.colormod = stov(argv(3));
 632                                                         break;
 633                                                 case "color_glow":
 634                                                         e.glowmod = stov(argv(3));
 635                                                         break;
 636                                                 case "frame":
 637                                                         e.frame = stof(argv(3));
 638                                                         break;
 639                                                 case "scale":
 640                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 641                                                         break;
 642                                                 case "solidity":
 643                                                         switch(argv(3))
 644                                                         {
 645                                                                 case "0": // non-solid
 646                                                                         e.solid = SOLID_TRIGGER;
 647                                                                         break;
 648                                                                 case "1": // solid
 649                                                                         e.solid = SOLID_BBOX;
 650                                                                         break;
 651                                                                 default:
 652                                                                         break;
 653                                                         }
 654                                                 case "physics":
 655                                                         switch(argv(3))
 656                                                         {
 657                                                                 case "0": // static
 658                                                                         e.movetype = MOVETYPE_NONE;
 659                                                                         break;
 660                                                                 case "1": // movable
 661                                                                         e.movetype = MOVETYPE_TOSS;
 662                                                                         break;
 663                                                                 case "2": // physical
 664                                                                         e.movetype = MOVETYPE_PHYSICS;
 665                                                                         break;
 666                                                                 default:
 667                                                                         break;
 668                                                         }
 669                                                         break;
 670                                                 case "force":
 671                                                         e.damageforcescale = stof(argv(3));
 672                                                         break;
 673                                                 case "material":
 674                                                         if(e.material)  strunzone(e.material);
 675                                                         if(argv(3))
 676                                                         {
 677                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 678                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".wav"));
 679                                                                 e.material = strzone(argv(3));
 680                                                         }
 681                                                         else
 682                                                                 e.material = string_null; // no material
 683                                                         break;
 684                                                 default:
 685                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 686                                                         return TRUE;
 687                                         }
 688
 689                                         // update last editing time
 690                                         if(e.message2)  strunzone(e.message2);
 691                                         e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S"));
 692
 693                                         if(autocvar_g_sandbox_info > 1)
 694                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 695                                         return TRUE;
 696                                 }
 697
 698                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 699                                 return TRUE;
 700
 701                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 702                         case "object_claim":
 703                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 704                                 if(self.crypto_idfp == "")
 705                                 {
 706                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 707                                         return TRUE;
 708                                 }
 709                                 e = sandbox_ObjectEdit_Get(TRUE);
 710                                 if(e != world)
 711                                 {
 712                                         // update the owner's name
 713                                         // Do this before checking if you're already the owner and skipping if such, so we
 714                                         // also update the player's nickname if he changed it (but has the same player UID)
 715                                         if(e.netname != self.netname)
 716                                         {
 717                                                 if(e.netname)   strunzone(e.netname);
 718                                                 e.netname = strzone(self.netname);
 719                                                 print_to(self, "^2SANDBOX - INFO: ^7Object owner name updated");
 720                                         }
 721
 722                                         if(e.crypto_idfp == self.crypto_idfp)
 723                                         {
 724                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 725                                                 return TRUE;
 726                                         }
 727
 728                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
 729                                         e.crypto_idfp = strzone(self.crypto_idfp);
 730
 731                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 732                                 }
 733                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 734                                 return TRUE;
 735
 736                         // ---------------- COMMAND: OBJECT, INFO ----------------
 737                         case "object_info":
 738                                 // prints public information about the object to the player
 739                                 e = sandbox_ObjectEdit_Get(FALSE);
 740                                 if(e != world)
 741                                 {
 742                                         switch(argv(2))
 743                                         {
 744                                                 case "object":
 745                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
 746                                                         return TRUE;
 747                                                 case "mesh":
 748                                                         s = "";
 749                                                         FOR_EACH_TAG(e)
 750                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
 751                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
 752                                                         return TRUE;
 753                                                 case "attachments":
 754                                                         // this should show the same info as 'mesh' but for attachments
 755                                                         s = "";
 756                                                         entity head;
 757                                                         i = 0;
 758                                                         for(head = world; (head = find(head, classname, "object")); )
 759                                                         {
 760                                                                 if(head.owner == e)
 761                                                                 {
 762                                                                         ++i; // start from 1
 763                                                                         gettaginfo(e, head.tag_index);
 764                                                                         s = strcat(s, "^1attachment ", ftos(i), "^7 has mesh \"^3", head.model, "^7\" at animation frame ^3", ftos(head.frame));
 765                                                                         s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
 766                                                                 }
 767                                                         }
 768                                                         if(i) // object contains attachments
 769                                                                 print_to(self, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(i), "^7 attachment(s): ", s));
 770                                                         else
 771                                                                 print_to(self, "^2SANDBOX - INFO: ^7Object contains no attachments");
 772                                                         return TRUE;
 773                                         }
 774                                 }
 775                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
 776                                 return TRUE;
 777
 778                         // ---------------- COMMAND: DEFAULT ----------------
 779                         default:
 780                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 781                                 return TRUE;
 782                 }
 783         }
 784         return FALSE;
 785 }
 786
 787 float autosave_time;
 788 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 789 {
 790         if(!autocvar_g_sandbox_storage_autosave)
 791                 return FALSE;
 792         if(time < autosave_time)
 793                 return FALSE;
 794         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 795
 796         sandbox_Database_Save();
 797
 798         return TRUE;
 799 }
 800
 801 MUTATOR_HOOKFUNCTION(sandbox_SetModname)
 802 {
 803         modname = "Sandbox";
 804         return TRUE;
 805 }
 806
 807 MUTATOR_DEFINITION(sandbox)
 808 {
 809         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 810         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 811         MUTATOR_HOOK(SetModname, sandbox_SetModname, CBC_ORDER_ANY);
 812
 813         MUTATOR_ONADD
 814         {
 815                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 816                 if(autocvar_g_sandbox_storage_autoload)
 817                         sandbox_Database_Load();
 818         }
 819
 820         MUTATOR_ONROLLBACK_OR_REMOVE
 821         {
 822                 // nothing to roll back
 823         }
 824
 825         MUTATOR_ONREMOVE
 826         {
 827                 // nothing to remove
 828         }
 829
 830         return FALSE;
 831 }
 832