qcsrc/server/player.qc

   1 #include "player.qh"
   2
   3 #include "bot/api.qh"
   4 #include "cheats.qh"
   5 #include "g_damage.qh"
   6 #include "g_subs.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "weapons/throwing.qh"
  11 #include "command/common.qh"
  12 #include "../common/state.qh"
  13 #include "../common/anim.qh"
  14 #include "../common/animdecide.qh"
  15 #include "../common/csqcmodel_settings.qh"
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/triggers/subs.qh"
  18 #include "../common/playerstats.qh"
  19 #include "../lib/csqcmodel/sv_model.qh"
  20
  21 #include "../common/minigames/sv_minigames.qh"
  22
  23 #include "../common/physics/player.qh"
  24 #include "../common/effects/qc/all.qh"
  25 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  26 #include "../common/triggers/include.qh"
  27 #include "../common/wepent.qh"
  28
  29 #include "weapons/weaponstats.qh"
  30
  31 #include "../common/animdecide.qh"
  32
  33 void Drop_Special_Items(entity player)
  34 {
  35         // called when the player has become stuck or frozen
  36         // so objective items aren't stuck with the player
  37
  38         MUTATOR_CALLHOOK(DropSpecialItems, player);
  39 }
  40
  41 void CopyBody_Think(entity this)
  42 {
  43         if(this.CopyBody_nextthink && time > this.CopyBody_nextthink)
  44         {
  45                 this.CopyBody_think(this);
  46                 if(wasfreed(this))
  47                         return;
  48                 this.CopyBody_nextthink = this.nextthink;
  49                 this.CopyBody_think = getthink(this);
  50                 setthink(this, CopyBody_Think);
  51         }
  52         CSQCMODEL_AUTOUPDATE(this);
  53         this.nextthink = time;
  54 }
  55 void CopyBody(entity this, float keepvelocity)
  56 {
  57         if (this.effects & EF_NODRAW)
  58                 return;
  59         entity clone = new(body);
  60         clone.enemy = this;
  61         clone.lip = this.lip;
  62         clone.colormap = this.colormap;
  63         clone.iscreature = this.iscreature;
  64         clone.teleportable = this.teleportable;
  65         clone.damagedbycontents = this.damagedbycontents;
  66         if(clone.damagedbycontents)
  67                 IL_PUSH(g_damagedbycontents, clone);
  68         clone.angles = this.angles;
  69         clone.v_angle = this.v_angle;
  70         clone.avelocity = this.avelocity;
  71         clone.damageforcescale = this.damageforcescale;
  72         clone.effects = this.effects;
  73         clone.glowmod = this.glowmod;
  74         clone.event_damage = this.event_damage;
  75         clone.anim_state = this.anim_state;
  76         clone.anim_time = this.anim_time;
  77         clone.anim_lower_action = this.anim_lower_action;
  78         clone.anim_lower_time = this.anim_lower_time;
  79         clone.anim_upper_action = this.anim_upper_action;
  80         clone.anim_upper_time = this.anim_upper_time;
  81         clone.anim_implicit_state = this.anim_implicit_state;
  82         clone.anim_implicit_time = this.anim_implicit_time;
  83         clone.anim_lower_implicit_action = this.anim_lower_implicit_action;
  84         clone.anim_lower_implicit_time = this.anim_lower_implicit_time;
  85         clone.anim_upper_implicit_action = this.anim_upper_implicit_action;
  86         clone.anim_upper_implicit_time = this.anim_upper_implicit_time;
  87         clone.dphitcontentsmask = this.dphitcontentsmask;
  88         clone.death_time = this.death_time;
  89         clone.pain_finished = this.pain_finished;
  90         clone.health = this.health;
  91         clone.armorvalue = this.armorvalue;
  92         clone.armortype = this.armortype;
  93         clone.model = this.model;
  94         clone.modelindex = this.modelindex;
  95         clone.skin = this.skin;
  96         clone.species = this.species;
  97         clone.move_qcphysics = false; // don't run gamecode logic on clones, too many
  98         set_movetype(clone, this.move_movetype);
  99         clone.solid = this.solid;
 100         clone.takedamage = this.takedamage;
 101         setcefc(clone, getcefc(this));
 102         clone.uncustomizeentityforclient = this.uncustomizeentityforclient;
 103         clone.uncustomizeentityforclient_set = this.uncustomizeentityforclient_set;
 104         if (keepvelocity == 1)
 105                 clone.velocity = this.velocity;
 106         clone.oldvelocity = clone.velocity;
 107         clone.alpha = this.alpha;
 108         clone.fade_time = this.fade_time;
 109         clone.fade_rate = this.fade_rate;
 110         //clone.weapon = this.weapon;
 111         setorigin(clone, this.origin);
 112         setsize(clone, this.mins, this.maxs);
 113         clone.reset = SUB_Remove;
 114         clone._ps = this._ps;
 115
 116         Drag_MoveDrag(this, clone);
 117
 118         if(clone.colormap <= maxclients && clone.colormap > 0)
 119                 clone.colormap = 1024 + this.clientcolors;
 120
 121         CSQCMODEL_AUTOINIT(clone);
 122         clone.CopyBody_nextthink = this.nextthink;
 123         clone.CopyBody_think = getthink(this);
 124         clone.nextthink = time;
 125         setthink(clone, CopyBody_Think);
 126         // "bake" the current animation frame for clones (they don't get clientside animation)
 127         animdecide_load_if_needed(clone);
 128         animdecide_setframes(clone, false, frame, frame1time, frame2, frame2time);
 129
 130         IL_PUSH(g_clones, clone);
 131
 132         MUTATOR_CALLHOOK(CopyBody, this, clone, keepvelocity);
 133 }
 134
 135 void player_setupanimsformodel(entity this)
 136 {
 137         // load animation info
 138         animdecide_load_if_needed(this);
 139         animdecide_setstate(this, 0, false);
 140 }
 141
 142 void player_anim(entity this)
 143 {
 144         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 145         if(IS_DEAD(this)) {
 146                 if (!deadbits) {
 147                         // Decide on which death animation to use.
 148                         if(random() < 0.5)
 149                                 deadbits = ANIMSTATE_DEAD1;
 150                         else
 151                                 deadbits = ANIMSTATE_DEAD2;
 152                 }
 153         } else {
 154                 // Clear a previous death animation.
 155                 deadbits = 0;
 156         }
 157         int animbits = deadbits;
 158         if(STAT(FROZEN, this))
 159                 animbits |= ANIMSTATE_FROZEN;
 160         if(this.move_movetype == MOVETYPE_FOLLOW)
 161                 animbits |= ANIMSTATE_FOLLOW;
 162         if(this.crouch)
 163                 animbits |= ANIMSTATE_DUCK;
 164         animdecide_setstate(this, animbits, false);
 165         animdecide_setimplicitstate(this, IS_ONGROUND(this));
 166 }
 167
 168 void PlayerCorpseDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 169 {
 170         float take, save;
 171         vector v;
 172         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 173
 174         // damage resistance (ignore most of the damage from a bullet or similar)
 175         damage = max(damage - 5, 1);
 176
 177         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 178         take = v.x;
 179         save = v.y;
 180
 181         if(sound_allowed(MSG_BROADCAST, attacker))
 182         {
 183                 if (save > 10)
 184                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 185                 else if (take > 30)
 186                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 187                 else if (take > 10)
 188                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM);
 189         }
 190
 191         if (take > 50)
 192                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 193         if (take > 100)
 194                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 195
 196         this.armorvalue = this.armorvalue - save;
 197         this.health = this.health - take;
 198         // pause regeneration for 5 seconds
 199         this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 200
 201         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 202         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 203         this.dmg_inflictor = inflictor;
 204
 205         if (this.health <= -autocvar_sv_gibhealth && this.alpha >= 0)
 206         {
 207                 // don't use any animations as a gib
 208                 this.frame = 0;
 209                 // view just above the floor
 210                 this.view_ofs = '0 0 4';
 211
 212                 Violence_GibSplash(this, 1, 1, attacker);
 213                 this.alpha = -1;
 214                 this.solid = SOLID_NOT; // restore later
 215                 this.takedamage = DAMAGE_NO; // restore later
 216                 if(this.damagedbycontents)
 217                         IL_REMOVE(g_damagedbycontents, this);
 218                 this.damagedbycontents = false;
 219         }
 220 }
 221
 222 void calculate_player_respawn_time(entity this)
 223 {
 224         if(g_ca)
 225                 return;
 226
 227         float gametype_setting_tmp;
 228         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 229         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 230         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 231         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 232         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 233         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 234
 235         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 236         if (teamplay)
 237         {
 238                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 239                         if(it.team == this.team)
 240                                 ++pcount;
 241                 ));
 242                 if (sdelay_small_count == 0)
 243                         sdelay_small_count = 1;
 244                 if (sdelay_large_count == 0)
 245                         sdelay_large_count = 1;
 246         }
 247         else
 248         {
 249                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 250                         ++pcount;
 251                 ));
 252                 if (sdelay_small_count == 0)
 253                 {
 254                         if (IS_INDEPENDENT_PLAYER(this))
 255                         {
 256                                 // Players play independently. No point in requiring enemies.
 257                                 sdelay_small_count = 1;
 258                         }
 259                         else
 260                         {
 261                                 // Players play AGAINST each other. Enemies required.
 262                                 sdelay_small_count = 2;
 263                         }
 264                 }
 265                 if (sdelay_large_count == 0)
 266                 {
 267                         if (IS_INDEPENDENT_PLAYER(this))
 268                         {
 269                                 // Players play independently. No point in requiring enemies.
 270                                 sdelay_large_count = 1;
 271                         }
 272                         else
 273                         {
 274                                 // Players play AGAINST each other. Enemies required.
 275                                 sdelay_large_count = 2;
 276                         }
 277                 }
 278         }
 279
 280         float sdelay;
 281
 282         if (pcount <= sdelay_small_count)
 283                 sdelay = sdelay_small;
 284         else if (pcount >= sdelay_large_count)
 285                 sdelay = sdelay_large;
 286         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 287                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 288
 289         if(waves)
 290                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
 291         else
 292                 this.respawn_time = time + sdelay;
 293
 294         if(sdelay < sdelay_max)
 295                 this.respawn_time_max = time + sdelay_max;
 296         else
 297                 this.respawn_time_max = this.respawn_time;
 298
 299         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
 300                 this.respawn_countdown = 10; // first number to count down from is 10
 301         else
 302                 this.respawn_countdown = -1; // do not count down
 303
 304         if(autocvar_g_forced_respawn)
 305                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
 306 }
 307
 308 void PlayerDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 309 {
 310         float take, save, dh, da;
 311         vector v;
 312         float excess;
 313
 314         dh = max(this.health, 0);
 315         da = max(this.armorvalue, 0);
 316
 317         if(!DEATH_ISSPECIAL(deathtype))
 318         {
 319                 damage *= bound(1.0, this.cvar_cl_handicap, 10.0);
 320                 if(this != attacker)
 321                         damage /= bound(1.0, attacker.cvar_cl_handicap, 10.0);
 322         }
 323
 324         if (time < this.spawnshieldtime && autocvar_g_spawnshield_blockdamage < 1)
 325                 damage *= 1 - max(0, autocvar_g_spawnshield_blockdamage);
 326
 327         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 328         {
 329                 // tuba causes blood to come out of the ears
 330                 vector ear1, ear2;
 331                 vector d;
 332                 float f;
 333                 ear1 = this.origin;
 334                 ear1_z += 0.125 * this.view_ofs.z + 0.875 * this.maxs.z; // 7/8
 335                 ear2 = ear1;
 336                 makevectors(this.angles);
 337                 ear1 += v_right * -10;
 338                 ear2 += v_right * +10;
 339                 d = inflictor.origin - this.origin;
 340                 if (d)
 341                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 342                 else
 343                         f = 0;  // Assum ecenter.
 344                 force = v_right * vlen(force);
 345                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), this, attacker);
 346                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), this, attacker);
 347                 if(f > 0)
 348                 {
 349                         hitloc = ear1;
 350                         force = force * -1;
 351                 }
 352                 else
 353                 {
 354                         hitloc = ear2;
 355                         // force is already good
 356                 }
 357         }
 358         else
 359                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
 360
 361         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 362         take = v.x;
 363         save = v.y;
 364
 365         if(attacker == this)
 366         {
 367                 // don't reset pushltime for this damage as it may be an attempt to
 368                 // escape a lava pit or similar
 369                 //this.pushltime = 0;
 370                 this.istypefrag = 0;
 371         }
 372         else if(IS_PLAYER(attacker))
 373         {
 374                 this.pusher = attacker;
 375                 this.pushltime = time + autocvar_g_maxpushtime;
 376                 this.istypefrag = PHYS_INPUT_BUTTON_CHAT(this);
 377         }
 378         else if(time < this.pushltime)
 379         {
 380                 attacker = this.pusher;
 381                 this.pushltime = max(this.pushltime, time + 0.6);
 382         }
 383         else
 384         {
 385                 this.pushltime = 0;
 386                 this.istypefrag = 0;
 387         }
 388
 389         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor, inflictor, attacker, this, force, take, save, deathtype, damage);
 390         take = bound(0, M_ARGV(4, float), this.health);
 391         save = bound(0, M_ARGV(5, float), this.armorvalue);
 392         excess = max(0, damage - take - save);
 393
 394         if(sound_allowed(MSG_BROADCAST, attacker))
 395         {
 396                 if (save > 10)
 397                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
 398                 else if (take > 30)
 399                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
 400                 else if (take > 10)
 401                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 402         }
 403
 404         if (take > 50)
 405                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
 406         if (take > 100)
 407                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
 408
 409         if (time >= this.spawnshieldtime || autocvar_g_spawnshield_blockdamage < 1)
 410         {
 411                 if (!(this.flags & FL_GODMODE))
 412                 {
 413                         this.armorvalue = this.armorvalue - save;
 414                         this.health = this.health - take;
 415                         // pause regeneration for 5 seconds
 416                         if(take)
 417                                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 418
 419                         if (time > this.pain_finished)          //Don't switch pain sequences like crazy
 420                         {
 421                                 this.pain_finished = time + 0.5;        //Supajoe
 422
 423                                 if(autocvar_sv_gentle < 1) {
 424                                         if(this.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 425                                         {
 426                                                 if (!this.animstate_override)
 427                                                 {
 428                                                         if (random() > 0.5)
 429                                                                 animdecide_setaction(this, ANIMACTION_PAIN1, true);
 430                                                         else
 431                                                                 animdecide_setaction(this, ANIMACTION_PAIN2, true);
 432                                                 }
 433                                         }
 434
 435                                         if(sound_allowed(MSG_BROADCAST, attacker))
 436                                         if(this.health < 25 || !(DEATH_WEAPONOF(deathtype).spawnflags & WEP_FLAG_CANCLIMB) || take > 20 || attacker != this)
 437                                         if(this.health > 1)
 438                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 439                                         {
 440                                                 if(deathtype == DEATH_FALL.m_id)
 441                                                         PlayerSound(this, playersound_fall, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 442                                                 else if(this.health > 75)
 443                                                         PlayerSound(this, playersound_pain100, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 444                                                 else if(this.health > 50)
 445                                                         PlayerSound(this, playersound_pain75, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 446                                                 else if(this.health > 25)
 447                                                         PlayerSound(this, playersound_pain50, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 448                                                 else
 449                                                         PlayerSound(this, playersound_pain25, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 450                                         }
 451                                 }
 452                         }
 453
 454                         // throw off bot aim temporarily
 455                         float shake;
 456                         if(IS_BOT_CLIENT(this) && this.health >= 1)
 457                         {
 458                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 459                                 this.v_angle_x = this.v_angle.x + (random() * 2 - 1) * shake;
 460                                 this.v_angle_y = this.v_angle.y + (random() * 2 - 1) * shake;
 461                                 this.v_angle_x = bound(-90, this.v_angle.x, 90);
 462                         }
 463                 }
 464                 else
 465                         this.max_armorvalue += (save + take);
 466         }
 467         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
 468         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
 469         this.dmg_inflictor = inflictor;
 470
 471         if (this != attacker) {
 472                 float realdmg = damage - excess;
 473                 if (IS_PLAYER(attacker)) {
 474                         PlayerScore_Add(attacker, SP_DMG, realdmg);
 475                 }
 476                 if (IS_PLAYER(this)) {
 477                         PlayerScore_Add(this, SP_DMGTAKEN, realdmg);
 478                 }
 479         }
 480
 481         bool abot = (IS_BOT_CLIENT(attacker));
 482         bool vbot = (IS_BOT_CLIENT(this));
 483
 484         bool valid_damage_for_weaponstats = false;
 485         Weapon awep = WEP_Null;
 486         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 487
 488         if(vbot || IS_REAL_CLIENT(this))
 489         if(abot || IS_REAL_CLIENT(attacker))
 490         if(attacker && this != attacker)
 491         if(DIFF_TEAM(this, attacker))
 492         {
 493                 if(DEATH_ISSPECIAL(deathtype))
 494                         awep = attacker.(weaponentity).m_weapon;
 495                 else
 496                         awep = DEATH_WEAPONOF(deathtype);
 497                 valid_damage_for_weaponstats = true;
 498         }
 499
 500         dh = dh - max(this.health, 0);
 501         da = da - max(this.armorvalue, 0);
 502         if(valid_damage_for_weaponstats)
 503         {
 504                 WeaponStats_LogDamage(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot, dh + da);
 505         }
 506
 507         MUTATOR_CALLHOOK(PlayerDamaged, attacker, this, dh, da, hitloc, deathtype, damage);
 508
 509         if (this.health < 1)
 510         {
 511                 float defer_ClientKill_Now_TeamChange;
 512                 defer_ClientKill_Now_TeamChange = false;
 513
 514                 if(this.alivetime)
 515                 {
 516                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 517                         this.alivetime = 0;
 518                 }
 519
 520                 if(valid_damage_for_weaponstats)
 521                         WeaponStats_LogKill(awep.m_id, abot, this.(weaponentity).m_weapon.m_id, vbot);
 522
 523                 if(autocvar_sv_gentle < 1)
 524                 if(sound_allowed(MSG_BROADCAST, attacker))
 525                 {
 526                         if(deathtype == DEATH_DROWN.m_id)
 527                                 PlayerSound(this, playersound_drown, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 528                         else
 529                                 PlayerSound(this, playersound_death, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
 530                 }
 531
 532                 // get rid of kill indicator
 533                 if(this.killindicator)
 534                 {
 535                         delete(this.killindicator);
 536                         this.killindicator = NULL;
 537                         if(CS(this).killindicator_teamchange)
 538                                 defer_ClientKill_Now_TeamChange = true;
 539
 540                         if(this.classname == "body")
 541                         if(deathtype == DEATH_KILL.m_id)
 542                         {
 543                                 // for the lemmings fans, a small harmless explosion
 544                                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 545                         }
 546                 }
 547
 548                 // print an obituary message
 549                 if(this.classname != "body")
 550                         Obituary (attacker, inflictor, this, deathtype);
 551
 552         // increment frag counter for used weapon type
 553         Weapon w = DEATH_WEAPONOF(deathtype);
 554                 if(w != WEP_Null && accuracy_isgooddamage(attacker, this))
 555                         CS(attacker).accuracy.(accuracy_frags[w.m_id-1]) += 1;
 556
 557                 MUTATOR_CALLHOOK(PlayerDies, inflictor, attacker, this, deathtype, damage);
 558                 damage = M_ARGV(4, float);
 559                 excess = max(0, damage - take - save);
 560
 561                 //Weapon wep = this.(weaponentity).m_weapon;
 562                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 563                 {
 564                         .entity went = weaponentities[slot];
 565                         if(!this.(weaponentity))
 566                                 continue; // TODO: clones have no weapon, but we don't want to have to check this all the time
 567                         Weapon wep = this.(weaponentity).m_weapon;
 568                         wep.wr_playerdeath(wep, this, went);
 569                 }
 570
 571                 RemoveGrapplingHooks(this);
 572
 573                 Portal_ClearAllLater(this);
 574
 575                 this.fixangle = true;
 576
 577                 if(defer_ClientKill_Now_TeamChange)
 578                         ClientKill_Now_TeamChange(this); // can turn player into spectator
 579
 580                 // player could have been miraculously resuscitated ;)
 581                 // e.g. players in freezetag get frozen, they don't really die
 582                 if(this.health >= 1 || !(IS_PLAYER(this) || this.classname == "body"))
 583                         return;
 584
 585                 // when we get here, player actually dies
 586
 587                 Unfreeze(this); // remove any icy remains
 588                 this.health = 0; // Unfreeze resets health, so we need to set it back
 589
 590                 // clear waypoints
 591                 WaypointSprite_PlayerDead(this);
 592                 // throw a weapon
 593                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 594                 {
 595                         .entity went = weaponentities[slot];
 596                         SpawnThrownWeapon(this, this.origin + (this.mins + this.maxs) * 0.5, this.(went).m_weapon, went);
 597                 }
 598
 599                 // become fully visible
 600                 this.alpha = default_player_alpha;
 601                 // make the corpse upright (not tilted)
 602                 this.angles_x = 0;
 603                 this.angles_z = 0;
 604                 // don't spin
 605                 this.avelocity = '0 0 0';
 606                 // view from the floor
 607                 this.view_ofs = '0 0 -8';
 608                 // toss the corpse
 609                 set_movetype(this, MOVETYPE_TOSS);
 610                 // shootable corpse
 611                 this.solid = SOLID_CORPSE;
 612                 PS(this).ballistics_density = autocvar_g_ballistics_density_corpse;
 613                 // don't stick to the floor
 614                 UNSET_ONGROUND(this);
 615                 // dying animation
 616                 this.deadflag = DEAD_DYING;
 617
 618                 STAT(MOVEVARS_SPECIALCOMMAND, this) = false; // sweet release
 619
 620                 // when to allow respawn
 621                 calculate_player_respawn_time(this);
 622
 623                 this.death_time = time;
 624                 if (random() < 0.5)
 625                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD1, true);
 626                 else
 627                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD2, true);
 628                 if (this.maxs.z > 5)
 629                 {
 630                         this.maxs_z = 5;
 631                         setsize(this, this.mins, this.maxs);
 632                 }
 633                 // set damage function to corpse damage
 634                 this.event_damage = PlayerCorpseDamage;
 635                 // call the corpse damage function just in case it wants to gib
 636                 this.event_damage(this, inflictor, attacker, excess, deathtype, hitloc, force);
 637
 638                 // set up to fade out later
 639                 SUB_SetFade (this, time + 6 + random (), 1);
 640                 // reset body think wrapper broken by SUB_SetFade
 641                 if(this.classname == "body" && getthink(this) != CopyBody_Think) {
 642                         this.CopyBody_think = getthink(this);
 643                         this.CopyBody_nextthink = this.nextthink;
 644                         setthink(this, CopyBody_Think);
 645                         this.nextthink = time;
 646                 }
 647
 648                 if(autocvar_sv_gentle > 0 || autocvar_ekg || this.classname == "body") {
 649                         // remove corpse
 650                         // clones don't run any animation code any more, so we must gib them when they die :(
 651                         PlayerCorpseDamage(this, inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 652                 }
 653
 654                 // reset fields the weapons may use just in case
 655                 if(this.classname != "body")
 656                 {
 657                         FOREACH(Weapons, it != WEP_Null,
 658                         {
 659                                 it.wr_resetplayer(it, this);
 660                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 661                                 {
 662                                         ATTACK_FINISHED_FOR(this, it.m_id, slot) = 0;
 663                                 }
 664                         });
 665                 }
 666                 MUTATOR_CALLHOOK(PlayerDied, this);
 667         }
 668 }
 669
 670 bool MoveToTeam(entity client, int team_colour, int type)
 671 {
 672         int lockteams_backup = lockteams;  // backup any team lock
 673         lockteams = 0;  // disable locked teams
 674         TeamchangeFrags(client);  // move the players frags
 675         if (!SetPlayerTeamSimple(client, team_colour))
 676         {
 677                 return false;
 678         }
 679         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE.m_id, client.origin, '0 0 0');  // kill the player
 680         lockteams = lockteams_backup;  // restore the team lock
 681         LogTeamchange(client.playerid, client.team, type);
 682         return true;
 683 }
 684
 685 /** print(), but only print if the server is not local */
 686 void dedicated_print(string input)
 687 {
 688         if (server_is_dedicated) print(input);
 689 }
 690
 691 void PrintToChat(entity player, string text)
 692 {
 693         text = strcat("\{1}^7", text, "\n");
 694         sprint(player, text);
 695 }
 696
 697 void DebugPrintToChat(entity player, string text)
 698 {
 699         if (autocvar_developer)
 700         {
 701                 PrintToChat(player, text);
 702         }
 703 }
 704
 705 void PrintToChatAll(string text)
 706 {
 707         text = strcat("\{1}^7", text, "\n");
 708         bprint(text);
 709 }
 710
 711 void DebugPrintToChatAll(string text)
 712 {
 713         if (autocvar_developer)
 714         {
 715                 PrintToChatAll(text);
 716         }
 717 }
 718
 719 void PrintToChatTeam(int teamnum, string text)
 720 {
 721         text = strcat("\{1}^7", text, "\n");
 722         FOREACH_CLIENT(IS_REAL_CLIENT(it),
 723         {
 724                 if (it.team == teamnum)
 725                 {
 726                         sprint(it, text);
 727                 }
 728         });
 729 }
 730
 731 void DebugPrintToChatTeam(int teamnum, string text)
 732 {
 733         if (autocvar_developer)
 734         {
 735                 PrintToChatTeam(teamnum, text);
 736         }
 737 }
 738
 739 /**
 740  * message "": do not say, just test flood control
 741  * return value:
 742  *   1 = accept
 743  *   0 = reject
 744  *  -1 = fake accept
 745  */
 746 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
 747 {
 748         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
 749         msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
 750
 751     if(source)
 752                 msgin = formatmessage(source, msgin);
 753
 754     string colorstr;
 755         if (!IS_PLAYER(source))
 756                 colorstr = "^0"; // black for spectators
 757         else if(teamplay)
 758                 colorstr = Team_ColorCode(source.team);
 759         else
 760         {
 761                 colorstr = "";
 762                 teamsay = false;
 763         }
 764
 765         if(game_stopped)
 766                 teamsay = false;
 767
 768     if (!source) {
 769                 colorstr = "";
 770                 teamsay = false;
 771     }
 772
 773         if(msgin != "")
 774                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 775
 776         /*
 777          * using bprint solves this... me stupid
 778         // how can we prevent the message from appearing in a listen server?
 779         // for now, just give "say" back and only handle say_team
 780         if(!teamsay)
 781         {
 782                 clientcommand(source, strcat("say ", msgin));
 783                 return;
 784         }
 785         */
 786
 787     string namestr = "";
 788     if (source)
 789         namestr = playername(source, autocvar_g_chat_teamcolors);
 790
 791     string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
 792
 793     string msgstr, cmsgstr;
 794     string privatemsgprefix = string_null;
 795     int privatemsgprefixlen = 0;
 796         if (msgin == "") {
 797         msgstr = cmsgstr = "";
 798         } else {
 799                 if(privatesay)
 800                 {
 801                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 802                         privatemsgprefixlen = strlen(msgstr);
 803                         msgstr = strcat(msgstr, msgin);
 804                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 805                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
 806                 }
 807                 else if(teamsay)
 808                 {
 809                         if(strstrofs(msgin, "/me", 0) >= 0)
 810                         {
 811                                 //msgin = strreplace("/me", "", msgin);
 812                                 //msgin = substring(msgin, 3, strlen(msgin));
 813                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
 814                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
 815                         }
 816                         else
 817                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 818                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 819                 }
 820                 else
 821                 {
 822                         if(strstrofs(msgin, "/me", 0) >= 0)
 823                         {
 824                                 //msgin = strreplace("/me", "", msgin);
 825                                 //msgin = substring(msgin, 3, strlen(msgin));
 826                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
 827                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
 828                         }
 829                         else {
 830                 msgstr = "\{1}";
 831                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
 832                 msgstr = strcat(msgstr, msgin);
 833             }
 834                         cmsgstr = "";
 835                 }
 836                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 837         }
 838
 839         string fullmsgstr = msgstr;
 840         string fullcmsgstr = cmsgstr;
 841
 842         // FLOOD CONTROL
 843         int flood = 0;
 844         var .float flood_field = floodcontrol_chat;
 845         if(floodcontrol && source)
 846         {
 847                 float flood_spl;
 848                 float flood_burst;
 849                 float flood_lmax;
 850                 float lines;
 851                 if(privatesay)
 852                 {
 853                         flood_spl = autocvar_g_chat_flood_spl_tell;
 854                         flood_burst = autocvar_g_chat_flood_burst_tell;
 855                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 856                         flood_field = floodcontrol_chattell;
 857                 }
 858                 else if(teamsay)
 859                 {
 860                         flood_spl = autocvar_g_chat_flood_spl_team;
 861                         flood_burst = autocvar_g_chat_flood_burst_team;
 862                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 863                         flood_field = floodcontrol_chatteam;
 864                 }
 865                 else
 866                 {
 867                         flood_spl = autocvar_g_chat_flood_spl;
 868                         flood_burst = autocvar_g_chat_flood_burst;
 869                         flood_lmax = autocvar_g_chat_flood_lmax;
 870                         flood_field = floodcontrol_chat;
 871                 }
 872                 flood_burst = max(0, flood_burst - 1);
 873                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 874
 875                 // do flood control for the default line size
 876                 if(msgstr != "")
 877                 {
 878                         getWrappedLine_remaining = msgstr;
 879                         msgstr = "";
 880                         lines = 0;
 881                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 882                         {
 883                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 884                                 ++lines;
 885                         }
 886                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 887
 888                         if(getWrappedLine_remaining != "")
 889                         {
 890                                 msgstr = strcat(msgstr, "\n");
 891                                 flood = 2;
 892                         }
 893
 894                         if (time >= source.(flood_field))
 895                         {
 896                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
 897                         }
 898                         else
 899                         {
 900                                 flood = 1;
 901                                 msgstr = fullmsgstr;
 902                         }
 903                 }
 904                 else
 905                 {
 906                         if (time >= source.(flood_field))
 907                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
 908                         else
 909                                 flood = 1;
 910                 }
 911
 912                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 913                         source.(flood_field) = flood = 0;
 914         }
 915
 916     string sourcemsgstr, sourcecmsgstr;
 917         if(flood == 2) // cannot happen for empty msgstr
 918         {
 919                 if(autocvar_g_chat_flood_notify_flooder)
 920                 {
 921                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 922                         sourcecmsgstr = "";
 923                 }
 924                 else
 925                 {
 926                         sourcemsgstr = fullmsgstr;
 927                         sourcecmsgstr = fullcmsgstr;
 928                 }
 929                 cmsgstr = "";
 930         }
 931         else
 932         {
 933                 sourcemsgstr = msgstr;
 934                 sourcecmsgstr = cmsgstr;
 935         }
 936
 937         if (!privatesay && source && !IS_PLAYER(source))
 938         {
 939                 if (!game_stopped)
 940                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
 941                         teamsay = -1; // spectators
 942         }
 943
 944         if(flood)
 945                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.\n");
 946
 947         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 948         if(privatesay)
 949                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 950
 951     int ret;
 952         if(source && CS(source).muted)
 953         {
 954                 // always fake the message
 955                 ret = -1;
 956         }
 957         else if(flood == 1)
 958         {
 959                 if (autocvar_g_chat_flood_notify_flooder)
 960                 {
 961                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
 962                         ret = 0;
 963                 }
 964                 else
 965                         ret = -1;
 966         }
 967         else
 968         {
 969                 ret = 1;
 970         }
 971
 972         if (privatesay && source && !IS_PLAYER(source))
 973         {
 974                 if (!game_stopped)
 975                 if ((privatesay && !IS_PLAYER(privatesay)) || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
 976                         ret = -1; // just hide the message completely
 977         }
 978
 979         MUTATOR_CALLHOOK(ChatMessage, source, ret);
 980         ret = M_ARGV(1, int);
 981
 982         if(sourcemsgstr != "" && ret != 0)
 983         {
 984                 if(ret < 0) // faked message, because the player is muted
 985                 {
 986                         sprint(source, sourcemsgstr);
 987                         if(sourcecmsgstr != "" && !privatesay)
 988                                 centerprint(source, sourcecmsgstr);
 989                 }
 990                 else if(privatesay) // private message, between 2 people only
 991                 {
 992                         sprint(source, sourcemsgstr);
 993                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 994                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
 995                         {
 996                                 sprint(privatesay, msgstr);
 997                                 if(cmsgstr != "")
 998                                         centerprint(privatesay, cmsgstr);
 999                         }
1000                 }
1001                 else if ( teamsay && CS(source).active_minigame )
1002                 {
1003                         sprint(source, sourcemsgstr);
1004                         dedicated_print(msgstr); // send to server console too
1005                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1006                 }
1007                 else if(teamsay > 0) // team message, only sent to team mates
1008                 {
1009                         sprint(source, sourcemsgstr);
1010                         dedicated_print(msgstr); // send to server console too
1011                         if(sourcecmsgstr != "")
1012                                 centerprint(source, sourcecmsgstr);
1013                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
1014                                 sprint(it, msgstr);
1015                                 if(cmsgstr != "")
1016                                         centerprint(it, cmsgstr);
1017                         });
1018                 }
1019                 else if(teamsay < 0) // spectator message, only sent to spectators
1020                 {
1021                         sprint(source, sourcemsgstr);
1022                         dedicated_print(msgstr); // send to server console too
1023                         FOREACH_CLIENT(!IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1024                 }
1025                 else
1026                 {
1027             if (source) {
1028                 sprint(source, sourcemsgstr);
1029                 dedicated_print(msgstr); // send to server console too
1030                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
1031             }
1032             FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), sprint(it, msgstr));
1033         }
1034         }
1035
1036         return ret;
1037 }