qcsrc/server/player.qc

   1 #include "player.qh"
   2
   3 #include "bot/api.qh"
   4 #include "cheats.qh"
   5 #include "g_damage.qh"
   6 #include "g_subs.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "weapons/throwing.qh"
  11 #include "command/common.qh"
  12 #include "../common/state.qh"
  13 #include "../common/anim.qh"
  14 #include "../common/animdecide.qh"
  15 #include "../common/csqcmodel_settings.qh"
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/triggers/subs.qh"
  18 #include "../common/playerstats.qh"
  19 #include "../lib/csqcmodel/sv_model.qh"
  20
  21 #include "../common/minigames/sv_minigames.qh"
  22
  23 #include "../common/physics/player.qh"
  24 #include "../common/effects/qc/all.qh"
  25 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  26 #include "../common/triggers/include.qh"
  27 #include "../common/wepent.qh"
  28
  29 #include "weapons/weaponstats.qh"
  30
  31 #include "../common/animdecide.qh"
  32
  33 void Drop_Special_Items(entity player)
  34 {
  35         // called when the player has become stuck or frozen
  36         // so objective items aren't stuck with the player
  37
  38         MUTATOR_CALLHOOK(DropSpecialItems, player);
  39 }
  40
  41 void CopyBody_Think(entity this)
  42 {
  43         if(this.CopyBody_nextthink && time > this.CopyBody_nextthink)
  44         {
  45                 this.CopyBody_think(this);
  46                 if(wasfreed(this))
  47                         return;
  48                 this.CopyBody_nextthink = this.nextthink;
  49                 this.CopyBody_think = getthink(this);
  50                 setthink(this, CopyBody_Think);
  51         }
  52         CSQCMODEL_AUTOUPDATE(this);
  53         this.nextthink = time;
  54 }
  55 void CopyBody(entity this, float keepvelocity)
  56 {
  57         if (this.effects & EF_NODRAW)
  58                 return;
  59         entity clone = new(body);
  60         clone.enemy = this;
  61         clone.lip = this.lip;
  62         clone.colormap = this.colormap;
  63         clone.iscreature = this.iscreature;
  64         clone.teleportable = this.teleportable;
  65         clone.damagedbycontents = this.damagedbycontents;
  66         if(clone.damagedbycontents)
  67                 IL_PUSH(g_damagedbycontents, clone);
  68         clone.angles = this.angles;
  69         clone.v_angle = this.v_angle;
  70         clone.avelocity = this.avelocity;
  71         clone.damageforcescale = this.damageforcescale;
  72         clone.effects = this.effects;
  73         clone.glowmod = this.glowmod;
  74         clone.event_damage = this.event_damage;
  75         clone.anim_state = this.anim_state;
  76         clone.anim_time = this.anim_time;
  77         clone.anim_lower_action = this.anim_lower_action;
  78         clone.anim_lower_time = this.anim_lower_time;
  79         clone.anim_upper_action = this.anim_upper_action;
  80         clone.anim_upper_time = this.anim_upper_time;
  81         clone.anim_implicit_state = this.anim_implicit_state;
  82         clone.anim_implicit_time = this.anim_implicit_time;
  83         clone.anim_lower_implicit_action = this.anim_lower_implicit_action;
  84         clone.anim_lower_implicit_time = this.anim_lower_implicit_time;
  85         clone.anim_upper_implicit_action = this.anim_upper_implicit_action;
  86         clone.anim_upper_implicit_time = this.anim_upper_implicit_time;
  87         clone.dphitcontentsmask = this.dphitcontentsmask;
  88         clone.death_time = this.death_time;
  89         clone.pain_finished = this.pain_finished;
  90         clone.health = this.health;
  91         clone.armorvalue = this.armorvalue;
  92         clone.armortype = this.armortype;
  93         clone.model = this.model;
  94         clone.modelindex = this.modelindex;
  95         clone.skin = this.skin;
  96         clone.species = this.species;
  97         clone.move_qcphysics = false; // don't run gamecode logic on clones, too many
  98         set_movetype(clone, this.move_movetype);
  99         clone.solid = this.solid;
 100         clone.ballistics_density = this.ballistics_density;
 101         clone.takedamage = this.takedamage;
 102         setcefc(clone, getcefc(this));
 103         clone.uncustomizeentityforclient = this.uncustomizeentityforclient;
 104         clone.uncustomizeentityforclient_set = this.uncustomizeentityforclient_set;
 105         if (keepvelocity == 1)
 106                 clone.velocity = this.velocity;
 107         clone.oldvelocity = clone.velocity;
 108         clone.alpha = this.alpha;
 109         clone.fade_time = this.fade_time;
 110         clone.fade_rate = this.fade_rate;
 111         //clone.weapon = this.weapon;
 112         setorigin(clone, this.origin);
 113         setsize(clone, this.mins, this.maxs);
 114         clone.prevorigin = this.origin;
 115         clone.reset = SUB_Remove;
 116         clone._ps = this._ps;
 117
 118         Drag_MoveDrag(this, clone);
 119
 120         if(clone.colormap <= maxclients && clone.colormap > 0)
 121                 clone.colormap = 1024 + this.clientcolors;
 122
 123         CSQCMODEL_AUTOINIT(clone);
 124         clone.CopyBody_nextthink = this.nextthink;
 125         clone.CopyBody_think = getthink(this);
 126         clone.nextthink = time;
 127         setthink(clone, CopyBody_Think);
 128         // "bake" the current animation frame for clones (they don't get clientside animation)
 129         animdecide_load_if_needed(clone);
 130         animdecide_setframes(clone, false, frame, frame1time, frame2, frame2time);
 131
 132         IL_PUSH(g_clones, clone);
 133
 134         MUTATOR_CALLHOOK(CopyBody, this, clone, keepvelocity);
 135 }
 136
 137 void player_setupanimsformodel(entity this)
 138 {
 139         // load animation info
 140         animdecide_load_if_needed(this);
 141         animdecide_setstate(this, 0, false);
 142 }
 143
 144 void player_anim(entity this)
 145 {
 146         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 147         if(IS_DEAD(this)) {
 148                 if (!deadbits) {
 149                         // Decide on which death animation to use.
 150                         if(random() < 0.5)
 151                                 deadbits = ANIMSTATE_DEAD1;
 152                         else
 153                                 deadbits = ANIMSTATE_DEAD2;
 154                 }
 155         } else {
 156                 // Clear a previous death animation.
 157                 deadbits = 0;
 158         }
 159         int animbits = deadbits;
 160         if(STAT(FROZEN, this))
 161                 animbits |= ANIMSTATE_FROZEN;
 162         if(this.move_movetype == MOVETYPE_FOLLOW)
 163                 animbits |= ANIMSTATE_FOLLOW;
 164         if(this.crouch)
 165                 animbits |= ANIMSTATE_DUCK;
 166         animdecide_setstate(this, animbits, false);
 167         animdecide_setimplicitstate(this, IS_ONGROUND(this));
 168 }
 169
 170 void PlayerCorpseDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 171 {
 172         float take, save;
 173         vector v;
 174         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 175
 176         // damage resistance (ignore most of the damage from a bullet or similar)
 177         damage = max(damage - 5, 1);
 178
 179         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 180         take = v.x;
 181         save = v.y;
 182
 183         if(sound_allowed(MSG_BROADCAST, attacker))
 184         {
 185                 if (save > 10)
 186                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 187                 else if (take > 30)
 188                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 189                 else if (take > 10)
 190                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM);
 191         }
 192
 193         if (take > 50)
 194                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 195         if (take > 100)
 196                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 197
 198         this.armorvalue = this.armorvalue - save;
 199         this.health = this.health - take;
 200         // pause regeneration for 5 seconds
 201         this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 202
 203         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 204         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 205         this.dmg_inflictor = inflictor;
 206
 207         if (this.health <= -autocvar_sv_gibhealth && this.alpha >= 0)
 208         {
 209                 // don't use any animations as a gib
 210                 this.frame = 0;
 211                 // view just above the floor
 212                 this.view_ofs = '0 0 4';
 213
 214                 Violence_GibSplash(this, 1, 1, attacker);
 215                 this.alpha = -1;
 216                 this.solid = SOLID_NOT; // restore later
 217                 this.takedamage = DAMAGE_NO; // restore later
 218                 if(this.damagedbycontents)
 219                         IL_REMOVE(g_damagedbycontents, this);
 220                 this.damagedbycontents = false;
 221         }
 222 }
 223
 224 void calculate_player_respawn_time(entity this)
 225 {
 226         if(g_ca)
 227                 return;
 228
 229         float gametype_setting_tmp;
 230         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 231         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 232         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 233         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 234         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 235         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 236
 237         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 238         if (teamplay)
 239         {
 240                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 241                         if(it.team == this.team)
 242                                 ++pcount;
 243                 ));
 244                 if (sdelay_small_count == 0)
 245                         sdelay_small_count = 1;
 246                 if (sdelay_large_count == 0)
 247                         sdelay_large_count = 1;
 248         }
 249         else
 250         {
 251                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 252                         ++pcount;
 253                 ));
 254                 if (sdelay_small_count == 0)
 255                 {
 256                         if (g_cts)
 257                         {
 258                                 // Players play independently. No point in requiring enemies.
 259                                 sdelay_small_count = 1;
 260                         }
 261                         else
 262                         {
 263                                 // Players play AGAINST each other. Enemies required.
 264                                 sdelay_small_count = 2;
 265                         }
 266                 }
 267                 if (sdelay_large_count == 0)
 268                 {
 269                         if (g_cts)
 270                         {
 271                                 // Players play independently. No point in requiring enemies.
 272                                 sdelay_large_count = 1;
 273                         }
 274                         else
 275                         {
 276                                 // Players play AGAINST each other. Enemies required.
 277                                 sdelay_large_count = 2;
 278                         }
 279                 }
 280         }
 281
 282         float sdelay;
 283
 284         if (pcount <= sdelay_small_count)
 285                 sdelay = sdelay_small;
 286         else if (pcount >= sdelay_large_count)
 287                 sdelay = sdelay_large;
 288         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 289                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 290
 291         if(waves)
 292                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
 293         else
 294                 this.respawn_time = time + sdelay;
 295
 296         if(sdelay < sdelay_max)
 297                 this.respawn_time_max = time + sdelay_max;
 298         else
 299                 this.respawn_time_max = this.respawn_time;
 300
 301         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
 302                 this.respawn_countdown = 10; // first number to count down from is 10
 303         else
 304                 this.respawn_countdown = -1; // do not count down
 305
 306         if(autocvar_g_forced_respawn)
 307                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
 308 }
 309
 310 void PlayerDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 311 {
 312         float take, save, dh, da;
 313         vector v;
 314         float valid_damage_for_weaponstats;
 315         float excess;
 316
 317         dh = max(this.health, 0);
 318         da = max(this.armorvalue, 0);
 319
 320         if(!DEATH_ISSPECIAL(deathtype))
 321         {
 322                 damage *= sqrt(bound(1.0, this.cvar_cl_handicap, 100.0));
 323                 if(this != attacker)
 324                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 325         }
 326
 327         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 328         {
 329                 // tuba causes blood to come out of the ears
 330                 vector ear1, ear2;
 331                 vector d;
 332                 float f;
 333                 ear1 = this.origin;
 334                 ear1_z += 0.125 * this.view_ofs.z + 0.875 * this.maxs.z; // 7/8
 335                 ear2 = ear1;
 336                 makevectors(this.angles);
 337                 ear1 += v_right * -10;
 338                 ear2 += v_right * +10;
 339                 d = inflictor.origin - this.origin;
 340                 if (d)
 341                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 342                 else
 343                         f = 0;  // Assum ecenter.
 344                 force = v_right * vlen(force);
 345                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), this, attacker);
 346                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), this, attacker);
 347                 if(f > 0)
 348                 {
 349                         hitloc = ear1;
 350                         force = force * -1;
 351                 }
 352                 else
 353                 {
 354                         hitloc = ear2;
 355                         // force is already good
 356                 }
 357         }
 358         else
 359                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 360
 361
 362         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 363         take = v.x;
 364         save = v.y;
 365
 366         if(attacker == this)
 367         {
 368                 // don't reset pushltime for this damage as it may be an attempt to
 369                 // escape a lava pit or similar
 370                 //this.pushltime = 0;
 371                 this.istypefrag = 0;
 372         }
 373         else if(IS_PLAYER(attacker))
 374         {
 375                 this.pusher = attacker;
 376                 this.pushltime = time + autocvar_g_maxpushtime;
 377                 this.istypefrag = PHYS_INPUT_BUTTON_CHAT(this);
 378         }
 379         else if(time < this.pushltime)
 380         {
 381                 attacker = this.pusher;
 382                 this.pushltime = max(this.pushltime, time + 0.6);
 383         }
 384         else
 385         {
 386                 this.pushltime = 0;
 387                 this.istypefrag = 0;
 388         }
 389
 390         if (time < this.spawnshieldtime && autocvar_g_spawnshield_blockdamage < 1)
 391         {
 392                 vector v = healtharmor_applydamage(this.armorvalue, max(0, autocvar_g_spawnshield_blockdamage), deathtype, damage);
 393                 take = v.x;
 394                 save = v.y;
 395         }
 396
 397         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor, inflictor, attacker, this, force, take, save, deathtype, damage);
 398         take = bound(0, M_ARGV(4, float), this.health);
 399         save = bound(0, M_ARGV(5, float), this.armorvalue);
 400         excess = max(0, damage - take - save);
 401
 402         if(sound_allowed(MSG_BROADCAST, attacker))
 403         {
 404                 if (save > 10)
 405                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 406                 else if (take > 30)
 407                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 408                 else if (take > 10)
 409                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 410         }
 411
 412         if (take > 50)
 413                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 414         if (take > 100)
 415                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 416
 417         if (time >= this.spawnshieldtime || autocvar_g_spawnshield_blockdamage < 1)
 418         {
 419                 if (!(this.flags & FL_GODMODE))
 420                 {
 421                         this.armorvalue = this.armorvalue - save;
 422                         this.health = this.health - take;
 423                         // pause regeneration for 5 seconds
 424                         if(take)
 425                                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 426
 427                         if (time > this.pain_finished)          //Don't switch pain sequences like crazy
 428                         {
 429                                 this.pain_finished = time + 0.5;        //Supajoe
 430
 431                                 if(autocvar_sv_gentle < 1) {
 432                                         if(this.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 433                                         {
 434                                                 if (!this.animstate_override)
 435                                                 {
 436                                                         if (random() > 0.5)
 437                                                                 animdecide_setaction(this, ANIMACTION_PAIN1, true);
 438                                                         else
 439                                                                 animdecide_setaction(this, ANIMACTION_PAIN2, true);
 440                                                 }
 441                                         }
 442
 443                                         if(sound_allowed(MSG_BROADCAST, attacker))
 444                                         if((this.health < 2 * WEP_CVAR_PRI(blaster, damage) * autocvar_g_balance_selfdamagepercent + 1) || !(DEATH_WEAPONOF(deathtype).spawnflags & WEP_FLAG_CANCLIMB) || attacker != this) // WEAPONTODO: create separate limit for pain notification with laser
 445                                         if(this.health > 1)
 446                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 447                                         {
 448                                                 if(deathtype == DEATH_FALL.m_id)
 449                                                         PlayerSound(this, playersound_fall, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 450                                                 else if(this.health > 75)
 451                                                         PlayerSound(this, playersound_pain100, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 452                                                 else if(this.health > 50)
 453                                                         PlayerSound(this, playersound_pain75, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 454                                                 else if(this.health > 25)
 455                                                         PlayerSound(this, playersound_pain50, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 456                                                 else
 457                                                         PlayerSound(this, playersound_pain25, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 458                                         }
 459                                 }
 460                         }
 461
 462                         // throw off bot aim temporarily
 463                         float shake;
 464                         if(IS_BOT_CLIENT(this) && this.health >= 1)
 465                         {
 466                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 467                                 this.v_angle_x = this.v_angle.x + (random() * 2 - 1) * shake;
 468                                 this.v_angle_y = this.v_angle.y + (random() * 2 - 1) * shake;
 469                                 this.v_angle_x = bound(-90, this.v_angle.x, 90);
 470                         }
 471                 }
 472                 else
 473                         this.max_armorvalue += (save + take);
 474         }
 475         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 476         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 477         this.dmg_inflictor = inflictor;
 478
 479         if (this != attacker) {
 480                 float realdmg = damage - excess;
 481                 if (IS_PLAYER(attacker)) {
 482                         PlayerScore_Add(attacker, SP_DMG, realdmg);
 483                 }
 484                 if (IS_PLAYER(this)) {
 485                         PlayerScore_Add(this, SP_DMGTAKEN, realdmg);
 486                 }
 487         }
 488
 489         bool abot = (IS_BOT_CLIENT(attacker));
 490         bool vbot = (IS_BOT_CLIENT(this));
 491
 492         valid_damage_for_weaponstats = 0;
 493         Weapon awep = WEP_Null;
 494         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 495
 496         if(vbot || IS_REAL_CLIENT(this))
 497         if(abot || IS_REAL_CLIENT(attacker))
 498         if(attacker && this != attacker)
 499         if(DIFF_TEAM(this, attacker))
 500         {
 501                 if(DEATH_ISSPECIAL(deathtype))
 502                         awep = attacker.(weaponentity).m_weapon;
 503                 else
 504                         awep = DEATH_WEAPONOF(deathtype);
 505                 valid_damage_for_weaponstats = 1;
 506         }
 507
 508         dh = dh - max(this.health, 0);
 509         da = da - max(this.armorvalue, 0);
 510         if(valid_damage_for_weaponstats)
 511         {
 512                 WeaponStats_LogDamage(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot, dh + da);
 513         }
 514         if (dh + da)
 515         {
 516                 MUTATOR_CALLHOOK(PlayerDamaged, attacker, this, dh, da, hitloc, deathtype);
 517         }
 518
 519         if (this.health < 1)
 520         {
 521                 float defer_ClientKill_Now_TeamChange;
 522                 defer_ClientKill_Now_TeamChange = false;
 523
 524                 if(this.alivetime)
 525                 {
 526                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 527                         this.alivetime = 0;
 528                 }
 529
 530                 if(valid_damage_for_weaponstats)
 531                         WeaponStats_LogKill(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot);
 532
 533                 if(autocvar_sv_gentle < 1)
 534                 if(sound_allowed(MSG_BROADCAST, attacker))
 535                 {
 536                         if(deathtype == DEATH_DROWN.m_id)
 537                                 PlayerSound(this, playersound_drown, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 538                         else
 539                                 PlayerSound(this, playersound_death, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 540                 }
 541
 542                 // get rid of kill indicator
 543                 if(this.killindicator)
 544                 {
 545                         delete(this.killindicator);
 546                         this.killindicator = NULL;
 547                         if(this.killindicator_teamchange)
 548                                 defer_ClientKill_Now_TeamChange = true;
 549
 550                         if(this.classname == "body")
 551                         if(deathtype == DEATH_KILL.m_id)
 552                         {
 553                                 // for the lemmings fans, a small harmless explosion
 554                                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 555                         }
 556                 }
 557
 558                 // print an obituary message
 559                 if(this.classname != "body")
 560                         Obituary (attacker, inflictor, this, deathtype);
 561
 562         // increment frag counter for used weapon type
 563         Weapon w = DEATH_WEAPONOF(deathtype);
 564                 if(w != WEP_Null && accuracy_isgooddamage(attacker, this))
 565                         attacker.accuracy.(accuracy_frags[w.m_id-1]) += 1;
 566
 567                 MUTATOR_CALLHOOK(PlayerDies, inflictor, attacker, this, deathtype, damage);
 568                 excess = M_ARGV(4, float);
 569
 570                 Weapon wep = this.(weaponentity).m_weapon;
 571                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 572                 {
 573                         .entity went = weaponentities[slot];
 574                         wep.wr_playerdeath(wep, this, went);
 575                 }
 576
 577                 RemoveGrapplingHooks(this);
 578
 579                 Portal_ClearAllLater(this);
 580
 581                 this.fixangle = true;
 582
 583                 if(defer_ClientKill_Now_TeamChange)
 584                         ClientKill_Now_TeamChange(this); // can turn player into spectator
 585
 586                 // player could have been miraculously resuscitated ;)
 587                 // e.g. players in freezetag get frozen, they don't really die
 588                 if(this.health >= 1 || !(IS_PLAYER(this) || this.classname == "body"))
 589                         return;
 590
 591                 // when we get here, player actually dies
 592
 593                 Unfreeze(this); // remove any icy remains
 594                 this.health = 0; // Unfreeze resets health, so we need to set it back
 595
 596                 // clear waypoints
 597                 WaypointSprite_PlayerDead(this);
 598                 // throw a weapon
 599                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 600                 {
 601                         .entity went = weaponentities[slot];
 602                         SpawnThrownWeapon(this, this.origin + (this.mins + this.maxs) * 0.5, this.(went).m_switchweapon.m_id, went);
 603                 }
 604
 605                 // become fully visible
 606                 this.alpha = default_player_alpha;
 607                 // make the corpse upright (not tilted)
 608                 this.angles_x = 0;
 609                 this.angles_z = 0;
 610                 // don't spin
 611                 this.avelocity = '0 0 0';
 612                 // view from the floor
 613                 this.view_ofs = '0 0 -8';
 614                 // toss the corpse
 615                 set_movetype(this, MOVETYPE_TOSS);
 616                 // shootable corpse
 617                 this.solid = SOLID_CORPSE;
 618                 this.ballistics_density = autocvar_g_ballistics_density_corpse;
 619                 // don't stick to the floor
 620                 UNSET_ONGROUND(this);
 621                 // dying animation
 622                 this.deadflag = DEAD_DYING;
 623
 624                 // when to allow respawn
 625                 calculate_player_respawn_time(this);
 626
 627                 this.death_time = time;
 628                 if (random() < 0.5)
 629                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD1, true);
 630                 else
 631                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD2, true);
 632                 if (this.maxs.z > 5)
 633                 {
 634                         this.maxs_z = 5;
 635                         setsize(this, this.mins, this.maxs);
 636                 }
 637                 // set damage function to corpse damage
 638                 this.event_damage = PlayerCorpseDamage;
 639                 // call the corpse damage function just in case it wants to gib
 640                 this.event_damage(this, inflictor, attacker, excess, deathtype, hitloc, force);
 641
 642                 // set up to fade out later
 643                 SUB_SetFade (this, time + 6 + random (), 1);
 644                 // reset body think wrapper broken by SUB_SetFade
 645                 if(this.classname == "body" && getthink(this) != CopyBody_Think) {
 646                         this.CopyBody_think = getthink(this);
 647                         this.CopyBody_nextthink = this.nextthink;
 648                         setthink(this, CopyBody_Think);
 649                         this.nextthink = time;
 650                 }
 651
 652                 if(autocvar_sv_gentle > 0 || autocvar_ekg || this.classname == "body") {
 653                         // remove corpse
 654                         // clones don't run any animation code any more, so we must gib them when they die :(
 655                         PlayerCorpseDamage(this, inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 656                 }
 657
 658                 // reset fields the weapons may use just in case
 659                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 660                         it.wr_resetplayer(it, this);
 661                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 662                         {
 663                                 ATTACK_FINISHED_FOR(this, it.m_id, slot) = 0;
 664                         }
 665                 ));
 666         }
 667 }
 668
 669 void MoveToTeam(entity client, int team_colour, int type)
 670 {
 671         int lockteams_backup = lockteams;  // backup any team lock
 672         lockteams = 0;  // disable locked teams
 673         TeamchangeFrags(client);  // move the players frags
 674         SetPlayerColors(client, team_colour - 1);  // set the players colour
 675         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE.m_id, client.origin, '0 0 0');  // kill the player
 676         lockteams = lockteams_backup;  // restore the team lock
 677         LogTeamchange(client.playerid, client.team, type);
 678 }
 679
 680 /** print(), but only print if the server is not local */
 681 void dedicated_print(string input)
 682 {
 683         if (server_is_dedicated) print(input);
 684 }
 685
 686 /**
 687  * message "": do not say, just test flood control
 688  * return value:
 689  *   1 = accept
 690  *   0 = reject
 691  *  -1 = fake accept
 692  */
 693 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
 694 {
 695         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
 696         msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
 697
 698         msgin = formatmessage(source, msgin);
 699
 700     string colorstr;
 701         if (!IS_PLAYER(source))
 702                 colorstr = "^0"; // black for spectators
 703         else if(teamplay)
 704                 colorstr = Team_ColorCode(source.team);
 705         else
 706         {
 707                 colorstr = "";
 708                 teamsay = false;
 709         }
 710
 711         if(intermission_running)
 712                 teamsay = false;
 713
 714     if (!source) {
 715                 colorstr = "";
 716                 teamsay = false;
 717     }
 718
 719         if(msgin != "")
 720                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 721
 722         /*
 723          * using bprint solves this... me stupid
 724         // how can we prevent the message from appearing in a listen server?
 725         // for now, just give "say" back and only handle say_team
 726         if(!teamsay)
 727         {
 728                 clientcommand(source, strcat("say ", msgin));
 729                 return;
 730         }
 731         */
 732
 733     string namestr = "";
 734     if (source)
 735         namestr = autocvar_g_chat_teamcolors ? playername(source) : source.netname;
 736
 737     string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
 738
 739     string msgstr, cmsgstr;
 740     string privatemsgprefix = string_null;
 741     int privatemsgprefixlen = 0;
 742         if (msgin == "") {
 743         msgstr = cmsgstr = "";
 744         } else {
 745                 if(privatesay)
 746                 {
 747                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 748                         privatemsgprefixlen = strlen(msgstr);
 749                         msgstr = strcat(msgstr, msgin);
 750                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 751                         if(autocvar_g_chat_teamcolors)
 752                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 753                         else
 754                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 755                 }
 756                 else if(teamsay)
 757                 {
 758                         if(strstrofs(msgin, "/me", 0) >= 0)
 759                         {
 760                                 //msgin = strreplace("/me", "", msgin);
 761                                 //msgin = substring(msgin, 3, strlen(msgin));
 762                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
 763                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
 764                         }
 765                         else
 766                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 767                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 768                 }
 769                 else
 770                 {
 771                         if(strstrofs(msgin, "/me", 0) >= 0)
 772                         {
 773                                 //msgin = strreplace("/me", "", msgin);
 774                                 //msgin = substring(msgin, 3, strlen(msgin));
 775                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
 776                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
 777                         }
 778                         else {
 779                 msgstr = "\{1}";
 780                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
 781                 msgstr = strcat(msgstr, msgin);
 782             }
 783                         cmsgstr = "";
 784                 }
 785                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 786         }
 787
 788         string fullmsgstr = msgstr;
 789         string fullcmsgstr = cmsgstr;
 790
 791         // FLOOD CONTROL
 792         int flood = 0;
 793         var .float flood_field = floodcontrol_chat;
 794         if(floodcontrol)
 795         {
 796                 float flood_spl;
 797                 float flood_burst;
 798                 float flood_lmax;
 799                 float lines;
 800                 if(privatesay)
 801                 {
 802                         flood_spl = autocvar_g_chat_flood_spl_tell;
 803                         flood_burst = autocvar_g_chat_flood_burst_tell;
 804                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 805                         flood_field = floodcontrol_chattell;
 806                 }
 807                 else if(teamsay)
 808                 {
 809                         flood_spl = autocvar_g_chat_flood_spl_team;
 810                         flood_burst = autocvar_g_chat_flood_burst_team;
 811                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 812                         flood_field = floodcontrol_chatteam;
 813                 }
 814                 else
 815                 {
 816                         flood_spl = autocvar_g_chat_flood_spl;
 817                         flood_burst = autocvar_g_chat_flood_burst;
 818                         flood_lmax = autocvar_g_chat_flood_lmax;
 819                         flood_field = floodcontrol_chat;
 820                 }
 821                 flood_burst = max(0, flood_burst - 1);
 822                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 823
 824                 // do flood control for the default line size
 825                 if(msgstr != "")
 826                 {
 827                         getWrappedLine_remaining = msgstr;
 828                         msgstr = "";
 829                         lines = 0;
 830                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 831                         {
 832                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 833                                 ++lines;
 834                         }
 835                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 836
 837                         if(getWrappedLine_remaining != "")
 838                         {
 839                                 msgstr = strcat(msgstr, "\n");
 840                                 flood = 2;
 841                         }
 842
 843                         if (time >= source.(flood_field))
 844                         {
 845                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
 846                         }
 847                         else
 848                         {
 849                                 flood = 1;
 850                                 msgstr = fullmsgstr;
 851                         }
 852                 }
 853                 else
 854                 {
 855                         if (time >= source.(flood_field))
 856                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
 857                         else
 858                                 flood = 1;
 859                 }
 860
 861                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 862                         source.(flood_field) = flood = 0;
 863         }
 864
 865     string sourcemsgstr, sourcecmsgstr;
 866         if(flood == 2) // cannot happen for empty msgstr
 867         {
 868                 if(autocvar_g_chat_flood_notify_flooder)
 869                 {
 870                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 871                         sourcecmsgstr = "";
 872                 }
 873                 else
 874                 {
 875                         sourcemsgstr = fullmsgstr;
 876                         sourcecmsgstr = fullcmsgstr;
 877                 }
 878                 cmsgstr = "";
 879         }
 880         else
 881         {
 882                 sourcemsgstr = msgstr;
 883                 sourcecmsgstr = cmsgstr;
 884         }
 885
 886         if (!privatesay && source && !IS_PLAYER(source))
 887         {
 888                 if (!intermission_running)
 889                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 890                                 teamsay = -1; // spectators
 891         }
 892
 893         if(flood)
 894                 LOG_INFO("NOTE: ", playername(source), "^7 is flooding.\n");
 895
 896         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 897         if(privatesay)
 898                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 899
 900     int ret;
 901         if(source.muted)
 902         {
 903                 // always fake the message
 904                 ret = -1;
 905         }
 906         else if(flood == 1)
 907         {
 908                 if (autocvar_g_chat_flood_notify_flooder)
 909                 {
 910                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
 911                         ret = 0;
 912                 }
 913                 else
 914                         ret = -1;
 915         }
 916         else
 917         {
 918                 ret = 1;
 919         }
 920
 921         if(sourcemsgstr != "" && ret != 0)
 922         {
 923                 if(ret < 0) // faked message, because the player is muted
 924                 {
 925                         sprint(source, sourcemsgstr);
 926                         if(sourcecmsgstr != "" && !privatesay)
 927                                 centerprint(source, sourcecmsgstr);
 928                 }
 929                 else if(privatesay) // private message, between 2 people only
 930                 {
 931                         sprint(source, sourcemsgstr);
 932                         sprint(privatesay, msgstr);
 933                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 934                         if(cmsgstr != "")
 935                                 centerprint(privatesay, cmsgstr);
 936                 }
 937                 else if ( teamsay && source.active_minigame )
 938                 {
 939                         sprint(source, sourcemsgstr);
 940                         dedicated_print(msgstr); // send to server console too
 941                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && it.active_minigame == source.active_minigame, sprint(it, msgstr));
 942                 }
 943                 else if(teamsay > 0) // team message, only sent to team mates
 944                 {
 945                         sprint(source, sourcemsgstr);
 946                         dedicated_print(msgstr); // send to server console too
 947                         if(sourcecmsgstr != "")
 948                                 centerprint(source, sourcecmsgstr);
 949                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && it.team == source.team, {
 950                                 sprint(it, msgstr);
 951                                 if(cmsgstr != "")
 952                                         centerprint(it, cmsgstr);
 953                         });
 954                 }
 955                 else if(teamsay < 0) // spectator message, only sent to spectators
 956                 {
 957                         sprint(source, sourcemsgstr);
 958                         dedicated_print(msgstr); // send to server console too
 959                         FOREACH_CLIENT(!IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source, sprint(it, msgstr));
 960                 }
 961                 else
 962                 {
 963             if (source) {
 964                 sprint(source, sourcemsgstr);
 965                 dedicated_print(msgstr); // send to server console too
 966                 MX_Say(strcat(playername(source), "^7: ", msgin));
 967             }
 968             FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source, sprint(it, msgstr));
 969         }
 970         }
 971
 972         return ret;
 973 }