qcsrc/server/mutators/sandbox.qc

   1 float object_count;
   2 .string object_clipboard;
   3 .entity object_attach;
   4 .string material;
   5
   6 .float touch_timer;
   7 void sandbox_Object_Touch()
   8 {
   9         // apply material impact effects
  10
  11         if(!self.material)
  12                 return;
  13         if(self.touch_timer > time)
  14                 return; // don't execute each frame
  15         self.touch_timer = time + 0.1;
  16
  17         // make particle count and sound volume depend on impact speed
  18         float intensity;
  19         intensity = vlen(self.velocity) + vlen(other.velocity);
  20         if(intensity) // avoid divisions by 0
  21                 intensity /= 2; // average the two velocities
  22         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  23                 return; // impact not strong enough to do anything
  24         // now offset intensity and apply it to the effects
  25         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  26         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  27
  28         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  29         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  30 }
  31
  32 entity sandbox_EditObject_Get()
  33 {
  34         // returns the traced entity if the player can edit it, and world if not
  35         // attached objects are SOLID_NOT and don't risk getting traced
  36
  37         makevectors(self.v_angle);
  38         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  39
  40         if(trace_ent.classname != "object")
  41                 return world; // entity is not an object
  42         if(!trace_ent.crypto_idfp)
  43                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  44         else if not(trace_ent.crypto_idfp != self.crypto_idfp && !autocvar_g_sandbox_editor_free)
  45                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  46         return world;
  47 }
  48
  49 void sandbox_EditObject_Scale(entity e, float f)
  50 {
  51         e.scale = f;
  52         if(e.scale)
  53         {
  54                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  55                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  56         }
  57 }
  58
  59 .float old_movetype;
  60 void sandbox_AttachObject_Set(entity e, entity parent, string s)
  61 {
  62         // attaches e to parent on string s
  63
  64         e.old_movetype = e.movetype; // persist this
  65
  66         e.movetype = MOVETYPE_FOLLOW;
  67         e.solid = SOLID_NOT;
  68         e.takedamage = DAMAGE_NO;
  69
  70         setattachment(e, parent, s);
  71         e.owner = parent;
  72 }
  73
  74 void sandbox_AttachObject_Remove(entity e)
  75 {
  76         // detaches any object attached to e
  77
  78         entity head;
  79         for(head = world; (head = find(head, classname, "object")); )
  80         {
  81                 if(head.owner == e)
  82                 {
  83                         head.movetype = head.old_movetype; // revert to previous physics
  84                         head.solid = SOLID_BBOX;
  85                         head.takedamage = DAMAGE_AIM;
  86
  87                         setattachment(head, world, "");
  88                         head.owner = world;
  89
  90                         // objects reset origin and angles when detached, so apply the parent's to prevent teleporting
  91                         setorigin(head, e.origin);
  92                         head.angles = e.angles;
  93                 }
  94         }
  95 }
  96
  97 entity sandbox_SpawnObject()
  98 {
  99         // spawn a new object with default properties
 100
 101         entity e;
 102         e = spawn();
 103         e.classname = "object";
 104         e.takedamage = DAMAGE_AIM;
 105         e.damageforcescale = 1;
 106         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 107         e.movetype = MOVETYPE_TOSS;
 108         e.frame = 0;
 109         e.skin = 0;
 110         e.material = string_null;
 111         e.touch = sandbox_Object_Touch;
 112
 113         // set the object's owner via player UID
 114         // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 115         if(self.crypto_idfp != "")
 116                 e.crypto_idfp = strzone(self.crypto_idfp);
 117         else
 118                 print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 119
 120         // set origin and direction based on player position and view angle
 121         makevectors(self.v_angle);
 122         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 123         setorigin(e, trace_endpos);
 124         e.angles_y = self.v_angle_y;
 125
 126         object_count += 1;
 127         return e;
 128 }
 129
 130 void sandbox_RemoveObject(entity e)
 131 {
 132         sandbox_AttachObject_Remove(e); // detach child objects
 133         if(e.material)
 134         {
 135                 strunzone(e.material);
 136                 e.material = string_null;
 137         }
 138         if(e.crypto_idfp)
 139         {
 140                 strunzone(e.crypto_idfp);
 141                 e.crypto_idfp = string_null;
 142         }
 143         remove(e);
 144         e = world;
 145
 146         object_count -= 1;
 147 }
 148
 149 string sandbox_Storage_Save(entity e)
 150 {
 151         // save object properties
 152         string s;
 153
 154         s = strcat(e.model, " ");
 155         s = strcat(s, ftos(e.skin), " ");
 156         s = strcat(s, ftos(e.alpha), " ");
 157         s = strcat(s, sprintf("\"%.9v\"", e.colormod), " ");
 158         s = strcat(s, sprintf("\"%.9v\"", e.glowmod), " ");
 159         s = strcat(s, ftos(e.frame), " ");
 160         s = strcat(s, ftos(e.scale), " ");
 161         s = strcat(s, ftos(e.movetype), " ");
 162         s = strcat(s, ftos(e.damageforcescale), " ");
 163         s = strcat(s, e.material, " ");
 164
 165         return s;
 166 }
 167
 168 void sandbox_Storage_Load(entity e, string s)
 169 {
 170         // load object properties
 171         tokenize_console(s);
 172
 173         setmodel(e, argv(0));
 174         e.skin = stof(argv(1));
 175         e.alpha = stof(argv(2));
 176         e.colormod = stov(argv(3));
 177         e.glowmod = stov(argv(4));
 178         e.frame = stof(argv(5));
 179         sandbox_EditObject_Scale(e, stof(argv(6)));
 180         e.movetype = stof(argv(7));
 181         e.damageforcescale = stof(argv(8));
 182         if(e.material)  strunzone(e.material);  if(argv(9))     e.material = strzone(argv(9));  else    e.material = string_null;
 183 }
 184
 185 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 186 {
 187         if(MUTATOR_RETURNVALUE) // command was already handled?
 188                 return FALSE;
 189         if(cmd_name == "g_sandbox")
 190         {
 191                 if(cmd_argc < 2)
 192                 {
 193                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 194                         return TRUE;
 195                 }
 196
 197                 switch(argv(1))
 198                 {
 199                         entity e;
 200                         float i;
 201
 202                         // ---------------- COMMAND: HELP ----------------
 203                         case "help":
 204                                 print_to(self, "You can use the following sandbox commands:");
 205                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 206                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 207                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 208                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 209                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 210                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 211                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 212                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 213                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 214                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 215                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 216                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 217                                 print_to(self, "^3alpha value ^7- sets object transparency");
 218                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 219                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 220                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 221                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 222                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 223                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 224                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 225                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 226                                 return TRUE;
 227
 228                         // ---------------- COMMAND: SPAWN OBJECT ----------------
 229                         case "object_spawn":
 230                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 231                                 {
 232                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 233                                         return TRUE;
 234                                 }
 235                                 if(cmd_argc < 3)
 236                                 {
 237                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 238                                         return TRUE;
 239                                 }
 240                                 else if not(fexists(argv(2)))
 241                                 {
 242                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 243                                         return TRUE;
 244                                 }
 245
 246                                 e = sandbox_SpawnObject();
 247                                 setmodel(e, argv(2));
 248
 249                                 if(autocvar_g_sandbox_info > 0)
 250                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 251                                 return TRUE;
 252
 253                         // ---------------- COMMAND: REMOVE OBJECT ----------------
 254                         case "object_remove":
 255                                 e = sandbox_EditObject_Get();
 256                                 if(e != world)
 257                                 {
 258                                         if(autocvar_g_sandbox_info > 0)
 259                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 260                                         sandbox_RemoveObject(e);
 261                                         return TRUE;
 262                                 }
 263
 264                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 265                                 return TRUE;
 266
 267                         // ---------------- COMMAND: DUPLICATE OBJECT ----------------
 268                         case "object_duplicate":
 269                                 switch(argv(2))
 270                                 {
 271                                         case "copy":
 272                                                 // copies customizable properties of the selected object to the clipboard
 273                                                 e = sandbox_EditObject_Get(); // you can only copy objects you can edit, so this works
 274                                                 if(e != world)
 275                                                 {
 276                                                         if(self.object_clipboard)
 277                                                                 strunzone(self.object_clipboard);
 278                                                         self.object_clipboard = strzone(sandbox_Storage_Save(e));
 279
 280                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 281                                                         return TRUE;
 282                                                 }
 283                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have edit rights over");
 284                                                 return TRUE;
 285
 286                                         case "paste":
 287                                                 // spawns a new object using the properties in the player's clipboard
 288                                                 if(!self.object_clipboard) // no object in clipboard
 289                                                 {
 290                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 291                                                         return TRUE;
 292                                                 }
 293                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 294                                                 {
 295                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 296                                                         return TRUE;
 297                                                 }
 298
 299                                                 e = sandbox_SpawnObject();
 300                                                 sandbox_Storage_Load(e, self.object_clipboard);
 301
 302                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 303                                                 if(autocvar_g_sandbox_info > 0)
 304                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 305                                                 return TRUE;
 306                                 }
 307                                 return TRUE;
 308
 309                         // ---------------- COMMAND: CLAIM OBJECT ----------------
 310                         case "object_claim":
 311                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 312                                 if(self.crypto_idfp == "")
 313                                 {
 314                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 315                                         return TRUE;
 316                                 }
 317                                 e = sandbox_EditObject_Get();
 318                                 if(e != world)
 319                                 {
 320                                         if(e.crypto_idfp == self.crypto_idfp)
 321                                         {
 322                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 323                                                 return TRUE;
 324                                         }
 325
 326                                         if(e.crypto_idfp)
 327                                                 strunzone(e.crypto_idfp);
 328                                         e.crypto_idfp = self.crypto_idfp;
 329                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 330                                 }
 331                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 332                                 return TRUE;
 333
 334                         // ---------------- COMMAND: ATTACH OBJECT ----------------
 335                         case "object_attach":
 336                                 switch(argv(2))
 337                                 {
 338                                         case "get":
 339                                                 // select e as the object as meant to be attached
 340                                                 e = sandbox_EditObject_Get();
 341                                                 if(e != world)
 342                                                 {
 343                                                         self.object_attach = e;
 344                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 345                                                         return TRUE;
 346                                                 }
 347                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 348                                                 return TRUE;
 349                                         case "set":
 350                                                 if(self.object_attach == world)
 351                                                 {
 352                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 353                                                         return TRUE;
 354                                                 }
 355
 356                                                 // attaches the previously selected object to e
 357                                                 e = sandbox_EditObject_Get();
 358                                                 if(e != world)
 359                                                 {
 360                                                         sandbox_AttachObject_Set(self.object_attach, e, argv(3));
 361                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 362                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 363                                                         if(autocvar_g_sandbox_info > 1)
 364                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 365                                                         return TRUE;
 366                                                 }
 367                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 368                                                 return TRUE;
 369                                         case "remove":
 370                                                 // removes e if it was attached
 371                                                 e = sandbox_EditObject_Get();
 372                                                 if(e != world)
 373                                                 {
 374                                                         sandbox_AttachObject_Remove(e);
 375                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 376                                                         if(autocvar_g_sandbox_info > 1)
 377                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 378                                                         return TRUE;
 379                                                 }
 380                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 381                                                 return TRUE;
 382                                 }
 383                                 return TRUE;
 384
 385                         // ---------------- COMMAND: EDIT OBJECT ----------------
 386                         case "object_edit":
 387                                 if(!argv(2))
 388                                 {
 389                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 390                                         return TRUE;
 391                                 }
 392
 393                                 e = sandbox_EditObject_Get();
 394                                 if(e != world)
 395                                 {
 396                                         switch(argv(2))
 397                                         {
 398                                                 case "skin":
 399                                                         e.skin = stof(argv(3));
 400                                                         break;
 401                                                 case "alpha":
 402                                                         e.alpha = stof(argv(3));
 403                                                         break;
 404                                                 case "color_main":
 405                                                         e.colormod = stov(argv(3));
 406                                                         break;
 407                                                 case "color_glow":
 408                                                         e.glowmod = stov(argv(3));
 409                                                         break;
 410                                                 case "frame":
 411                                                         e.frame = stof(argv(3));
 412                                                         break;
 413                                                 case "scale":
 414                                                         sandbox_EditObject_Scale(e, stof(argv(3)));
 415                                                         break;
 416                                                 case "physics":
 417                                                         switch(argv(3))
 418                                                         {
 419                                                                 case "0": // static
 420                                                                         e.movetype = MOVETYPE_NONE;
 421                                                                         break;
 422                                                                 case "1": // movable
 423                                                                         e.movetype = MOVETYPE_TOSS;
 424                                                                         break;
 425                                                                 case "2": // physical
 426                                                                         e.movetype = MOVETYPE_PHYSICS;
 427                                                                         break;
 428                                                                 default:
 429                                                                         break;
 430                                                         }
 431                                                         break;
 432                                                 case "force":
 433                                                         e.damageforcescale = stof(argv(3));
 434                                                         break;
 435                                                 case "material":
 436                                                         if(e.material)
 437                                                                 strunzone(e.material);
 438                                                         if(argv(3))
 439                                                         {
 440                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 441                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 442                                                                 e.material = strzone(argv(3));
 443                                                         }
 444                                                         else
 445                                                                 e.material = string_null; // no material
 446                                                         break;
 447                                                 default:
 448                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 449                                                         break;
 450                                         }
 451                                         if(autocvar_g_sandbox_info > 1)
 452                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 453                                         return TRUE;
 454                                 }
 455
 456                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 457                                 return TRUE;
 458
 459                         // ---------------- COMMAND: DEFAULT ----------------
 460                         default:
 461                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 462                                 return TRUE;
 463                 }
 464         }
 465         return FALSE;
 466 }
 467
 468 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 469 {
 470         // if the player is close enough to their object, they can drag it
 471
 472         if(autocvar_sv_cheats)
 473                 return FALSE; // cheat dragging is used instead
 474
 475         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 476         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 477         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 478         // it goes out of range while slinging it around.
 479
 480         entity e;
 481         float grab;
 482
 483         e = sandbox_EditObject_Get();
 484         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 485                 grab = TRUE;
 486
 487         if(Drag(e, grab)) // execute dragging
 488                 return TRUE;
 489
 490         return FALSE;
 491 }
 492
 493 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 494 {
 495         // unzone the player's clipboard if it's not empty
 496         if(self.object_clipboard)
 497         {
 498                 strunzone(self.object_clipboard);
 499                 self.object_clipboard = string_null;
 500         }
 501
 502         return FALSE;
 503 }
 504
 505 MUTATOR_DEFINITION(sandbox)
 506 {
 507         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 508         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 509         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 510
 511         return FALSE;
 512 }
 513