qcsrc/server/playerstats.qc

   1 float playerstats_db;
   2 string teamstats_last;
   3 string playerstats_last;
   4 string events_last;
   5 .float playerstats_addedglobalinfo;
   6 .string playerstats_id;
   7
   8 void PlayerStats_Init() // initiated before InitGameplayMode so that scores are added properly
   9 {
  10         string uri;
  11         playerstats_db = -1;
  12         playerstats_waitforme = TRUE;
  13         uri = autocvar_g_playerstats_uri;
  14         if(uri == "")
  15                 return;
  16         playerstats_db = db_create();
  17         if(playerstats_db >= 0)
  18                 playerstats_waitforme = FALSE; // must wait for it at match end
  19
  20         serverflags |= SERVERFLAG_PLAYERSTATS;
  21
  22         PlayerStats_AddEvent(PLAYERSTATS_ALIVETIME);
  23         PlayerStats_AddEvent(PLAYERSTATS_AVGLATENCY);
  24         PlayerStats_AddEvent(PLAYERSTATS_WINS);
  25         PlayerStats_AddEvent(PLAYERSTATS_MATCHES);
  26         PlayerStats_AddEvent(PLAYERSTATS_JOINS);
  27         PlayerStats_AddEvent(PLAYERSTATS_SCOREBOARD_VALID);
  28         PlayerStats_AddEvent(PLAYERSTATS_SCOREBOARD_POS);
  29         PlayerStats_AddEvent(PLAYERSTATS_RANK);
  30
  31     // accuracy stats
  32     entity w;
  33     float i;
  34     for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  35     {
  36         w = get_weaponinfo(i);
  37
  38         PlayerStats_AddEvent(strcat("acc-", w.netname, "-hit"));
  39         PlayerStats_AddEvent(strcat("acc-", w.netname, "-fired"));
  40
  41         PlayerStats_AddEvent(strcat("acc-", w.netname, "-cnt-hit"));
  42         PlayerStats_AddEvent(strcat("acc-", w.netname, "-cnt-fired"));
  43
  44         PlayerStats_AddEvent(strcat("acc-", w.netname, "-frags"));
  45     }
  46
  47         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3);
  48         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5);
  49         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10);
  50         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15);
  51         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20);
  52         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25);
  53         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30);
  54         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_BOTLIKE);
  55         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD);
  56         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM);
  57 }
  58
  59 void PlayerStats_AddPlayer(entity e)
  60 {
  61         string s;
  62
  63         if(playerstats_db < 0)
  64                 return;
  65         if(e.playerstats_id)
  66                 return;
  67
  68         s = string_null;
  69         if(e.crypto_idfp != "" && e.cvar_cl_allow_uidtracking == 1)
  70                 s = e.crypto_idfp;
  71         else if(clienttype(e) == CLIENTTYPE_BOT)
  72                 s = sprintf("bot#%g#%s", skill, e.cleanname);
  73
  74         if((s == "") || find(world, playerstats_id, s)) // already have one of the ID - next one can't be tracked then!
  75         {
  76                 if(clienttype(e) == CLIENTTYPE_BOT)
  77                         s = sprintf("bot#%d", e.playerid);
  78                 else
  79                         s = sprintf("player#%d", e.playerid);
  80         }
  81
  82         e.playerstats_id = strzone(s);
  83
  84         string key;
  85         key = sprintf("%s:*", e.playerstats_id);
  86
  87         string p;
  88         p = db_get(playerstats_db, key);
  89         if(p == "")
  90         {
  91                 if(playerstats_last)
  92                 {
  93                         db_put(playerstats_db, key, playerstats_last);
  94                         strunzone(playerstats_last);
  95                 }
  96                 else
  97                         db_put(playerstats_db, key, "#");
  98                 playerstats_last = strzone(e.playerstats_id);
  99         }
 100 }
 101
 102 void PlayerStats_AddTeam(float t) // TODO: doesn't this remain unused?
 103 {
 104         if(playerstats_db < 0)
 105                 return;
 106
 107         string key;
 108         key = sprintf("%d", t);
 109
 110         string p;
 111         p = db_get(playerstats_db, key);
 112         if(p == "")
 113         {
 114                 if(teamstats_last)
 115                 {
 116                         db_put(playerstats_db, key, teamstats_last);
 117                         strunzone(teamstats_last);
 118                 }
 119                 else
 120                         db_put(playerstats_db, key, "#");
 121                 teamstats_last = strzone(key);
 122         }
 123 }
 124
 125 void PlayerStats_AddEvent(string event_id)
 126 {
 127         if(playerstats_db < 0)
 128                 return;
 129
 130         string key;
 131         key = sprintf("*:%s", event_id);
 132
 133         string p;
 134         p = db_get(playerstats_db, key);
 135         if(p == "")
 136         {
 137                 if(events_last)
 138                 {
 139                         db_put(playerstats_db, key, events_last);
 140                         strunzone(events_last);
 141                 }
 142                 else
 143                         db_put(playerstats_db, key, "#");
 144                 events_last = strzone(event_id);
 145         }
 146 }
 147
 148 float PlayerStats_Event(entity e, string event_id, float value)
 149 {
 150         if((e.playerstats_id == "") || playerstats_db < 0)
 151                 return 0;
 152
 153         string key;
 154         float val;
 155         key = sprintf("%s:%s", e.playerstats_id, event_id);
 156         val = stof(db_get(playerstats_db, key));
 157         val += value;
 158         db_put(playerstats_db, key, ftos(val));
 159         return val;
 160 }
 161
 162 void PlayerStats_TeamScore(float t, string event_id, float value) // TODO: doesn't this remain unused?
 163 {
 164         string key;
 165         float val;
 166         key = sprintf("team#%d:%s", t, event_id);
 167         val = stof(db_get(playerstats_db, key));
 168         val += value;
 169         db_put(playerstats_db, key, ftos(val));
 170 }
 171
 172 /*
 173         format spec:
 174
 175         A collection of lines of the format <key> SPACE <value> NEWLINE, where
 176         <key> is always a single character.
 177
 178         The following keys are defined:
 179
 180         V: format version (always a fixed number) - this MUST be the first line!
 181         #: comment (MUST be ignored by any parser)
 182         R: release information on the server
 183         T: time at which the game ended
 184         G: game type
 185         O: mod name (icon request) as in server browser
 186         M: map name
 187         I: match ID (see "matchid" in g_world.qc
 188         S: "hostname" of the server
 189         C: number of "unpure" cvar changes
 190         U: UDP port number of the server
 191         D: duration of the match
 192         P: player ID of an existing player; this also sets the owner for all following "n", "e" and "t" lines (lower case!)
 193         n: nickname of the player (optional)
 194         t: team ID
 195         i: player index
 196         e: followed by an event name, a space, and the event count/score
 197                 event names can be:
 198                         alivetime: total playing time of the player
 199                         avglatency: average network latency compounded throughout the match
 200                         wins: number of games won (can only be set if matches is set)
 201                         matches: number of matches played to the end (not aborted by map switch)
 202                         joins: number of matches joined (always 1 unless player never played during the match)
 203                         scoreboardvalid: set to 1 if the player was there at the end of the match
 204                         total-<scoreboardname>: total score of that scoreboard item
 205                         scoreboard-<scoreboardname>: end-of-game score of that scoreboard item (can differ in non-team games)
 206                         achievement-<achievementname>: achievement counters (their "count" is usually 1 if nonzero at all)
 207                         kills-<index>: number of kills against the indexed player
 208                         rank <number>: rank of player
 209                         acc-<weapon netname>-hit: total damage dealt
 210                         acc-<weapon netname>-fired: total damage that all fired projectiles *could* have dealt
 211                         acc-<weapon netname>-cnt-hit: amount of shots that actually hit
 212                         acc-<weapon netname>-cnt-fired: amount of fired shots
 213                         acc-<weapon netname>-frags: amount of frags dealt by weapon
 214
 215         Response format (not used yet): see https://gist.github.com/4284222
 216 */
 217
 218 void PlayerStats_ready(entity fh, entity pass, float status)
 219 {
 220         string p, pn;
 221         string e, en;
 222         string nn, tt;
 223         string s;
 224
 225         switch(status)
 226         {
 227                 case URL_READY_CANWRITE:
 228                         url_fputs(fh, "V 6\n");
 229 #ifdef WATERMARK
 230                         url_fputs(fh, sprintf("R %s\n", WATERMARK));
 231 #endif
 232                         url_fputs(fh, sprintf("T %s.%06d\n", strftime(FALSE, "%s"), floor(random() * 1000000)));
 233                         url_fputs(fh, sprintf("G %s\n", GetGametype()));
 234                         url_fputs(fh, sprintf("O %s\n", modname));
 235                         url_fputs(fh, sprintf("M %s\n", GetMapname()));
 236                         url_fputs(fh, sprintf("I %s\n", matchid));
 237                         url_fputs(fh, sprintf("S %s\n", cvar_string("hostname")));
 238                         url_fputs(fh, sprintf("C %d\n", cvar_purechanges_count));
 239                         url_fputs(fh, sprintf("U %d\n", cvar("port")));
 240                         url_fputs(fh, sprintf("D %f\n", max(0, time - game_starttime)));
 241                         for(p = playerstats_last; (pn = db_get(playerstats_db, sprintf("%s:*", p))) != ""; p = pn)
 242                         {
 243                                 url_fputs(fh, sprintf("P %s\n", p));
 244                                 nn = db_get(playerstats_db, sprintf("%s:_playerid", p));
 245                                 if(nn != "")
 246                                         url_fputs(fh, sprintf("i %s\n", nn));
 247                                 nn = db_get(playerstats_db, sprintf("%s:_netname", p));
 248                                 if(nn != "")
 249                                         url_fputs(fh, sprintf("n %s\n", nn));
 250                                 if(teamplay)
 251                                 {
 252                                         tt = db_get(playerstats_db, sprintf("%s:_team", p));
 253                                         url_fputs(fh, sprintf("t %s\n", tt));
 254                                 }
 255                                 for(e = events_last; (en = db_get(playerstats_db, sprintf("*:%s", e))) != ""; e = en)
 256                                 {
 257                                         float v;
 258                                         v = stof(db_get(playerstats_db, sprintf("%s:%s", p, e)));
 259                                         if(v != 0)
 260                                                 url_fputs(fh, sprintf("e %s %g\n", e, v));
 261                                 }
 262                         }
 263                         url_fputs(fh, "\n");
 264                         url_fclose(fh);
 265                         break;
 266                 case URL_READY_CANREAD:
 267                         // url_fclose is processing, we got a response for writing the data
 268                         // this must come from HTTP
 269                         print("Got response from player stats server:\n");
 270                         while((s = url_fgets(fh)))
 271                                 print("  ", s, "\n");
 272                         print("End of response.\n");
 273                         url_fclose(fh);
 274                         break;
 275                 case URL_READY_CLOSED:
 276                         // url_fclose has finished
 277                         print("Player stats written\n");
 278                         playerstats_waitforme = TRUE;
 279                         db_close(playerstats_db);
 280                         playerstats_db = -1;
 281                         break;
 282                 case URL_READY_ERROR:
 283                 default:
 284                         print("Player stats writing failed: ", ftos(status), "\n");
 285                         playerstats_waitforme = TRUE;
 286                         if(playerstats_db >= 0)
 287                         {
 288                                 db_close(playerstats_db);
 289                                 playerstats_db = -1;
 290                         }
 291                         break;
 292         }
 293 }
 294
 295 //#NO AUTOCVARS START
 296 void PlayerStats_Shutdown()
 297 {
 298         string uri;
 299
 300         if(playerstats_db < 0)
 301                 return;
 302
 303         uri = autocvar_g_playerstats_uri;
 304         if(uri != "")
 305         {
 306                 playerstats_waitforme = FALSE;
 307                 url_multi_fopen(uri, FILE_APPEND, PlayerStats_ready, world);
 308         }
 309         else
 310         {
 311                 playerstats_waitforme = TRUE;
 312                 db_close(playerstats_db);
 313                 playerstats_db = -1;
 314         }
 315 }
 316 //#NO AUTOCVARS END
 317
 318 void PlayerStats_Accuracy(entity p)
 319 {
 320     entity a, w;
 321     a = p.accuracy;
 322     float i;
 323
 324     for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 325     {
 326         w = get_weaponinfo(i);
 327
 328         PlayerStats_Event(p, strcat("acc-", w.netname, "-hit"), a.(accuracy_hit[i-1]));
 329         PlayerStats_Event(p, strcat("acc-", w.netname, "-fired"), a.(accuracy_fired[i-1]));
 330
 331         PlayerStats_Event(p, strcat("acc-", w.netname, "-cnt-hit"), a.(accuracy_cnt_hit[i-1]));
 332         PlayerStats_Event(p, strcat("acc-", w.netname, "-cnt-fired"), a.(accuracy_cnt_fired[i-1]));
 333
 334         PlayerStats_Event(p, strcat("acc-", w.netname, "-frags"), a.(accuracy_frags[i-1]));
 335     }
 336     //backtrace(strcat("adding player stat accuracy for ", p.netname, ".\n"));
 337 }
 338
 339 void PlayerStats_AddGlobalInfo(entity p)
 340 {
 341         if(playerstats_db < 0)
 342                 return;
 343         if((p.playerstats_id == "") || playerstats_db < 0)
 344                 return;
 345         p.playerstats_addedglobalinfo = TRUE;
 346
 347         // add global info!
 348         if(p.alivetime)
 349         {
 350                 PlayerStats_Event(p, PLAYERSTATS_ALIVETIME, time - p.alivetime);
 351                 p.alivetime = 0;
 352         }
 353
 354         db_put(playerstats_db, sprintf("%s:_playerid", p.playerstats_id), ftos(p.playerid));
 355
 356         if(p.cvar_cl_allow_uid2name == 1 || clienttype(p) == CLIENTTYPE_BOT)
 357                 db_put(playerstats_db, sprintf("%s:_netname", p.playerstats_id), p.netname);
 358
 359         if(teamplay)
 360                 db_put(playerstats_db, sprintf("%s:_team", p.playerstats_id), ftos(p.team));
 361
 362         if(stof(db_get(playerstats_db, sprintf("%d:%s", p.playerstats_id, PLAYERSTATS_ALIVETIME))) > 0)
 363                 PlayerStats_Event(p, PLAYERSTATS_JOINS, 1);
 364
 365         PlayerStats_Accuracy(p);
 366
 367         if(clienttype(p) == CLIENTTYPE_REAL)
 368         {
 369                 if(p.latency_cnt)
 370                 {
 371                         float latency = (p.latency_sum / p.latency_cnt);
 372                         if(latency) { PlayerStats_Event(p, PLAYERSTATS_AVGLATENCY, latency); }
 373                 }
 374         }
 375
 376         strunzone(p.playerstats_id);
 377         p.playerstats_id = string_null;
 378 }
 379
 380 .float scoreboard_pos;
 381 void PlayerStats_EndMatch(float finished)
 382 {
 383         entity p;
 384         PlayerScore_Sort(score_dummyfield, 0, 0, 0);
 385         PlayerScore_Sort(scoreboard_pos, 1, 1, 1);
 386         FOR_EACH_CLIENT(p)
 387         {
 388                 // add personal score rank
 389                 PlayerStats_Event(p, PLAYERSTATS_RANK, p.score_dummyfield);
 390
 391                 if(!p.scoreboard_pos)
 392                         continue;
 393
 394                 // scoreboard is valid!
 395                 PlayerStats_Event(p, PLAYERSTATS_SCOREBOARD_VALID, 1);
 396
 397                 // add scoreboard position
 398                 PlayerStats_Event(p, PLAYERSTATS_SCOREBOARD_POS, p.scoreboard_pos);
 399
 400                 // add scoreboard data
 401                 PlayerScore_PlayerStats(p);
 402
 403                 // if the match ended normally, add winning info
 404                 if(finished)
 405                 {
 406                         PlayerStats_Event(p, PLAYERSTATS_WINS, p.winning);
 407                         PlayerStats_Event(p, PLAYERSTATS_MATCHES, 1);
 408                 }
 409         }
 410 }