qcsrc/server/player.qc

   1 #include "player.qh"
   2
   3 #include <common/effects/all.qh>
   4 #include "bot/api.qh"
   5 #include "cheats.qh"
   6 #include "g_damage.qh"
   7 #include "g_subs.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "weapons/throwing.qh"
  12 #include "command/common.qh"
  13 #include "../common/state.qh"
  14 #include "../common/anim.qh"
  15 #include "../common/animdecide.qh"
  16 #include "../common/csqcmodel_settings.qh"
  17 #include "../common/deathtypes/all.qh"
  18 #include "../common/triggers/subs.qh"
  19 #include "../common/playerstats.qh"
  20 #include "../lib/csqcmodel/sv_model.qh"
  21
  22 #include "../common/minigames/sv_minigames.qh"
  23
  24 #include "../common/physics/player.qh"
  25 #include "../common/effects/qc/_mod.qh"
  26 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  27 #include "../common/triggers/include.qh"
  28 #include "../common/wepent.qh"
  29
  30 #include "weapons/weaponstats.qh"
  31
  32 #include "../common/animdecide.qh"
  33
  34 void Drop_Special_Items(entity player)
  35 {
  36         // called when the player has become stuck or frozen
  37         // so objective items aren't stuck with the player
  38
  39         MUTATOR_CALLHOOK(DropSpecialItems, player);
  40 }
  41
  42 void CopyBody_Think(entity this)
  43 {
  44         if(this.CopyBody_nextthink && time > this.CopyBody_nextthink)
  45         {
  46                 this.CopyBody_think(this);
  47                 if(wasfreed(this))
  48                         return;
  49                 this.CopyBody_nextthink = this.nextthink;
  50                 this.CopyBody_think = getthink(this);
  51                 setthink(this, CopyBody_Think);
  52         }
  53         CSQCMODEL_AUTOUPDATE(this);
  54         this.nextthink = time;
  55 }
  56 void CopyBody(entity this, float keepvelocity)
  57 {
  58         if (this.effects & EF_NODRAW)
  59                 return;
  60         entity clone = new(body);
  61         clone.enemy = this;
  62         clone.lip = this.lip;
  63         clone.colormap = this.colormap;
  64         clone.iscreature = this.iscreature;
  65         clone.teleportable = this.teleportable;
  66         clone.damagedbycontents = this.damagedbycontents;
  67         if(clone.damagedbycontents)
  68                 IL_PUSH(g_damagedbycontents, clone);
  69         clone.angles = this.angles;
  70         clone.v_angle = this.v_angle;
  71         clone.avelocity = this.avelocity;
  72         clone.damageforcescale = this.damageforcescale;
  73         clone.effects = this.effects;
  74         clone.glowmod = this.glowmod;
  75         clone.event_damage = this.event_damage;
  76         clone.anim_state = this.anim_state;
  77         clone.anim_time = this.anim_time;
  78         clone.anim_lower_action = this.anim_lower_action;
  79         clone.anim_lower_time = this.anim_lower_time;
  80         clone.anim_upper_action = this.anim_upper_action;
  81         clone.anim_upper_time = this.anim_upper_time;
  82         clone.anim_implicit_state = this.anim_implicit_state;
  83         clone.anim_implicit_time = this.anim_implicit_time;
  84         clone.anim_lower_implicit_action = this.anim_lower_implicit_action;
  85         clone.anim_lower_implicit_time = this.anim_lower_implicit_time;
  86         clone.anim_upper_implicit_action = this.anim_upper_implicit_action;
  87         clone.anim_upper_implicit_time = this.anim_upper_implicit_time;
  88         clone.dphitcontentsmask = this.dphitcontentsmask;
  89         clone.death_time = this.death_time;
  90         clone.pain_finished = this.pain_finished;
  91         clone.health = this.health;
  92         clone.armorvalue = this.armorvalue;
  93         clone.armortype = this.armortype;
  94         clone.model = this.model;
  95         clone.modelindex = this.modelindex;
  96         clone.skin = this.skin;
  97         clone.species = this.species;
  98         clone.move_qcphysics = false; // don't run gamecode logic on clones, too many
  99         set_movetype(clone, this.move_movetype);
 100         clone.solid = this.solid;
 101         clone.takedamage = this.takedamage;
 102         setcefc(clone, getcefc(this));
 103         clone.uncustomizeentityforclient = this.uncustomizeentityforclient;
 104         clone.uncustomizeentityforclient_set = this.uncustomizeentityforclient_set;
 105         if (keepvelocity == 1)
 106                 clone.velocity = this.velocity;
 107         clone.oldvelocity = clone.velocity;
 108         clone.alpha = this.alpha;
 109         clone.fade_time = this.fade_time;
 110         clone.fade_rate = this.fade_rate;
 111         //clone.weapon = this.weapon;
 112         setorigin(clone, this.origin);
 113         setsize(clone, this.mins, this.maxs);
 114         clone.reset = SUB_Remove;
 115         clone._ps = this._ps;
 116
 117         Drag_MoveDrag(this, clone);
 118
 119         if(clone.colormap <= maxclients && clone.colormap > 0)
 120                 clone.colormap = 1024 + this.clientcolors;
 121
 122         CSQCMODEL_AUTOINIT(clone);
 123         clone.CopyBody_nextthink = this.nextthink;
 124         clone.CopyBody_think = getthink(this);
 125         clone.nextthink = time;
 126         setthink(clone, CopyBody_Think);
 127         // "bake" the current animation frame for clones (they don't get clientside animation)
 128         animdecide_load_if_needed(clone);
 129         animdecide_setframes(clone, false, frame, frame1time, frame2, frame2time);
 130
 131         IL_PUSH(g_clones, clone);
 132
 133         MUTATOR_CALLHOOK(CopyBody, this, clone, keepvelocity);
 134 }
 135
 136 void player_setupanimsformodel(entity this)
 137 {
 138         // load animation info
 139         animdecide_load_if_needed(this);
 140         animdecide_setstate(this, 0, false);
 141 }
 142
 143 void player_anim(entity this)
 144 {
 145         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 146         if(IS_DEAD(this)) {
 147                 if (!deadbits) {
 148                         // Decide on which death animation to use.
 149                         if(random() < 0.5)
 150                                 deadbits = ANIMSTATE_DEAD1;
 151                         else
 152                                 deadbits = ANIMSTATE_DEAD2;
 153                 }
 154         } else {
 155                 // Clear a previous death animation.
 156                 deadbits = 0;
 157         }
 158         int animbits = deadbits;
 159         if(STAT(FROZEN, this))
 160                 animbits |= ANIMSTATE_FROZEN;
 161         if(this.move_movetype == MOVETYPE_FOLLOW)
 162                 animbits |= ANIMSTATE_FOLLOW;
 163         if(this.crouch)
 164                 animbits |= ANIMSTATE_DUCK;
 165         animdecide_setstate(this, animbits, false);
 166         animdecide_setimplicitstate(this, IS_ONGROUND(this));
 167 }
 168
 169 void PlayerCorpseDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 170 {
 171         float take, save;
 172         vector v;
 173         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 174
 175         // damage resistance (ignore most of the damage from a bullet or similar)
 176         damage = max(damage - 5, 1);
 177
 178         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 179         take = v.x;
 180         save = v.y;
 181
 182         if(sound_allowed(MSG_BROADCAST, attacker))
 183         {
 184                 if (save > 10)
 185                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 186                 else if (take > 30)
 187                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 188                 else if (take > 10)
 189                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM);
 190         }
 191
 192         if (take > 50)
 193                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 194         if (take > 100)
 195                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 196
 197         this.armorvalue = this.armorvalue - save;
 198         this.health = this.health - take;
 199         // pause regeneration for 5 seconds
 200         this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 201
 202         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 203         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 204         this.dmg_inflictor = inflictor;
 205
 206         if (this.health <= -autocvar_sv_gibhealth && this.alpha >= 0)
 207         {
 208                 // don't use any animations as a gib
 209                 this.frame = 0;
 210                 // view just above the floor
 211                 this.view_ofs = '0 0 4';
 212
 213                 Violence_GibSplash(this, 1, 1, attacker);
 214                 this.alpha = -1;
 215                 this.solid = SOLID_NOT; // restore later
 216                 this.takedamage = DAMAGE_NO; // restore later
 217                 if(this.damagedbycontents)
 218                         IL_REMOVE(g_damagedbycontents, this);
 219                 this.damagedbycontents = false;
 220         }
 221 }
 222
 223 void calculate_player_respawn_time(entity this)
 224 {
 225         if(g_ca)
 226                 return;
 227
 228         float gametype_setting_tmp;
 229         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 230         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 231         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 232         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 233         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 234         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 235
 236         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 237         if (teamplay)
 238         {
 239                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
 240                         if(it.team == this.team)
 241                                 ++pcount;
 242                 });
 243                 if (sdelay_small_count == 0)
 244                         sdelay_small_count = 1;
 245                 if (sdelay_large_count == 0)
 246                         sdelay_large_count = 1;
 247         }
 248         else
 249         {
 250                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
 251                         ++pcount;
 252                 });
 253                 if (sdelay_small_count == 0)
 254                 {
 255                         if (IS_INDEPENDENT_PLAYER(this))
 256                         {
 257                                 // Players play independently. No point in requiring enemies.
 258                                 sdelay_small_count = 1;
 259                         }
 260                         else
 261                         {
 262                                 // Players play AGAINST each other. Enemies required.
 263                                 sdelay_small_count = 2;
 264                         }
 265                 }
 266                 if (sdelay_large_count == 0)
 267                 {
 268                         if (IS_INDEPENDENT_PLAYER(this))
 269                         {
 270                                 // Players play independently. No point in requiring enemies.
 271                                 sdelay_large_count = 1;
 272                         }
 273                         else
 274                         {
 275                                 // Players play AGAINST each other. Enemies required.
 276                                 sdelay_large_count = 2;
 277                         }
 278                 }
 279         }
 280
 281         float sdelay;
 282
 283         if (pcount <= sdelay_small_count)
 284                 sdelay = sdelay_small;
 285         else if (pcount >= sdelay_large_count)
 286                 sdelay = sdelay_large;
 287         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 288                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 289
 290         if(waves)
 291                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
 292         else
 293                 this.respawn_time = time + sdelay;
 294
 295         if(sdelay < sdelay_max)
 296                 this.respawn_time_max = time + sdelay_max;
 297         else
 298                 this.respawn_time_max = this.respawn_time;
 299
 300         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
 301                 this.respawn_countdown = 10; // first number to count down from is 10
 302         else
 303                 this.respawn_countdown = -1; // do not count down
 304
 305         if(autocvar_g_forced_respawn)
 306                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
 307 }
 308
 309 void PlayerDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 310 {
 311         float take, save, dh, da;
 312         vector v;
 313         float excess;
 314
 315         dh = max(this.health, 0);
 316         da = max(this.armorvalue, 0);
 317
 318         if(!DEATH_ISSPECIAL(deathtype))
 319         {
 320                 damage *= bound(1.0, CS(this).cvar_cl_handicap, 10.0);
 321                 if(this != attacker && IS_PLAYER(attacker))
 322                         damage /= bound(1.0, CS(attacker).cvar_cl_handicap, 10.0);
 323         }
 324
 325         if (time < this.spawnshieldtime && autocvar_g_spawnshield_blockdamage < 1)
 326                 damage *= 1 - max(0, autocvar_g_spawnshield_blockdamage);
 327
 328         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 329         {
 330                 // tuba causes blood to come out of the ears
 331                 vector ear1, ear2;
 332                 vector d;
 333                 float f;
 334                 ear1 = this.origin;
 335                 ear1_z += 0.125 * this.view_ofs.z + 0.875 * this.maxs.z; // 7/8
 336                 ear2 = ear1;
 337                 makevectors(this.angles);
 338                 ear1 += v_right * -10;
 339                 ear2 += v_right * +10;
 340                 d = inflictor.origin - this.origin;
 341                 if (d)
 342                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 343                 else
 344                         f = 0;  // Assum ecenter.
 345                 force = v_right * vlen(force);
 346                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), this, attacker);
 347                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), this, attacker);
 348                 if(f > 0)
 349                 {
 350                         hitloc = ear1;
 351                         force = force * -1;
 352                 }
 353                 else
 354                 {
 355                         hitloc = ear2;
 356                         // force is already good
 357                 }
 358         }
 359         else
 360                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 361
 362         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 363         take = v.x;
 364         save = v.y;
 365
 366         if(attacker == this)
 367         {
 368                 // don't reset pushltime for this damage as it may be an attempt to
 369                 // escape a lava pit or similar
 370                 //this.pushltime = 0;
 371                 this.istypefrag = 0;
 372         }
 373         else if(IS_PLAYER(attacker))
 374         {
 375                 this.pusher = attacker;
 376                 this.pushltime = time + autocvar_g_maxpushtime;
 377                 this.istypefrag = PHYS_INPUT_BUTTON_CHAT(this);
 378         }
 379         else if(time < this.pushltime)
 380         {
 381                 attacker = this.pusher;
 382                 this.pushltime = max(this.pushltime, time + 0.6);
 383         }
 384         else
 385         {
 386                 this.pushltime = 0;
 387                 this.istypefrag = 0;
 388         }
 389
 390         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor, inflictor, attacker, this, force, take, save, deathtype, damage);
 391         take = bound(0, M_ARGV(4, float), this.health);
 392         save = bound(0, M_ARGV(5, float), this.armorvalue);
 393         excess = max(0, damage - take - save);
 394
 395         if(sound_allowed(MSG_BROADCAST, attacker))
 396         {
 397                 if (save > 10)
 398                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 399                 else if (take > 30)
 400                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 401                 else if (take > 10)
 402                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 403         }
 404
 405         if (take > 50)
 406                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 407         if (take > 100)
 408                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 409
 410         if (time >= this.spawnshieldtime || autocvar_g_spawnshield_blockdamage < 1)
 411         {
 412                 if (!(this.flags & FL_GODMODE))
 413                 {
 414                         this.armorvalue = this.armorvalue - save;
 415                         this.health = this.health - take;
 416                         // pause regeneration for 5 seconds
 417                         if(take)
 418                                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 419
 420                         if (time > this.pain_finished)          //Don't switch pain sequences like crazy
 421                         {
 422                                 this.pain_finished = time + 0.5;        //Supajoe
 423
 424                                 if(autocvar_sv_gentle < 1) {
 425                                         if(this.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 426                                         {
 427                                                 if (!this.animstate_override)
 428                                                 {
 429                                                         if (random() > 0.5)
 430                                                                 animdecide_setaction(this, ANIMACTION_PAIN1, true);
 431                                                         else
 432                                                                 animdecide_setaction(this, ANIMACTION_PAIN2, true);
 433                                                 }
 434                                         }
 435
 436                                         if(sound_allowed(MSG_BROADCAST, attacker))
 437                                         if(this.health < 25 || !(DEATH_WEAPONOF(deathtype).spawnflags & WEP_FLAG_CANCLIMB) || take > 20 || attacker != this)
 438                                         if(this.health > 1)
 439                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 440                                         {
 441                                                 if(deathtype == DEATH_FALL.m_id)
 442                                                         PlayerSound(this, playersound_fall, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 443                                                 else if(this.health > 75)
 444                                                         PlayerSound(this, playersound_pain100, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 445                                                 else if(this.health > 50)
 446                                                         PlayerSound(this, playersound_pain75, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 447                                                 else if(this.health > 25)
 448                                                         PlayerSound(this, playersound_pain50, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 449                                                 else
 450                                                         PlayerSound(this, playersound_pain25, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 451                                         }
 452                                 }
 453                         }
 454
 455                         // throw off bot aim temporarily
 456                         float shake;
 457                         if(IS_BOT_CLIENT(this) && this.health >= 1)
 458                         {
 459                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 460                                 this.v_angle_x = this.v_angle.x + (random() * 2 - 1) * shake;
 461                                 this.v_angle_y = this.v_angle.y + (random() * 2 - 1) * shake;
 462                                 this.v_angle_x = bound(-90, this.v_angle.x, 90);
 463                         }
 464                 }
 465                 else
 466                         this.max_armorvalue += (save + take);
 467         }
 468         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 469         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 470         this.dmg_inflictor = inflictor;
 471
 472         if (this != attacker) {
 473                 float realdmg = damage - excess;
 474                 if (IS_PLAYER(attacker)) {
 475                         GameRules_scoring_add(attacker, DMG, realdmg);
 476                 }
 477                 if (IS_PLAYER(this)) {
 478                         GameRules_scoring_add(this, DMGTAKEN, realdmg);
 479                 }
 480         }
 481
 482         bool abot = (IS_BOT_CLIENT(attacker));
 483         bool vbot = (IS_BOT_CLIENT(this));
 484
 485         bool valid_damage_for_weaponstats = false;
 486         Weapon awep = WEP_Null;
 487         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 488
 489         if(vbot || IS_REAL_CLIENT(this))
 490         if(abot || IS_REAL_CLIENT(attacker))
 491         if(attacker && this != attacker)
 492         if(DIFF_TEAM(this, attacker))
 493         {
 494                 if(DEATH_ISSPECIAL(deathtype))
 495                         awep = attacker.(weaponentity).m_weapon;
 496                 else
 497                         awep = DEATH_WEAPONOF(deathtype);
 498                 valid_damage_for_weaponstats = true;
 499         }
 500
 501         dh = dh - max(this.health, 0);
 502         da = da - max(this.armorvalue, 0);
 503         if(valid_damage_for_weaponstats)
 504         {
 505                 WeaponStats_LogDamage(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot, dh + da);
 506         }
 507
 508         MUTATOR_CALLHOOK(PlayerDamaged, attacker, this, dh, da, hitloc, deathtype, damage);
 509
 510         if (this.health < 1)
 511         {
 512                 float defer_ClientKill_Now_TeamChange;
 513                 defer_ClientKill_Now_TeamChange = false;
 514
 515                 if(this.alivetime)
 516                 {
 517                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 518                         this.alivetime = 0;
 519                 }
 520
 521                 if(valid_damage_for_weaponstats)
 522                         WeaponStats_LogKill(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot);
 523
 524                 if(autocvar_sv_gentle < 1)
 525                 if(sound_allowed(MSG_BROADCAST, attacker))
 526                 {
 527                         if(deathtype == DEATH_DROWN.m_id)
 528                                 PlayerSound(this, playersound_drown, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 529                         else
 530                                 PlayerSound(this, playersound_death, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 531                 }
 532
 533                 // get rid of kill indicator
 534                 if(this.killindicator)
 535                 {
 536                         delete(this.killindicator);
 537                         this.killindicator = NULL;
 538                         if(CS(this).killindicator_teamchange)
 539                                 defer_ClientKill_Now_TeamChange = true;
 540
 541                         if(this.classname == "body")
 542                         if(deathtype == DEATH_KILL.m_id)
 543                         {
 544                                 // for the lemmings fans, a small harmless explosion
 545                                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 546                         }
 547                 }
 548
 549                 // print an obituary message
 550                 if(this.classname != "body")
 551                         Obituary (attacker, inflictor, this, deathtype);
 552
 553         // increment frag counter for used weapon type
 554         Weapon w = DEATH_WEAPONOF(deathtype);
 555                 if(w != WEP_Null && accuracy_isgooddamage(attacker, this))
 556                         CS(attacker).accuracy.(accuracy_frags[w.m_id-1]) += 1;
 557
 558                 MUTATOR_CALLHOOK(PlayerDies, inflictor, attacker, this, deathtype, damage);
 559                 damage = M_ARGV(4, float);
 560                 excess = max(0, damage - take - save);
 561
 562                 //Weapon wep = this.(weaponentity).m_weapon;
 563                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 564                 {
 565                         .entity went = weaponentities[slot];
 566                         if(!this.(weaponentity))
 567                                 continue; // TODO: clones have no weapon, but we don't want to have to check this all the time
 568                         Weapon wep = this.(weaponentity).m_weapon;
 569                         wep.wr_playerdeath(wep, this, went);
 570                 }
 571
 572                 RemoveGrapplingHooks(this);
 573
 574                 Portal_ClearAllLater(this);
 575
 576                 this.fixangle = true;
 577
 578                 if(defer_ClientKill_Now_TeamChange)
 579                         ClientKill_Now_TeamChange(this); // can turn player into spectator
 580
 581                 // player could have been miraculously resuscitated ;)
 582                 // e.g. players in freezetag get frozen, they don't really die
 583                 if(this.health >= 1 || !(IS_PLAYER(this) || this.classname == "body"))
 584                         return;
 585
 586                 // when we get here, player actually dies
 587
 588                 Unfreeze(this); // remove any icy remains
 589                 this.health = 0; // Unfreeze resets health, so we need to set it back
 590
 591                 // clear waypoints
 592                 WaypointSprite_PlayerDead(this);
 593                 // throw a weapon
 594                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 595                 {
 596                         .entity went = weaponentities[slot];
 597                         SpawnThrownWeapon(this, this.origin + (this.mins + this.maxs) * 0.5, this.(went).m_weapon, went);
 598                 }
 599
 600                 // become fully visible
 601                 this.alpha = default_player_alpha;
 602                 // make the corpse upright (not tilted)
 603                 this.angles_x = 0;
 604                 this.angles_z = 0;
 605                 // don't spin
 606                 this.avelocity = '0 0 0';
 607                 // view from the floor
 608                 this.view_ofs = '0 0 -8';
 609                 // toss the corpse
 610                 set_movetype(this, MOVETYPE_TOSS);
 611                 // shootable corpse
 612                 this.solid = SOLID_CORPSE;
 613                 PS(this).ballistics_density = autocvar_g_ballistics_density_corpse;
 614                 // don't stick to the floor
 615                 UNSET_ONGROUND(this);
 616                 // dying animation
 617                 this.deadflag = DEAD_DYING;
 618
 619                 STAT(MOVEVARS_SPECIALCOMMAND, this) = false; // sweet release
 620
 621                 // when to allow respawn
 622                 calculate_player_respawn_time(this);
 623
 624                 this.death_time = time;
 625                 if (random() < 0.5)
 626                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD1, true);
 627                 else
 628                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD2, true);
 629                 if (this.maxs.z > 5)
 630                 {
 631                         this.maxs_z = 5;
 632                         setsize(this, this.mins, this.maxs);
 633                 }
 634                 // set damage function to corpse damage
 635                 this.event_damage = PlayerCorpseDamage;
 636                 // call the corpse damage function just in case it wants to gib
 637                 this.event_damage(this, inflictor, attacker, excess, deathtype, hitloc, force);
 638
 639                 // set up to fade out later
 640                 SUB_SetFade (this, time + 6 + random (), 1);
 641                 // reset body think wrapper broken by SUB_SetFade
 642                 if(this.classname == "body" && getthink(this) != CopyBody_Think) {
 643                         this.CopyBody_think = getthink(this);
 644                         this.CopyBody_nextthink = this.nextthink;
 645                         setthink(this, CopyBody_Think);
 646                         this.nextthink = time;
 647                 }
 648
 649                 if(autocvar_sv_gentle > 0 || autocvar_ekg || this.classname == "body") {
 650                         // remove corpse
 651                         // clones don't run any animation code any more, so we must gib them when they die :(
 652                         PlayerCorpseDamage(this, inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 653                 }
 654
 655                 // reset fields the weapons may use just in case
 656                 if(this.classname != "body")
 657                 {
 658                         FOREACH(Weapons, it != WEP_Null,
 659                         {
 660                                 it.wr_resetplayer(it, this);
 661                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 662                                 {
 663                                         ATTACK_FINISHED_FOR(this, it.m_id, slot) = 0;
 664                                 }
 665                         });
 666                 }
 667                 MUTATOR_CALLHOOK(PlayerDied, this);
 668         }
 669 }
 670
 671 bool MoveToTeam(entity client, int team_colour, int type)
 672 {
 673         int lockteams_backup = lockteams;  // backup any team lock
 674         lockteams = 0;  // disable locked teams
 675         TeamchangeFrags(client);  // move the players frags
 676         if (!SetPlayerTeamSimple(client, team_colour))
 677         {
 678                 return false;
 679         }
 680         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE.m_id, client.origin, '0 0 0');  // kill the player
 681         lockteams = lockteams_backup;  // restore the team lock
 682         LogTeamchange(client.playerid, client.team, type);
 683         return true;
 684 }
 685
 686 /** print(), but only print if the server is not local */
 687 void dedicated_print(string input)
 688 {
 689         if (server_is_dedicated) print(input);
 690 }
 691
 692 void PrintToChat(entity player, string text)
 693 {
 694         text = strcat("\{1}^7", text, "\n");
 695         sprint(player, text);
 696 }
 697
 698 void DebugPrintToChat(entity player, string text)
 699 {
 700         if (autocvar_developer)
 701         {
 702                 PrintToChat(player, text);
 703         }
 704 }
 705
 706 void PrintToChatAll(string text)
 707 {
 708         text = strcat("\{1}^7", text, "\n");
 709         bprint(text);
 710 }
 711
 712 void DebugPrintToChatAll(string text)
 713 {
 714         if (autocvar_developer)
 715         {
 716                 PrintToChatAll(text);
 717         }
 718 }
 719
 720 void PrintToChatTeam(int teamnum, string text)
 721 {
 722         text = strcat("\{1}^7", text, "\n");
 723         FOREACH_CLIENT(IS_REAL_CLIENT(it),
 724         {
 725                 if (it.team == teamnum)
 726                 {
 727                         sprint(it, text);
 728                 }
 729         });
 730 }
 731
 732 void DebugPrintToChatTeam(int teamnum, string text)
 733 {
 734         if (autocvar_developer)
 735         {
 736                 PrintToChatTeam(teamnum, text);
 737         }
 738 }
 739
 740 /**
 741  * message "": do not say, just test flood control
 742  * return value:
 743  *   1 = accept
 744  *   0 = reject
 745  *  -1 = fake accept
 746  */
 747 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
 748 {
 749         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
 750         msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
 751
 752     if(source)
 753                 msgin = formatmessage(source, msgin);
 754
 755     string colorstr;
 756         if (!IS_PLAYER(source))
 757                 colorstr = "^0"; // black for spectators
 758         else if(teamplay)
 759                 colorstr = Team_ColorCode(source.team);
 760         else
 761         {
 762                 colorstr = "";
 763                 teamsay = false;
 764         }
 765
 766         if(game_stopped)
 767                 teamsay = false;
 768
 769     if (!source) {
 770                 colorstr = "";
 771                 teamsay = false;
 772     }
 773
 774         if(msgin != "")
 775                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 776
 777         /*
 778          * using bprint solves this... me stupid
 779         // how can we prevent the message from appearing in a listen server?
 780         // for now, just give "say" back and only handle say_team
 781         if(!teamsay)
 782         {
 783                 clientcommand(source, strcat("say ", msgin));
 784                 return;
 785         }
 786         */
 787
 788     string namestr = "";
 789     if (source)
 790         namestr = playername(source, autocvar_g_chat_teamcolors);
 791
 792     string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
 793
 794     string msgstr, cmsgstr;
 795     string privatemsgprefix = string_null;
 796     int privatemsgprefixlen = 0;
 797         if (msgin == "") {
 798         msgstr = cmsgstr = "";
 799         } else {
 800                 if(privatesay)
 801                 {
 802                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 803                         privatemsgprefixlen = strlen(msgstr);
 804                         msgstr = strcat(msgstr, msgin);
 805                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 806                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
 807                 }
 808                 else if(teamsay)
 809                 {
 810                         if(strstrofs(msgin, "/me", 0) >= 0)
 811                         {
 812                                 //msgin = strreplace("/me", "", msgin);
 813                                 //msgin = substring(msgin, 3, strlen(msgin));
 814                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
 815                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
 816                         }
 817                         else
 818                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 819                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 820                 }
 821                 else
 822                 {
 823                         if(strstrofs(msgin, "/me", 0) >= 0)
 824                         {
 825                                 //msgin = strreplace("/me", "", msgin);
 826                                 //msgin = substring(msgin, 3, strlen(msgin));
 827                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
 828                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
 829                         }
 830                         else {
 831                 msgstr = "\{1}";
 832                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
 833                 msgstr = strcat(msgstr, msgin);
 834             }
 835                         cmsgstr = "";
 836                 }
 837                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 838         }
 839
 840         string fullmsgstr = msgstr;
 841         string fullcmsgstr = cmsgstr;
 842
 843         // FLOOD CONTROL
 844         int flood = 0;
 845         var .float flood_field = floodcontrol_chat;
 846         if(floodcontrol && source)
 847         {
 848                 float flood_spl;
 849                 float flood_burst;
 850                 float flood_lmax;
 851                 float lines;
 852                 if(privatesay)
 853                 {
 854                         flood_spl = autocvar_g_chat_flood_spl_tell;
 855                         flood_burst = autocvar_g_chat_flood_burst_tell;
 856                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 857                         flood_field = floodcontrol_chattell;
 858                 }
 859                 else if(teamsay)
 860                 {
 861                         flood_spl = autocvar_g_chat_flood_spl_team;
 862                         flood_burst = autocvar_g_chat_flood_burst_team;
 863                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 864                         flood_field = floodcontrol_chatteam;
 865                 }
 866                 else
 867                 {
 868                         flood_spl = autocvar_g_chat_flood_spl;
 869                         flood_burst = autocvar_g_chat_flood_burst;
 870                         flood_lmax = autocvar_g_chat_flood_lmax;
 871                         flood_field = floodcontrol_chat;
 872                 }
 873                 flood_burst = max(0, flood_burst - 1);
 874                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 875
 876                 // do flood control for the default line size
 877                 if(msgstr != "")
 878                 {
 879                         getWrappedLine_remaining = msgstr;
 880                         msgstr = "";
 881                         lines = 0;
 882                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 883                         {
 884                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 885                                 ++lines;
 886                         }
 887                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 888
 889                         if(getWrappedLine_remaining != "")
 890                         {
 891                                 msgstr = strcat(msgstr, "\n");
 892                                 flood = 2;
 893                         }
 894
 895                         if (time >= source.(flood_field))
 896                         {
 897                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
 898                         }
 899                         else
 900                         {
 901                                 flood = 1;
 902                                 msgstr = fullmsgstr;
 903                         }
 904                 }
 905                 else
 906                 {
 907                         if (time >= source.(flood_field))
 908                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
 909                         else
 910                                 flood = 1;
 911                 }
 912
 913                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 914                         source.(flood_field) = flood = 0;
 915         }
 916
 917     string sourcemsgstr, sourcecmsgstr;
 918         if(flood == 2) // cannot happen for empty msgstr
 919         {
 920                 if(autocvar_g_chat_flood_notify_flooder)
 921                 {
 922                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 923                         sourcecmsgstr = "";
 924                 }
 925                 else
 926                 {
 927                         sourcemsgstr = fullmsgstr;
 928                         sourcecmsgstr = fullcmsgstr;
 929                 }
 930                 cmsgstr = "";
 931         }
 932         else
 933         {
 934                 sourcemsgstr = msgstr;
 935                 sourcecmsgstr = cmsgstr;
 936         }
 937
 938         if (!privatesay && source && !IS_PLAYER(source))
 939         {
 940                 if (!game_stopped)
 941                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
 942                         teamsay = -1; // spectators
 943         }
 944
 945         if(flood)
 946                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
 947
 948         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 949         if(privatesay)
 950                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 951
 952     int ret;
 953         if(source && CS(source).muted)
 954         {
 955                 // always fake the message
 956                 ret = -1;
 957         }
 958         else if(flood == 1)
 959         {
 960                 if (autocvar_g_chat_flood_notify_flooder)
 961                 {
 962                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
 963                         ret = 0;
 964                 }
 965                 else
 966                         ret = -1;
 967         }
 968         else
 969         {
 970                 ret = 1;
 971         }
 972
 973         if (privatesay && source && !IS_PLAYER(source))
 974         {
 975                 if (!game_stopped)
 976                 if ((privatesay && !IS_PLAYER(privatesay)) || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
 977                         ret = -1; // just hide the message completely
 978         }
 979
 980         MUTATOR_CALLHOOK(ChatMessage, source, ret);
 981         ret = M_ARGV(1, int);
 982
 983         if(sourcemsgstr != "" && ret != 0)
 984         {
 985                 if(ret < 0) // faked message, because the player is muted
 986                 {
 987                         sprint(source, sourcemsgstr);
 988                         if(sourcecmsgstr != "" && !privatesay)
 989                                 centerprint(source, sourcecmsgstr);
 990                 }
 991                 else if(privatesay) // private message, between 2 people only
 992                 {
 993                         sprint(source, sourcemsgstr);
 994                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 995                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
 996                         {
 997                                 sprint(privatesay, msgstr);
 998                                 if(cmsgstr != "")
 999                                         centerprint(privatesay, cmsgstr);
1000                         }
1001                 }
1002                 else if ( teamsay && CS(source).active_minigame )
1003                 {
1004                         sprint(source, sourcemsgstr);
1005                         dedicated_print(msgstr); // send to server console too
1006                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1007                 }
1008                 else if(teamsay > 0) // team message, only sent to team mates
1009                 {
1010                         sprint(source, sourcemsgstr);
1011                         dedicated_print(msgstr); // send to server console too
1012                         if(sourcecmsgstr != "")
1013                                 centerprint(source, sourcecmsgstr);
1014                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
1015                                 sprint(it, msgstr);
1016                                 if(cmsgstr != "")
1017                                         centerprint(it, cmsgstr);
1018                         });
1019                 }
1020                 else if(teamsay < 0) // spectator message, only sent to spectators
1021                 {
1022                         sprint(source, sourcemsgstr);
1023                         dedicated_print(msgstr); // send to server console too
1024                         FOREACH_CLIENT(!IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1025                 }
1026                 else
1027                 {
1028             if (source) {
1029                 sprint(source, sourcemsgstr);
1030                 dedicated_print(msgstr); // send to server console too
1031                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
1032             }
1033             FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1034         }
1035         }
1036
1037         return ret;
1038 }