Properly support team field on trigger_multiple
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / player.qc
1 #include "player.qh"
2
3 #include <common/effects/all.qh>
4 #include "bot/api.qh"
5 #include "cheats.qh"
6 #include "g_damage.qh"
7 #include "handicap.qh"
8 #include "g_subs.qh"
9 #include "miscfunctions.qh"
10 #include "portals.qh"
11 #include "teamplay.qh"
12 #include "weapons/throwing.qh"
13 #include "command/common.qh"
14 #include "../common/state.qh"
15 #include "../common/anim.qh"
16 #include "../common/animdecide.qh"
17 #include "../common/csqcmodel_settings.qh"
18 #include "../common/deathtypes/all.qh"
19 #include "../common/triggers/subs.qh"
20 #include "../common/playerstats.qh"
21 #include "../lib/csqcmodel/sv_model.qh"
22
23 #include "../common/minigames/sv_minigames.qh"
24
25 #include "../common/physics/player.qh"
26 #include "../common/effects/qc/_mod.qh"
27 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
28 #include "../common/triggers/include.qh"
29 #include "../common/wepent.qh"
30
31 #include "weapons/weaponstats.qh"
32
33 #include "../common/animdecide.qh"
34
35 void Drop_Special_Items(entity player)
36 {
37         // called when the player has become stuck or frozen
38         // so objective items aren't stuck with the player
39
40         MUTATOR_CALLHOOK(DropSpecialItems, player);
41 }
42
43 void CopyBody_Think(entity this)
44 {
45         if(this.CopyBody_nextthink && time > this.CopyBody_nextthink)
46         {
47                 this.CopyBody_think(this);
48                 if(wasfreed(this))
49                         return;
50                 this.CopyBody_nextthink = this.nextthink;
51                 this.CopyBody_think = getthink(this);
52                 setthink(this, CopyBody_Think);
53         }
54         CSQCMODEL_AUTOUPDATE(this);
55         this.nextthink = time;
56 }
57 void CopyBody(entity this, float keepvelocity)
58 {
59         if (this.effects & EF_NODRAW)
60                 return;
61         entity clone = new(body);
62         clone.enemy = this;
63         clone.lip = this.lip;
64         clone.colormap = this.colormap;
65         clone.iscreature = this.iscreature;
66         clone.teleportable = this.teleportable;
67         clone.damagedbycontents = this.damagedbycontents;
68         if(clone.damagedbycontents)
69                 IL_PUSH(g_damagedbycontents, clone);
70         clone.angles = this.angles;
71         clone.v_angle = this.v_angle;
72         clone.avelocity = this.avelocity;
73         clone.damageforcescale = this.damageforcescale;
74         clone.effects = this.effects;
75         clone.glowmod = this.glowmod;
76         clone.event_damage = this.event_damage;
77         clone.anim_state = this.anim_state;
78         clone.anim_time = this.anim_time;
79         clone.anim_lower_action = this.anim_lower_action;
80         clone.anim_lower_time = this.anim_lower_time;
81         clone.anim_upper_action = this.anim_upper_action;
82         clone.anim_upper_time = this.anim_upper_time;
83         clone.anim_implicit_state = this.anim_implicit_state;
84         clone.anim_implicit_time = this.anim_implicit_time;
85         clone.anim_lower_implicit_action = this.anim_lower_implicit_action;
86         clone.anim_lower_implicit_time = this.anim_lower_implicit_time;
87         clone.anim_upper_implicit_action = this.anim_upper_implicit_action;
88         clone.anim_upper_implicit_time = this.anim_upper_implicit_time;
89         clone.dphitcontentsmask = this.dphitcontentsmask;
90         clone.death_time = this.death_time;
91         clone.pain_finished = this.pain_finished;
92         clone.health = this.health;
93         clone.armorvalue = this.armorvalue;
94         clone.armortype = this.armortype;
95         clone.model = this.model;
96         clone.modelindex = this.modelindex;
97         clone.skin = this.skin;
98         clone.species = this.species;
99         clone.move_qcphysics = false; // don't run gamecode logic on clones, too many
100         set_movetype(clone, this.move_movetype);
101         clone.solid = this.solid;
102         clone.takedamage = this.takedamage;
103         setcefc(clone, getcefc(this));
104         clone.uncustomizeentityforclient = this.uncustomizeentityforclient;
105         clone.uncustomizeentityforclient_set = this.uncustomizeentityforclient_set;
106         if (keepvelocity == 1)
107                 clone.velocity = this.velocity;
108         clone.oldvelocity = clone.velocity;
109         clone.alpha = this.alpha;
110         clone.fade_time = this.fade_time;
111         clone.fade_rate = this.fade_rate;
112         //clone.weapon = this.weapon;
113         setorigin(clone, this.origin);
114         setsize(clone, this.mins, this.maxs);
115         clone.reset = SUB_Remove;
116         clone._ps = this._ps;
117
118         Drag_MoveDrag(this, clone);
119
120         if(clone.colormap <= maxclients && clone.colormap > 0)
121                 clone.colormap = 1024 + this.clientcolors;
122
123         CSQCMODEL_AUTOINIT(clone);
124         clone.CopyBody_nextthink = this.nextthink;
125         clone.CopyBody_think = getthink(this);
126         clone.nextthink = time;
127         setthink(clone, CopyBody_Think);
128         // "bake" the current animation frame for clones (they don't get clientside animation)
129         animdecide_load_if_needed(clone);
130         animdecide_setframes(clone, false, frame, frame1time, frame2, frame2time);
131
132         IL_PUSH(g_clones, clone);
133
134         MUTATOR_CALLHOOK(CopyBody, this, clone, keepvelocity);
135 }
136
137 void player_setupanimsformodel(entity this)
138 {
139         // load animation info
140         animdecide_load_if_needed(this);
141         animdecide_setstate(this, 0, false);
142 }
143
144 void player_anim(entity this)
145 {
146         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
147         if(IS_DEAD(this)) {
148                 if (!deadbits) {
149                         // Decide on which death animation to use.
150                         if(random() < 0.5)
151                                 deadbits = ANIMSTATE_DEAD1;
152                         else
153                                 deadbits = ANIMSTATE_DEAD2;
154                 }
155         } else {
156                 // Clear a previous death animation.
157                 deadbits = 0;
158         }
159         int animbits = deadbits;
160         if(STAT(FROZEN, this))
161                 animbits |= ANIMSTATE_FROZEN;
162         if(this.move_movetype == MOVETYPE_FOLLOW)
163                 animbits |= ANIMSTATE_FOLLOW;
164         if(this.crouch)
165                 animbits |= ANIMSTATE_DUCK;
166         animdecide_setstate(this, animbits, false);
167         animdecide_setimplicitstate(this, IS_ONGROUND(this));
168 }
169
170 void PlayerCorpseDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
171 {
172         float take, save;
173         vector v;
174         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
175
176         // damage resistance (ignore most of the damage from a bullet or similar)
177         damage = max(damage - 5, 1);
178
179         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
180         take = v.x;
181         save = v.y;
182
183         if(sound_allowed(MSG_BROADCAST, attacker))
184         {
185                 if (save > 10)
186                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
187                 else if (take > 30)
188                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
189                 else if (take > 10)
190                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM);
191         }
192
193         if (take > 50)
194                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
195         if (take > 100)
196                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
197
198         this.armorvalue = this.armorvalue - save;
199         this.health = this.health - take;
200         // pause regeneration for 5 seconds
201         this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
202
203         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
204         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
205         this.dmg_inflictor = inflictor;
206
207         if (this.health <= -autocvar_sv_gibhealth && this.alpha >= 0)
208         {
209                 // don't use any animations as a gib
210                 this.frame = 0;
211                 // view just above the floor
212                 this.view_ofs = '0 0 4';
213
214                 Violence_GibSplash(this, 1, 1, attacker);
215                 this.alpha = -1;
216                 this.solid = SOLID_NOT; // restore later
217                 this.takedamage = DAMAGE_NO; // restore later
218                 if(this.damagedbycontents)
219                         IL_REMOVE(g_damagedbycontents, this);
220                 this.damagedbycontents = false;
221         }
222 }
223
224 void calculate_player_respawn_time(entity this)
225 {
226         if(g_ca)
227                 return;
228
229         float gametype_setting_tmp;
230         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
231         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
232         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
233         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
234         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
235         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
236
237         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
238         if (teamplay)
239         {
240                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
241                         if(it.team == this.team)
242                                 ++pcount;
243                 });
244                 if (sdelay_small_count == 0)
245                         sdelay_small_count = 1;
246                 if (sdelay_large_count == 0)
247                         sdelay_large_count = 1;
248         }
249         else
250         {
251                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
252                         ++pcount;
253                 });
254                 if (sdelay_small_count == 0)
255                 {
256                         if (IS_INDEPENDENT_PLAYER(this))
257                         {
258                                 // Players play independently. No point in requiring enemies.
259                                 sdelay_small_count = 1;
260                         }
261                         else
262                         {
263                                 // Players play AGAINST each other. Enemies required.
264                                 sdelay_small_count = 2;
265                         }
266                 }
267                 if (sdelay_large_count == 0)
268                 {
269                         if (IS_INDEPENDENT_PLAYER(this))
270                         {
271                                 // Players play independently. No point in requiring enemies.
272                                 sdelay_large_count = 1;
273                         }
274                         else
275                         {
276                                 // Players play AGAINST each other. Enemies required.
277                                 sdelay_large_count = 2;
278                         }
279                 }
280         }
281
282         float sdelay;
283
284         if (pcount <= sdelay_small_count)
285                 sdelay = sdelay_small;
286         else if (pcount >= sdelay_large_count)
287                 sdelay = sdelay_large;
288         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
289                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
290
291         if(waves)
292                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
293         else
294                 this.respawn_time = time + sdelay;
295
296         if(sdelay < sdelay_max)
297                 this.respawn_time_max = time + sdelay_max;
298         else
299                 this.respawn_time_max = this.respawn_time;
300
301         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
302                 this.respawn_countdown = 10; // first number to count down from is 10
303         else
304                 this.respawn_countdown = -1; // do not count down
305
306         if(autocvar_g_forced_respawn)
307                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
308 }
309
310 void PlayerDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
311 {
312         float take, save, dh, da;
313         vector v;
314         float excess;
315
316         dh = max(this.health, 0);
317         da = max(this.armorvalue, 0);
318
319         if(!DEATH_ISSPECIAL(deathtype))
320         {
321                 damage *= Handicap_GetTotalHandicap(this);
322                 if (this != attacker && IS_PLAYER(attacker))
323                 {
324                         damage /= Handicap_GetTotalHandicap(attacker);
325                 }
326         }
327
328         if (time < this.spawnshieldtime && autocvar_g_spawnshield_blockdamage < 1)
329                 damage *= 1 - max(0, autocvar_g_spawnshield_blockdamage);
330
331         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
332         {
333                 // tuba causes blood to come out of the ears
334                 vector ear1, ear2;
335                 vector d;
336                 float f;
337                 ear1 = this.origin;
338                 ear1_z += 0.125 * this.view_ofs.z + 0.875 * this.maxs.z; // 7/8
339                 ear2 = ear1;
340                 makevectors(this.angles);
341                 ear1 += v_right * -10;
342                 ear2 += v_right * +10;
343                 d = inflictor.origin - this.origin;
344                 if (d)
345                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
346                 else
347                         f = 0;  // Assum ecenter.
348                 force = v_right * vlen(force);
349                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), this, attacker);
350                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), this, attacker);
351                 if(f > 0)
352                 {
353                         hitloc = ear1;
354                         force = force * -1;
355                 }
356                 else
357                 {
358                         hitloc = ear2;
359                         // force is already good
360                 }
361         }
362         else
363                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
364
365         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
366         take = v.x;
367         save = v.y;
368
369         if(attacker == this)
370         {
371                 // don't reset pushltime for this damage as it may be an attempt to
372                 // escape a lava pit or similar
373                 //this.pushltime = 0;
374                 this.istypefrag = 0;
375         }
376         else if(IS_PLAYER(attacker))
377         {
378                 this.pusher = attacker;
379                 this.pushltime = time + autocvar_g_maxpushtime;
380                 this.istypefrag = PHYS_INPUT_BUTTON_CHAT(this);
381         }
382         else if(time < this.pushltime)
383         {
384                 attacker = this.pusher;
385                 this.pushltime = max(this.pushltime, time + 0.6);
386         }
387         else
388         {
389                 this.pushltime = 0;
390                 this.istypefrag = 0;
391         }
392
393         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor, inflictor, attacker, this, force, take, save, deathtype, damage);
394         take = bound(0, M_ARGV(4, float), this.health);
395         save = bound(0, M_ARGV(5, float), this.armorvalue);
396         excess = max(0, damage - take - save);
397
398         if(sound_allowed(MSG_BROADCAST, attacker))
399         {
400                 if (save > 10)
401                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
402                 else if (take > 30)
403                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
404                 else if (take > 10)
405                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
406         }
407
408         if (take > 50)
409                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
410         if (take > 100)
411                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
412
413         if (time >= this.spawnshieldtime || autocvar_g_spawnshield_blockdamage < 1)
414         {
415                 if (!(this.flags & FL_GODMODE))
416                 {
417                         this.armorvalue = this.armorvalue - save;
418                         this.health = this.health - take;
419                         // pause regeneration for 5 seconds
420                         if(take)
421                                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
422
423                         if (time > this.pain_finished)          //Don't switch pain sequences like crazy
424                         {
425                                 this.pain_finished = time + 0.5;        //Supajoe
426
427                                 if(autocvar_sv_gentle < 1) {
428                                         if(this.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
429                                         {
430                                                 if (!this.animstate_override)
431                                                 {
432                                                         if (random() > 0.5)
433                                                                 animdecide_setaction(this, ANIMACTION_PAIN1, true);
434                                                         else
435                                                                 animdecide_setaction(this, ANIMACTION_PAIN2, true);
436                                                 }
437                                         }
438
439                                         if(sound_allowed(MSG_BROADCAST, attacker))
440                                         if(this.health < 25 || !(DEATH_WEAPONOF(deathtype).spawnflags & WEP_FLAG_CANCLIMB) || take > 20 || attacker != this)
441                                         if(this.health > 1)
442                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
443                                         {
444                                                 if(deathtype == DEATH_FALL.m_id)
445                                                         PlayerSound(this, playersound_fall, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
446                                                 else if(this.health > 75)
447                                                         PlayerSound(this, playersound_pain100, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
448                                                 else if(this.health > 50)
449                                                         PlayerSound(this, playersound_pain75, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
450                                                 else if(this.health > 25)
451                                                         PlayerSound(this, playersound_pain50, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
452                                                 else
453                                                         PlayerSound(this, playersound_pain25, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
454                                         }
455                                 }
456                         }
457
458                         // throw off bot aim temporarily
459                         float shake;
460                         if(IS_BOT_CLIENT(this) && this.health >= 1)
461                         {
462                                 shake = damage * 5 / (bound(0,skill,100) + 1);
463                                 this.v_angle_x = this.v_angle.x + (random() * 2 - 1) * shake;
464                                 this.v_angle_y = this.v_angle.y + (random() * 2 - 1) * shake;
465                                 this.v_angle_x = bound(-90, this.v_angle.x, 90);
466                         }
467                 }
468                 else
469                         this.max_armorvalue += (save + take);
470         }
471         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
472         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
473         this.dmg_inflictor = inflictor;
474
475         if (this != attacker) {
476                 float realdmg = damage - excess;
477                 if (IS_PLAYER(attacker)) {
478                         GameRules_scoring_add(attacker, DMG, realdmg);
479                 }
480                 if (IS_PLAYER(this)) {
481                         GameRules_scoring_add(this, DMGTAKEN, realdmg);
482                 }
483         }
484
485         bool abot = (IS_BOT_CLIENT(attacker));
486         bool vbot = (IS_BOT_CLIENT(this));
487
488         bool valid_damage_for_weaponstats = false;
489         Weapon awep = WEP_Null;
490         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
491
492         if(vbot || IS_REAL_CLIENT(this))
493         if(abot || IS_REAL_CLIENT(attacker))
494         if(attacker && this != attacker)
495         if(DIFF_TEAM(this, attacker))
496         {
497                 if(DEATH_ISSPECIAL(deathtype))
498                         awep = attacker.(weaponentity).m_weapon;
499                 else
500                         awep = DEATH_WEAPONOF(deathtype);
501                 valid_damage_for_weaponstats = true;
502         }
503
504         dh = dh - max(this.health, 0);
505         da = da - max(this.armorvalue, 0);
506         if(valid_damage_for_weaponstats)
507         {
508                 WeaponStats_LogDamage(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot, dh + da);
509         }
510
511         MUTATOR_CALLHOOK(PlayerDamaged, attacker, this, dh, da, hitloc, deathtype, damage);
512
513         if (this.health < 1)
514         {
515                 float defer_ClientKill_Now_TeamChange;
516                 defer_ClientKill_Now_TeamChange = false;
517
518                 if(this.alivetime)
519                 {
520                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
521                         this.alivetime = 0;
522                 }
523
524                 if(valid_damage_for_weaponstats)
525                         WeaponStats_LogKill(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot);
526
527                 if(autocvar_sv_gentle < 1)
528                 if(sound_allowed(MSG_BROADCAST, attacker))
529                 {
530                         if(deathtype == DEATH_DROWN.m_id)
531                                 PlayerSound(this, playersound_drown, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
532                         else
533                                 PlayerSound(this, playersound_death, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
534                 }
535
536                 // get rid of kill indicator
537                 if(this.killindicator)
538                 {
539                         delete(this.killindicator);
540                         this.killindicator = NULL;
541                         if(this.killindicator_teamchange)
542                                 defer_ClientKill_Now_TeamChange = true;
543
544                         if(this.classname == "body")
545                         if(deathtype == DEATH_KILL.m_id)
546                         {
547                                 // for the lemmings fans, a small harmless explosion
548                                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
549                         }
550                 }
551
552                 // print an obituary message
553                 if(this.classname != "body")
554                         Obituary (attacker, inflictor, this, deathtype);
555
556         // increment frag counter for used weapon type
557         Weapon w = DEATH_WEAPONOF(deathtype);
558                 if(w != WEP_Null && accuracy_isgooddamage(attacker, this))
559                         CS(attacker).accuracy.(accuracy_frags[w.m_id-1]) += 1;
560
561                 this.respawn_time = 0;
562                 MUTATOR_CALLHOOK(PlayerDies, inflictor, attacker, this, deathtype, damage);
563                 damage = M_ARGV(4, float);
564                 excess = max(0, damage - take - save);
565
566                 //Weapon wep = this.(weaponentity).m_weapon;
567                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
568                 {
569                         .entity went = weaponentities[slot];
570                         if(!this.(weaponentity))
571                                 continue; // TODO: clones have no weapon, but we don't want to have to check this all the time
572                         Weapon wep = this.(weaponentity).m_weapon;
573                         wep.wr_playerdeath(wep, this, went);
574                 }
575
576                 RemoveGrapplingHooks(this);
577
578                 Portal_ClearAllLater(this);
579
580                 this.fixangle = true;
581
582                 if(defer_ClientKill_Now_TeamChange)
583                         ClientKill_Now_TeamChange(this); // can turn player into spectator
584
585                 // player could have been miraculously resuscitated ;)
586                 // e.g. players in freezetag get frozen, they don't really die
587                 if(this.health >= 1 || !(IS_PLAYER(this) || this.classname == "body"))
588                         return;
589
590                 if (!this.respawn_time) // can be set in the mutator hook PlayerDies
591                         calculate_player_respawn_time(this);
592
593                 // when we get here, player actually dies
594
595                 Unfreeze(this); // remove any icy remains
596                 this.health = 0; // Unfreeze resets health, so we need to set it back
597
598                 // clear waypoints
599                 WaypointSprite_PlayerDead(this);
600                 // throw a weapon
601                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
602                 {
603                         .entity went = weaponentities[slot];
604                         SpawnThrownWeapon(this, this.origin + (this.mins + this.maxs) * 0.5, this.(went).m_weapon, went);
605                 }
606
607                 // become fully visible
608                 this.alpha = default_player_alpha;
609                 // make the corpse upright (not tilted)
610                 this.angles_x = 0;
611                 this.angles_z = 0;
612                 // don't spin
613                 this.avelocity = '0 0 0';
614                 // view from the floor
615                 this.view_ofs = '0 0 -8';
616                 // toss the corpse
617                 set_movetype(this, MOVETYPE_TOSS);
618                 // shootable corpse
619                 this.solid = SOLID_CORPSE;
620                 PS(this).ballistics_density = autocvar_g_ballistics_density_corpse;
621                 // don't stick to the floor
622                 UNSET_ONGROUND(this);
623                 // dying animation
624                 this.deadflag = DEAD_DYING;
625
626                 STAT(MOVEVARS_SPECIALCOMMAND, this) = false; // sweet release
627
628                 this.death_time = time;
629                 if (random() < 0.5)
630                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD1, true);
631                 else
632                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD2, true);
633                 if (this.maxs.z > 5)
634                 {
635                         this.maxs_z = 5;
636                         setsize(this, this.mins, this.maxs);
637                 }
638                 // set damage function to corpse damage
639                 this.event_damage = PlayerCorpseDamage;
640                 // call the corpse damage function just in case it wants to gib
641                 this.event_damage(this, inflictor, attacker, excess, deathtype, hitloc, force);
642
643                 // set up to fade out later
644                 SUB_SetFade (this, time + 6 + random (), 1);
645                 // reset body think wrapper broken by SUB_SetFade
646                 if(this.classname == "body" && getthink(this) != CopyBody_Think) {
647                         this.CopyBody_think = getthink(this);
648                         this.CopyBody_nextthink = this.nextthink;
649                         setthink(this, CopyBody_Think);
650                         this.nextthink = time;
651                 }
652
653                 if(autocvar_sv_gentle > 0 || autocvar_ekg || this.classname == "body") {
654                         // remove corpse
655                         // clones don't run any animation code any more, so we must gib them when they die :(
656                         PlayerCorpseDamage(this, inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
657                 }
658
659                 // reset fields the weapons may use just in case
660                 if(this.classname != "body")
661                 {
662                         FOREACH(Weapons, it != WEP_Null,
663                         {
664                                 it.wr_resetplayer(it, this);
665                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
666                                 {
667                                         ATTACK_FINISHED_FOR(this, it.m_id, slot) = 0;
668                                 }
669                         });
670                 }
671                 MUTATOR_CALLHOOK(PlayerDied, this);
672         }
673 }
674
675 bool MoveToTeam(entity client, int team_colour, int type)
676 {
677         int lockteams_backup = lockteams;  // backup any team lock
678         lockteams = 0;  // disable locked teams
679         TeamchangeFrags(client);  // move the players frags
680         if (!SetPlayerTeamSimple(client, team_colour))
681         {
682                 return false;
683         }
684         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE.m_id, client.origin, '0 0 0');  // kill the player
685         lockteams = lockteams_backup;  // restore the team lock
686         LogTeamchange(client.playerid, client.team, type);
687         return true;
688 }
689
690 /** print(), but only print if the server is not local */
691 void dedicated_print(string input)
692 {
693         if (server_is_dedicated) print(input);
694 }
695
696 void PrintToChat(entity player, string text)
697 {
698         text = strcat("\{1}^7", text, "\n");
699         sprint(player, text);
700 }
701
702 void DebugPrintToChat(entity player, string text)
703 {
704         if (autocvar_developer)
705         {
706                 PrintToChat(player, text);
707         }
708 }
709
710 void PrintToChatAll(string text)
711 {
712         text = strcat("\{1}^7", text, "\n");
713         bprint(text);
714 }
715
716 void DebugPrintToChatAll(string text)
717 {
718         if (autocvar_developer)
719         {
720                 PrintToChatAll(text);
721         }
722 }
723
724 void PrintToChatTeam(int teamnum, string text)
725 {
726         text = strcat("\{1}^7", text, "\n");
727         FOREACH_CLIENT(IS_REAL_CLIENT(it),
728         {
729                 if (it.team == teamnum)
730                 {
731                         sprint(it, text);
732                 }
733         });
734 }
735
736 void DebugPrintToChatTeam(int teamnum, string text)
737 {
738         if (autocvar_developer)
739         {
740                 PrintToChatTeam(teamnum, text);
741         }
742 }
743
744 /**
745  * message "": do not say, just test flood control
746  * return value:
747  *   1 = accept
748  *   0 = reject
749  *  -1 = fake accept
750  */
751 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
752 {
753         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
754         msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
755
756     if(source)
757                 msgin = formatmessage(source, msgin);
758
759     string colorstr;
760         if (!IS_PLAYER(source))
761                 colorstr = "^0"; // black for spectators
762         else if(teamplay)
763                 colorstr = Team_ColorCode(source.team);
764         else
765         {
766                 colorstr = "";
767                 teamsay = false;
768         }
769
770         if(game_stopped)
771                 teamsay = false;
772
773     if (!source) {
774                 colorstr = "";
775                 teamsay = false;
776     }
777
778         if(msgin != "")
779                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
780
781         /*
782          * using bprint solves this... me stupid
783         // how can we prevent the message from appearing in a listen server?
784         // for now, just give "say" back and only handle say_team
785         if(!teamsay)
786         {
787                 clientcommand(source, strcat("say ", msgin));
788                 return;
789         }
790         */
791
792     string namestr = "";
793     if (source)
794         namestr = playername(source, autocvar_g_chat_teamcolors);
795
796     string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
797
798     string msgstr, cmsgstr;
799     string privatemsgprefix = string_null;
800     int privatemsgprefixlen = 0;
801         if (msgin == "") {
802         msgstr = cmsgstr = "";
803         } else {
804                 if(privatesay)
805                 {
806                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
807                         privatemsgprefixlen = strlen(msgstr);
808                         msgstr = strcat(msgstr, msgin);
809                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
810                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
811                 }
812                 else if(teamsay)
813                 {
814                         if(strstrofs(msgin, "/me", 0) >= 0)
815                         {
816                                 //msgin = strreplace("/me", "", msgin);
817                                 //msgin = substring(msgin, 3, strlen(msgin));
818                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
819                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
820                         }
821                         else
822                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
823                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
824                 }
825                 else
826                 {
827                         if(strstrofs(msgin, "/me", 0) >= 0)
828                         {
829                                 //msgin = strreplace("/me", "", msgin);
830                                 //msgin = substring(msgin, 3, strlen(msgin));
831                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
832                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
833                         }
834                         else {
835                 msgstr = "\{1}";
836                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
837                 msgstr = strcat(msgstr, msgin);
838             }
839                         cmsgstr = "";
840                 }
841                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
842         }
843
844         string fullmsgstr = msgstr;
845         string fullcmsgstr = cmsgstr;
846
847         // FLOOD CONTROL
848         int flood = 0;
849         var .float flood_field = floodcontrol_chat;
850         if(floodcontrol && source)
851         {
852                 float flood_spl;
853                 float flood_burst;
854                 float flood_lmax;
855                 float lines;
856                 if(privatesay)
857                 {
858                         flood_spl = autocvar_g_chat_flood_spl_tell;
859                         flood_burst = autocvar_g_chat_flood_burst_tell;
860                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
861                         flood_field = floodcontrol_chattell;
862                 }
863                 else if(teamsay)
864                 {
865                         flood_spl = autocvar_g_chat_flood_spl_team;
866                         flood_burst = autocvar_g_chat_flood_burst_team;
867                         flood_lmax = autocvar_g_chat_flood_lmax_team;
868                         flood_field = floodcontrol_chatteam;
869                 }
870                 else
871                 {
872                         flood_spl = autocvar_g_chat_flood_spl;
873                         flood_burst = autocvar_g_chat_flood_burst;
874                         flood_lmax = autocvar_g_chat_flood_lmax;
875                         flood_field = floodcontrol_chat;
876                 }
877                 flood_burst = max(0, flood_burst - 1);
878                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
879
880                 // do flood control for the default line size
881                 if(msgstr != "")
882                 {
883                         getWrappedLine_remaining = msgstr;
884                         msgstr = "";
885                         lines = 0;
886                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
887                         {
888                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
889                                 ++lines;
890                         }
891                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
892
893                         if(getWrappedLine_remaining != "")
894                         {
895                                 msgstr = strcat(msgstr, "\n");
896                                 flood = 2;
897                         }
898
899                         if (time >= source.(flood_field))
900                         {
901                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
902                         }
903                         else
904                         {
905                                 flood = 1;
906                                 msgstr = fullmsgstr;
907                         }
908                 }
909                 else
910                 {
911                         if (time >= source.(flood_field))
912                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
913                         else
914                                 flood = 1;
915                 }
916
917                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
918                         source.(flood_field) = flood = 0;
919         }
920
921     string sourcemsgstr, sourcecmsgstr;
922         if(flood == 2) // cannot happen for empty msgstr
923         {
924                 if(autocvar_g_chat_flood_notify_flooder)
925                 {
926                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
927                         sourcecmsgstr = "";
928                 }
929                 else
930                 {
931                         sourcemsgstr = fullmsgstr;
932                         sourcecmsgstr = fullcmsgstr;
933                 }
934                 cmsgstr = "";
935         }
936         else
937         {
938                 sourcemsgstr = msgstr;
939                 sourcecmsgstr = cmsgstr;
940         }
941
942         if (!privatesay && source && !IS_PLAYER(source))
943         {
944                 if (!game_stopped)
945                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
946                         teamsay = -1; // spectators
947         }
948
949         if(flood)
950                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
951
952         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
953         if(privatesay)
954                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
955
956     int ret;
957         if(source && CS(source).muted)
958         {
959                 // always fake the message
960                 ret = -1;
961         }
962         else if(flood == 1)
963         {
964                 if (autocvar_g_chat_flood_notify_flooder)
965                 {
966                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
967                         ret = 0;
968                 }
969                 else
970                         ret = -1;
971         }
972         else
973         {
974                 ret = 1;
975         }
976
977         if (privatesay && source && !IS_PLAYER(source))
978         {
979                 if (!game_stopped)
980                 if ((privatesay && !IS_PLAYER(privatesay)) || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
981                         ret = -1; // just hide the message completely
982         }
983
984         MUTATOR_CALLHOOK(ChatMessage, source, ret);
985         ret = M_ARGV(1, int);
986
987         if(sourcemsgstr != "" && ret != 0)
988         {
989                 if(ret < 0) // faked message, because the player is muted
990                 {
991                         sprint(source, sourcemsgstr);
992                         if(sourcecmsgstr != "" && !privatesay)
993                                 centerprint(source, sourcecmsgstr);
994                 }
995                 else if(privatesay) // private message, between 2 people only
996                 {
997                         sprint(source, sourcemsgstr);
998                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
999                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
1000                         {
1001                                 sprint(privatesay, msgstr);
1002                                 if(cmsgstr != "")
1003                                         centerprint(privatesay, cmsgstr);
1004                         }
1005                 }
1006                 else if ( teamsay && CS(source).active_minigame )
1007                 {
1008                         sprint(source, sourcemsgstr);
1009                         dedicated_print(msgstr); // send to server console too
1010                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1011                 }
1012                 else if(teamsay > 0) // team message, only sent to team mates
1013                 {
1014                         sprint(source, sourcemsgstr);
1015                         dedicated_print(msgstr); // send to server console too
1016                         if(sourcecmsgstr != "")
1017                                 centerprint(source, sourcecmsgstr);
1018                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
1019                                 sprint(it, msgstr);
1020                                 if(cmsgstr != "")
1021                                         centerprint(it, cmsgstr);
1022                         });
1023                 }
1024                 else if(teamsay < 0) // spectator message, only sent to spectators
1025                 {
1026                         sprint(source, sourcemsgstr);
1027                         dedicated_print(msgstr); // send to server console too
1028                         FOREACH_CLIENT(!IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1029                 }
1030                 else
1031                 {
1032             if (source) {
1033                 sprint(source, sourcemsgstr);
1034                 dedicated_print(msgstr); // send to server console too
1035                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
1036             }
1037             FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1038         }
1039         }
1040
1041         return ret;
1042 }