qcsrc/server/mutators/sandbox.qc

   1 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
   2 {
   3         if(MUTATOR_RETURNVALUE) // command was already handled?
   4                 return FALSE;
   5         if(cmd_name == "g_sandbox")
   6         {
   7                 if(cmd_argc < 2)
   8                 {
   9                         print_to(self, "Sandbox mode is active. For more information, use 'g_sandbox help'");
  10                         return TRUE;
  11                 }
  12
  13                 if(argv(1) == "help")
  14                 {
  15                         print_to(self, "You can use the following sandbox commands:");
  16                         print_to(self, "^7\"^2spawn_object ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
  17                         print_to(self, "^7\"^2spawn_item ^3item^7\" spawns the specified item in front of the player. Only weapons are currently supported");
  18                         return TRUE;
  19                 }
  20                 else if(argv(1) == "spawn_object")
  21                 {
  22                         // don't allow spawning objects without a model
  23                         if(cmd_argc < 3)
  24                         {
  25                                 print_to(self, "WARNING: Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'spawn_object' command");
  26                                 return TRUE;
  27                         }
  28                         else if not(fexists(argv(2)))
  29                         {
  30                                 print_to(self, "WARNING: Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
  31                                 return TRUE;
  32                         }
  33
  34                         // spawn a new object with the default settings
  35                         entity e;
  36                         e = spawn();
  37                         e.owner = self;
  38                         e.classname = "object";
  39                         e.takedamage = DAMAGE_NO;
  40
  41                         // those properties are defaults that can be edited later
  42                         e.movetype = MOVETYPE_TOSS;
  43                         e.solid = SOLID_TRIGGER;
  44
  45                         makevectors(self.v_angle);
  46                         traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance, MOVE_NOMONSTERS, self);
  47                         setorigin(e, trace_endpos);
  48                         setmodel(e, argv(2));
  49                         e.angles_y = self.v_angle_y; // apply the player's direction to the object, as he spawns it from behind
  50
  51                         if(autocvar_g_sandbox_info)
  52                                 print(strcat(self.netname, " spawned an object at origin ", vtos(e.origin), "\n"));
  53
  54                         return TRUE;
  55                 }
  56                 else if(argv(1) == "spawn_item")
  57                 {
  58                         // spawn a new item
  59                         // weapons are the only items currently supported
  60
  61                         if(cmd_argc < 3)
  62                         {
  63                                 print_to(self, "WARNING: Attempted to spawn an item without specifying its type. Please specify the name of your item after the 'spawn_item' command");
  64                                 return TRUE;
  65                         }
  66
  67                         entity e;
  68                         float i;
  69                         makevectors(self.v_angle);
  70                         traceline(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance, MOVE_NOMONSTERS, self);
  71
  72                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  73                         {
  74                                 e = get_weaponinfo(i);
  75                                 if(e.netname == argv(2))
  76                                 {
  77                                         W_ThrowNewWeapon(self, i, FALSE, trace_endpos, '0 0 0');
  78                                         if(autocvar_g_sandbox_info)
  79                                                 print(strcat(self.netname, " spawned a ^2", e.netname, "^7 at origin ", vtos(e.origin), "\n"));
  80                                         return TRUE;
  81                                 }
  82                         }
  83
  84                         print_to(self, "WARNING: Attempted to spawn an invalid or unsupported item. See 'g_sandbox help' for supported items");
  85                         return TRUE;
  86                 }
  87         }
  88         return FALSE;
  89 }
  90
  91 MUTATOR_DEFINITION(sandbox)
  92 {
  93         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
  94
  95         return 0;
  96 }