qcsrc/server/mutators/sandbox.qc

   1 #include "../_all.qh"
   2
   3 #include "mutator.qh"
   4
   5 const float MAX_STORAGE_ATTACHMENTS = 16;
   6 float object_count;
   7 .float object_flood;
   8 .entity object_attach;
   9 .string material;
  10
  11 .float touch_timer;
  12 void sandbox_ObjectFunction_Touch()
  13 {
  14         // apply material impact effects
  15
  16         if(!self.material)
  17                 return;
  18         if(self.touch_timer > time)
  19                 return; // don't execute each frame
  20         self.touch_timer = time + 0.1;
  21
  22         // make particle count and sound volume depend on impact speed
  23         float intensity;
  24         intensity = vlen(self.velocity) + vlen(other.velocity);
  25         if(intensity) // avoid divisions by 0
  26                 intensity /= 2; // average the two velocities
  27         if (!(intensity >= autocvar_g_sandbox_object_material_velocity_min))
  28                 return; // impact not strong enough to do anything
  29         // now offset intensity and apply it to the effects
  30         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  31         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  32
  33         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".wav"), VOL_BASE * intensity, ATTEN_NORM);
  34         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  35 }
  36
  37 void sandbox_ObjectFunction_Think()
  38 {
  39         entity e;
  40
  41         // decide if and how this object can be grabbed
  42         if(autocvar_g_sandbox_readonly)
  43                 self.grab = 0; // no grabbing
  44         else if(autocvar_g_sandbox_editor_free < 2 && self.crypto_idfp)
  45                 self.grab = 1; // owner only
  46         else
  47                 self.grab = 3; // anyone
  48
  49         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
  50         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
  51         // since if the owning player disconnects, the object's owner should also be reset.
  52         FOR_EACH_REALPLAYER(e) // bots can't have objects
  53         {
  54                 if(self.crypto_idfp == e.crypto_idfp)
  55                 {
  56                         self.realowner = e;
  57                         break;
  58                 }
  59                 self.realowner = world;
  60         }
  61
  62         self.nextthink = time;
  63
  64         CSQCMODEL_AUTOUPDATE();
  65 }
  66
  67 .float old_solid, old_movetype;
  68 entity sandbox_ObjectEdit_Get(float permissions)
  69 {
  70         // Returns the traced entity if the player can edit it, and world if not.
  71         // If permissions if false, the object is returned regardless of editing rights.
  72         // Attached objects are SOLID_NOT and do not get traced.
  73
  74         crosshair_trace_plusvisibletriggers(self);
  75         if(vlen(self.origin - trace_ent.origin) > autocvar_g_sandbox_editor_distance_edit)
  76                 return world; // out of trace range
  77         if(trace_ent.classname != "object")
  78                 return world; // entity is not an object
  79         if(!permissions)
  80                 return trace_ent; // don't check permissions, anyone can edit this object
  81         if(trace_ent.crypto_idfp == "")
  82                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  83         if (!(trace_ent.realowner != self && autocvar_g_sandbox_editor_free < 2))
  84                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  85         return world;
  86 }
  87
  88 void sandbox_ObjectEdit_Scale(entity e, float f)
  89 {
  90         e.scale = f;
  91         if(e.scale)
  92         {
  93                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  94                 setmodel(e, e.model); // reset mins and maxs based on mesh
  95                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  96         }
  97 }
  98
  99 void sandbox_ObjectAttach_Remove(entity e);
 100 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
 101 {
 102         // attaches e to parent on string s
 103
 104         // we can't attach to an attachment, for obvious reasons
 105         sandbox_ObjectAttach_Remove(e);
 106
 107         e.old_solid = e.solid; // persist solidity
 108         e.old_movetype = e.movetype; // persist physics
 109         e.movetype = MOVETYPE_FOLLOW;
 110         e.solid = SOLID_NOT;
 111         e.takedamage = DAMAGE_NO;
 112
 113         setattachment(e, parent, s);
 114         e.owner = parent;
 115 }
 116
 117 void sandbox_ObjectAttach_Remove(entity e)
 118 {
 119         // detaches any object attached to e
 120
 121         entity head;
 122         for(head = world; (head = find(head, classname, "object")); )
 123         {
 124                 if(head.owner == e)
 125                 {
 126                         vector org;
 127                         org = gettaginfo(head, 0);
 128                         setattachment(head, world, "");
 129                         head.owner = world;
 130
 131                         // objects change origin and angles when detached, so apply previous position
 132                         setorigin(head, org);
 133                         head.angles = e.angles; // don't allow detached objects to spin or roll
 134
 135                         head.solid = head.old_solid; // restore persisted solidity
 136                         head.movetype = head.old_movetype; // restore persisted physics
 137                         head.takedamage = DAMAGE_AIM;
 138                 }
 139         }
 140 }
 141
 142 entity sandbox_ObjectSpawn(float database)
 143 {
 144         // spawn a new object with default properties
 145
 146         entity e, oldself;
 147         e = spawn();
 148         e.classname = "object";
 149         e.takedamage = DAMAGE_AIM;
 150         e.damageforcescale = 1;
 151         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 152         e.movetype = MOVETYPE_TOSS;
 153         e.frame = 0;
 154         e.skin = 0;
 155         e.material = string_null;
 156         e.touch = sandbox_ObjectFunction_Touch;
 157         e.think = sandbox_ObjectFunction_Think;
 158         e.nextthink = time;
 159         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
 160
 161         if(!database)
 162         {
 163                 // set the object's owner via player UID
 164                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 165                 if(self.crypto_idfp != "")
 166                         e.crypto_idfp = strzone(self.crypto_idfp);
 167                 else
 168                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 169
 170                 // set public object information
 171                 e.netname = strzone(self.netname); // name of the owner
 172                 e.message = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // creation time
 173                 e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // last editing time
 174
 175                 // set origin and direction based on player position and view angle
 176                 makevectors(self.v_angle);
 177                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 178                 setorigin(e, trace_endpos);
 179                 e.angles_y = self.v_angle.y;
 180         }
 181
 182         oldself = self;
 183         self = e;
 184         CSQCMODEL_AUTOINIT();
 185         self = oldself;
 186
 187         object_count += 1;
 188         return e;
 189 }
 190
 191 void sandbox_ObjectRemove(entity e)
 192 {
 193         sandbox_ObjectAttach_Remove(e); // detach child objects
 194
 195         // if the object being removed has been selected for attachment by a player, unset it
 196         entity head;
 197         FOR_EACH_REALPLAYER(head) // bots can't have objects
 198         {
 199                 if(head.object_attach == e)
 200                         head.object_attach = world;
 201         }
 202
 203         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
 204         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
 205         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
 206         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
 207         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
 208         remove(e);
 209         e = world;
 210
 211         object_count -= 1;
 212 }
 213
 214 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 215
 216 string sandbox_ObjectPort_Save(entity e, float database)
 217 {
 218         // save object properties, and return them as a string
 219         float i = 0;
 220         string s;
 221         entity head;
 222
 223         for(head = world; (head = find(head, classname, "object")); )
 224         {
 225                 // the main object needs to be first in the array [0] with attached objects following
 226                 float slot, physics, solidity;
 227                 if(head == e) // this is the main object, place it first
 228                 {
 229                         slot = 0;
 230                         solidity = head.solid; // applied solidity is normal solidity for children
 231                         physics = head.movetype; // applied physics are normal physics for parents
 232                 }
 233                 else if(head.owner == e) // child object, list them in order
 234                 {
 235                         i += 1; // children start from 1
 236                         slot = i;
 237                         solidity = head.old_solid; // persisted solidity is normal solidity for children
 238                         physics = head.old_movetype; // persisted physics are normal physics for children
 239                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 240                 }
 241                 else
 242                         continue;
 243
 244                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 245                 if(slot)
 246                 {
 247                         // properties stored only for child objects
 248                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 249                 }
 250                 else
 251                 {
 252                         // properties stored only for parent objects
 253                         if(database)
 254                         {
 255                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 256                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 257                         }
 258                 }
 259                 // properties stored for all objects
 260                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 261                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 262                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 263                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 264                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 265                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 266                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 267                 port_string[slot] = strcat(port_string[slot], ftos(solidity), " ");
 268                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 269                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 270                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 271                 if(database)
 272                 {
 273                         // properties stored only for the database
 274                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 275                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
 276                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
 277                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
 278                 }
 279         }
 280
 281         // now apply the array to a simple string, with the ; symbol separating objects
 282         s = "";
 283         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 284         {
 285                 if(port_string[i])
 286                         s = strcat(s, port_string[i], "; ");
 287                 port_string[i] = string_null; // fully clear the string
 288         }
 289
 290         return s;
 291 }
 292
 293 entity sandbox_ObjectPort_Load(string s, float database)
 294 {
 295         // load object properties, and spawn a new object with them
 296         float n, i;
 297         entity e = world, parent = world;
 298
 299         // separate objects between the ; symbols
 300         n = tokenizebyseparator(s, "; ");
 301         for(i = 0; i < n; ++i)
 302                 port_string[i] = argv(i);
 303
 304         // now separate and apply the properties of each object
 305         for(i = 0; i < n; ++i)
 306         {
 307                 float argv_num;
 308                 string tagname = string_null;
 309                 argv_num = 0;
 310                 tokenize_console(port_string[i]);
 311                 e = sandbox_ObjectSpawn(database);
 312
 313                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 314                 if(i)
 315                 {
 316                         // properties stored only for child objects
 317                         if(argv(argv_num) != "")        tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 318                 }
 319                 else
 320                 {
 321                         // properties stored only for parent objects
 322                         if(database)
 323                         {
 324                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 325                                 e.angles = stov(argv(argv_num));        ++argv_num;
 326                         }
 327                         parent = e; // mark parent objects as such
 328                 }
 329                 // properties stored for all objects
 330                 setmodel(e, argv(argv_num));    ++argv_num;
 331                 e.skin = stof(argv(argv_num));  ++argv_num;
 332                 e.alpha = stof(argv(argv_num)); ++argv_num;
 333                 e.colormod = stov(argv(argv_num));      ++argv_num;
 334                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 335                 e.frame = stof(argv(argv_num)); ++argv_num;
 336                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 337                 e.solid = e.old_solid = stof(argv(argv_num));   ++argv_num;
 338                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 339                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 340                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "")        e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 341                 if(database)
 342                 {
 343                         // properties stored only for the database
 344                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "")        e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 345                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
 346                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
 347                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
 348                 }
 349
 350                 // attach last
 351                 if(i)
 352                         sandbox_ObjectAttach_Set(e, parent, tagname);
 353         }
 354
 355         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 356                 port_string[i] = string_null; // fully clear the string
 357
 358         return e;
 359 }
 360
 361 void sandbox_Database_Save()
 362 {
 363         // saves all objects to the database file
 364         entity head;
 365         string file_name;
 366         float file_get;
 367
 368         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 369         file_get = fopen(file_name, FILE_WRITE);
 370         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(true, "%d-%m-%Y %H:%M:%S")));
 371         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 372
 373         for(head = world; (head = find(head, classname, "object")); )
 374         {
 375                 // attached objects are persisted separately, ignore them here
 376                 if(head.owner != world)
 377                         continue;
 378
 379                 // use a line of text for each object, listing all properties
 380                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, true), "\n"));
 381         }
 382         fclose(file_get);
 383 }
 384
 385 void sandbox_Database_Load()
 386 {
 387         // loads all objects from the database file
 388         string file_read, file_name;
 389         float file_get, i;
 390
 391         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 392         file_get = fopen(file_name, FILE_READ);
 393         if(file_get < 0)
 394         {
 395                 if(autocvar_g_sandbox_info > 0)
 396                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 397         }
 398         else
 399         {
 400                 for (;;)
 401                 {
 402                         file_read = fgets(file_get);
 403                         if(file_read == "")
 404                                 break;
 405                         if(substring(file_read, 0, 2) == "//")
 406                                 continue;
 407                         if(substring(file_read, 0, 1) == "#")
 408                                 continue;
 409
 410                         entity e;
 411                         e = sandbox_ObjectPort_Load(file_read, true);
 412
 413                         if(e.material)
 414                         {
 415                                 // since objects are being loaded for the first time, precache material sounds for each
 416                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 417                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".wav"));
 418                         }
 419                 }
 420                 if(autocvar_g_sandbox_info > 0)
 421                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 422         }
 423         fclose(file_get);
 424 }
 425
 426 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 427 {
 428         if(MUTATOR_RETURNVALUE) // command was already handled?
 429                 return false;
 430         if(cmd_name == "g_sandbox")
 431         {
 432                 if(autocvar_g_sandbox_readonly)
 433                 {
 434                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active, but in read-only mode. Sandbox commands cannot be used");
 435                         return true;
 436                 }
 437                 if(cmd_argc < 2)
 438                 {
 439                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active. For usage information, type 'sandbox help'");
 440                         return true;
 441                 }
 442
 443                 switch(argv(1))
 444                 {
 445                         entity e;
 446                         float i;
 447                         string s;
 448
 449                         // ---------------- COMMAND: HELP ----------------
 450                         case "help":
 451                                 print_to(self, "You can use the following sandbox commands:");
 452                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 453                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 454                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
 455                                 print_to(self, "^3copy value ^7- copies the properties of the object to the specified client cvar");
 456                                 print_to(self, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
 457                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 458                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 459                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 460                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 461                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 462                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 463                                 print_to(self, "^3alpha value ^7- sets object transparency");
 464                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 465                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 466                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 467                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 468                                 print_to(self, "^3solidity value ^7- object collisions, 0 = non-solid, 1 = solid");
 469                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 470                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 471                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 472                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 473                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object");
 474                                 print_to(self, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
 475                                 print_to(self, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
 476                                 print_to(self, "^3attachments ^7- prints information about the object's attachments");
 477                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 478                                 return true;
 479
 480                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 481                         case "object_spawn":
 482                                 if(time < self.object_flood)
 483                                 {
 484                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 485                                         return true;
 486                                 }
 487                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 488                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 489                                 {
 490                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 491                                         return true;
 492                                 }
 493                                 if(cmd_argc < 3)
 494                                 {
 495                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 496                                         return true;
 497                                 }
 498                                 if (!(fexists(argv(2))))
 499                                 {
 500                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 501                                         return true;
 502                                 }
 503
 504                                 e = sandbox_ObjectSpawn(false);
 505                                 setmodel(e, argv(2));
 506
 507                                 if(autocvar_g_sandbox_info > 0)
 508                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 509                                 return true;
 510
 511                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 512                         case "object_remove":
 513                                 e = sandbox_ObjectEdit_Get(true);
 514                                 if(e != world)
 515                                 {
 516                                         if(autocvar_g_sandbox_info > 0)
 517                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 518                                         sandbox_ObjectRemove(e);
 519                                         return true;
 520                                 }
 521
 522                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 523                                 return true;
 524
 525                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 526                         case "object_duplicate":
 527                                 switch(argv(2))
 528                                 {
 529                                         case "copy":
 530                                                 // copies customizable properties of the selected object to the clipboard cvar
 531                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 532                                                 if(e != world)
 533                                                 {
 534                                                         s = sandbox_ObjectPort_Save(e, false);
 535                                                         s = strreplace("\"", "\\\"", s);
 536                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
 537
 538                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 539                                                         return true;
 540                                                 }
 541                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 542                                                 return true;
 543
 544                                         case "paste":
 545                                                 // spawns a new object using the properties in the player's clipboard cvar
 546                                                 if(time < self.object_flood)
 547                                                 {
 548                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 549                                                         return true;
 550                                                 }
 551                                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 552                                                 if(argv(3) == "") // no object in clipboard
 553                                                 {
 554                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 555                                                         return true;
 556                                                 }
 557                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 558                                                 {
 559                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 560                                                         return true;
 561                                                 }
 562                                                 e = sandbox_ObjectPort_Load(argv(3), false);
 563
 564                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 565                                                 if(autocvar_g_sandbox_info > 0)
 566                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 567                                                 return true;
 568                                 }
 569                                 return true;
 570
 571                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 572                         case "object_attach":
 573                                 switch(argv(2))
 574                                 {
 575                                         case "get":
 576                                                 // select e as the object as meant to be attached
 577                                                 e = sandbox_ObjectEdit_Get(true);
 578                                                 if(e != world)
 579                                                 {
 580                                                         self.object_attach = e;
 581                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 582                                                         return true;
 583                                                 }
 584                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 585                                                 return true;
 586                                         case "set":
 587                                                 if(self.object_attach == world)
 588                                                 {
 589                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 590                                                         return true;
 591                                                 }
 592
 593                                                 // attaches the previously selected object to e
 594                                                 e = sandbox_ObjectEdit_Get(true);
 595                                                 if(e != world)
 596                                                 {
 597                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 598                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 599                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 600                                                         if(autocvar_g_sandbox_info > 1)
 601                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 602                                                         return true;
 603                                                 }
 604                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 605                                                 return true;
 606                                         case "remove":
 607                                                 // removes e if it was attached
 608                                                 e = sandbox_ObjectEdit_Get(true);
 609                                                 if(e != world)
 610                                                 {
 611                                                         sandbox_ObjectAttach_Remove(e);
 612                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 613                                                         if(autocvar_g_sandbox_info > 1)
 614                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 615                                                         return true;
 616                                                 }
 617                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 618                                                 return true;
 619                                 }
 620                                 return true;
 621
 622                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 623                         case "object_edit":
 624                                 if(argv(2) == "")
 625                                 {
 626                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 627                                         return true;
 628                                 }
 629
 630                                 e = sandbox_ObjectEdit_Get(true);
 631                                 if(e != world)
 632                                 {
 633                                         switch(argv(2))
 634                                         {
 635                                                 case "skin":
 636                                                         e.skin = stof(argv(3));
 637                                                         break;
 638                                                 case "alpha":
 639                                                         e.alpha = stof(argv(3));
 640                                                         break;
 641                                                 case "color_main":
 642                                                         e.colormod = stov(argv(3));
 643                                                         break;
 644                                                 case "color_glow":
 645                                                         e.glowmod = stov(argv(3));
 646                                                         break;
 647                                                 case "frame":
 648                                                         e.frame = stof(argv(3));
 649                                                         break;
 650                                                 case "scale":
 651                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 652                                                         break;
 653                                                 case "solidity":
 654                                                         switch(argv(3))
 655                                                         {
 656                                                                 case "0": // non-solid
 657                                                                         e.solid = SOLID_TRIGGER;
 658                                                                         break;
 659                                                                 case "1": // solid
 660                                                                         e.solid = SOLID_BBOX;
 661                                                                         break;
 662                                                                 default:
 663                                                                         break;
 664                                                         }
 665                                                 case "physics":
 666                                                         switch(argv(3))
 667                                                         {
 668                                                                 case "0": // static
 669                                                                         e.movetype = MOVETYPE_NONE;
 670                                                                         break;
 671                                                                 case "1": // movable
 672                                                                         e.movetype = MOVETYPE_TOSS;
 673                                                                         break;
 674                                                                 case "2": // physical
 675                                                                         e.movetype = MOVETYPE_PHYSICS;
 676                                                                         break;
 677                                                                 default:
 678                                                                         break;
 679                                                         }
 680                                                         break;
 681                                                 case "force":
 682                                                         e.damageforcescale = stof(argv(3));
 683                                                         break;
 684                                                 case "material":
 685                                                         if(e.material)  strunzone(e.material);
 686                                                         if(argv(3))
 687                                                         {
 688                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 689                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".wav"));
 690                                                                 e.material = strzone(argv(3));
 691                                                         }
 692                                                         else
 693                                                                 e.material = string_null; // no material
 694                                                         break;
 695                                                 default:
 696                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 697                                                         return true;
 698                                         }
 699
 700                                         // update last editing time
 701                                         if(e.message2)  strunzone(e.message2);
 702                                         e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S"));
 703
 704                                         if(autocvar_g_sandbox_info > 1)
 705                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 706                                         return true;
 707                                 }
 708
 709                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 710                                 return true;
 711
 712                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 713                         case "object_claim":
 714                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 715                                 if(self.crypto_idfp == "")
 716                                 {
 717                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 718                                         return true;
 719                                 }
 720                                 e = sandbox_ObjectEdit_Get(true);
 721                                 if(e != world)
 722                                 {
 723                                         // update the owner's name
 724                                         // Do this before checking if you're already the owner and skipping if such, so we
 725                                         // also update the player's nickname if he changed it (but has the same player UID)
 726                                         if(e.netname != self.netname)
 727                                         {
 728                                                 if(e.netname)   strunzone(e.netname);
 729                                                 e.netname = strzone(self.netname);
 730                                                 print_to(self, "^2SANDBOX - INFO: ^7Object owner name updated");
 731                                         }
 732
 733                                         if(e.crypto_idfp == self.crypto_idfp)
 734                                         {
 735                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 736                                                 return true;
 737                                         }
 738
 739                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
 740                                         e.crypto_idfp = strzone(self.crypto_idfp);
 741
 742                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 743                                 }
 744                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 745                                 return true;
 746
 747                         // ---------------- COMMAND: OBJECT, INFO ----------------
 748                         case "object_info":
 749                                 // prints public information about the object to the player
 750                                 e = sandbox_ObjectEdit_Get(false);
 751                                 if(e != world)
 752                                 {
 753                                         switch(argv(2))
 754                                         {
 755                                                 case "object":
 756                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
 757                                                         return true;
 758                                                 case "mesh":
 759                                                         s = "";
 760                                                         FOR_EACH_TAG(e)
 761                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
 762                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
 763                                                         return true;
 764                                                 case "attachments":
 765                                                         // this should show the same info as 'mesh' but for attachments
 766                                                         s = "";
 767                                                         entity head;
 768                                                         i = 0;
 769                                                         for(head = world; (head = find(head, classname, "object")); )
 770                                                         {
 771                                                                 if(head.owner == e)
 772                                                                 {
 773                                                                         ++i; // start from 1
 774                                                                         gettaginfo(e, head.tag_index);
 775                                                                         s = strcat(s, "^1attachment ", ftos(i), "^7 has mesh \"^3", head.model, "^7\" at animation frame ^3", ftos(head.frame));
 776                                                                         s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
 777                                                                 }
 778                                                         }
 779                                                         if(i) // object contains attachments
 780                                                                 print_to(self, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(i), "^7 attachment(s): ", s));
 781                                                         else
 782                                                                 print_to(self, "^2SANDBOX - INFO: ^7Object contains no attachments");
 783                                                         return true;
 784                                         }
 785                                 }
 786                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
 787                                 return true;
 788
 789                         // ---------------- COMMAND: DEFAULT ----------------
 790                         default:
 791                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 792                                 return true;
 793                 }
 794         }
 795         return false;
 796 }
 797
 798 float autosave_time;
 799 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 800 {
 801         if(!autocvar_g_sandbox_storage_autosave)
 802                 return false;
 803         if(time < autosave_time)
 804                 return false;
 805         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 806
 807         sandbox_Database_Save();
 808
 809         return true;
 810 }
 811
 812 MUTATOR_HOOKFUNCTION(sandbox_SetModname)
 813 {
 814         modname = "Sandbox";
 815         return true;
 816 }
 817
 818 MUTATOR_DEFINITION(sandbox)
 819 {
 820         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 821         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 822         MUTATOR_HOOK(SetModname, sandbox_SetModname, CBC_ORDER_ANY);
 823
 824         MUTATOR_ONADD
 825         {
 826                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 827                 if(autocvar_g_sandbox_storage_autoload)
 828                         sandbox_Database_Load();
 829         }
 830
 831         MUTATOR_ONROLLBACK_OR_REMOVE
 832         {
 833                 // nothing to roll back
 834         }
 835
 836         MUTATOR_ONREMOVE
 837         {
 838                 // nothing to remove
 839         }
 840
 841         return false;
 842 }
 843