For consistency, still handle the private messages
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / player.qc
1 #include "player.qh"
2
3 #include "bot/api.qh"
4 #include "cheats.qh"
5 #include "g_damage.qh"
6 #include "g_subs.qh"
7 #include "miscfunctions.qh"
8 #include "portals.qh"
9 #include "teamplay.qh"
10 #include "weapons/throwing.qh"
11 #include "command/common.qh"
12 #include "../common/state.qh"
13 #include "../common/anim.qh"
14 #include "../common/animdecide.qh"
15 #include "../common/csqcmodel_settings.qh"
16 #include "../common/deathtypes/all.qh"
17 #include "../common/triggers/subs.qh"
18 #include "../common/playerstats.qh"
19 #include "../lib/csqcmodel/sv_model.qh"
20
21 #include "../common/minigames/sv_minigames.qh"
22
23 #include "../common/physics/player.qh"
24 #include "../common/effects/qc/all.qh"
25 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
26 #include "../common/triggers/include.qh"
27
28 #include "weapons/weaponstats.qh"
29
30 #include "../common/animdecide.qh"
31
32 void Drop_Special_Items(entity player)
33 {
34         // called when the player has become stuck or frozen
35         // so objective items aren't stuck with the player
36
37         MUTATOR_CALLHOOK(DropSpecialItems, player);
38 }
39
40 void CopyBody_Think(entity this)
41 {
42         if(this.CopyBody_nextthink && time > this.CopyBody_nextthink)
43         {
44                 this.CopyBody_think(this);
45                 if(wasfreed(this))
46                         return;
47                 this.CopyBody_nextthink = this.nextthink;
48                 this.CopyBody_think = getthink(this);
49                 setthink(this, CopyBody_Think);
50         }
51         CSQCMODEL_AUTOUPDATE(this);
52         this.nextthink = time;
53 }
54 void CopyBody(entity this, float keepvelocity)
55 {
56         if (this.effects & EF_NODRAW)
57                 return;
58         entity clone = new(body);
59         clone.enemy = this;
60         clone.lip = this.lip;
61         clone.colormap = this.colormap;
62         clone.iscreature = this.iscreature;
63         clone.teleportable = this.teleportable;
64         clone.damagedbycontents = this.damagedbycontents;
65         if(clone.damagedbycontents)
66                 IL_PUSH(g_damagedbycontents, clone);
67         clone.angles = this.angles;
68         clone.v_angle = this.v_angle;
69         clone.avelocity = this.avelocity;
70         clone.damageforcescale = this.damageforcescale;
71         clone.effects = this.effects;
72         clone.glowmod = this.glowmod;
73         clone.event_damage = this.event_damage;
74         clone.anim_state = this.anim_state;
75         clone.anim_time = this.anim_time;
76         clone.anim_lower_action = this.anim_lower_action;
77         clone.anim_lower_time = this.anim_lower_time;
78         clone.anim_upper_action = this.anim_upper_action;
79         clone.anim_upper_time = this.anim_upper_time;
80         clone.anim_implicit_state = this.anim_implicit_state;
81         clone.anim_implicit_time = this.anim_implicit_time;
82         clone.anim_lower_implicit_action = this.anim_lower_implicit_action;
83         clone.anim_lower_implicit_time = this.anim_lower_implicit_time;
84         clone.anim_upper_implicit_action = this.anim_upper_implicit_action;
85         clone.anim_upper_implicit_time = this.anim_upper_implicit_time;
86         clone.dphitcontentsmask = this.dphitcontentsmask;
87         clone.death_time = this.death_time;
88         clone.pain_finished = this.pain_finished;
89         clone.health = this.health;
90         clone.armorvalue = this.armorvalue;
91         clone.armortype = this.armortype;
92         clone.model = this.model;
93         clone.modelindex = this.modelindex;
94         clone.skin = this.skin;
95         clone.species = this.species;
96         clone.move_qcphysics = false; // don't run gamecode logic on clones, too many
97         set_movetype(clone, this.move_movetype);
98         clone.solid = this.solid;
99         clone.ballistics_density = this.ballistics_density;
100         clone.takedamage = this.takedamage;
101         setcefc(clone, getcefc(this));
102         clone.uncustomizeentityforclient = this.uncustomizeentityforclient;
103         clone.uncustomizeentityforclient_set = this.uncustomizeentityforclient_set;
104         if (keepvelocity == 1)
105                 clone.velocity = this.velocity;
106         clone.oldvelocity = clone.velocity;
107         clone.alpha = this.alpha;
108         clone.fade_time = this.fade_time;
109         clone.fade_rate = this.fade_rate;
110         //clone.weapon = this.weapon;
111         setorigin(clone, this.origin);
112         setsize(clone, this.mins, this.maxs);
113         clone.prevorigin = this.origin;
114         clone.reset = SUB_Remove;
115         clone._ps = this._ps;
116
117         Drag_MoveDrag(this, clone);
118
119         if(clone.colormap <= maxclients && clone.colormap > 0)
120                 clone.colormap = 1024 + this.clientcolors;
121
122         CSQCMODEL_AUTOINIT(clone);
123         clone.CopyBody_nextthink = this.nextthink;
124         clone.CopyBody_think = getthink(this);
125         clone.nextthink = time;
126         setthink(clone, CopyBody_Think);
127         // "bake" the current animation frame for clones (they don't get clientside animation)
128         animdecide_load_if_needed(clone);
129         animdecide_setframes(clone, false, frame, frame1time, frame2, frame2time);
130
131         IL_PUSH(g_clones, clone);
132
133         MUTATOR_CALLHOOK(CopyBody, this, clone, keepvelocity);
134 }
135
136 void player_setupanimsformodel(entity this)
137 {
138         // load animation info
139         animdecide_load_if_needed(this);
140         animdecide_setstate(this, 0, false);
141 }
142
143 void player_anim(entity this)
144 {
145         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
146         if(IS_DEAD(this)) {
147                 if (!deadbits) {
148                         // Decide on which death animation to use.
149                         if(random() < 0.5)
150                                 deadbits = ANIMSTATE_DEAD1;
151                         else
152                                 deadbits = ANIMSTATE_DEAD2;
153                 }
154         } else {
155                 // Clear a previous death animation.
156                 deadbits = 0;
157         }
158         int animbits = deadbits;
159         if(STAT(FROZEN, this))
160                 animbits |= ANIMSTATE_FROZEN;
161         if(this.move_movetype == MOVETYPE_FOLLOW)
162                 animbits |= ANIMSTATE_FOLLOW;
163         if(this.crouch)
164                 animbits |= ANIMSTATE_DUCK;
165         animdecide_setstate(this, animbits, false);
166         animdecide_setimplicitstate(this, IS_ONGROUND(this));
167 }
168
169 void PlayerCorpseDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
170 {
171         float take, save;
172         vector v;
173         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
174
175         // damage resistance (ignore most of the damage from a bullet or similar)
176         damage = max(damage - 5, 1);
177
178         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
179         take = v.x;
180         save = v.y;
181
182         if(sound_allowed(MSG_BROADCAST, attacker))
183         {
184                 if (save > 10)
185                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
186                 else if (take > 30)
187                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
188                 else if (take > 10)
189                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM);
190         }
191
192         if (take > 50)
193                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
194         if (take > 100)
195                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
196
197         this.armorvalue = this.armorvalue - save;
198         this.health = this.health - take;
199         // pause regeneration for 5 seconds
200         this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
201
202         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
203         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
204         this.dmg_inflictor = inflictor;
205
206         if (this.health <= -autocvar_sv_gibhealth && this.alpha >= 0)
207         {
208                 // don't use any animations as a gib
209                 this.frame = 0;
210                 // view just above the floor
211                 this.view_ofs = '0 0 4';
212
213                 Violence_GibSplash(this, 1, 1, attacker);
214                 this.alpha = -1;
215                 this.solid = SOLID_NOT; // restore later
216                 this.takedamage = DAMAGE_NO; // restore later
217                 if(this.damagedbycontents)
218                         IL_REMOVE(g_damagedbycontents, this);
219                 this.damagedbycontents = false;
220         }
221 }
222
223 void calculate_player_respawn_time(entity this)
224 {
225         if(g_ca)
226                 return;
227
228         float gametype_setting_tmp;
229         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
230         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
231         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
232         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
233         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
234         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
235
236         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
237         if (teamplay)
238         {
239                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
240                         if(it.team == this.team)
241                                 ++pcount;
242                 ));
243                 if (sdelay_small_count == 0)
244                         sdelay_small_count = 1;
245                 if (sdelay_large_count == 0)
246                         sdelay_large_count = 1;
247         }
248         else
249         {
250                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
251                         ++pcount;
252                 ));
253                 if (sdelay_small_count == 0)
254                 {
255                         if (g_cts)
256                         {
257                                 // Players play independently. No point in requiring enemies.
258                                 sdelay_small_count = 1;
259                         }
260                         else
261                         {
262                                 // Players play AGAINST each other. Enemies required.
263                                 sdelay_small_count = 2;
264                         }
265                 }
266                 if (sdelay_large_count == 0)
267                 {
268                         if (g_cts)
269                         {
270                                 // Players play independently. No point in requiring enemies.
271                                 sdelay_large_count = 1;
272                         }
273                         else
274                         {
275                                 // Players play AGAINST each other. Enemies required.
276                                 sdelay_large_count = 2;
277                         }
278                 }
279         }
280
281         float sdelay;
282
283         if (pcount <= sdelay_small_count)
284                 sdelay = sdelay_small;
285         else if (pcount >= sdelay_large_count)
286                 sdelay = sdelay_large;
287         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
288                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
289
290         if(waves)
291                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
292         else
293                 this.respawn_time = time + sdelay;
294
295         if(sdelay < sdelay_max)
296                 this.respawn_time_max = time + sdelay_max;
297         else
298                 this.respawn_time_max = this.respawn_time;
299
300         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
301                 this.respawn_countdown = 10; // first number to count down from is 10
302         else
303                 this.respawn_countdown = -1; // do not count down
304
305         if(autocvar_g_forced_respawn)
306                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
307 }
308
309 void PlayerDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
310 {
311         float take, save, dh, da;
312         vector v;
313         float valid_damage_for_weaponstats;
314         float excess;
315
316         dh = max(this.health, 0);
317         da = max(this.armorvalue, 0);
318
319         if(!DEATH_ISSPECIAL(deathtype))
320         {
321                 damage *= sqrt(bound(1.0, this.cvar_cl_handicap, 100.0));
322                 if(this != attacker)
323                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
324         }
325
326         if (time < this.spawnshieldtime && autocvar_g_spawnshield_blockdamage < 1)
327                 damage *= 1 - max(0, autocvar_g_spawnshield_blockdamage);
328
329         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
330         {
331                 // tuba causes blood to come out of the ears
332                 vector ear1, ear2;
333                 vector d;
334                 float f;
335                 ear1 = this.origin;
336                 ear1_z += 0.125 * this.view_ofs.z + 0.875 * this.maxs.z; // 7/8
337                 ear2 = ear1;
338                 makevectors(this.angles);
339                 ear1 += v_right * -10;
340                 ear2 += v_right * +10;
341                 d = inflictor.origin - this.origin;
342                 if (d)
343                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
344                 else
345                         f = 0;  // Assum ecenter.
346                 force = v_right * vlen(force);
347                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), this, attacker);
348                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), this, attacker);
349                 if(f > 0)
350                 {
351                         hitloc = ear1;
352                         force = force * -1;
353                 }
354                 else
355                 {
356                         hitloc = ear2;
357                         // force is already good
358                 }
359         }
360         else
361                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
362
363         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
364         take = v.x;
365         save = v.y;
366
367         if(attacker == this)
368         {
369                 // don't reset pushltime for this damage as it may be an attempt to
370                 // escape a lava pit or similar
371                 //this.pushltime = 0;
372                 this.istypefrag = 0;
373         }
374         else if(IS_PLAYER(attacker))
375         {
376                 this.pusher = attacker;
377                 this.pushltime = time + autocvar_g_maxpushtime;
378                 this.istypefrag = PHYS_INPUT_BUTTON_CHAT(this);
379         }
380         else if(time < this.pushltime)
381         {
382                 attacker = this.pusher;
383                 this.pushltime = max(this.pushltime, time + 0.6);
384         }
385         else
386         {
387                 this.pushltime = 0;
388                 this.istypefrag = 0;
389         }
390
391         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor, inflictor, attacker, this, force, take, save, deathtype, damage);
392         take = bound(0, M_ARGV(4, float), this.health);
393         save = bound(0, M_ARGV(5, float), this.armorvalue);
394         excess = max(0, damage - take - save);
395
396         if(sound_allowed(MSG_BROADCAST, attacker))
397         {
398                 if (save > 10)
399                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
400                 else if (take > 30)
401                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
402                 else if (take > 10)
403                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
404         }
405
406         if (take > 50)
407                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
408         if (take > 100)
409                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
410
411         if (time >= this.spawnshieldtime || autocvar_g_spawnshield_blockdamage < 1)
412         {
413                 if (!(this.flags & FL_GODMODE))
414                 {
415                         this.armorvalue = this.armorvalue - save;
416                         this.health = this.health - take;
417                         // pause regeneration for 5 seconds
418                         if(take)
419                                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
420
421                         if (time > this.pain_finished)          //Don't switch pain sequences like crazy
422                         {
423                                 this.pain_finished = time + 0.5;        //Supajoe
424
425                                 if(autocvar_sv_gentle < 1) {
426                                         if(this.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
427                                         {
428                                                 if (!this.animstate_override)
429                                                 {
430                                                         if (random() > 0.5)
431                                                                 animdecide_setaction(this, ANIMACTION_PAIN1, true);
432                                                         else
433                                                                 animdecide_setaction(this, ANIMACTION_PAIN2, true);
434                                                 }
435                                         }
436
437                                         if(sound_allowed(MSG_BROADCAST, attacker))
438                                         if((this.health < 2 * WEP_CVAR_PRI(blaster, damage) * autocvar_g_balance_selfdamagepercent + 1) || !(DEATH_WEAPONOF(deathtype).spawnflags & WEP_FLAG_CANCLIMB) || attacker != this) // WEAPONTODO: create separate limit for pain notification with laser
439                                         if(this.health > 1)
440                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
441                                         {
442                                                 if(deathtype == DEATH_FALL.m_id)
443                                                         PlayerSound(this, playersound_fall, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
444                                                 else if(this.health > 75)
445                                                         PlayerSound(this, playersound_pain100, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
446                                                 else if(this.health > 50)
447                                                         PlayerSound(this, playersound_pain75, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
448                                                 else if(this.health > 25)
449                                                         PlayerSound(this, playersound_pain50, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
450                                                 else
451                                                         PlayerSound(this, playersound_pain25, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
452                                         }
453                                 }
454                         }
455
456                         // throw off bot aim temporarily
457                         float shake;
458                         if(IS_BOT_CLIENT(this) && this.health >= 1)
459                         {
460                                 shake = damage * 5 / (bound(0,skill,100) + 1);
461                                 this.v_angle_x = this.v_angle.x + (random() * 2 - 1) * shake;
462                                 this.v_angle_y = this.v_angle.y + (random() * 2 - 1) * shake;
463                                 this.v_angle_x = bound(-90, this.v_angle.x, 90);
464                         }
465                 }
466                 else
467                         this.max_armorvalue += (save + take);
468         }
469         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
470         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
471         this.dmg_inflictor = inflictor;
472
473         if (this != attacker) {
474                 float realdmg = damage - excess;
475                 if (IS_PLAYER(attacker)) {
476                         PlayerScore_Add(attacker, SP_DMG, realdmg);
477                 }
478                 if (IS_PLAYER(this)) {
479                         PlayerScore_Add(this, SP_DMGTAKEN, realdmg);
480                 }
481         }
482
483         bool abot = (IS_BOT_CLIENT(attacker));
484         bool vbot = (IS_BOT_CLIENT(this));
485
486         valid_damage_for_weaponstats = 0;
487         Weapon awep = WEP_Null;
488
489         if(vbot || IS_REAL_CLIENT(this))
490         if(abot || IS_REAL_CLIENT(attacker))
491         if(attacker && this != attacker)
492         if(DIFF_TEAM(this, attacker))
493         {
494                 if(DEATH_ISSPECIAL(deathtype))
495                         awep = PS(attacker).m_weapon;
496                 else
497                         awep = DEATH_WEAPONOF(deathtype);
498                 valid_damage_for_weaponstats = 1;
499         }
500
501         dh = dh - max(this.health, 0);
502         da = da - max(this.armorvalue, 0);
503         if(valid_damage_for_weaponstats)
504         {
505                 WeaponStats_LogDamage(awep.m_id, abot, PS(this).m_weapon.m_id, vbot, dh + da);
506         }
507         if (damage)
508         {
509                 MUTATOR_CALLHOOK(PlayerDamaged, attacker, this, dh, da, hitloc, deathtype, damage);
510         }
511
512         if (this.health < 1)
513         {
514                 float defer_ClientKill_Now_TeamChange;
515                 defer_ClientKill_Now_TeamChange = false;
516
517                 if(this.alivetime)
518                 {
519                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
520                         this.alivetime = 0;
521                 }
522
523                 if(valid_damage_for_weaponstats)
524                         WeaponStats_LogKill(awep.m_id, abot, PS(this).m_weapon.m_id, vbot);
525
526                 if(autocvar_sv_gentle < 1)
527                 if(sound_allowed(MSG_BROADCAST, attacker))
528                 {
529                         if(deathtype == DEATH_DROWN.m_id)
530                                 PlayerSound(this, playersound_drown, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
531                         else
532                                 PlayerSound(this, playersound_death, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
533                 }
534
535                 // get rid of kill indicator
536                 if(this.killindicator)
537                 {
538                         delete(this.killindicator);
539                         this.killindicator = NULL;
540                         if(this.killindicator_teamchange)
541                                 defer_ClientKill_Now_TeamChange = true;
542
543                         if(this.classname == "body")
544                         if(deathtype == DEATH_KILL.m_id)
545                         {
546                                 // for the lemmings fans, a small harmless explosion
547                                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
548                         }
549                 }
550
551                 // print an obituary message
552                 if(this.classname != "body")
553                         Obituary (attacker, inflictor, this, deathtype);
554
555         // increment frag counter for used weapon type
556         Weapon w = DEATH_WEAPONOF(deathtype);
557                 if(w != WEP_Null && accuracy_isgooddamage(attacker, this))
558                         attacker.accuracy.(accuracy_frags[w.m_id-1]) += 1;
559
560                 MUTATOR_CALLHOOK(PlayerDies, inflictor, attacker, this, deathtype, damage);
561                 excess = M_ARGV(4, float);
562
563                 Weapon wep = PS(this).m_weapon;
564                 /*for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
565                 {
566                         .entity weaponentity = weaponentities[slot];
567                         wep.wr_playerdeath(wep, this, weaponentity);
568                 }*/
569                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
570                 wep.wr_playerdeath(wep, this, weaponentity);
571
572                 RemoveGrapplingHook(this);
573
574                 Portal_ClearAllLater(this);
575
576                 this.fixangle = true;
577
578                 if(defer_ClientKill_Now_TeamChange)
579                         ClientKill_Now_TeamChange(this); // can turn player into spectator
580
581                 // player could have been miraculously resuscitated ;)
582                 // e.g. players in freezetag get frozen, they don't really die
583                 if(this.health >= 1 || !(IS_PLAYER(this) || this.classname == "body"))
584                         return;
585
586                 // when we get here, player actually dies
587
588                 Unfreeze(this); // remove any icy remains
589                 this.health = 0; // Unfreeze resets health, so we need to set it back
590
591                 // clear waypoints
592                 WaypointSprite_PlayerDead(this);
593                 // throw a weapon
594                 SpawnThrownWeapon(this, this.origin + (this.mins + this.maxs) * 0.5, PS(this).m_switchweapon.m_id);
595
596                 // become fully visible
597                 this.alpha = default_player_alpha;
598                 // make the corpse upright (not tilted)
599                 this.angles_x = 0;
600                 this.angles_z = 0;
601                 // don't spin
602                 this.avelocity = '0 0 0';
603                 // view from the floor
604                 this.view_ofs = '0 0 -8';
605                 // toss the corpse
606                 set_movetype(this, MOVETYPE_TOSS);
607                 // shootable corpse
608                 this.solid = SOLID_CORPSE;
609                 this.ballistics_density = autocvar_g_ballistics_density_corpse;
610                 // don't stick to the floor
611                 UNSET_ONGROUND(this);
612                 // dying animation
613                 this.deadflag = DEAD_DYING;
614
615                 // when to allow respawn
616                 calculate_player_respawn_time(this);
617
618                 this.death_time = time;
619                 if (random() < 0.5)
620                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD1, true);
621                 else
622                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD2, true);
623                 if (this.maxs.z > 5)
624                 {
625                         this.maxs_z = 5;
626                         setsize(this, this.mins, this.maxs);
627                 }
628                 // set damage function to corpse damage
629                 this.event_damage = PlayerCorpseDamage;
630                 // call the corpse damage function just in case it wants to gib
631                 this.event_damage(this, inflictor, attacker, excess, deathtype, hitloc, force);
632
633                 // set up to fade out later
634                 SUB_SetFade (this, time + 6 + random (), 1);
635                 // reset body think wrapper broken by SUB_SetFade
636                 if(this.classname == "body" && getthink(this) != CopyBody_Think) {
637                         this.CopyBody_think = getthink(this);
638                         this.CopyBody_nextthink = this.nextthink;
639                         setthink(this, CopyBody_Think);
640                         this.nextthink = time;
641                 }
642
643                 if(autocvar_sv_gentle > 0 || autocvar_ekg || this.classname == "body") {
644                         // remove corpse
645                         // clones don't run any animation code any more, so we must gib them when they die :(
646                         PlayerCorpseDamage(this, inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
647                 }
648
649                 // reset fields the weapons may use just in case
650                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
651                         it.wr_resetplayer(it, this);
652                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
653                         {
654                                 ATTACK_FINISHED_FOR(this, it.m_id, slot) = 0;
655                         }
656                 ));
657         }
658 }
659
660 void MoveToTeam(entity client, int team_colour, int type)
661 {
662         int lockteams_backup = lockteams;  // backup any team lock
663         lockteams = 0;  // disable locked teams
664         TeamchangeFrags(client);  // move the players frags
665         SetPlayerColors(client, team_colour - 1);  // set the players colour
666         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE.m_id, client.origin, '0 0 0');  // kill the player
667         lockteams = lockteams_backup;  // restore the team lock
668         LogTeamchange(client.playerid, client.team, type);
669 }
670
671 /** print(), but only print if the server is not local */
672 void dedicated_print(string input)
673 {
674         if (server_is_dedicated) print(input);
675 }
676
677 /**
678  * message "": do not say, just test flood control
679  * return value:
680  *   1 = accept
681  *   0 = reject
682  *  -1 = fake accept
683  */
684 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
685 {
686         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
687         msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
688
689         msgin = formatmessage(source, msgin);
690
691     string colorstr;
692         if (!IS_PLAYER(source))
693                 colorstr = "^0"; // black for spectators
694         else if(teamplay)
695                 colorstr = Team_ColorCode(source.team);
696         else
697         {
698                 colorstr = "";
699                 teamsay = false;
700         }
701
702         if(intermission_running)
703                 teamsay = false;
704
705     if (!source) {
706                 colorstr = "";
707                 teamsay = false;
708     }
709
710         if(msgin != "")
711                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
712
713         /*
714          * using bprint solves this... me stupid
715         // how can we prevent the message from appearing in a listen server?
716         // for now, just give "say" back and only handle say_team
717         if(!teamsay)
718         {
719                 clientcommand(source, strcat("say ", msgin));
720                 return;
721         }
722         */
723
724     string namestr = "";
725     if (source)
726         namestr = autocvar_g_chat_teamcolors ? playername(source) : source.netname;
727
728     string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
729
730     string msgstr, cmsgstr;
731     string privatemsgprefix = string_null;
732     int privatemsgprefixlen = 0;
733         if (msgin == "") {
734         msgstr = cmsgstr = "";
735         } else {
736                 if(privatesay)
737                 {
738                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
739                         privatemsgprefixlen = strlen(msgstr);
740                         msgstr = strcat(msgstr, msgin);
741                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
742                         if(autocvar_g_chat_teamcolors)
743                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
744                         else
745                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
746                 }
747                 else if(teamsay)
748                 {
749                         if(strstrofs(msgin, "/me", 0) >= 0)
750                         {
751                                 //msgin = strreplace("/me", "", msgin);
752                                 //msgin = substring(msgin, 3, strlen(msgin));
753                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
754                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
755                         }
756                         else
757                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
758                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
759                 }
760                 else
761                 {
762                         if(strstrofs(msgin, "/me", 0) >= 0)
763                         {
764                                 //msgin = strreplace("/me", "", msgin);
765                                 //msgin = substring(msgin, 3, strlen(msgin));
766                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
767                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
768                         }
769                         else {
770                 msgstr = "\{1}";
771                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
772                 msgstr = strcat(msgstr, msgin);
773             }
774                         cmsgstr = "";
775                 }
776                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
777         }
778
779         string fullmsgstr = msgstr;
780         string fullcmsgstr = cmsgstr;
781
782         // FLOOD CONTROL
783         int flood = 0;
784         var .float flood_field = floodcontrol_chat;
785         if(floodcontrol)
786         {
787                 float flood_spl;
788                 float flood_burst;
789                 float flood_lmax;
790                 float lines;
791                 if(privatesay)
792                 {
793                         flood_spl = autocvar_g_chat_flood_spl_tell;
794                         flood_burst = autocvar_g_chat_flood_burst_tell;
795                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
796                         flood_field = floodcontrol_chattell;
797                 }
798                 else if(teamsay)
799                 {
800                         flood_spl = autocvar_g_chat_flood_spl_team;
801                         flood_burst = autocvar_g_chat_flood_burst_team;
802                         flood_lmax = autocvar_g_chat_flood_lmax_team;
803                         flood_field = floodcontrol_chatteam;
804                 }
805                 else
806                 {
807                         flood_spl = autocvar_g_chat_flood_spl;
808                         flood_burst = autocvar_g_chat_flood_burst;
809                         flood_lmax = autocvar_g_chat_flood_lmax;
810                         flood_field = floodcontrol_chat;
811                 }
812                 flood_burst = max(0, flood_burst - 1);
813                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
814
815                 // do flood control for the default line size
816                 if(msgstr != "")
817                 {
818                         getWrappedLine_remaining = msgstr;
819                         msgstr = "";
820                         lines = 0;
821                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
822                         {
823                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
824                                 ++lines;
825                         }
826                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
827
828                         if(getWrappedLine_remaining != "")
829                         {
830                                 msgstr = strcat(msgstr, "\n");
831                                 flood = 2;
832                         }
833
834                         if (time >= source.(flood_field))
835                         {
836                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
837                         }
838                         else
839                         {
840                                 flood = 1;
841                                 msgstr = fullmsgstr;
842                         }
843                 }
844                 else
845                 {
846                         if (time >= source.(flood_field))
847                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
848                         else
849                                 flood = 1;
850                 }
851
852                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
853                         source.(flood_field) = flood = 0;
854         }
855
856     string sourcemsgstr, sourcecmsgstr;
857         if(flood == 2) // cannot happen for empty msgstr
858         {
859                 if(autocvar_g_chat_flood_notify_flooder)
860                 {
861                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
862                         sourcecmsgstr = "";
863                 }
864                 else
865                 {
866                         sourcemsgstr = fullmsgstr;
867                         sourcecmsgstr = fullcmsgstr;
868                 }
869                 cmsgstr = "";
870         }
871         else
872         {
873                 sourcemsgstr = msgstr;
874                 sourcecmsgstr = cmsgstr;
875         }
876
877         if (!privatesay && source && !IS_PLAYER(source))
878         {
879                 if (!intermission_running)
880                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
881                                 teamsay = -1; // spectators
882         }
883
884         if(flood)
885                 LOG_INFO("NOTE: ", playername(source), "^7 is flooding.\n");
886
887         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
888         if(privatesay)
889                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
890
891     int ret;
892         if(source.muted)
893         {
894                 // always fake the message
895                 ret = -1;
896         }
897         else if(flood == 1)
898         {
899                 if (autocvar_g_chat_flood_notify_flooder)
900                 {
901                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
902                         ret = 0;
903                 }
904                 else
905                         ret = -1;
906         }
907         else
908         {
909                 ret = 1;
910         }
911
912         MUTATOR_CALLHOOK(ChatMessage, source, ret);
913         ret = M_ARGV(1, int);
914
915         if(sourcemsgstr != "" && ret != 0)
916         {
917                 if(ret < 0) // faked message, because the player is muted
918                 {
919                         sprint(source, sourcemsgstr);
920                         if(sourcecmsgstr != "" && !privatesay)
921                                 centerprint(source, sourcecmsgstr);
922                 }
923                 else if(privatesay) // private message, between 2 people only
924                 {
925                         sprint(source, sourcemsgstr);
926                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
927                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
928                         {
929                                 sprint(privatesay, msgstr);
930                                 if(cmsgstr != "")
931                                         centerprint(privatesay, cmsgstr);
932                         }
933                 }
934                 else if ( teamsay && source.active_minigame )
935                 {
936                         sprint(source, sourcemsgstr);
937                         dedicated_print(msgstr); // send to server console too
938                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && it.active_minigame == source.active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
939                 }
940                 else if(teamsay > 0) // team message, only sent to team mates
941                 {
942                         sprint(source, sourcemsgstr);
943                         dedicated_print(msgstr); // send to server console too
944                         if(sourcecmsgstr != "")
945                                 centerprint(source, sourcecmsgstr);
946                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
947                                 sprint(it, msgstr);
948                                 if(cmsgstr != "")
949                                         centerprint(it, cmsgstr);
950                         });
951                 }
952                 else if(teamsay < 0) // spectator message, only sent to spectators
953                 {
954                         sprint(source, sourcemsgstr);
955                         dedicated_print(msgstr); // send to server console too
956                         FOREACH_CLIENT(!IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
957                 }
958                 else
959                 {
960             if (source) {
961                 sprint(source, sourcemsgstr);
962                 dedicated_print(msgstr); // send to server console too
963                 MX_Say(strcat(playername(source), "^7: ", msgin));
964             }
965             FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
966         }
967         }
968
969         return ret;
970 }