qcsrc/server/playerstats.qc

   1 float playerstats_db;
   2 string teamstats_last;
   3 string playerstats_last;
   4 string events_last;
   5 .float playerstats_addedglobalinfo;
   6 .string playerstats_id;
   7
   8 void PlayerStats_Init()
   9 {
  10         string uri;
  11         playerstats_db = -1;
  12         playerstats_waitforme = TRUE;
  13         uri = autocvar_g_playerstats_uri;
  14         if(uri == "")
  15                 return;
  16         playerstats_db = db_create();
  17         if(playerstats_db >= 0)
  18                 playerstats_waitforme = FALSE; // must wait for it at match end
  19
  20         serverflags |= SERVERFLAG_PLAYERSTATS;
  21
  22         PlayerStats_AddEvent(PLAYERSTATS_ALIVETIME);
  23         PlayerStats_AddEvent(PLAYERSTATS_WINS);
  24         PlayerStats_AddEvent(PLAYERSTATS_MATCHES);
  25         PlayerStats_AddEvent(PLAYERSTATS_JOINS);
  26         PlayerStats_AddEvent(PLAYERSTATS_SCOREBOARD_VALID);
  27         PlayerStats_AddEvent(PLAYERSTATS_RANK);
  28
  29     // accuracy stats
  30     entity w;
  31     float i;
  32     for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  33     {
  34         w = get_weaponinfo(i);
  35
  36         PlayerStats_AddEvent(strcat("acc-", w.netname, "-hit"));
  37         PlayerStats_AddEvent(strcat("acc-", w.netname, "-fired"));
  38
  39         PlayerStats_AddEvent(strcat("acc-", w.netname, "-cnt-hit"));
  40         PlayerStats_AddEvent(strcat("acc-", w.netname, "-cnt-fired"));
  41
  42         PlayerStats_AddEvent(strcat("acc-", w.netname, "-frags"));
  43     }
  44
  45         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3);
  46         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5);
  47         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10);
  48         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15);
  49         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20);
  50         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25);
  51         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30);
  52         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_BOTLIKE);
  53         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD);
  54         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM);
  55 }
  56
  57 void PlayerStats_AddPlayer(entity e)
  58 {
  59         if(playerstats_db < 0)
  60                 return;
  61         if(e.playerstats_id)
  62                 return;
  63
  64         if(e.crypto_idfp != "" && e.cvar_cl_allow_uidtracking == 1)
  65                 e.playerstats_id = strzone(e.crypto_idfp);
  66         else if(clienttype(e) == CLIENTTYPE_BOT)
  67                 e.playerstats_id = strzone(sprintf("bot#%d", e.playerid));
  68         else
  69                 e.playerstats_id = strzone(sprintf("player#%d", e.playerid));
  70
  71         string key;
  72         key = sprintf("%s:*", e.playerstats_id);
  73
  74         string p;
  75         p = db_get(playerstats_db, key);
  76         if(p == "")
  77         {
  78                 if(playerstats_last)
  79                 {
  80                         db_put(playerstats_db, key, playerstats_last);
  81                         strunzone(playerstats_last);
  82                 }
  83                 else
  84                         db_put(playerstats_db, key, "#");
  85                 playerstats_last = strzone(e.playerstats_id);
  86         }
  87 }
  88
  89 void PlayerStats_AddTeam(float t) // TODO: doesn't this remain unused?
  90 {
  91         if(playerstats_db < 0)
  92                 return;
  93
  94         string key;
  95         key = sprintf("%d", t);
  96
  97         string p;
  98         p = db_get(playerstats_db, key);
  99         if(p == "")
 100         {
 101                 if(teamstats_last)
 102                 {
 103                         db_put(playerstats_db, key, teamstats_last);
 104                         strunzone(teamstats_last);
 105                 }
 106                 else
 107                         db_put(playerstats_db, key, "#");
 108                 teamstats_last = strzone(key);
 109         }
 110 }
 111
 112 void PlayerStats_AddEvent(string event_id)
 113 {
 114         if(playerstats_db < 0)
 115                 return;
 116
 117         string key;
 118         key = sprintf("*:%s", event_id);
 119
 120         string p;
 121         p = db_get(playerstats_db, key);
 122         if(p == "")
 123         {
 124                 if(events_last)
 125                 {
 126                         db_put(playerstats_db, key, events_last);
 127                         strunzone(events_last);
 128                 }
 129                 else
 130                         db_put(playerstats_db, key, "#");
 131                 events_last = strzone(event_id);
 132         }
 133 }
 134
 135 void PlayerStats_Event(entity e, string event_id, float value)
 136 {
 137         if(!e.playerstats_id || playerstats_db < 0)
 138                 return;
 139
 140         string key;
 141         float val;
 142         key = sprintf("%s:%s", e.playerstats_id, event_id);
 143         val = stof(db_get(playerstats_db, key));
 144         val += value;
 145         db_put(playerstats_db, key, ftos(val));
 146 }
 147
 148 void PlayerStats_TeamScore(float t, string event_id, float value) // TODO: doesn't this remain unused?
 149 {
 150         string key;
 151         float val;
 152         key = sprintf("team#%d:%s", t, event_id);
 153         val = stof(db_get(playerstats_db, key));
 154         val += value;
 155         db_put(playerstats_db, key, ftos(val));
 156 }
 157
 158 /*
 159         format spec:
 160
 161         A collection of lines of the format <key> SPACE <value> NEWLINE, where
 162         <key> is always a single character.
 163
 164         The following keys are defined:
 165
 166         V: format version (always 1) - this MUST be the first line!
 167         #: comment (MUST be ignored by any parser)
 168         R: release information on the server
 169         T: time at which the game ended
 170         G: game type
 171         M: map name
 172         S: "hostname" of the server
 173         C: number of "unpure" cvar changes
 174         P: player ID of an existing player; this also sets the owner for all following "n", "e" and "t" lines (lower case!)
 175         n: nickname of the player (optional)
 176     t: team ID
 177         e: followed by an event name, a space, and the event count/score
 178                 event names can be:
 179                         alivetime: total playing time of the player
 180                         wins: number of games won (can only be set if matches is set)
 181                         matches: number of matches played to the end (not aborted by map switch)
 182                         joins: number of matches joined (always 1 unless player never played during the match)
 183                         scoreboardvalid: set to 1 if the player was there at the end of the match
 184                         total-<scoreboardname>: total score of that scoreboard item
 185                         scoreboard-<scoreboardname>: end-of-game score of that scoreboard item (can differ in non-team games)
 186                         achievement-<achievementname>: achievement counters
 187                         rank <number>: rank of player
 188                         acc-<weapon netname>-hit: total damage dealt
 189                         acc-<weapon netname>-fired: total damage that all fired projectiles *could* have dealt
 190                         acc-<weapon netname>-cnt-hit: amount of shots that actually hit
 191                         acc-<weapon netname>-cnt-fired: amount of fired shots
 192                         acc-<weapon netname>-frags: amount of frags dealt by weapon
 193 */
 194
 195 void PlayerStats_ready(entity fh, entity pass, float status)
 196 {
 197         string p, pn;
 198         string e, en;
 199         string nn, tt;
 200         string s;
 201
 202         switch(status)
 203         {
 204                 case URL_READY_CANWRITE:
 205                         url_fputs(fh, "V 1\n");
 206 #ifdef WATERMARK
 207                         url_fputs(fh, sprintf("R %s\n", WATERMARK()));
 208 #endif
 209                         url_fputs(fh, sprintf("T %s.%06d\n", strftime(FALSE, "%s"), floor(random() * 1000000)));
 210                         url_fputs(fh, sprintf("G %s\n", GetGametype()));
 211                         url_fputs(fh, sprintf("M %s\n", GetMapname()));
 212                         url_fputs(fh, sprintf("I %s\n", matchid));
 213                         url_fputs(fh, sprintf("S %s\n", cvar_string("hostname")));
 214                         url_fputs(fh, sprintf("C %d\n", cvar_purechanges_count));
 215                         for(p = playerstats_last; (pn = db_get(playerstats_db, sprintf("%s:*", p))) != ""; p = pn)
 216                         {
 217                                 url_fputs(fh, sprintf("P %s\n", p));
 218                                 nn = db_get(playerstats_db, sprintf("%s:_playerid", p));
 219                                 if(nn != "")
 220                                         url_fputs(fh, sprintf("i %s\n", nn));
 221                                 nn = db_get(playerstats_db, sprintf("%s:_netname", p));
 222                                 if(nn != "")
 223                                         url_fputs(fh, sprintf("n %s\n", nn));
 224                                 if(teamplay)
 225                                 {
 226                                         tt = db_get(playerstats_db, sprintf("%s:_team", p));
 227                                         url_fputs(fh, sprintf("t %s\n", tt));
 228                                 }
 229                                 for(e = events_last; (en = db_get(playerstats_db, sprintf("*:%s", e))) != ""; e = en)
 230                                 {
 231                                         float v;
 232                                         v = stof(db_get(playerstats_db, sprintf("%s:%s", p, e)));
 233                                         if(v != 0)
 234                                                 url_fputs(fh, sprintf("e %s %g\n", e, v));
 235                                 }
 236                         }
 237                         url_fputs(fh, "\n");
 238                         url_fclose(fh);
 239                         break;
 240                 case URL_READY_CANREAD:
 241                         // url_fclose is processing, we got a response for writing the data
 242                         // this must come from HTTP
 243                         print("Got response from player stats server:\n");
 244                         while((s = url_fgets(fh)))
 245                                 print("  ", s, "\n");
 246                         print("End of response.\n");
 247                         url_fclose(fh);
 248                         break;
 249                 case URL_READY_CLOSED:
 250                         // url_fclose has finished
 251                         print("Player stats written\n");
 252                         playerstats_waitforme = TRUE;
 253                         db_close(playerstats_db);
 254                         playerstats_db = -1;
 255                         break;
 256                 case URL_READY_ERROR:
 257                 default:
 258                         print("Player stats writing failed: ", ftos(status), "\n");
 259                         playerstats_waitforme = TRUE;
 260                         if(playerstats_db >= 0)
 261                         {
 262                                 db_close(playerstats_db);
 263                                 playerstats_db = -1;
 264                         }
 265                         break;
 266         }
 267 }
 268
 269 //#NO AUTOCVARS START
 270 void PlayerStats_Shutdown()
 271 {
 272         string uri;
 273
 274         if(playerstats_db < 0)
 275                 return;
 276
 277         uri = autocvar_g_playerstats_uri;
 278         if(uri != "")
 279         {
 280                 playerstats_waitforme = FALSE;
 281                 url_multi_fopen(uri, FILE_APPEND, PlayerStats_ready, world);
 282         }
 283         else
 284         {
 285                 playerstats_waitforme = TRUE;
 286                 db_close(playerstats_db);
 287                 playerstats_db = -1;
 288         }
 289 }
 290 //#NO AUTOCVARS END
 291
 292 void PlayerStats_Accuracy(entity p)
 293 {
 294     entity a, w;
 295     a = p.accuracy;
 296     float i;
 297
 298     for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 299     {
 300         w = get_weaponinfo(i);
 301
 302         PlayerStats_Event(p, strcat("acc-", w.netname, "-hit"), a.(accuracy_hit[i-1]));
 303         PlayerStats_Event(p, strcat("acc-", w.netname, "-fired"), a.(accuracy_fired[i-1]));
 304
 305         PlayerStats_Event(p, strcat("acc-", w.netname, "-cnt-hit"), a.(accuracy_cnt_hit[i-1]));
 306         PlayerStats_Event(p, strcat("acc-", w.netname, "-cnt-fired"), a.(accuracy_cnt_fired[i-1]));
 307
 308         PlayerStats_Event(p, strcat("acc-", w.netname, "-frags"), a.(accuracy_frags[i-1]));
 309     }
 310 }
 311
 312 void PlayerStats_AddGlobalInfo(entity p)
 313 {
 314         if(playerstats_db < 0)
 315                 return;
 316         if(!p.playerstats_id || playerstats_db < 0)
 317                 return;
 318         p.playerstats_addedglobalinfo = TRUE;
 319
 320         // add global info!
 321         if(p.alivetime)
 322         {
 323                 PlayerStats_Event(p, PLAYERSTATS_ALIVETIME, time - p.alivetime);
 324                 p.alivetime = 0;
 325         }
 326
 327         db_put(playerstats_db, sprintf("%s:_playerid", p.playerstats_id), ftos(p.playerid));
 328
 329         if(p.cvar_cl_allow_uid2name == 1 || clienttype(p) == CLIENTTYPE_BOT)
 330                 db_put(playerstats_db, sprintf("%s:_netname", p.playerstats_id), p.netname);
 331
 332     if(teamplay)
 333                 db_put(playerstats_db, sprintf("%s:_team", p.playerstats_id), ftos(p.team));
 334
 335         if(stof(db_get(playerstats_db, sprintf("%d:%s", p.playerstats_id, PLAYERSTATS_ALIVETIME))) > 0)
 336                 PlayerStats_Event(p, PLAYERSTATS_JOINS, 1);
 337
 338         PlayerStats_Accuracy(p);
 339
 340         strunzone(p.playerstats_id);
 341         p.playerstats_id = string_null;
 342 }
 343
 344 void PlayerStats_EndMatch(float finished)
 345 {
 346         entity p, winner;
 347         winner = PlayerScore_Sort(score_dummyfield);
 348         FOR_EACH_CLIENT(p) // spectators intentionally not included
 349         {
 350                 PlayerStats_Accuracy(p);
 351                 if(g_arena || g_lms || g_ca)
 352                 {
 353                         if(p.alivetime <= 0)
 354                                 continue;
 355                 }
 356                 else
 357                 {
 358                         if(p.classname != "player")
 359                                 continue;
 360                 }
 361                 PlayerScore_PlayerStats(p);
 362                 PlayerStats_Event(p, PLAYERSTATS_SCOREBOARD_VALID, 1);
 363                 if(finished)
 364                 {
 365                         PlayerStats_Event(p, PLAYERSTATS_WINS, p.winning);
 366                         PlayerStats_Event(p, PLAYERSTATS_MATCHES, 1);
 367                         PlayerStats_Event(p, PLAYERSTATS_RANK, p.score_dummyfield);
 368                 }
 369         }
 370 }