qcsrc/server/portals.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qh"
   5     #include "../dpdefs/dpextensions.qh"
   6     #include "../warpzonelib/anglestransform.qh"
   7     #include "../warpzonelib/util_server.qh"
   8     #include "../common/constants.qh"
   9     #include "../common/util.qh"
  10     #include "../common/weapons/weapons.qh"
  11     #include "autocvars.qh"
  12     #include "defs.qh"
  13     #include "../common/notifications.qh"
  14     #include "../common/deathtypes.qh"
  15     #include "mutators/mutators_include.qh"
  16     #include "../csqcmodellib/sv_model.qh"
  17     #include "portals.qh"
  18     #include "g_hook.qh"
  19 #endif
  20
  21 #define PORTALS_ARE_NOT_SOLID
  22
  23 const vector SAFENUDGE = '1 1 1';
  24 const vector SAFERNUDGE = '8 8 8';
  25
  26 .vector portal_transform;
  27 .vector portal_safe_origin;
  28 .float portal_wants_to_vanish;
  29 .float portal_activatetime;
  30 .float savemodelindex;
  31
  32 float PlayerEdgeDistance(entity p, vector v)
  33 {
  34         vector vbest;
  35
  36         if(v.x < 0) vbest.x = p.mins.x; else vbest.x = p.maxs.x;
  37         if(v.y < 0) vbest.y = p.mins.y; else vbest.y = p.maxs.y;
  38         if(v.z < 0) vbest.z = p.mins.z; else vbest.z = p.maxs.z;
  39
  40         return vbest * v;
  41 }
  42
  43 vector Portal_ApplyTransformToPlayerAngle(vector transform, vector vangle)
  44 {
  45         vector old_forward, old_up;
  46         vector old_yawforward;
  47         vector new_forward, new_up;
  48         vector new_yawforward;
  49
  50         vector ang;
  51         ang = vangle;
  52         /*
  53            ang_x = bound(-89, mod(-ang_x + 180, 360) - 180, 89);
  54            ang = AnglesTransform_ApplyToVAngles(transform, ang);
  55          */
  56
  57         // PLAYERS use different math
  58 #ifndef POSITIVE_PITCH_IS_DOWN
  59         ang.x = -ang.x;
  60 #endif
  61
  62         //print("reference: ", vtos(AnglesTransform_ApplyToVAngles(transform, ang)), "\n");
  63
  64         fixedmakevectors(ang);
  65         old_forward = v_forward;
  66         old_up = v_up;
  67         fixedmakevectors(ang.y * '0 1 0');
  68         old_yawforward = v_forward;
  69
  70         // their aiming directions are portalled...
  71         new_forward = AnglesTransform_Apply(transform, old_forward);
  72         new_up = AnglesTransform_Apply(transform, old_up);
  73         new_yawforward = AnglesTransform_Apply(transform, old_yawforward);
  74
  75         // but now find a new sense of direction
  76         // this is NOT easy!
  77         // assume new_forward points straight up.
  78         // What is our yaw?
  79         //
  80         // new_up could now point forward OR backward... which direction to choose?
  81
  82         if(new_forward.z > 0.7 || new_forward.z < -0.7) // far up; in this case, the "up" vector points backwards
  83         {
  84                 // new_yawforward and new_yawup define the new aiming half-circle
  85                 // we "just" need to find out whether new_up or -new_up is in that half circle
  86                 ang = fixedvectoangles(new_forward); // this still gets us a nice pitch value...
  87                 if(new_up * new_yawforward < 0)
  88                         new_up = -1 * new_up;
  89                 ang.y = vectoyaw(new_up); // this vector is the yaw we want
  90                 //print("UP/DOWN path: ", vtos(ang), "\n");
  91         }
  92         else
  93         {
  94                 // good angles; here, "forward" suffices
  95                 ang = fixedvectoangles(new_forward);
  96                 //print("GOOD path: ", vtos(ang), "\n");
  97         }
  98
  99 #ifndef POSITIVE_PITCH_IS_DOWN
 100         ang.x = -ang.x;
 101 #endif
 102         ang.z = vangle.z;
 103         return ang;
 104 }
 105
 106 .vector right_vector;
 107 float Portal_TeleportPlayer(entity teleporter, entity player)
 108 {
 109         vector from, to, safe, step, transform, ang, newvel;
 110         float planeshift, s, t;
 111
 112         if (!teleporter.enemy)
 113         {
 114                 backtrace("Portal_TeleportPlayer called without other portal being set. Stop.");
 115                 return 0;
 116         }
 117
 118         from = teleporter.origin;
 119         transform = teleporter.portal_transform;
 120
 121         to = teleporter.enemy.origin;
 122         to = to + AnglesTransform_Apply(teleporter.portal_transform, player.origin - from);
 123         newvel = AnglesTransform_Apply(transform, player.velocity);
 124         // this now is INSIDE the plane... can't use that
 125
 126         // shift it out
 127         fixedmakevectors(teleporter.enemy.mangle);
 128
 129         // first shift it ON the plane if needed
 130         planeshift = ((teleporter.enemy.origin - to) * v_forward) + PlayerEdgeDistance(player, v_forward) + 1;
 131         /*
 132         if(planeshift > 0 && (newvel * v_forward) > vlen(newvel) * 0.01)
 133                 // if we can't, let us not do the planeshift and do somewhat incorrect transformation in the end
 134                 to += newvel * (planeshift / (newvel * v_forward));
 135         else
 136         */
 137                 to += v_forward * planeshift;
 138
 139         s = (to - teleporter.enemy.origin) * v_right;
 140         t = (to - teleporter.enemy.origin) * v_up;
 141         s = bound(-48, s, 48);
 142         t = bound(-48, t, 48);
 143         to = teleporter.enemy.origin
 144            + ((to - teleporter.enemy.origin) * v_forward) * v_forward
 145            +     s                                        * v_right
 146            +     t                                        * v_up;
 147
 148         safe = teleporter.enemy.portal_safe_origin; // a valid player origin
 149         step = to + ((safe - to) * v_forward) * v_forward;
 150         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, step, MOVE_NOMONSTERS, player);
 151         if(trace_startsolid)
 152         {
 153                 print("'safe' teleport location is not safe!\n");
 154                 // FAIL TODO why does this happen?
 155                 return 0;
 156         }
 157         safe = trace_endpos + normalize(safe - trace_endpos) * 0;
 158         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, to, MOVE_NOMONSTERS, player);
 159         if(trace_startsolid)
 160         {
 161                 print("trace_endpos in solid, this can't be!\n");
 162                 // FAIL TODO why does this happen? (reported by MrBougo)
 163                 return 0;
 164         }
 165         to = trace_endpos + normalize(safe - trace_endpos) * 0;
 166         //print(vtos(to), "\n");
 167
 168         // ang_x stuff works around weird quake angles
 169         if(IS_PLAYER(player))
 170                 ang = Portal_ApplyTransformToPlayerAngle(transform, player.v_angle);
 171         else
 172                 ang = AnglesTransform_ApplyToAngles(transform, player.angles);
 173
 174         // factor -1 allows chaining portals, but may be weird
 175         player.right_vector = -1 * AnglesTransform_Apply(transform, player.right_vector);
 176
 177         entity oldself = self;
 178         self = player;
 179         MUTATOR_CALLHOOK(PortalTeleport);
 180         player = self;
 181         self = oldself;
 182
 183         if (!teleporter.enemy)
 184         {
 185                 backtrace("Portal_TeleportPlayer ended up without other portal being set BEFORE TeleportPlayer. Stop.");
 186                 return 0;
 187         }
 188
 189         tdeath_hit = 0;
 190         TeleportPlayer(teleporter, player, to, ang, newvel, teleporter.enemy.absmin, teleporter.enemy.absmax, TELEPORT_FLAGS_PORTAL);
 191         if(tdeath_hit)
 192         {
 193                 // telefrag within 1 second of portal creation = amazing
 194                 if(time < teleporter.teleport_time + 1)
 195                         Send_Notification(NOTIF_ONE, player, MSG_ANNCE, ANNCE_ACHIEVEMENT_AMAZING);
 196         }
 197
 198         if (!teleporter.enemy)
 199         {
 200                 backtrace("Portal_TeleportPlayer ended up without other portal being set AFTER TeleportPlayer. Stop.");
 201                 return 0;
 202         }
 203
 204         // reset fade counter
 205         teleporter.portal_wants_to_vanish = 0;
 206         teleporter.fade_time = time + autocvar_g_balance_portal_lifetime;
 207         teleporter.health = autocvar_g_balance_portal_health;
 208         teleporter.enemy.health = autocvar_g_balance_portal_health;
 209
 210         return 1;
 211 }
 212
 213 float Portal_FindSafeOrigin(entity portal)
 214 {
 215         vector o;
 216         o = portal.origin;
 217         portal.mins = PL_MIN - SAFERNUDGE;
 218         portal.maxs = PL_MAX + SAFERNUDGE;
 219         fixedmakevectors(portal.mangle);
 220         portal.origin += 16 * v_forward;
 221         if(!move_out_of_solid(portal))
 222         {
 223 #ifdef DEBUG
 224                 print("NO SAFE ORIGIN\n");
 225 #endif
 226                 return 0;
 227         }
 228         portal.portal_safe_origin = portal.origin;
 229         setorigin(portal, o);
 230         return 1;
 231 }
 232
 233 float Portal_WillHitPlane(vector eorg, vector emins, vector emaxs, vector evel, vector porg, vector pnorm, float psize)
 234 {
 235         float dist, distpersec, delta;
 236         vector v;
 237
 238         dist = (eorg - porg) * pnorm;
 239         dist += min(emins.x * pnorm.x, emaxs.x * pnorm.x);
 240         dist += min(emins.y * pnorm.y, emaxs.y * pnorm.y);
 241         dist += min(emins.z * pnorm.z, emaxs.z * pnorm.z);
 242         if(dist < -1) // other side?
 243                 return 0;
 244 #ifdef PORTALS_ARE_NOT_SOLID
 245         distpersec = evel * pnorm;
 246         if(distpersec >= 0) // going away from the portal?
 247                 return 0;
 248         // we don't need this check with solid portals, them being SOLID_BSP should suffice
 249         delta = dist / distpersec;
 250         v = eorg - evel * delta - porg;
 251         v = v - pnorm * (pnorm * v);
 252         return vlen(v) < psize;
 253 #else
 254         return 1;
 255 #endif
 256 }
 257
 258 void Portal_Touch()
 259 {
 260         vector g;
 261
 262 #ifdef PORTALS_ARE_NOT_SOLID
 263         // portal is being removed?
 264         if(self.solid != SOLID_TRIGGER)
 265                 return; // possibly engine bug
 266
 267         if(IS_PLAYER(other))
 268                 return; // handled by think
 269 #endif
 270
 271         if(other.classname == "item_flag_team")
 272                 return; // never portal these
 273
 274         if(other.classname == "grapplinghook")
 275                 return; // handled by think
 276
 277         if(!self.enemy)
 278                 error("Portal_Touch called for a broken portal\n");
 279
 280 #ifdef PORTALS_ARE_NOT_SOLID
 281         if(trace_fraction < 1)
 282                 return; // only handle TouchAreaGrid ones (only these can teleport)
 283 #else
 284         if(trace_fraction >= 1)
 285                 return; // only handle impacts
 286 #endif
 287
 288         if(other.classname == "porto")
 289         {
 290                 if(other.portal_id == self.portal_id)
 291                         return;
 292         }
 293         if(time < self.portal_activatetime)
 294                 if(other == self.aiment)
 295                 {
 296                         self.portal_activatetime = time + 0.1;
 297                         return;
 298                 }
 299         if(other != self.aiment)
 300                 if(IS_PLAYER(other))
 301                         if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.aiment))
 302                                 return; // cannot go through someone else's portal
 303         if(other.aiment != self.aiment)
 304                 if(IS_PLAYER(other.aiment))
 305                         if(IS_INDEPENDENT_PLAYER(other.aiment) || IS_INDEPENDENT_PLAYER(self.aiment))
 306                                 return; // cannot go through someone else's portal
 307         fixedmakevectors(self.mangle);
 308         g = frametime * '0 0 -1' * autocvar_sv_gravity;
 309         if(!Portal_WillHitPlane(other.origin, other.mins, other.maxs, other.velocity + g, self.origin, v_forward, self.maxs.x))
 310                 return;
 311
 312         /*
 313         if(other.mins_x < PL_MIN_x || other.mins_y < PL_MIN_y || other.mins_z < PL_MIN_z
 314         || other.maxs_x > PL_MAX_x || other.maxs_y > PL_MAX_y || other.maxs_z > PL_MAX_z)
 315         {
 316                 // can't teleport this
 317                 return;
 318         }
 319         */
 320
 321         if(Portal_TeleportPlayer(self, other))
 322                 if(other.classname == "porto")
 323                         if(other.effects & EF_RED)
 324                                 other.effects += EF_BLUE - EF_RED;
 325 }
 326
 327 void Portal_Think();
 328 void Portal_MakeBrokenPortal(entity portal)
 329 {
 330         portal.skin = 2;
 331         portal.solid = SOLID_NOT;
 332         portal.touch = func_null;
 333         portal.think = func_null;
 334         portal.effects = 0;
 335         portal.nextthink = 0;
 336         portal.takedamage = DAMAGE_NO;
 337 }
 338
 339 void Portal_MakeWaitingPortal(entity portal)
 340 {
 341         portal.skin = 2;
 342         portal.solid = SOLID_NOT;
 343         portal.touch = func_null;
 344         portal.think = func_null;
 345         portal.effects = EF_ADDITIVE;
 346         portal.nextthink = 0;
 347         portal.takedamage = DAMAGE_YES;
 348 }
 349
 350 void Portal_MakeInPortal(entity portal)
 351 {
 352         portal.skin = 0;
 353         portal.solid = SOLID_NOT; // this is done when connecting them!
 354         portal.touch = Portal_Touch;
 355         portal.think = Portal_Think;
 356         portal.effects = EF_RED;
 357         portal.nextthink = time;
 358         portal.takedamage = DAMAGE_NO;
 359 }
 360
 361 void Portal_MakeOutPortal(entity portal)
 362 {
 363         portal.skin = 1;
 364         portal.solid = SOLID_NOT;
 365         portal.touch = func_null;
 366         portal.think = func_null;
 367         portal.effects = EF_STARDUST | EF_BLUE;
 368         portal.nextthink = 0;
 369         portal.takedamage = DAMAGE_YES;
 370 }
 371
 372 void Portal_Disconnect(entity teleporter, entity destination)
 373 {
 374         teleporter.enemy = world;
 375         destination.enemy = world;
 376         Portal_MakeBrokenPortal(teleporter);
 377         Portal_MakeBrokenPortal(destination);
 378 }
 379
 380 void Portal_Connect(entity teleporter, entity destination)
 381 {
 382         teleporter.portal_transform = AnglesTransform_RightDivide(AnglesTransform_TurnDirectionFR(destination.mangle), teleporter.mangle);
 383
 384         teleporter.enemy = destination;
 385         destination.enemy = teleporter;
 386         Portal_MakeInPortal(teleporter);
 387         Portal_MakeOutPortal(destination);
 388         teleporter.fade_time = time + autocvar_g_balance_portal_lifetime;
 389         destination.fade_time = teleporter.fade_time;
 390         teleporter.portal_wants_to_vanish = 0;
 391         destination.portal_wants_to_vanish = 0;
 392         teleporter.teleport_time = time;
 393 #ifdef PORTALS_ARE_NOT_SOLID
 394         teleporter.solid = SOLID_TRIGGER;
 395 #else
 396         teleporter.solid = SOLID_BSP;
 397 #endif
 398 }
 399
 400 void Portal_Remove(entity portal, float killed)
 401 {
 402         entity e;
 403         e = portal.enemy;
 404
 405         if(e)
 406         {
 407                 Portal_Disconnect(portal, e);
 408                 Portal_Remove(e, killed);
 409         }
 410
 411         if(portal == portal.aiment.portal_in)
 412                 portal.aiment.portal_in = world;
 413         if(portal == portal.aiment.portal_out)
 414                 portal.aiment.portal_out = world;
 415         //portal.aiment = world;
 416
 417         // makes the portal vanish
 418         if(killed)
 419         {
 420                 fixedmakevectors(portal.mangle);
 421                 sound(portal, CH_SHOTS, "porto/explode.wav", VOL_BASE, ATTEN_NORM);
 422                 pointparticles(particleeffectnum("rocket_explode"), portal.origin + v_forward * 16, v_forward * 1024, 4);
 423                 remove(portal);
 424         }
 425         else
 426         {
 427                 Portal_MakeBrokenPortal(portal);
 428                 sound(portal, CH_SHOTS, "porto/expire.wav", VOL_BASE, ATTEN_NORM);
 429                 SUB_SetFade(portal, time, 0.5);
 430         }
 431 }
 432
 433 void Portal_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 434 {
 435         if(deathtype == DEATH_TELEFRAG)
 436                 return;
 437         if(attacker != self.aiment)
 438                 if(IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(self.aiment))
 439                         return;
 440         self.health -= damage;
 441         if(self.health < 0)
 442                 Portal_Remove(self, 1);
 443 }
 444
 445 void Portal_Think_TryTeleportPlayer(entity e, vector g)
 446 {
 447         if(!Portal_WillHitPlane(e.origin, e.mins, e.maxs, e.velocity + g, self.origin, v_forward, self.maxs.x))
 448                 return;
 449
 450         // if e would hit the portal in a frame...
 451         // already teleport him
 452         tracebox(e.origin, e.mins, e.maxs, e.origin + e.velocity * 2 * frametime, MOVE_NORMAL, e);
 453         if(trace_ent == self)
 454                 Portal_TeleportPlayer(self, e);
 455 }
 456
 457 void Portal_Think()
 458 {
 459         entity e, o;
 460         vector g;
 461
 462 #ifdef PORTALS_ARE_NOT_SOLID
 463         // portal is being removed?
 464         if(self.solid != SOLID_TRIGGER)
 465                 return; // possibly engine bug
 466
 467         if(!self.enemy)
 468                 error("Portal_Think called for a broken portal\n");
 469
 470         o = self.aiment;
 471         self.solid = SOLID_BBOX;
 472         self.aiment = world;
 473
 474         g = frametime * '0 0 -1' * autocvar_sv_gravity;
 475
 476         fixedmakevectors(self.mangle);
 477
 478         FOR_EACH_PLAYER(e)
 479         {
 480                 if(e != o)
 481                         if(IS_INDEPENDENT_PLAYER(e) || IS_INDEPENDENT_PLAYER(o))
 482                                 continue; // cannot go through someone else's portal
 483
 484                 if(e != o || time >= self.portal_activatetime)
 485                         Portal_Think_TryTeleportPlayer(e, g);
 486
 487                 if(e.hook)
 488                         Portal_Think_TryTeleportPlayer(e.hook, g);
 489         }
 490         self.solid = SOLID_TRIGGER;
 491         self.aiment = o;
 492 #endif
 493
 494         self.nextthink = time;
 495
 496         if(time > self.fade_time)
 497                 Portal_Remove(self, 0);
 498 }
 499
 500 float Portal_Customize()
 501 {
 502         if(IS_SPEC(other))
 503                 other = other.enemy;
 504         if(other == self.aiment)
 505         {
 506                 self.modelindex = self.savemodelindex;
 507         }
 508         else if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.aiment))
 509         {
 510                 self.modelindex = 0;
 511         }
 512         else
 513         {
 514                 self.modelindex = self.savemodelindex;
 515         }
 516         return true;
 517 }
 518
 519 // cleanup:
 520 //   when creating in-portal:
 521 //     disconnect
 522 //     clear existing in-portal
 523 //     set as in-portal
 524 //     connect
 525 //   when creating out-portal:
 526 //     disconnect
 527 //     clear existing out-portal
 528 //     set as out-portal
 529 //   when player dies:
 530 //     disconnect portals
 531 //     clear both portals
 532 //   after timeout of in-portal:
 533 //     disconnect portals
 534 //     clear both portals
 535 //   TODO: ensure only one portal shot at once
 536 float Portal_SetInPortal(entity own, entity portal)
 537 {
 538         if(own.portal_in)
 539         {
 540                 if(own.portal_out)
 541                         Portal_Disconnect(own.portal_in, own.portal_out);
 542                 Portal_Remove(own.portal_in, 0);
 543         }
 544         own.portal_in = portal;
 545         if(own.portal_out)
 546         {
 547                 own.portal_out.portal_id = portal.portal_id;
 548                 Portal_Connect(own.portal_in, own.portal_out);
 549         }
 550         return 2;
 551 }
 552 float Portal_SetOutPortal(entity own, entity portal)
 553 {
 554         if(own.portal_out)
 555         {
 556                 if(own.portal_in)
 557                         Portal_Disconnect(own.portal_in, own.portal_out);
 558                 Portal_Remove(own.portal_out, 0);
 559         }
 560         own.portal_out = portal;
 561         if(own.portal_in)
 562         {
 563                 own.portal_in.portal_id = portal.portal_id;
 564                 Portal_Connect(own.portal_in, own.portal_out);
 565         }
 566         return 1;
 567 }
 568 void Portal_ClearAll_PortalsOnly(entity own)
 569 {
 570         if(own.portal_in)
 571                 Portal_Remove(own.portal_in, 0);
 572         if(own.portal_out)
 573                 Portal_Remove(own.portal_out, 0);
 574 }
 575 void Portal_ClearAll(entity own)
 576 {
 577         Portal_ClearAll_PortalsOnly(own);
 578         W_Porto_Remove(own);
 579 }
 580 void Portal_RemoveLater_Think()
 581 {
 582         Portal_Remove(self, self.cnt);
 583 }
 584 void Portal_RemoveLater(entity portal, float kill)
 585 {
 586         Portal_MakeBrokenPortal(portal);
 587         portal.cnt = kill;
 588         portal.think = Portal_RemoveLater_Think;
 589         portal.nextthink = time;
 590 }
 591 void Portal_ClearAllLater_PortalsOnly(entity own)
 592 {
 593         if(own.portal_in)
 594                 Portal_RemoveLater(own.portal_in, 0);
 595         if(own.portal_out)
 596                 Portal_RemoveLater(own.portal_out, 0);
 597 }
 598 void Portal_ClearAllLater(entity own)
 599 {
 600         Portal_ClearAllLater_PortalsOnly(own);
 601         W_Porto_Remove(own);
 602 }
 603 void Portal_ClearWithID(entity own, float id)
 604 {
 605         if(own.portal_in)
 606                 if(own.portal_in.portal_id == id)
 607                 {
 608                         if(own.portal_out)
 609                                 Portal_Disconnect(own.portal_in, own.portal_out);
 610                         Portal_Remove(own.portal_in, 0);
 611                 }
 612         if(own.portal_out)
 613                 if(own.portal_out.portal_id == id)
 614                 {
 615                         if(own.portal_in)
 616                                 Portal_Disconnect(own.portal_in, own.portal_out);
 617                         Portal_Remove(own.portal_out, 0);
 618                 }
 619 }
 620
 621 entity Portal_Spawn(entity own, vector org, vector ang)
 622 {
 623         entity portal;
 624
 625         fixedmakevectors(ang);
 626         if(!CheckWireframeBox(own, org - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 627                 return world;
 628
 629         portal = spawn();
 630         portal.classname = "portal";
 631         portal.aiment = own;
 632         setorigin(portal, org);
 633         portal.mangle = ang;
 634         portal.angles = ang;
 635         portal.angles_x = -portal.angles.x; // is a bmodel
 636         portal.think = Portal_Think;
 637         portal.nextthink = 0;
 638         portal.portal_activatetime = time + 0.1;
 639         portal.takedamage = DAMAGE_AIM;
 640         portal.event_damage = Portal_Damage;
 641         portal.fade_time = time + autocvar_g_balance_portal_lifetime;
 642         portal.health = autocvar_g_balance_portal_health;
 643         setmodel(portal, "models/portal.md3");
 644         portal.savemodelindex = portal.modelindex;
 645         portal.customizeentityforclient = Portal_Customize;
 646
 647         if(!Portal_FindSafeOrigin(portal))
 648         {
 649                 remove(portal);
 650                 return world;
 651         }
 652
 653         setsize(portal, '-48 -48 -48', '48 48 48');
 654         Portal_MakeWaitingPortal(portal);
 655
 656         return portal;
 657 }
 658
 659 float Portal_SpawnInPortalAtTrace(entity own, vector dir, float portal_id_val)
 660 {
 661         entity portal;
 662         vector ang;
 663         vector org;
 664
 665         org = trace_endpos;
 666         ang = fixedvectoangles2(trace_plane_normal, dir);
 667         fixedmakevectors(ang);
 668
 669         portal = Portal_Spawn(own, org, ang);
 670         if(!portal)
 671                 return 0;
 672
 673         portal.portal_id = portal_id_val;
 674         Portal_SetInPortal(own, portal);
 675
 676         return 1;
 677 }
 678
 679 float Portal_SpawnOutPortalAtTrace(entity own, vector dir, float portal_id_val)
 680 {
 681         entity portal;
 682         vector ang;
 683         vector org;
 684
 685         org = trace_endpos;
 686         ang = fixedvectoangles2(trace_plane_normal, dir);
 687         fixedmakevectors(ang);
 688
 689         portal = Portal_Spawn(own, org, ang);
 690         if(!portal)
 691                 return 0;
 692
 693         portal.portal_id = portal_id_val;
 694         Portal_SetOutPortal(own, portal);
 695
 696         return 1;
 697 }