qcsrc/server/mutators/sandbox.qc

   1 float object_count;
   2 .string object_clipboard;
   3 .entity object_attach;
   4 .string material;
   5
   6 .float touch_timer;
   7 void sandbox_Object_Touch()
   8 {
   9         // apply material impact effects
  10
  11         if(!self.material)
  12                 return;
  13         if(self.touch_timer > time)
  14                 return; // don't execute each frame
  15         self.touch_timer = time + 0.1;
  16
  17         // make particle count and sound volume depend on impact speed
  18         float intensity;
  19         intensity = vlen(self.velocity) + vlen(other.velocity);
  20         if(intensity) // avoid divisions by 0
  21                 intensity /= 2; // average the two velocities
  22         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  23                 return; // impact not strong enough to do anything
  24         // now offset intensity and apply it to the effects
  25         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  26         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  27
  28         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  29         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  30 }
  31
  32 entity sandbox_EditObject_Get()
  33 {
  34         // returns the traced entity if the player can edit it, and world if not
  35         // attached objects are SOLID_NOT and don't risk getting traced
  36
  37         makevectors(self.v_angle);
  38         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  39
  40         if(trace_ent.classname != "object")
  41                 return world; // entity is not an object
  42         if(!trace_ent.crypto_idfp)
  43                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  44         else if not(trace_ent.crypto_idfp != self.crypto_idfp && !autocvar_g_sandbox_editor_free)
  45                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  46         return world;
  47 }
  48
  49 void sandbox_EditObject_Scale(entity e, float f)
  50 {
  51         e.scale = f;
  52         if(e.scale)
  53         {
  54                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  55                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  56         }
  57 }
  58
  59 .float old_movetype;
  60 void sandbox_AttachObject_Set(entity e, entity parent, string s)
  61 {
  62         // attaches e to parent on string s
  63
  64         e.old_movetype = e.movetype; // persist this
  65
  66         e.movetype = MOVETYPE_FOLLOW;
  67         e.solid = SOLID_NOT;
  68         e.takedamage = DAMAGE_NO;
  69
  70         setattachment(e, parent, s);
  71         e.owner = parent;
  72 }
  73
  74 void sandbox_AttachObject_Remove(entity e)
  75 {
  76         // detaches any object attached to e
  77
  78         entity head;
  79         for(head = world; (head = find(head, classname, "object")); )
  80         {
  81                 if(head.owner == e)
  82                 {
  83                         head.movetype = head.old_movetype; // revert to previous physics
  84                         head.solid = SOLID_BBOX;
  85                         head.takedamage = DAMAGE_AIM;
  86
  87                         setattachment(head, world, "");
  88                         head.owner = world;
  89
  90                         // objects reset origin and angles when detached, so apply the parent's to prevent teleporting
  91                         setorigin(head, e.origin);
  92                         head.angles = e.angles;
  93                 }
  94         }
  95 }
  96
  97 entity sandbox_SpawnObject(float database)
  98 {
  99         // spawn a new object with default properties
 100
 101         entity e;
 102         e = spawn();
 103         e.classname = "object";
 104         e.takedamage = DAMAGE_AIM;
 105         e.damageforcescale = 1;
 106         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 107         e.movetype = MOVETYPE_TOSS;
 108         e.frame = 0;
 109         e.skin = 0;
 110         e.material = string_null;
 111         e.touch = sandbox_Object_Touch;
 112
 113         if(!database)
 114         {
 115                 // set the object's owner via player UID
 116                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 117                 if(self.crypto_idfp != "")
 118                         e.crypto_idfp = strzone(self.crypto_idfp);
 119                 else
 120                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 121
 122                 // set origin and direction based on player position and view angle
 123                 makevectors(self.v_angle);
 124                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 125                 setorigin(e, trace_endpos);
 126                 e.angles_y = self.v_angle_y;
 127         }
 128
 129         object_count += 1;
 130         return e;
 131 }
 132
 133 void sandbox_RemoveObject(entity e)
 134 {
 135         sandbox_AttachObject_Remove(e); // detach child objects
 136         if(e.material)
 137         {
 138                 strunzone(e.material);
 139                 e.material = string_null;
 140         }
 141         if(e.crypto_idfp)
 142         {
 143                 strunzone(e.crypto_idfp);
 144                 e.crypto_idfp = string_null;
 145         }
 146         remove(e);
 147         e = world;
 148
 149         object_count -= 1;
 150 }
 151
 152 string sandbox_Storage_Save(entity e, float database)
 153 {
 154         // save object properties
 155         string s;
 156
 157         s = strcat(e.model, " ");
 158         s = strcat(s, ftos(e.skin), " ");
 159         s = strcat(s, ftos(e.alpha), " ");
 160         s = strcat(s, sprintf("\"%.9v\"", e.colormod), " ");
 161         s = strcat(s, sprintf("\"%.9v\"", e.glowmod), " ");
 162         s = strcat(s, ftos(e.frame), " ");
 163         s = strcat(s, ftos(e.scale), " ");
 164         s = strcat(s, ftos(e.movetype), " ");
 165         s = strcat(s, ftos(e.damageforcescale), " ");
 166         s = strcat(s, e.material, " ");
 167         if(database)
 168         {
 169                 s = strcat(s, e.crypto_idfp, " ");
 170                 s = strcat(s, sprintf("\"%.9v\"", e.origin), " ");
 171                 s = strcat(s, sprintf("\"%.9v\"", e.angles), " ");
 172         }
 173
 174         return s;
 175 }
 176
 177 void sandbox_Storage_Load(entity e, string s, float database)
 178 {
 179         // load object properties
 180         tokenize_console(s);
 181
 182         setmodel(e, argv(0));
 183         e.skin = stof(argv(1));
 184         e.alpha = stof(argv(2));
 185         e.colormod = stov(argv(3));
 186         e.glowmod = stov(argv(4));
 187         e.frame = stof(argv(5));
 188         sandbox_EditObject_Scale(e, stof(argv(6)));
 189         e.movetype = stof(argv(7));
 190         e.damageforcescale = stof(argv(8));
 191         if(e.material)  strunzone(e.material);  if(argv(9))     e.material = strzone(argv(9));  else    e.material = string_null;
 192         if(database)
 193         {
 194                 if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(10))    e.crypto_idfp = strzone(argv(10));      else    e.crypto_idfp = string_null;
 195                 setorigin(e, stov(argv(11)));
 196                 e.angles = stov(argv(12));
 197         }
 198 }
 199
 200 void sandbox_Storage_DatabaseSave()
 201 {
 202         // saves all objects to the database file
 203         if(!object_count)
 204                 return; // nothing to store
 205
 206         entity head;
 207         string fn;
 208         float fh;
 209
 210         fn = strcat("sandbox/storage_", GetMapname(), ".txt");
 211         fh = fopen(fn, FILE_WRITE);
 212         fputs(fh, strcat("// sandbox storage for map ", GetMapname(), ", containing a total of ", ftos(object_count), " objects.\n"));
 213         for(head = world; (head = find(head, classname, "object")); )
 214         {
 215                 // Unfortunately, attached objects cannot be persisted yet. That's because the parent is specified as an entity,
 216                 // but only properties can be saved to this file, leaving no way to identify the owner once all objects are spawned
 217                 // TODO: Find some way to fix this!
 218                 if(head.owner != world)
 219                         continue;
 220
 221                 // a line with the properties of each file
 222                 fputs(fh, strcat(sandbox_Storage_Save(head, TRUE), "\n"));
 223         }
 224         fclose(fh);
 225 }
 226
 227 void sandbox_Storage_DatabaseLoad()
 228 {
 229
 230 }
 231
 232 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 233 {
 234         if(MUTATOR_RETURNVALUE) // command was already handled?
 235                 return FALSE;
 236         if(cmd_name == "g_sandbox")
 237         {
 238                 if(cmd_argc < 2)
 239                 {
 240                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 241                         return TRUE;
 242                 }
 243
 244                 switch(argv(1))
 245                 {
 246                         entity e;
 247                         float i;
 248
 249                         // ---------------- COMMAND: HELP ----------------
 250                         case "help":
 251                                 print_to(self, "You can use the following sandbox commands:");
 252                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 253                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 254                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 255                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 256                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 257                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 258                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 259                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 260                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 261                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 262                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 263                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 264                                 print_to(self, "^3alpha value ^7- sets object transparency");
 265                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 266                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 267                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 268                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 269                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 270                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 271                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 272                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 273                                 return TRUE;
 274
 275                         // ---------------- COMMAND: SPAWN OBJECT ----------------
 276                         case "object_spawn":
 277                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 278                                 {
 279                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 280                                         return TRUE;
 281                                 }
 282                                 if(cmd_argc < 3)
 283                                 {
 284                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 285                                         return TRUE;
 286                                 }
 287                                 else if not(fexists(argv(2)))
 288                                 {
 289                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 290                                         return TRUE;
 291                                 }
 292
 293                                 e = sandbox_SpawnObject(FALSE);
 294                                 setmodel(e, argv(2));
 295
 296                                 if(autocvar_g_sandbox_info > 0)
 297                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 298                                 return TRUE;
 299
 300                         // ---------------- COMMAND: REMOVE OBJECT ----------------
 301                         case "object_remove":
 302                                 e = sandbox_EditObject_Get();
 303                                 if(e != world)
 304                                 {
 305                                         if(autocvar_g_sandbox_info > 0)
 306                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 307                                         sandbox_RemoveObject(e);
 308                                         return TRUE;
 309                                 }
 310
 311                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 312                                 return TRUE;
 313
 314                         // ---------------- COMMAND: DUPLICATE OBJECT ----------------
 315                         case "object_duplicate":
 316                                 switch(argv(2))
 317                                 {
 318                                         case "copy":
 319                                                 // copies customizable properties of the selected object to the clipboard
 320                                                 e = sandbox_EditObject_Get(); // you can only copy objects you can edit, so this works
 321                                                 if(e != world)
 322                                                 {
 323                                                         if(self.object_clipboard)
 324                                                                 strunzone(self.object_clipboard);
 325                                                         self.object_clipboard = strzone(sandbox_Storage_Save(e, FALSE));
 326
 327                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 328                                                         return TRUE;
 329                                                 }
 330                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have edit rights over");
 331                                                 return TRUE;
 332
 333                                         case "paste":
 334                                                 // spawns a new object using the properties in the player's clipboard
 335                                                 if(!self.object_clipboard) // no object in clipboard
 336                                                 {
 337                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 338                                                         return TRUE;
 339                                                 }
 340                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 341                                                 {
 342                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 343                                                         return TRUE;
 344                                                 }
 345
 346                                                 e = sandbox_SpawnObject(FALSE);
 347                                                 sandbox_Storage_Load(e, self.object_clipboard, FALSE);
 348
 349                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 350                                                 if(autocvar_g_sandbox_info > 0)
 351                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 352                                                 return TRUE;
 353                                 }
 354                                 return TRUE;
 355
 356                         // ---------------- COMMAND: CLAIM OBJECT ----------------
 357                         case "object_claim":
 358                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 359                                 if(self.crypto_idfp == "")
 360                                 {
 361                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 362                                         return TRUE;
 363                                 }
 364                                 e = sandbox_EditObject_Get();
 365                                 if(e != world)
 366                                 {
 367                                         if(e.crypto_idfp == self.crypto_idfp)
 368                                         {
 369                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 370                                                 return TRUE;
 371                                         }
 372
 373                                         if(e.crypto_idfp)
 374                                                 strunzone(e.crypto_idfp);
 375                                         e.crypto_idfp = self.crypto_idfp;
 376                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 377                                 }
 378                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 379                                 return TRUE;
 380
 381                         // ---------------- COMMAND: ATTACH OBJECT ----------------
 382                         case "object_attach":
 383                                 switch(argv(2))
 384                                 {
 385                                         case "get":
 386                                                 // select e as the object as meant to be attached
 387                                                 e = sandbox_EditObject_Get();
 388                                                 if(e != world)
 389                                                 {
 390                                                         self.object_attach = e;
 391                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 392                                                         return TRUE;
 393                                                 }
 394                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 395                                                 return TRUE;
 396                                         case "set":
 397                                                 if(self.object_attach == world)
 398                                                 {
 399                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 400                                                         return TRUE;
 401                                                 }
 402
 403                                                 // attaches the previously selected object to e
 404                                                 e = sandbox_EditObject_Get();
 405                                                 if(e != world)
 406                                                 {
 407                                                         sandbox_AttachObject_Set(self.object_attach, e, argv(3));
 408                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 409                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 410                                                         if(autocvar_g_sandbox_info > 1)
 411                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 412                                                         return TRUE;
 413                                                 }
 414                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 415                                                 return TRUE;
 416                                         case "remove":
 417                                                 // removes e if it was attached
 418                                                 e = sandbox_EditObject_Get();
 419                                                 if(e != world)
 420                                                 {
 421                                                         sandbox_AttachObject_Remove(e);
 422                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 423                                                         if(autocvar_g_sandbox_info > 1)
 424                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 425                                                         return TRUE;
 426                                                 }
 427                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 428                                                 return TRUE;
 429                                 }
 430                                 return TRUE;
 431
 432                         // ---------------- COMMAND: EDIT OBJECT ----------------
 433                         case "object_edit":
 434                                 if(!argv(2))
 435                                 {
 436                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 437                                         return TRUE;
 438                                 }
 439
 440                                 e = sandbox_EditObject_Get();
 441                                 if(e != world)
 442                                 {
 443                                         switch(argv(2))
 444                                         {
 445                                                 case "skin":
 446                                                         e.skin = stof(argv(3));
 447                                                         break;
 448                                                 case "alpha":
 449                                                         e.alpha = stof(argv(3));
 450                                                         break;
 451                                                 case "color_main":
 452                                                         e.colormod = stov(argv(3));
 453                                                         break;
 454                                                 case "color_glow":
 455                                                         e.glowmod = stov(argv(3));
 456                                                         break;
 457                                                 case "frame":
 458                                                         e.frame = stof(argv(3));
 459                                                         break;
 460                                                 case "scale":
 461                                                         sandbox_EditObject_Scale(e, stof(argv(3)));
 462                                                         break;
 463                                                 case "physics":
 464                                                         switch(argv(3))
 465                                                         {
 466                                                                 case "0": // static
 467                                                                         e.movetype = MOVETYPE_NONE;
 468                                                                         break;
 469                                                                 case "1": // movable
 470                                                                         e.movetype = MOVETYPE_TOSS;
 471                                                                         break;
 472                                                                 case "2": // physical
 473                                                                         e.movetype = MOVETYPE_PHYSICS;
 474                                                                         break;
 475                                                                 default:
 476                                                                         break;
 477                                                         }
 478                                                         break;
 479                                                 case "force":
 480                                                         e.damageforcescale = stof(argv(3));
 481                                                         break;
 482                                                 case "material":
 483                                                         if(e.material)
 484                                                                 strunzone(e.material);
 485                                                         if(argv(3))
 486                                                         {
 487                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 488                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 489                                                                 e.material = strzone(argv(3));
 490                                                         }
 491                                                         else
 492                                                                 e.material = string_null; // no material
 493                                                         break;
 494                                                 default:
 495                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 496                                                         break;
 497                                         }
 498                                         if(autocvar_g_sandbox_info > 1)
 499                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 500                                         return TRUE;
 501                                 }
 502
 503                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 504                                 return TRUE;
 505
 506                         // ---------------- COMMAND: DEFAULT ----------------
 507                         default:
 508                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 509                                 return TRUE;
 510                 }
 511         }
 512         return FALSE;
 513 }
 514
 515 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 516 {
 517         // if the player is close enough to their object, they can drag it
 518
 519         if(autocvar_sv_cheats)
 520                 return FALSE; // cheat dragging is used instead
 521
 522         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 523         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 524         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 525         // it goes out of range while slinging it around.
 526
 527         entity e;
 528         float grab;
 529
 530         e = sandbox_EditObject_Get();
 531         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 532                 grab = TRUE;
 533
 534         if(Drag(e, grab)) // execute dragging
 535                 return TRUE;
 536
 537         return FALSE;
 538 }
 539
 540 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 541 {
 542         // unzone the player's clipboard if it's not empty
 543         if(self.object_clipboard)
 544         {
 545                 strunzone(self.object_clipboard);
 546                 self.object_clipboard = string_null;
 547         }
 548
 549         return FALSE;
 550 }
 551
 552 float autosave_time;
 553 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 554 {
 555         if(!autocvar_g_sandbox_storage_autosave)
 556                 return FALSE;
 557         if(time < autocvar_g_sandbox_storage_autosave)
 558                 return FALSE;
 559         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 560
 561         sandbox_Storage_DatabaseSave();
 562
 563         return TRUE;
 564 }
 565
 566 MUTATOR_DEFINITION(sandbox)
 567 {
 568         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 569         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 570         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 571         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 572
 573         return FALSE;
 574 }
 575