Merge remote-tracking branch 'origin/samual/fix_deathfade'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / playerstats.qc
1 float playerstats_db;
2 string teamstats_last;
3 string playerstats_last;
4 string events_last;
5 .float playerstats_addedglobalinfo;
6 .string playerstats_id;
7
8 void PlayerStats_Init() // initiated before InitGameplayMode so that scores are added properly
9 {
10         string uri;
11         playerstats_db = -1;
12         playerstats_waitforme = TRUE;
13         uri = autocvar_g_playerstats_uri;
14         if(uri == "")
15                 return;
16         playerstats_db = db_create();
17         if(playerstats_db >= 0)
18                 playerstats_waitforme = FALSE; // must wait for it at match end
19
20         serverflags |= SERVERFLAG_PLAYERSTATS;  
21
22         PlayerStats_AddEvent(PLAYERSTATS_ALIVETIME);
23         PlayerStats_AddEvent(PLAYERSTATS_AVGLATENCY);
24         PlayerStats_AddEvent(PLAYERSTATS_WINS);
25         PlayerStats_AddEvent(PLAYERSTATS_MATCHES);
26         PlayerStats_AddEvent(PLAYERSTATS_JOINS);
27         PlayerStats_AddEvent(PLAYERSTATS_SCOREBOARD_VALID);
28         PlayerStats_AddEvent(PLAYERSTATS_SCOREBOARD_POS);
29         PlayerStats_AddEvent(PLAYERSTATS_RANK);
30
31     // accuracy stats
32     entity w;
33     float i;
34     for(i = WEP_FIRST; i <= WEP_LAST; ++i)
35     {
36         w = get_weaponinfo(i);
37
38         PlayerStats_AddEvent(strcat("acc-", w.netname, "-hit"));
39         PlayerStats_AddEvent(strcat("acc-", w.netname, "-fired"));
40
41         PlayerStats_AddEvent(strcat("acc-", w.netname, "-cnt-hit"));
42         PlayerStats_AddEvent(strcat("acc-", w.netname, "-cnt-fired"));
43
44         PlayerStats_AddEvent(strcat("acc-", w.netname, "-frags"));
45     }
46
47         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3);
48         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5);
49         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10);
50         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15);
51         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20);
52         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25);
53         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30);
54         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_BOTLIKE);
55         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD);
56         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM);
57 }
58
59 void PlayerStats_AddPlayer(entity e)
60 {
61         string s;
62
63         if(playerstats_db < 0)
64                 return;
65         if(e.playerstats_id)
66                 return;
67
68         s = string_null;
69         if(e.crypto_idfp != "" && e.cvar_cl_allow_uidtracking == 1)
70                 s = e.crypto_idfp;
71         else if(IS_BOT_CLIENT(e))
72                 s = sprintf("bot#%g#%s", skill, e.cleanname);
73
74         if((s == "") || find(world, playerstats_id, s)) // already have one of the ID - next one can't be tracked then!
75         {
76                 if(IS_BOT_CLIENT(e))
77                         s = sprintf("bot#%d", e.playerid);
78                 else
79                         s = sprintf("player#%d", e.playerid);
80         }
81
82         e.playerstats_id = strzone(s);
83
84         string key;
85         key = sprintf("%s:*", e.playerstats_id);
86         
87         string p;
88         p = db_get(playerstats_db, key);
89         if(p == "")
90         {
91                 if(playerstats_last)
92                 {
93                         db_put(playerstats_db, key, playerstats_last);
94                         strunzone(playerstats_last);
95                 }
96                 else
97                         db_put(playerstats_db, key, "#");
98                 playerstats_last = strzone(e.playerstats_id);
99         }
100 }
101
102 void PlayerStats_AddTeam(float t)
103 {
104         if(playerstats_db < 0)
105                 return;
106
107         string key;
108         key = sprintf("%d", t);
109         
110         string p;
111         p = db_get(playerstats_db, key);
112         if(p == "")
113         {
114                 if(teamstats_last)
115                 {
116                         db_put(playerstats_db, key, teamstats_last);
117                         strunzone(teamstats_last);
118                 }
119                 else
120                         db_put(playerstats_db, key, "#");
121                 teamstats_last = strzone(key);
122         }
123 }
124
125 void PlayerStats_AddEvent(string event_id)
126 {
127         if(playerstats_db < 0)
128                 return;
129         
130         string key;
131         key = sprintf("*:%s", event_id);
132         
133         string p;
134         p = db_get(playerstats_db, key);
135         if(p == "")
136         {
137                 if(events_last)
138                 {
139                         db_put(playerstats_db, key, events_last);
140                         strunzone(events_last);
141                 }
142                 else
143                         db_put(playerstats_db, key, "#");
144                 events_last = strzone(event_id);
145         }
146 }
147
148 float PlayerStats_Event(entity e, string event_id, float value)
149 {
150         if((e.playerstats_id == "") || playerstats_db < 0)
151                 return 0;
152         
153         string key;
154         float val;
155         key = sprintf("%s:%s", e.playerstats_id, event_id);
156         val = stof(db_get(playerstats_db, key));
157         val += value;
158         db_put(playerstats_db, key, ftos(val));
159         return val;
160 }
161
162 void PlayerStats_TeamScore(float t, string event_id, float value)
163 {
164         string key;
165         float val;
166         key = sprintf("team#%d:%s", t, event_id);
167         val = stof(db_get(playerstats_db, key));
168         val += value;
169         db_put(playerstats_db, key, ftos(val));
170 }
171
172 /*
173         format spec:
174
175         A collection of lines of the format <key> SPACE <value> NEWLINE, where
176         <key> is always a single character.
177
178         The following keys are defined:
179
180         V: format version (always a fixed number) - this MUST be the first line!
181         #: comment (MUST be ignored by any parser)
182         R: release information on the server
183         T: time at which the game ended
184         G: game type
185         O: mod name (icon request) as in server browser
186         M: map name
187         I: match ID (see "matchid" in g_world.qc
188         S: "hostname" of the server
189         C: number of "unpure" cvar changes
190         U: UDP port number of the server
191         D: duration of the match
192         P: player ID of an existing player; this also sets the owner for all following "n", "e" and "t" lines (lower case!)
193         Q: team number of an existing team (format: team#NN); this also sets the owner for all following "e" lines (lower case!) 
194         n: nickname of the player (optional)
195         t: team ID
196         i: player index
197         e: followed by an event name, a space, and the event count/score
198                 event names can be:
199                         alivetime: total playing time of the player
200                         avglatency: average network latency compounded throughout the match
201                         wins: number of games won (can only be set if matches is set)
202                         matches: number of matches played to the end (not aborted by map switch)
203                         joins: number of matches joined (always 1 unless player never played during the match)
204                         scoreboardvalid: set to 1 if the player was there at the end of the match
205                         total-<scoreboardname>: total score of that scoreboard item
206                         scoreboard-<scoreboardname>: end-of-game score of that scoreboard item (can differ in non-team games)
207                         achievement-<achievementname>: achievement counters (their "count" is usually 1 if nonzero at all)
208                         kills-<index>: number of kills against the indexed player
209                         rank <number>: rank of player
210                         acc-<weapon netname>-hit: total damage dealt
211                         acc-<weapon netname>-fired: total damage that all fired projectiles *could* have dealt
212                         acc-<weapon netname>-cnt-hit: amount of shots that actually hit
213                         acc-<weapon netname>-cnt-fired: amount of fired shots
214                         acc-<weapon netname>-frags: amount of frags dealt by weapon
215
216         Response format (not used yet): see https://gist.github.com/4284222
217 */
218
219 void PlayerStats_ready(entity fh, entity pass, float status)
220 {
221         string t, tn;
222         string p, pn;
223         string e, en;
224         string nn, tt;
225         string s;
226
227         switch(status)
228         {
229                 case URL_READY_CANWRITE:
230                         url_fputs(fh, "V 7\n");
231 #ifdef WATERMARK
232                         url_fputs(fh, sprintf("R %s\n", WATERMARK));
233 #endif
234                         url_fputs(fh, sprintf("T %s.%06d\n", strftime(FALSE, "%s"), floor(random() * 1000000)));
235                         url_fputs(fh, sprintf("G %s\n", GetGametype()));
236                         url_fputs(fh, sprintf("O %s\n", modname));
237                         url_fputs(fh, sprintf("M %s\n", GetMapname()));
238                         url_fputs(fh, sprintf("I %s\n", matchid));
239                         url_fputs(fh, sprintf("S %s\n", cvar_string("hostname")));
240                         url_fputs(fh, sprintf("C %d\n", cvar_purechanges_count));
241                         url_fputs(fh, sprintf("U %d\n", cvar("port")));
242                         url_fputs(fh, sprintf("D %f\n", max(0, time - game_starttime)));
243                         if(teamplay)
244                         {
245                                 for(t = teamstats_last; (tn = db_get(playerstats_db, sprintf("%d", stof(t)))) != ""; t = tn)
246                                 {
247                                         url_fputs(fh, sprintf("Q team#%s\n", t));
248                                         for(e = events_last; (en = db_get(playerstats_db, sprintf("*:%s", e))) != ""; e = en)
249                                         {
250                                                 float v;
251                                                 v = stof(db_get(playerstats_db, sprintf("team#%d:%s", stof(t), e)));
252                                                 if(v != 0)
253                                                         url_fputs(fh, sprintf("e %s %g\n", e, v));
254                                         }
255                                 }
256                         }
257                         for(p = playerstats_last; (pn = db_get(playerstats_db, sprintf("%s:*", p))) != ""; p = pn)
258                         {
259                                 url_fputs(fh, sprintf("P %s\n", p));
260                                 nn = db_get(playerstats_db, sprintf("%s:_playerid", p));
261                                 if(nn != "")
262                                         url_fputs(fh, sprintf("i %s\n", nn));
263                                 nn = db_get(playerstats_db, sprintf("%s:_netname", p));
264                                 if(nn != "")
265                                         url_fputs(fh, sprintf("n %s\n", nn));
266                                 if(teamplay)
267                                 {
268                                         tt = db_get(playerstats_db, sprintf("%s:_team", p));
269                                         url_fputs(fh, sprintf("t %s\n", tt));
270                                 }
271                                 for(e = events_last; (en = db_get(playerstats_db, sprintf("*:%s", e))) != ""; e = en)
272                                 {
273                                         float v;
274                                         v = stof(db_get(playerstats_db, sprintf("%s:%s", p, e)));
275                                         if(v != 0)
276                                                 url_fputs(fh, sprintf("e %s %g\n", e, v));
277                                 }
278                         }
279                         url_fputs(fh, "\n");
280                         url_fclose(fh);
281                         break;
282                 case URL_READY_CANREAD:
283                         // url_fclose is processing, we got a response for writing the data
284                         // this must come from HTTP
285                         print("Got response from player stats server:\n");
286                         while((s = url_fgets(fh)))
287                                 print("  ", s, "\n");
288                         print("End of response.\n");
289                         url_fclose(fh);
290                         break;
291                 case URL_READY_CLOSED:
292                         // url_fclose has finished
293                         print("Player stats written\n");
294                         playerstats_waitforme = TRUE;
295                         db_close(playerstats_db);
296                         playerstats_db = -1;
297                         break;
298                 case URL_READY_ERROR:
299                 default:
300                         print("Player stats writing failed: ", ftos(status), "\n");
301                         playerstats_waitforme = TRUE;
302                         if(playerstats_db >= 0)
303                         {
304                                 db_close(playerstats_db);
305                                 playerstats_db = -1;
306                         }
307                         break;
308         }
309 }
310
311 //#NO AUTOCVARS START
312 void PlayerStats_Shutdown()
313 {
314         string uri;
315
316         if(playerstats_db < 0)
317                 return;
318
319         uri = autocvar_g_playerstats_uri;
320         if(uri != "")
321         {
322                 playerstats_waitforme = FALSE;
323                 url_multi_fopen(uri, FILE_APPEND, PlayerStats_ready, world);
324         }
325         else
326         {
327                 playerstats_waitforme = TRUE;
328                 db_close(playerstats_db);
329                 playerstats_db = -1;
330         }
331 }
332 //#NO AUTOCVARS END
333
334 void PlayerStats_Accuracy(entity p)
335 {
336     entity a, w;
337     a = p.accuracy;
338     float i;
339
340     for(i = WEP_FIRST; i <= WEP_LAST; ++i)
341     {
342         w = get_weaponinfo(i);
343
344         PlayerStats_Event(p, strcat("acc-", w.netname, "-hit"), a.(accuracy_hit[i-1]));
345         PlayerStats_Event(p, strcat("acc-", w.netname, "-fired"), a.(accuracy_fired[i-1]));
346
347         PlayerStats_Event(p, strcat("acc-", w.netname, "-cnt-hit"), a.(accuracy_cnt_hit[i-1]));
348         PlayerStats_Event(p, strcat("acc-", w.netname, "-cnt-fired"), a.(accuracy_cnt_fired[i-1]));
349
350         PlayerStats_Event(p, strcat("acc-", w.netname, "-frags"), a.(accuracy_frags[i-1]));
351     }
352     //backtrace(strcat("adding player stat accuracy for ", p.netname, ".\n"));
353 }
354
355 void PlayerStats_AddGlobalInfo(entity p)
356 {
357         if(playerstats_db < 0)
358                 return;
359         if((p.playerstats_id == "") || playerstats_db < 0)
360                 return;
361         p.playerstats_addedglobalinfo = TRUE;
362
363         // add global info!
364         if(p.alivetime)
365         {
366                 PlayerStats_Event(p, PLAYERSTATS_ALIVETIME, time - p.alivetime);
367                 p.alivetime = 0;
368         }
369
370         db_put(playerstats_db, sprintf("%s:_playerid", p.playerstats_id), ftos(p.playerid));
371
372         if(p.cvar_cl_allow_uid2name == 1 || IS_BOT_CLIENT(p))
373                 db_put(playerstats_db, sprintf("%s:_netname", p.playerstats_id), p.netname);
374
375         if(teamplay)
376                 db_put(playerstats_db, sprintf("%s:_team", p.playerstats_id), ftos(p.team));
377
378         if(stof(db_get(playerstats_db, sprintf("%d:%s", p.playerstats_id, PLAYERSTATS_ALIVETIME))) > 0)
379                 PlayerStats_Event(p, PLAYERSTATS_JOINS, 1);
380
381         PlayerStats_Accuracy(p);
382
383         if(IS_REAL_CLIENT(p))
384         {
385                 if(p.latency_cnt)
386                 {
387                         float latency = (p.latency_sum / p.latency_cnt);
388                         if(latency) { PlayerStats_Event(p, PLAYERSTATS_AVGLATENCY, latency); }
389                 }
390         }
391
392         strunzone(p.playerstats_id);
393         p.playerstats_id = string_null;
394 }
395
396 .float scoreboard_pos;
397 void PlayerStats_EndMatch(float finished)
398 {
399         entity p;
400         PlayerScore_Sort(score_dummyfield, 0, 0, 0);
401         PlayerScore_Sort(scoreboard_pos, 1, 1, 1);
402         if(teamplay)
403                 PlayerScore_TeamStats();
404         FOR_EACH_CLIENT(p)
405         {
406                 // add personal score rank
407                 PlayerStats_Event(p, PLAYERSTATS_RANK, p.score_dummyfield);
408
409                 if(!p.scoreboard_pos)
410                         continue;
411
412                 // scoreboard is valid!
413                 PlayerStats_Event(p, PLAYERSTATS_SCOREBOARD_VALID, 1);
414
415                 // add scoreboard position
416                 PlayerStats_Event(p, PLAYERSTATS_SCOREBOARD_POS, p.scoreboard_pos);
417
418                 // add scoreboard data
419                 PlayerScore_PlayerStats(p);
420
421                 // if the match ended normally, add winning info
422                 if(finished)
423                 {
424                         PlayerStats_Event(p, PLAYERSTATS_WINS, p.winning);
425                         PlayerStats_Event(p, PLAYERSTATS_MATCHES, 1);
426                 }
427         }
428 }