qcsrc/server/player.qc

   1 #include "player.qh"
   2
   3 #include "bot/api.qh"
   4 #include "cheats.qh"
   5 #include "g_damage.qh"
   6 #include "g_subs.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "weapons/throwing.qh"
  11 #include "command/common.qh"
  12 #include "../common/state.qh"
  13 #include "../common/anim.qh"
  14 #include "../common/animdecide.qh"
  15 #include "../common/csqcmodel_settings.qh"
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/triggers/subs.qh"
  18 #include "../common/playerstats.qh"
  19 #include "../lib/csqcmodel/sv_model.qh"
  20
  21 #include "../common/minigames/sv_minigames.qh"
  22
  23 #include "../common/physics/player.qh"
  24 #include "../common/effects/qc/all.qh"
  25 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  26 #include "../common/triggers/include.qh"
  27 #include "../common/wepent.qh"
  28
  29 #include "weapons/weaponstats.qh"
  30
  31 #include "../common/animdecide.qh"
  32
  33 void Drop_Special_Items(entity player)
  34 {
  35         // called when the player has become stuck or frozen
  36         // so objective items aren't stuck with the player
  37
  38         MUTATOR_CALLHOOK(DropSpecialItems, player);
  39 }
  40
  41 void CopyBody_Think(entity this)
  42 {
  43         if(this.CopyBody_nextthink && time > this.CopyBody_nextthink)
  44         {
  45                 this.CopyBody_think(this);
  46                 if(wasfreed(this))
  47                         return;
  48                 this.CopyBody_nextthink = this.nextthink;
  49                 this.CopyBody_think = getthink(this);
  50                 setthink(this, CopyBody_Think);
  51         }
  52         CSQCMODEL_AUTOUPDATE(this);
  53         this.nextthink = time;
  54 }
  55 void CopyBody(entity this, float keepvelocity)
  56 {
  57         if (this.effects & EF_NODRAW)
  58                 return;
  59         entity clone = new(body);
  60         clone.enemy = this;
  61         clone.lip = this.lip;
  62         clone.colormap = this.colormap;
  63         clone.iscreature = this.iscreature;
  64         clone.teleportable = this.teleportable;
  65         clone.damagedbycontents = this.damagedbycontents;
  66         if(clone.damagedbycontents)
  67                 IL_PUSH(g_damagedbycontents, clone);
  68         clone.angles = this.angles;
  69         clone.v_angle = this.v_angle;
  70         clone.avelocity = this.avelocity;
  71         clone.damageforcescale = this.damageforcescale;
  72         clone.effects = this.effects;
  73         clone.glowmod = this.glowmod;
  74         clone.event_damage = this.event_damage;
  75         clone.anim_state = this.anim_state;
  76         clone.anim_time = this.anim_time;
  77         clone.anim_lower_action = this.anim_lower_action;
  78         clone.anim_lower_time = this.anim_lower_time;
  79         clone.anim_upper_action = this.anim_upper_action;
  80         clone.anim_upper_time = this.anim_upper_time;
  81         clone.anim_implicit_state = this.anim_implicit_state;
  82         clone.anim_implicit_time = this.anim_implicit_time;
  83         clone.anim_lower_implicit_action = this.anim_lower_implicit_action;
  84         clone.anim_lower_implicit_time = this.anim_lower_implicit_time;
  85         clone.anim_upper_implicit_action = this.anim_upper_implicit_action;
  86         clone.anim_upper_implicit_time = this.anim_upper_implicit_time;
  87         clone.dphitcontentsmask = this.dphitcontentsmask;
  88         clone.death_time = this.death_time;
  89         clone.pain_finished = this.pain_finished;
  90         clone.health = this.health;
  91         clone.armorvalue = this.armorvalue;
  92         clone.armortype = this.armortype;
  93         clone.model = this.model;
  94         clone.modelindex = this.modelindex;
  95         clone.skin = this.skin;
  96         clone.species = this.species;
  97         clone.move_qcphysics = false; // don't run gamecode logic on clones, too many
  98         set_movetype(clone, this.move_movetype);
  99         clone.solid = this.solid;
 100         clone.ballistics_density = this.ballistics_density;
 101         clone.takedamage = this.takedamage;
 102         setcefc(clone, getcefc(this));
 103         clone.uncustomizeentityforclient = this.uncustomizeentityforclient;
 104         clone.uncustomizeentityforclient_set = this.uncustomizeentityforclient_set;
 105         if (keepvelocity == 1)
 106                 clone.velocity = this.velocity;
 107         clone.oldvelocity = clone.velocity;
 108         clone.alpha = this.alpha;
 109         clone.fade_time = this.fade_time;
 110         clone.fade_rate = this.fade_rate;
 111         //clone.weapon = this.weapon;
 112         setorigin(clone, this.origin);
 113         setsize(clone, this.mins, this.maxs);
 114         clone.prevorigin = this.origin;
 115         clone.reset = SUB_Remove;
 116         clone._ps = this._ps;
 117
 118         Drag_MoveDrag(this, clone);
 119
 120         if(clone.colormap <= maxclients && clone.colormap > 0)
 121                 clone.colormap = 1024 + this.clientcolors;
 122
 123         CSQCMODEL_AUTOINIT(clone);
 124         clone.CopyBody_nextthink = this.nextthink;
 125         clone.CopyBody_think = getthink(this);
 126         clone.nextthink = time;
 127         setthink(clone, CopyBody_Think);
 128         // "bake" the current animation frame for clones (they don't get clientside animation)
 129         animdecide_load_if_needed(clone);
 130         animdecide_setframes(clone, false, frame, frame1time, frame2, frame2time);
 131
 132         IL_PUSH(g_clones, clone);
 133
 134         MUTATOR_CALLHOOK(CopyBody, this, clone, keepvelocity);
 135 }
 136
 137 void player_setupanimsformodel(entity this)
 138 {
 139         // load animation info
 140         animdecide_load_if_needed(this);
 141         animdecide_setstate(this, 0, false);
 142 }
 143
 144 void player_anim(entity this)
 145 {
 146         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 147         if(IS_DEAD(this)) {
 148                 if (!deadbits) {
 149                         // Decide on which death animation to use.
 150                         if(random() < 0.5)
 151                                 deadbits = ANIMSTATE_DEAD1;
 152                         else
 153                                 deadbits = ANIMSTATE_DEAD2;
 154                 }
 155         } else {
 156                 // Clear a previous death animation.
 157                 deadbits = 0;
 158         }
 159         int animbits = deadbits;
 160         if(STAT(FROZEN, this))
 161                 animbits |= ANIMSTATE_FROZEN;
 162         if(this.move_movetype == MOVETYPE_FOLLOW)
 163                 animbits |= ANIMSTATE_FOLLOW;
 164         if(this.crouch)
 165                 animbits |= ANIMSTATE_DUCK;
 166         animdecide_setstate(this, animbits, false);
 167         animdecide_setimplicitstate(this, IS_ONGROUND(this));
 168 }
 169
 170 void PlayerCorpseDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 171 {
 172         float take, save;
 173         vector v;
 174         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 175
 176         // damage resistance (ignore most of the damage from a bullet or similar)
 177         damage = max(damage - 5, 1);
 178
 179         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 180         take = v.x;
 181         save = v.y;
 182
 183         if(sound_allowed(MSG_BROADCAST, attacker))
 184         {
 185                 if (save > 10)
 186                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 187                 else if (take > 30)
 188                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 189                 else if (take > 10)
 190                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM);
 191         }
 192
 193         if (take > 50)
 194                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 195         if (take > 100)
 196                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 197
 198         this.armorvalue = this.armorvalue - save;
 199         this.health = this.health - take;
 200         // pause regeneration for 5 seconds
 201         this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 202
 203         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 204         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 205         this.dmg_inflictor = inflictor;
 206
 207         if (this.health <= -autocvar_sv_gibhealth && this.alpha >= 0)
 208         {
 209                 // don't use any animations as a gib
 210                 this.frame = 0;
 211                 // view just above the floor
 212                 this.view_ofs = '0 0 4';
 213
 214                 Violence_GibSplash(this, 1, 1, attacker);
 215                 this.alpha = -1;
 216                 this.solid = SOLID_NOT; // restore later
 217                 this.takedamage = DAMAGE_NO; // restore later
 218                 if(this.damagedbycontents)
 219                         IL_REMOVE(g_damagedbycontents, this);
 220                 this.damagedbycontents = false;
 221         }
 222 }
 223
 224 void calculate_player_respawn_time(entity this)
 225 {
 226         if(g_ca)
 227                 return;
 228
 229         float gametype_setting_tmp;
 230         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 231         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 232         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 233         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 234         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 235         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 236
 237         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 238         if (teamplay)
 239         {
 240                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 241                         if(it.team == this.team)
 242                                 ++pcount;
 243                 ));
 244                 if (sdelay_small_count == 0)
 245                         sdelay_small_count = 1;
 246                 if (sdelay_large_count == 0)
 247                         sdelay_large_count = 1;
 248         }
 249         else
 250         {
 251                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 252                         ++pcount;
 253                 ));
 254                 if (sdelay_small_count == 0)
 255                 {
 256                         if (IS_INDEPENDENT_PLAYER(this))
 257                         {
 258                                 // Players play independently. No point in requiring enemies.
 259                                 sdelay_small_count = 1;
 260                         }
 261                         else
 262                         {
 263                                 // Players play AGAINST each other. Enemies required.
 264                                 sdelay_small_count = 2;
 265                         }
 266                 }
 267                 if (sdelay_large_count == 0)
 268                 {
 269                         if (IS_INDEPENDENT_PLAYER(this))
 270                         {
 271                                 // Players play independently. No point in requiring enemies.
 272                                 sdelay_large_count = 1;
 273                         }
 274                         else
 275                         {
 276                                 // Players play AGAINST each other. Enemies required.
 277                                 sdelay_large_count = 2;
 278                         }
 279                 }
 280         }
 281
 282         float sdelay;
 283
 284         if (pcount <= sdelay_small_count)
 285                 sdelay = sdelay_small;
 286         else if (pcount >= sdelay_large_count)
 287                 sdelay = sdelay_large;
 288         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 289                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 290
 291         if(waves)
 292                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
 293         else
 294                 this.respawn_time = time + sdelay;
 295
 296         if(sdelay < sdelay_max)
 297                 this.respawn_time_max = time + sdelay_max;
 298         else
 299                 this.respawn_time_max = this.respawn_time;
 300
 301         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
 302                 this.respawn_countdown = 10; // first number to count down from is 10
 303         else
 304                 this.respawn_countdown = -1; // do not count down
 305
 306         if(autocvar_g_forced_respawn)
 307                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
 308 }
 309
 310 void PlayerDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 311 {
 312         float take, save, dh, da;
 313         vector v;
 314         float valid_damage_for_weaponstats;
 315         float excess;
 316
 317         dh = max(this.health, 0);
 318         da = max(this.armorvalue, 0);
 319
 320         if(!DEATH_ISSPECIAL(deathtype))
 321         {
 322                 damage *= bound(1.0, this.cvar_cl_handicap, 10.0);
 323                 if(this != attacker)
 324                         damage /= bound(1.0, attacker.cvar_cl_handicap, 10.0);
 325         }
 326
 327         if (time < this.spawnshieldtime && autocvar_g_spawnshield_blockdamage < 1)
 328                 damage *= 1 - max(0, autocvar_g_spawnshield_blockdamage);
 329
 330         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 331         {
 332                 // tuba causes blood to come out of the ears
 333                 vector ear1, ear2;
 334                 vector d;
 335                 float f;
 336                 ear1 = this.origin;
 337                 ear1_z += 0.125 * this.view_ofs.z + 0.875 * this.maxs.z; // 7/8
 338                 ear2 = ear1;
 339                 makevectors(this.angles);
 340                 ear1 += v_right * -10;
 341                 ear2 += v_right * +10;
 342                 d = inflictor.origin - this.origin;
 343                 if (d)
 344                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 345                 else
 346                         f = 0;  // Assum ecenter.
 347                 force = v_right * vlen(force);
 348                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), this, attacker);
 349                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), this, attacker);
 350                 if(f > 0)
 351                 {
 352                         hitloc = ear1;
 353                         force = force * -1;
 354                 }
 355                 else
 356                 {
 357                         hitloc = ear2;
 358                         // force is already good
 359                 }
 360         }
 361         else
 362                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 363
 364         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 365         take = v.x;
 366         save = v.y;
 367
 368         if(attacker == this)
 369         {
 370                 // don't reset pushltime for this damage as it may be an attempt to
 371                 // escape a lava pit or similar
 372                 //this.pushltime = 0;
 373                 this.istypefrag = 0;
 374         }
 375         else if(IS_PLAYER(attacker))
 376         {
 377                 this.pusher = attacker;
 378                 this.pushltime = time + autocvar_g_maxpushtime;
 379                 this.istypefrag = PHYS_INPUT_BUTTON_CHAT(this);
 380         }
 381         else if(time < this.pushltime)
 382         {
 383                 attacker = this.pusher;
 384                 this.pushltime = max(this.pushltime, time + 0.6);
 385         }
 386         else
 387         {
 388                 this.pushltime = 0;
 389                 this.istypefrag = 0;
 390         }
 391
 392         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor, inflictor, attacker, this, force, take, save, deathtype, damage);
 393         take = bound(0, M_ARGV(4, float), this.health);
 394         save = bound(0, M_ARGV(5, float), this.armorvalue);
 395         excess = max(0, damage - take - save);
 396
 397         if(sound_allowed(MSG_BROADCAST, attacker))
 398         {
 399                 if (save > 10)
 400                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 401                 else if (take > 30)
 402                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 403                 else if (take > 10)
 404                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 405         }
 406
 407         if (take > 50)
 408                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 409         if (take > 100)
 410                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 411
 412         if (time >= this.spawnshieldtime || autocvar_g_spawnshield_blockdamage < 1)
 413         {
 414                 if (!(this.flags & FL_GODMODE))
 415                 {
 416                         this.armorvalue = this.armorvalue - save;
 417                         this.health = this.health - take;
 418                         // pause regeneration for 5 seconds
 419                         if(take)
 420                                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 421
 422                         if (time > this.pain_finished)          //Don't switch pain sequences like crazy
 423                         {
 424                                 this.pain_finished = time + 0.5;        //Supajoe
 425
 426                                 if(autocvar_sv_gentle < 1) {
 427                                         if(this.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 428                                         {
 429                                                 if (!this.animstate_override)
 430                                                 {
 431                                                         if (random() > 0.5)
 432                                                                 animdecide_setaction(this, ANIMACTION_PAIN1, true);
 433                                                         else
 434                                                                 animdecide_setaction(this, ANIMACTION_PAIN2, true);
 435                                                 }
 436                                         }
 437
 438                                         if(sound_allowed(MSG_BROADCAST, attacker))
 439                                         if(this.health < 25 || !(DEATH_WEAPONOF(deathtype).spawnflags & WEP_FLAG_CANCLIMB) || take > 20 || attacker != this)
 440                                         if(this.health > 1)
 441                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 442                                         {
 443                                                 if(deathtype == DEATH_FALL.m_id)
 444                                                         PlayerSound(this, playersound_fall, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 445                                                 else if(this.health > 75)
 446                                                         PlayerSound(this, playersound_pain100, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 447                                                 else if(this.health > 50)
 448                                                         PlayerSound(this, playersound_pain75, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 449                                                 else if(this.health > 25)
 450                                                         PlayerSound(this, playersound_pain50, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 451                                                 else
 452                                                         PlayerSound(this, playersound_pain25, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 453                                         }
 454                                 }
 455                         }
 456
 457                         // throw off bot aim temporarily
 458                         float shake;
 459                         if(IS_BOT_CLIENT(this) && this.health >= 1)
 460                         {
 461                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 462                                 this.v_angle_x = this.v_angle.x + (random() * 2 - 1) * shake;
 463                                 this.v_angle_y = this.v_angle.y + (random() * 2 - 1) * shake;
 464                                 this.v_angle_x = bound(-90, this.v_angle.x, 90);
 465                         }
 466                 }
 467                 else
 468                         this.max_armorvalue += (save + take);
 469         }
 470         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 471         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 472         this.dmg_inflictor = inflictor;
 473
 474         if (this != attacker) {
 475                 float realdmg = damage - excess;
 476                 if (IS_PLAYER(attacker)) {
 477                         PlayerScore_Add(attacker, SP_DMG, realdmg);
 478                 }
 479                 if (IS_PLAYER(this)) {
 480                         PlayerScore_Add(this, SP_DMGTAKEN, realdmg);
 481                 }
 482         }
 483
 484         bool abot = (IS_BOT_CLIENT(attacker));
 485         bool vbot = (IS_BOT_CLIENT(this));
 486
 487         valid_damage_for_weaponstats = 0;
 488         Weapon awep = WEP_Null;
 489         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 490
 491         if(vbot || IS_REAL_CLIENT(this))
 492         if(abot || IS_REAL_CLIENT(attacker))
 493         if(attacker && this != attacker)
 494         if(DIFF_TEAM(this, attacker))
 495         {
 496                 if(DEATH_ISSPECIAL(deathtype))
 497                         awep = attacker.(weaponentity).m_weapon;
 498                 else
 499                         awep = DEATH_WEAPONOF(deathtype);
 500                 valid_damage_for_weaponstats = 1;
 501         }
 502
 503         dh = dh - max(this.health, 0);
 504         da = da - max(this.armorvalue, 0);
 505         if(valid_damage_for_weaponstats)
 506         {
 507                 WeaponStats_LogDamage(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot, dh + da);
 508         }
 509
 510         MUTATOR_CALLHOOK(PlayerDamaged, attacker, this, dh, da, hitloc, deathtype, damage);
 511
 512         if (this.health < 1)
 513         {
 514                 float defer_ClientKill_Now_TeamChange;
 515                 defer_ClientKill_Now_TeamChange = false;
 516
 517                 if(this.alivetime)
 518                 {
 519                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 520                         this.alivetime = 0;
 521                 }
 522
 523                 if(valid_damage_for_weaponstats)
 524                         WeaponStats_LogKill(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot);
 525
 526                 if(autocvar_sv_gentle < 1)
 527                 if(sound_allowed(MSG_BROADCAST, attacker))
 528                 {
 529                         if(deathtype == DEATH_DROWN.m_id)
 530                                 PlayerSound(this, playersound_drown, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 531                         else
 532                                 PlayerSound(this, playersound_death, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 533                 }
 534
 535                 // get rid of kill indicator
 536                 if(this.killindicator)
 537                 {
 538                         delete(this.killindicator);
 539                         this.killindicator = NULL;
 540                         if(this.killindicator_teamchange)
 541                                 defer_ClientKill_Now_TeamChange = true;
 542
 543                         if(this.classname == "body")
 544                         if(deathtype == DEATH_KILL.m_id)
 545                         {
 546                                 // for the lemmings fans, a small harmless explosion
 547                                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 548                         }
 549                 }
 550
 551                 // print an obituary message
 552                 if(this.classname != "body")
 553                         Obituary (attacker, inflictor, this, deathtype);
 554
 555         // increment frag counter for used weapon type
 556         Weapon w = DEATH_WEAPONOF(deathtype);
 557                 if(w != WEP_Null && accuracy_isgooddamage(attacker, this))
 558                         attacker.accuracy.(accuracy_frags[w.m_id-1]) += 1;
 559
 560                 MUTATOR_CALLHOOK(PlayerDies, inflictor, attacker, this, deathtype, damage);
 561                 excess = M_ARGV(4, float);
 562
 563                 Weapon wep = this.(weaponentity).m_weapon;
 564                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 565                 {
 566                         .entity went = weaponentities[slot];
 567                         wep.wr_playerdeath(wep, this, went);
 568                 }
 569
 570                 RemoveGrapplingHooks(this);
 571
 572                 Portal_ClearAllLater(this);
 573
 574                 this.fixangle = true;
 575
 576                 if(defer_ClientKill_Now_TeamChange)
 577                         ClientKill_Now_TeamChange(this); // can turn player into spectator
 578
 579                 // player could have been miraculously resuscitated ;)
 580                 // e.g. players in freezetag get frozen, they don't really die
 581                 if(this.health >= 1 || !(IS_PLAYER(this) || this.classname == "body"))
 582                         return;
 583
 584                 // when we get here, player actually dies
 585
 586                 Unfreeze(this); // remove any icy remains
 587                 this.health = 0; // Unfreeze resets health, so we need to set it back
 588
 589                 // clear waypoints
 590                 WaypointSprite_PlayerDead(this);
 591                 // throw a weapon
 592                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 593                 {
 594                         .entity went = weaponentities[slot];
 595                         SpawnThrownWeapon(this, this.origin + (this.mins + this.maxs) * 0.5, this.(went).m_weapon, went);
 596                 }
 597
 598                 // become fully visible
 599                 this.alpha = default_player_alpha;
 600                 // make the corpse upright (not tilted)
 601                 this.angles_x = 0;
 602                 this.angles_z = 0;
 603                 // don't spin
 604                 this.avelocity = '0 0 0';
 605                 // view from the floor
 606                 this.view_ofs = '0 0 -8';
 607                 // toss the corpse
 608                 set_movetype(this, MOVETYPE_TOSS);
 609                 // shootable corpse
 610                 this.solid = SOLID_CORPSE;
 611                 this.ballistics_density = autocvar_g_ballistics_density_corpse;
 612                 // don't stick to the floor
 613                 UNSET_ONGROUND(this);
 614                 // dying animation
 615                 this.deadflag = DEAD_DYING;
 616
 617                 // when to allow respawn
 618                 calculate_player_respawn_time(this);
 619
 620                 this.death_time = time;
 621                 if (random() < 0.5)
 622                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD1, true);
 623                 else
 624                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD2, true);
 625                 if (this.maxs.z > 5)
 626                 {
 627                         this.maxs_z = 5;
 628                         setsize(this, this.mins, this.maxs);
 629                 }
 630                 // set damage function to corpse damage
 631                 this.event_damage = PlayerCorpseDamage;
 632                 // call the corpse damage function just in case it wants to gib
 633                 this.event_damage(this, inflictor, attacker, excess, deathtype, hitloc, force);
 634
 635                 // set up to fade out later
 636                 SUB_SetFade (this, time + 6 + random (), 1);
 637                 // reset body think wrapper broken by SUB_SetFade
 638                 if(this.classname == "body" && getthink(this) != CopyBody_Think) {
 639                         this.CopyBody_think = getthink(this);
 640                         this.CopyBody_nextthink = this.nextthink;
 641                         setthink(this, CopyBody_Think);
 642                         this.nextthink = time;
 643                 }
 644
 645                 if(autocvar_sv_gentle > 0 || autocvar_ekg || this.classname == "body") {
 646                         // remove corpse
 647                         // clones don't run any animation code any more, so we must gib them when they die :(
 648                         PlayerCorpseDamage(this, inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 649                 }
 650
 651                 // reset fields the weapons may use just in case
 652                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 653                         it.wr_resetplayer(it, this);
 654                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 655                         {
 656                                 ATTACK_FINISHED_FOR(this, it.m_id, slot) = 0;
 657                         }
 658                 ));
 659                 MUTATOR_CALLHOOK(PlayerDied, this);
 660         }
 661 }
 662
 663 void MoveToTeam(entity client, int team_colour, int type)
 664 {
 665         int lockteams_backup = lockteams;  // backup any team lock
 666         lockteams = 0;  // disable locked teams
 667         TeamchangeFrags(client);  // move the players frags
 668         SetPlayerColors(client, team_colour - 1);  // set the players colour
 669         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE.m_id, client.origin, '0 0 0');  // kill the player
 670         lockteams = lockteams_backup;  // restore the team lock
 671         LogTeamchange(client.playerid, client.team, type);
 672 }
 673
 674 /** print(), but only print if the server is not local */
 675 void dedicated_print(string input)
 676 {
 677         if (server_is_dedicated) print(input);
 678 }
 679
 680 void PrintToChat(entity player, string text)
 681 {
 682         text = strcat("\{1}^7", text, "\n");
 683         sprint(player, text);
 684 }
 685
 686 void DebugPrintToChat(entity player, string text)
 687 {
 688         if (autocvar_developer)
 689         {
 690                 PrintToChat(player, text);
 691         }
 692 }
 693
 694 void PrintToChatAll(string text)
 695 {
 696         text = strcat("\{1}^7", text, "\n");
 697         bprint(text);
 698 }
 699
 700 void DebugPrintToChatAll(string text)
 701 {
 702         if (autocvar_developer)
 703         {
 704                 PrintToChatAll(text);
 705         }
 706 }
 707
 708 void PrintToChatTeam(int teamnum, string text)
 709 {
 710         text = strcat("\{1}^7", text, "\n");
 711         FOREACH_CLIENT(IS_REAL_CLIENT(it),
 712         {
 713                 if (it.team == teamnum)
 714                 {
 715                         sprint(it, text);
 716                 }
 717         });
 718 }
 719
 720 void DebugPrintToChatTeam(int teamnum, string text)
 721 {
 722         if (autocvar_developer)
 723         {
 724                 PrintToChatTeam(teamnum, text);
 725         }
 726 }
 727
 728 /**
 729  * message "": do not say, just test flood control
 730  * return value:
 731  *   1 = accept
 732  *   0 = reject
 733  *  -1 = fake accept
 734  */
 735 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
 736 {
 737         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
 738         msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
 739
 740         msgin = formatmessage(source, msgin);
 741
 742     string colorstr;
 743         if (!IS_PLAYER(source))
 744                 colorstr = "^0"; // black for spectators
 745         else if(teamplay)
 746                 colorstr = Team_ColorCode(source.team);
 747         else
 748         {
 749                 colorstr = "";
 750                 teamsay = false;
 751         }
 752
 753         if(game_stopped)
 754                 teamsay = false;
 755
 756     if (!source) {
 757                 colorstr = "";
 758                 teamsay = false;
 759     }
 760
 761         if(msgin != "")
 762                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 763
 764         /*
 765          * using bprint solves this... me stupid
 766         // how can we prevent the message from appearing in a listen server?
 767         // for now, just give "say" back and only handle say_team
 768         if(!teamsay)
 769         {
 770                 clientcommand(source, strcat("say ", msgin));
 771                 return;
 772         }
 773         */
 774
 775     string namestr = "";
 776     if (source)
 777         namestr = playername(source, autocvar_g_chat_teamcolors);
 778
 779     string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
 780
 781     string msgstr, cmsgstr;
 782     string privatemsgprefix = string_null;
 783     int privatemsgprefixlen = 0;
 784         if (msgin == "") {
 785         msgstr = cmsgstr = "";
 786         } else {
 787                 if(privatesay)
 788                 {
 789                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 790                         privatemsgprefixlen = strlen(msgstr);
 791                         msgstr = strcat(msgstr, msgin);
 792                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 793                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
 794                 }
 795                 else if(teamsay)
 796                 {
 797                         if(strstrofs(msgin, "/me", 0) >= 0)
 798                         {
 799                                 //msgin = strreplace("/me", "", msgin);
 800                                 //msgin = substring(msgin, 3, strlen(msgin));
 801                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
 802                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
 803                         }
 804                         else
 805                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 806                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 807                 }
 808                 else
 809                 {
 810                         if(strstrofs(msgin, "/me", 0) >= 0)
 811                         {
 812                                 //msgin = strreplace("/me", "", msgin);
 813                                 //msgin = substring(msgin, 3, strlen(msgin));
 814                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
 815                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
 816                         }
 817                         else {
 818                 msgstr = "\{1}";
 819                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
 820                 msgstr = strcat(msgstr, msgin);
 821             }
 822                         cmsgstr = "";
 823                 }
 824                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 825         }
 826
 827         string fullmsgstr = msgstr;
 828         string fullcmsgstr = cmsgstr;
 829
 830         // FLOOD CONTROL
 831         int flood = 0;
 832         var .float flood_field = floodcontrol_chat;
 833         if(floodcontrol)
 834         {
 835                 float flood_spl;
 836                 float flood_burst;
 837                 float flood_lmax;
 838                 float lines;
 839                 if(privatesay)
 840                 {
 841                         flood_spl = autocvar_g_chat_flood_spl_tell;
 842                         flood_burst = autocvar_g_chat_flood_burst_tell;
 843                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 844                         flood_field = floodcontrol_chattell;
 845                 }
 846                 else if(teamsay)
 847                 {
 848                         flood_spl = autocvar_g_chat_flood_spl_team;
 849                         flood_burst = autocvar_g_chat_flood_burst_team;
 850                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 851                         flood_field = floodcontrol_chatteam;
 852                 }
 853                 else
 854                 {
 855                         flood_spl = autocvar_g_chat_flood_spl;
 856                         flood_burst = autocvar_g_chat_flood_burst;
 857                         flood_lmax = autocvar_g_chat_flood_lmax;
 858                         flood_field = floodcontrol_chat;
 859                 }
 860                 flood_burst = max(0, flood_burst - 1);
 861                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 862
 863                 // do flood control for the default line size
 864                 if(msgstr != "")
 865                 {
 866                         getWrappedLine_remaining = msgstr;
 867                         msgstr = "";
 868                         lines = 0;
 869                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 870                         {
 871                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 872                                 ++lines;
 873                         }
 874                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 875
 876                         if(getWrappedLine_remaining != "")
 877                         {
 878                                 msgstr = strcat(msgstr, "\n");
 879                                 flood = 2;
 880                         }
 881
 882                         if (time >= source.(flood_field))
 883                         {
 884                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
 885                         }
 886                         else
 887                         {
 888                                 flood = 1;
 889                                 msgstr = fullmsgstr;
 890                         }
 891                 }
 892                 else
 893                 {
 894                         if (time >= source.(flood_field))
 895                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
 896                         else
 897                                 flood = 1;
 898                 }
 899
 900                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 901                         source.(flood_field) = flood = 0;
 902         }
 903
 904     string sourcemsgstr, sourcecmsgstr;
 905         if(flood == 2) // cannot happen for empty msgstr
 906         {
 907                 if(autocvar_g_chat_flood_notify_flooder)
 908                 {
 909                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 910                         sourcecmsgstr = "";
 911                 }
 912                 else
 913                 {
 914                         sourcemsgstr = fullmsgstr;
 915                         sourcecmsgstr = fullcmsgstr;
 916                 }
 917                 cmsgstr = "";
 918         }
 919         else
 920         {
 921                 sourcemsgstr = msgstr;
 922                 sourcecmsgstr = cmsgstr;
 923         }
 924
 925         if (!privatesay && source && !IS_PLAYER(source))
 926         {
 927                 if (!game_stopped)
 928                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
 929                         teamsay = -1; // spectators
 930         }
 931
 932         if(flood)
 933                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.\n");
 934
 935         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 936         if(privatesay)
 937                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 938
 939     int ret;
 940         if(source.muted)
 941         {
 942                 // always fake the message
 943                 ret = -1;
 944         }
 945         else if(flood == 1)
 946         {
 947                 if (autocvar_g_chat_flood_notify_flooder)
 948                 {
 949                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
 950                         ret = 0;
 951                 }
 952                 else
 953                         ret = -1;
 954         }
 955         else
 956         {
 957                 ret = 1;
 958         }
 959
 960         if (privatesay && source && !IS_PLAYER(source))
 961         {
 962                 if (!game_stopped)
 963                 if ((privatesay && !IS_PLAYER(privatesay)) || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
 964                         ret = -1; // just hide the message completely
 965         }
 966
 967         MUTATOR_CALLHOOK(ChatMessage, source, ret);
 968         ret = M_ARGV(1, int);
 969
 970         if(sourcemsgstr != "" && ret != 0)
 971         {
 972                 if(ret < 0) // faked message, because the player is muted
 973                 {
 974                         sprint(source, sourcemsgstr);
 975                         if(sourcecmsgstr != "" && !privatesay)
 976                                 centerprint(source, sourcecmsgstr);
 977                 }
 978                 else if(privatesay) // private message, between 2 people only
 979                 {
 980                         sprint(source, sourcemsgstr);
 981                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 982                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
 983                         {
 984                                 sprint(privatesay, msgstr);
 985                                 if(cmsgstr != "")
 986                                         centerprint(privatesay, cmsgstr);
 987                         }
 988                 }
 989                 else if ( teamsay && source.active_minigame )
 990                 {
 991                         sprint(source, sourcemsgstr);
 992                         dedicated_print(msgstr); // send to server console too
 993                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && it.active_minigame == source.active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
 994                 }
 995                 else if(teamsay > 0) // team message, only sent to team mates
 996                 {
 997                         sprint(source, sourcemsgstr);
 998                         dedicated_print(msgstr); // send to server console too
 999                         if(sourcecmsgstr != "")
1000                                 centerprint(source, sourcecmsgstr);
1001                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
1002                                 sprint(it, msgstr);
1003                                 if(cmsgstr != "")
1004                                         centerprint(it, cmsgstr);
1005                         });
1006                 }
1007                 else if(teamsay < 0) // spectator message, only sent to spectators
1008                 {
1009                         sprint(source, sourcemsgstr);
1010                         dedicated_print(msgstr); // send to server console too
1011                         FOREACH_CLIENT(!IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1012                 }
1013                 else
1014                 {
1015             if (source) {
1016                 sprint(source, sourcemsgstr);
1017                 dedicated_print(msgstr); // send to server console too
1018                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
1019             }
1020             FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1021         }
1022         }
1023
1024         return ret;
1025 }