qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .float object_flood;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if (!(intensity >= autocvar_g_sandbox_object_material_velocity_min))
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".wav"), VOL_BASE * intensity, ATTEN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 void sandbox_ObjectFunction_Think()
  34 {
  35         entity e;
  36
  37         // decide if and how this object can be grabbed
  38         if(autocvar_g_sandbox_readonly)
  39                 self.grab = 0; // no grabbing
  40         else if(autocvar_g_sandbox_editor_free < 2 && self.crypto_idfp)
  41                 self.grab = 1; // owner only
  42         else
  43                 self.grab = 3; // anyone
  44
  45         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
  46         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
  47         // since if the owning player disconnects, the object's owner should also be reset.
  48         FOR_EACH_REALPLAYER(e) // bots can't have objects
  49         {
  50                 if(self.crypto_idfp == e.crypto_idfp)
  51                 {
  52                         self.realowner = e;
  53                         break;
  54                 }
  55                 self.realowner = world;
  56         }
  57
  58         self.nextthink = time;
  59
  60         CSQCMODEL_AUTOUPDATE();
  61 }
  62
  63 .float old_solid, old_movetype;
  64 entity sandbox_ObjectEdit_Get(float permissions)
  65 {
  66         // Returns the traced entity if the player can edit it, and world if not.
  67         // If permissions if false, the object is returned regardless of editing rights.
  68         // Attached objects are SOLID_NOT and do not get traced.
  69
  70         crosshair_trace_plusvisibletriggers(self);
  71         if(vlen(self.origin - trace_ent.origin) > autocvar_g_sandbox_editor_distance_edit)
  72                 return world; // out of trace range
  73         if(trace_ent.classname != "object")
  74                 return world; // entity is not an object
  75         if(!permissions)
  76                 return trace_ent; // don't check permissions, anyone can edit this object
  77         if(trace_ent.crypto_idfp == "")
  78                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  79         if (!(trace_ent.realowner != self && autocvar_g_sandbox_editor_free < 2))
  80                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  81         return world;
  82 }
  83
  84 void sandbox_ObjectEdit_Scale(entity e, float f)
  85 {
  86         e.scale = f;
  87         if(e.scale)
  88         {
  89                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  90                 setmodel(e, e.model); // reset mins and maxs based on mesh
  91                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  92         }
  93 }
  94
  95 void sandbox_ObjectAttach_Remove(entity e);
  96 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  97 {
  98         // attaches e to parent on string s
  99
 100         // we can't attach to an attachment, for obvious reasons
 101         sandbox_ObjectAttach_Remove(e);
 102
 103         e.old_solid = e.solid; // persist solidity
 104         e.old_movetype = e.movetype; // persist physics
 105         e.movetype = MOVETYPE_FOLLOW;
 106         e.solid = SOLID_NOT;
 107         e.takedamage = DAMAGE_NO;
 108
 109         setattachment(e, parent, s);
 110         e.owner = parent;
 111 }
 112
 113 void sandbox_ObjectAttach_Remove(entity e)
 114 {
 115         // detaches any object attached to e
 116
 117         entity head;
 118         for(head = world; (head = find(head, classname, "object")); )
 119         {
 120                 if(head.owner == e)
 121                 {
 122                         vector org;
 123                         org = gettaginfo(head, 0);
 124                         setattachment(head, world, "");
 125                         head.owner = world;
 126
 127                         // objects change origin and angles when detached, so apply previous position
 128                         setorigin(head, org);
 129                         head.angles = e.angles; // don't allow detached objects to spin or roll
 130
 131                         head.solid = head.old_solid; // restore persisted solidity
 132                         head.movetype = head.old_movetype; // restore persisted physics
 133                         head.takedamage = DAMAGE_AIM;
 134                 }
 135         }
 136 }
 137
 138 entity sandbox_ObjectSpawn(float database)
 139 {
 140         // spawn a new object with default properties
 141
 142         entity e, oldself;
 143         e = spawn();
 144         e.classname = "object";
 145         e.takedamage = DAMAGE_AIM;
 146         e.damageforcescale = 1;
 147         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 148         e.movetype = MOVETYPE_TOSS;
 149         e.frame = 0;
 150         e.skin = 0;
 151         e.material = string_null;
 152         e.touch = sandbox_ObjectFunction_Touch;
 153         e.think = sandbox_ObjectFunction_Think;
 154         e.nextthink = time;
 155         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
 156
 157         if(!database)
 158         {
 159                 // set the object's owner via player UID
 160                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 161                 if(self.crypto_idfp != "")
 162                         e.crypto_idfp = strzone(self.crypto_idfp);
 163                 else
 164                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 165
 166                 // set public object information
 167                 e.netname = strzone(self.netname); // name of the owner
 168                 e.message = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // creation time
 169                 e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // last editing time
 170
 171                 // set origin and direction based on player position and view angle
 172                 makevectors(self.v_angle);
 173                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 174                 setorigin(e, trace_endpos);
 175                 e.angles_y = self.v_angle.y;
 176         }
 177
 178         oldself = self;
 179         self = e;
 180         CSQCMODEL_AUTOINIT();
 181         self = oldself;
 182
 183         object_count += 1;
 184         return e;
 185 }
 186
 187 void sandbox_ObjectRemove(entity e)
 188 {
 189         sandbox_ObjectAttach_Remove(e); // detach child objects
 190
 191         // if the object being removed has been selected for attachment by a player, unset it
 192         entity head;
 193         FOR_EACH_REALPLAYER(head) // bots can't have objects
 194         {
 195                 if(head.object_attach == e)
 196                         head.object_attach = world;
 197         }
 198
 199         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
 200         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
 201         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
 202         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
 203         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
 204         remove(e);
 205         e = world;
 206
 207         object_count -= 1;
 208 }
 209
 210 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 211
 212 string sandbox_ObjectPort_Save(entity e, float database)
 213 {
 214         // save object properties, and return them as a string
 215         float i = 0;
 216         string s;
 217         entity head;
 218
 219         for(head = world; (head = find(head, classname, "object")); )
 220         {
 221                 // the main object needs to be first in the array [0] with attached objects following
 222                 float slot, physics, solidity;
 223                 if(head == e) // this is the main object, place it first
 224                 {
 225                         slot = 0;
 226                         solidity = head.solid; // applied solidity is normal solidity for children
 227                         physics = head.movetype; // applied physics are normal physics for parents
 228                 }
 229                 else if(head.owner == e) // child object, list them in order
 230                 {
 231                         i += 1; // children start from 1
 232                         slot = i;
 233                         solidity = head.old_solid; // persisted solidity is normal solidity for children
 234                         physics = head.old_movetype; // persisted physics are normal physics for children
 235                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 236                 }
 237                 else
 238                         continue;
 239
 240                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 241                 if(slot)
 242                 {
 243                         // properties stored only for child objects
 244                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 245                 }
 246                 else
 247                 {
 248                         // properties stored only for parent objects
 249                         if(database)
 250                         {
 251                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 252                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 253                         }
 254                 }
 255                 // properties stored for all objects
 256                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 257                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 258                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 259                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 260                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 261                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 262                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 263                 port_string[slot] = strcat(port_string[slot], ftos(solidity), " ");
 264                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 265                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 266                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 267                 if(database)
 268                 {
 269                         // properties stored only for the database
 270                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
 271                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
 272                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
 273                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
 274                 }
 275         }
 276
 277         // now apply the array to a simple string, with the ; symbol separating objects
 278         s = "";
 279         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 280         {
 281                 if(port_string[i])
 282                         s = strcat(s, port_string[i], "; ");
 283                 port_string[i] = string_null; // fully clear the string
 284         }
 285
 286         return s;
 287 }
 288
 289 entity sandbox_ObjectPort_Load(string s, float database)
 290 {
 291         // load object properties, and spawn a new object with them
 292         float n, i;
 293         entity e = world, parent = world;
 294
 295         // separate objects between the ; symbols
 296         n = tokenizebyseparator(s, "; ");
 297         for(i = 0; i < n; ++i)
 298                 port_string[i] = argv(i);
 299
 300         // now separate and apply the properties of each object
 301         for(i = 0; i < n; ++i)
 302         {
 303                 float argv_num;
 304                 string tagname = string_null;
 305                 argv_num = 0;
 306                 tokenize_console(port_string[i]);
 307                 e = sandbox_ObjectSpawn(database);
 308
 309                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 310                 if(i)
 311                 {
 312                         // properties stored only for child objects
 313                         if(argv(argv_num) != "")        tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 314                 }
 315                 else
 316                 {
 317                         // properties stored only for parent objects
 318                         if(database)
 319                         {
 320                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 321                                 e.angles = stov(argv(argv_num));        ++argv_num;
 322                         }
 323                         parent = e; // mark parent objects as such
 324                 }
 325                 // properties stored for all objects
 326                 setmodel(e, argv(argv_num));    ++argv_num;
 327                 e.skin = stof(argv(argv_num));  ++argv_num;
 328                 e.alpha = stof(argv(argv_num)); ++argv_num;
 329                 e.colormod = stov(argv(argv_num));      ++argv_num;
 330                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 331                 e.frame = stof(argv(argv_num)); ++argv_num;
 332                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 333                 e.solid = e.old_solid = stof(argv(argv_num));   ++argv_num;
 334                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 335                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 336                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "")        e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 337                 if(database)
 338                 {
 339                         // properties stored only for the database
 340                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "")        e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 341                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
 342                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
 343                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
 344                 }
 345
 346                 // attach last
 347                 if(i)
 348                         sandbox_ObjectAttach_Set(e, parent, tagname);
 349         }
 350
 351         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 352                 port_string[i] = string_null; // fully clear the string
 353
 354         return e;
 355 }
 356
 357 void sandbox_Database_Save()
 358 {
 359         // saves all objects to the database file
 360         entity head;
 361         string file_name;
 362         float file_get;
 363
 364         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 365         file_get = fopen(file_name, FILE_WRITE);
 366         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(true, "%d-%m-%Y %H:%M:%S")));
 367         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 368
 369         for(head = world; (head = find(head, classname, "object")); )
 370         {
 371                 // attached objects are persisted separately, ignore them here
 372                 if(head.owner != world)
 373                         continue;
 374
 375                 // use a line of text for each object, listing all properties
 376                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, true), "\n"));
 377         }
 378         fclose(file_get);
 379 }
 380
 381 void sandbox_Database_Load()
 382 {
 383         // loads all objects from the database file
 384         string file_read, file_name;
 385         float file_get, i;
 386
 387         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 388         file_get = fopen(file_name, FILE_READ);
 389         if(file_get < 0)
 390         {
 391                 if(autocvar_g_sandbox_info > 0)
 392                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 393         }
 394         else
 395         {
 396                 for (;;)
 397                 {
 398                         file_read = fgets(file_get);
 399                         if(file_read == "")
 400                                 break;
 401                         if(substring(file_read, 0, 2) == "//")
 402                                 continue;
 403                         if(substring(file_read, 0, 1) == "#")
 404                                 continue;
 405
 406                         entity e;
 407                         e = sandbox_ObjectPort_Load(file_read, true);
 408
 409                         if(e.material)
 410                         {
 411                                 // since objects are being loaded for the first time, precache material sounds for each
 412                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 413                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".wav"));
 414                         }
 415                 }
 416                 if(autocvar_g_sandbox_info > 0)
 417                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 418         }
 419         fclose(file_get);
 420 }
 421
 422 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 423 {
 424         if(MUTATOR_RETURNVALUE) // command was already handled?
 425                 return false;
 426         if(cmd_name == "g_sandbox")
 427         {
 428                 if(autocvar_g_sandbox_readonly)
 429                 {
 430                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active, but in read-only mode. Sandbox commands cannot be used");
 431                         return true;
 432                 }
 433                 if(cmd_argc < 2)
 434                 {
 435                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active. For usage information, type 'sandbox help'");
 436                         return true;
 437                 }
 438
 439                 switch(argv(1))
 440                 {
 441                         entity e;
 442                         float i;
 443                         string s;
 444
 445                         // ---------------- COMMAND: HELP ----------------
 446                         case "help":
 447                                 print_to(self, "You can use the following sandbox commands:");
 448                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 449                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 450                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
 451                                 print_to(self, "^3copy value ^7- copies the properties of the object to the specified client cvar");
 452                                 print_to(self, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
 453                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 454                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 455                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 456                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 457                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 458                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 459                                 print_to(self, "^3alpha value ^7- sets object transparency");
 460                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 461                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 462                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 463                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 464                                 print_to(self, "^3solidity value ^7- object collisions, 0 = non-solid, 1 = solid");
 465                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 466                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 467                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 468                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 469                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object");
 470                                 print_to(self, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
 471                                 print_to(self, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
 472                                 print_to(self, "^3attachments ^7- prints information about the object's attachments");
 473                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 474                                 return true;
 475
 476                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 477                         case "object_spawn":
 478                                 if(time < self.object_flood)
 479                                 {
 480                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 481                                         return true;
 482                                 }
 483                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 484                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 485                                 {
 486                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 487                                         return true;
 488                                 }
 489                                 if(cmd_argc < 3)
 490                                 {
 491                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 492                                         return true;
 493                                 }
 494                                 if (!(fexists(argv(2))))
 495                                 {
 496                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 497                                         return true;
 498                                 }
 499
 500                                 e = sandbox_ObjectSpawn(false);
 501                                 setmodel(e, argv(2));
 502
 503                                 if(autocvar_g_sandbox_info > 0)
 504                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 505                                 return true;
 506
 507                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 508                         case "object_remove":
 509                                 e = sandbox_ObjectEdit_Get(true);
 510                                 if(e != world)
 511                                 {
 512                                         if(autocvar_g_sandbox_info > 0)
 513                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 514                                         sandbox_ObjectRemove(e);
 515                                         return true;
 516                                 }
 517
 518                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 519                                 return true;
 520
 521                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 522                         case "object_duplicate":
 523                                 switch(argv(2))
 524                                 {
 525                                         case "copy":
 526                                                 // copies customizable properties of the selected object to the clipboard cvar
 527                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 528                                                 if(e != world)
 529                                                 {
 530                                                         s = sandbox_ObjectPort_Save(e, false);
 531                                                         s = strreplace("\"", "\\\"", s);
 532                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
 533
 534                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 535                                                         return true;
 536                                                 }
 537                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 538                                                 return true;
 539
 540                                         case "paste":
 541                                                 // spawns a new object using the properties in the player's clipboard cvar
 542                                                 if(time < self.object_flood)
 543                                                 {
 544                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 545                                                         return true;
 546                                                 }
 547                                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 548                                                 if(argv(3) == "") // no object in clipboard
 549                                                 {
 550                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 551                                                         return true;
 552                                                 }
 553                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 554                                                 {
 555                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 556                                                         return true;
 557                                                 }
 558                                                 e = sandbox_ObjectPort_Load(argv(3), false);
 559
 560                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 561                                                 if(autocvar_g_sandbox_info > 0)
 562                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 563                                                 return true;
 564                                 }
 565                                 return true;
 566
 567                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 568                         case "object_attach":
 569                                 switch(argv(2))
 570                                 {
 571                                         case "get":
 572                                                 // select e as the object as meant to be attached
 573                                                 e = sandbox_ObjectEdit_Get(true);
 574                                                 if(e != world)
 575                                                 {
 576                                                         self.object_attach = e;
 577                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 578                                                         return true;
 579                                                 }
 580                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 581                                                 return true;
 582                                         case "set":
 583                                                 if(self.object_attach == world)
 584                                                 {
 585                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 586                                                         return true;
 587                                                 }
 588
 589                                                 // attaches the previously selected object to e
 590                                                 e = sandbox_ObjectEdit_Get(true);
 591                                                 if(e != world)
 592                                                 {
 593                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 594                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 595                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 596                                                         if(autocvar_g_sandbox_info > 1)
 597                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 598                                                         return true;
 599                                                 }
 600                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 601                                                 return true;
 602                                         case "remove":
 603                                                 // removes e if it was attached
 604                                                 e = sandbox_ObjectEdit_Get(true);
 605                                                 if(e != world)
 606                                                 {
 607                                                         sandbox_ObjectAttach_Remove(e);
 608                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 609                                                         if(autocvar_g_sandbox_info > 1)
 610                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 611                                                         return true;
 612                                                 }
 613                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 614                                                 return true;
 615                                 }
 616                                 return true;
 617
 618                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 619                         case "object_edit":
 620                                 if(argv(2) == "")
 621                                 {
 622                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 623                                         return true;
 624                                 }
 625
 626                                 e = sandbox_ObjectEdit_Get(true);
 627                                 if(e != world)
 628                                 {
 629                                         switch(argv(2))
 630                                         {
 631                                                 case "skin":
 632                                                         e.skin = stof(argv(3));
 633                                                         break;
 634                                                 case "alpha":
 635                                                         e.alpha = stof(argv(3));
 636                                                         break;
 637                                                 case "color_main":
 638                                                         e.colormod = stov(argv(3));
 639                                                         break;
 640                                                 case "color_glow":
 641                                                         e.glowmod = stov(argv(3));
 642                                                         break;
 643                                                 case "frame":
 644                                                         e.frame = stof(argv(3));
 645                                                         break;
 646                                                 case "scale":
 647                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 648                                                         break;
 649                                                 case "solidity":
 650                                                         switch(argv(3))
 651                                                         {
 652                                                                 case "0": // non-solid
 653                                                                         e.solid = SOLID_TRIGGER;
 654                                                                         break;
 655                                                                 case "1": // solid
 656                                                                         e.solid = SOLID_BBOX;
 657                                                                         break;
 658                                                                 default:
 659                                                                         break;
 660                                                         }
 661                                                 case "physics":
 662                                                         switch(argv(3))
 663                                                         {
 664                                                                 case "0": // static
 665                                                                         e.movetype = MOVETYPE_NONE;
 666                                                                         break;
 667                                                                 case "1": // movable
 668                                                                         e.movetype = MOVETYPE_TOSS;
 669                                                                         break;
 670                                                                 case "2": // physical
 671                                                                         e.movetype = MOVETYPE_PHYSICS;
 672                                                                         break;
 673                                                                 default:
 674                                                                         break;
 675                                                         }
 676                                                         break;
 677                                                 case "force":
 678                                                         e.damageforcescale = stof(argv(3));
 679                                                         break;
 680                                                 case "material":
 681                                                         if(e.material)  strunzone(e.material);
 682                                                         if(argv(3))
 683                                                         {
 684                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 685                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".wav"));
 686                                                                 e.material = strzone(argv(3));
 687                                                         }
 688                                                         else
 689                                                                 e.material = string_null; // no material
 690                                                         break;
 691                                                 default:
 692                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 693                                                         return true;
 694                                         }
 695
 696                                         // update last editing time
 697                                         if(e.message2)  strunzone(e.message2);
 698                                         e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S"));
 699
 700                                         if(autocvar_g_sandbox_info > 1)
 701                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 702                                         return true;
 703                                 }
 704
 705                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 706                                 return true;
 707
 708                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 709                         case "object_claim":
 710                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 711                                 if(self.crypto_idfp == "")
 712                                 {
 713                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 714                                         return true;
 715                                 }
 716                                 e = sandbox_ObjectEdit_Get(true);
 717                                 if(e != world)
 718                                 {
 719                                         // update the owner's name
 720                                         // Do this before checking if you're already the owner and skipping if such, so we
 721                                         // also update the player's nickname if he changed it (but has the same player UID)
 722                                         if(e.netname != self.netname)
 723                                         {
 724                                                 if(e.netname)   strunzone(e.netname);
 725                                                 e.netname = strzone(self.netname);
 726                                                 print_to(self, "^2SANDBOX - INFO: ^7Object owner name updated");
 727                                         }
 728
 729                                         if(e.crypto_idfp == self.crypto_idfp)
 730                                         {
 731                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 732                                                 return true;
 733                                         }
 734
 735                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
 736                                         e.crypto_idfp = strzone(self.crypto_idfp);
 737
 738                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 739                                 }
 740                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 741                                 return true;
 742
 743                         // ---------------- COMMAND: OBJECT, INFO ----------------
 744                         case "object_info":
 745                                 // prints public information about the object to the player
 746                                 e = sandbox_ObjectEdit_Get(false);
 747                                 if(e != world)
 748                                 {
 749                                         switch(argv(2))
 750                                         {
 751                                                 case "object":
 752                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
 753                                                         return true;
 754                                                 case "mesh":
 755                                                         s = "";
 756                                                         FOR_EACH_TAG(e)
 757                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
 758                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
 759                                                         return true;
 760                                                 case "attachments":
 761                                                         // this should show the same info as 'mesh' but for attachments
 762                                                         s = "";
 763                                                         entity head;
 764                                                         i = 0;
 765                                                         for(head = world; (head = find(head, classname, "object")); )
 766                                                         {
 767                                                                 if(head.owner == e)
 768                                                                 {
 769                                                                         ++i; // start from 1
 770                                                                         gettaginfo(e, head.tag_index);
 771                                                                         s = strcat(s, "^1attachment ", ftos(i), "^7 has mesh \"^3", head.model, "^7\" at animation frame ^3", ftos(head.frame));
 772                                                                         s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
 773                                                                 }
 774                                                         }
 775                                                         if(i) // object contains attachments
 776                                                                 print_to(self, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(i), "^7 attachment(s): ", s));
 777                                                         else
 778                                                                 print_to(self, "^2SANDBOX - INFO: ^7Object contains no attachments");
 779                                                         return true;
 780                                         }
 781                                 }
 782                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
 783                                 return true;
 784
 785                         // ---------------- COMMAND: DEFAULT ----------------
 786                         default:
 787                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 788                                 return true;
 789                 }
 790         }
 791         return false;
 792 }
 793
 794 float autosave_time;
 795 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 796 {
 797         if(!autocvar_g_sandbox_storage_autosave)
 798                 return false;
 799         if(time < autosave_time)
 800                 return false;
 801         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 802
 803         sandbox_Database_Save();
 804
 805         return true;
 806 }
 807
 808 MUTATOR_HOOKFUNCTION(sandbox_SetModname)
 809 {
 810         modname = "Sandbox";
 811         return true;
 812 }
 813
 814 MUTATOR_DEFINITION(sandbox)
 815 {
 816         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 817         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 818         MUTATOR_HOOK(SetModname, sandbox_SetModname, CBC_ORDER_ANY);
 819
 820         MUTATOR_ONADD
 821         {
 822                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 823                 if(autocvar_g_sandbox_storage_autoload)
 824                         sandbox_Database_Load();
 825         }
 826
 827         MUTATOR_ONROLLBACK_OR_REMOVE
 828         {
 829                 // nothing to roll back
 830         }
 831
 832         MUTATOR_ONREMOVE
 833         {
 834                 // nothing to remove
 835         }
 836
 837         return false;
 838 }
 839