qcsrc/server/portals.qc

   1 #include "portals.qh"
   2 #include "_all.qh"
   3
   4 #include "g_hook.qh"
   5 #include "g_subs.qh"
   6 #include "mutators/mutators_include.qh"
   7 #include "t_teleporters.qh"
   8 #include "../common/constants.qh"
   9 #include "../common/deathtypes.qh"
  10 #include "../common/notifications.qh"
  11 #include "../common/util.qh"
  12 #include "../common/weapons/all.qh"
  13 #include "../csqcmodellib/sv_model.qh"
  14 #include "../warpzonelib/anglestransform.qh"
  15 #include "../warpzonelib/util_server.qh"
  16
  17 #define PORTALS_ARE_NOT_SOLID
  18
  19 const vector SAFENUDGE = '1 1 1';
  20 const vector SAFERNUDGE = '8 8 8';
  21
  22 .vector portal_transform;
  23 .vector portal_safe_origin;
  24 .float portal_wants_to_vanish;
  25 .float portal_activatetime;
  26 .float savemodelindex;
  27
  28 float PlayerEdgeDistance(entity p, vector v)
  29 {
  30         vector vbest;
  31
  32         if(v.x < 0) vbest.x = p.mins.x; else vbest.x = p.maxs.x;
  33         if(v.y < 0) vbest.y = p.mins.y; else vbest.y = p.maxs.y;
  34         if(v.z < 0) vbest.z = p.mins.z; else vbest.z = p.maxs.z;
  35
  36         return vbest * v;
  37 }
  38
  39 vector Portal_ApplyTransformToPlayerAngle(vector transform, vector vangle)
  40 {
  41         vector old_forward, old_up;
  42         vector old_yawforward;
  43         vector new_forward, new_up;
  44         vector new_yawforward;
  45
  46         vector ang;
  47         ang = vangle;
  48         /*
  49            ang_x = bound(-89, mod(-ang_x + 180, 360) - 180, 89);
  50            ang = AnglesTransform_ApplyToVAngles(transform, ang);
  51          */
  52
  53         // PLAYERS use different math
  54 #ifndef POSITIVE_PITCH_IS_DOWN
  55         ang.x = -ang.x;
  56 #endif
  57
  58         //print("reference: ", vtos(AnglesTransform_ApplyToVAngles(transform, ang)), "\n");
  59
  60         fixedmakevectors(ang);
  61         old_forward = v_forward;
  62         old_up = v_up;
  63         fixedmakevectors(ang.y * '0 1 0');
  64         old_yawforward = v_forward;
  65
  66         // their aiming directions are portalled...
  67         new_forward = AnglesTransform_Apply(transform, old_forward);
  68         new_up = AnglesTransform_Apply(transform, old_up);
  69         new_yawforward = AnglesTransform_Apply(transform, old_yawforward);
  70
  71         // but now find a new sense of direction
  72         // this is NOT easy!
  73         // assume new_forward points straight up.
  74         // What is our yaw?
  75         //
  76         // new_up could now point forward OR backward... which direction to choose?
  77
  78         if(new_forward.z > 0.7 || new_forward.z < -0.7) // far up; in this case, the "up" vector points backwards
  79         {
  80                 // new_yawforward and new_yawup define the new aiming half-circle
  81                 // we "just" need to find out whether new_up or -new_up is in that half circle
  82                 ang = fixedvectoangles(new_forward); // this still gets us a nice pitch value...
  83                 if(new_up * new_yawforward < 0)
  84                         new_up = -1 * new_up;
  85                 ang.y = vectoyaw(new_up); // this vector is the yaw we want
  86                 //print("UP/DOWN path: ", vtos(ang), "\n");
  87         }
  88         else
  89         {
  90                 // good angles; here, "forward" suffices
  91                 ang = fixedvectoangles(new_forward);
  92                 //print("GOOD path: ", vtos(ang), "\n");
  93         }
  94
  95 #ifndef POSITIVE_PITCH_IS_DOWN
  96         ang.x = -ang.x;
  97 #endif
  98         ang.z = vangle.z;
  99         return ang;
 100 }
 101
 102 .vector right_vector;
 103 float Portal_TeleportPlayer(entity teleporter, entity player)
 104 {
 105         vector from, to, safe, step, transform, ang, newvel;
 106         float planeshift, s, t;
 107
 108         if (!teleporter.enemy)
 109         {
 110                 backtrace("Portal_TeleportPlayer called without other portal being set. Stop.");
 111                 return 0;
 112         }
 113
 114         from = teleporter.origin;
 115         transform = teleporter.portal_transform;
 116
 117         to = teleporter.enemy.origin;
 118         to = to + AnglesTransform_Apply(teleporter.portal_transform, player.origin - from);
 119         newvel = AnglesTransform_Apply(transform, player.velocity);
 120         // this now is INSIDE the plane... can't use that
 121
 122         // shift it out
 123         fixedmakevectors(teleporter.enemy.mangle);
 124
 125         // first shift it ON the plane if needed
 126         planeshift = ((teleporter.enemy.origin - to) * v_forward) + PlayerEdgeDistance(player, v_forward) + 1;
 127         /*
 128         if(planeshift > 0 && (newvel * v_forward) > vlen(newvel) * 0.01)
 129                 // if we can't, let us not do the planeshift and do somewhat incorrect transformation in the end
 130                 to += newvel * (planeshift / (newvel * v_forward));
 131         else
 132         */
 133                 to += v_forward * planeshift;
 134
 135         s = (to - teleporter.enemy.origin) * v_right;
 136         t = (to - teleporter.enemy.origin) * v_up;
 137         s = bound(-48, s, 48);
 138         t = bound(-48, t, 48);
 139         to = teleporter.enemy.origin
 140            + ((to - teleporter.enemy.origin) * v_forward) * v_forward
 141            +     s                                        * v_right
 142            +     t                                        * v_up;
 143
 144         safe = teleporter.enemy.portal_safe_origin; // a valid player origin
 145         step = to + ((safe - to) * v_forward) * v_forward;
 146         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, step, MOVE_NOMONSTERS, player);
 147         if(trace_startsolid)
 148         {
 149                 print("'safe' teleport location is not safe!\n");
 150                 // FAIL TODO why does this happen?
 151                 return 0;
 152         }
 153         safe = trace_endpos + normalize(safe - trace_endpos) * 0;
 154         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, to, MOVE_NOMONSTERS, player);
 155         if(trace_startsolid)
 156         {
 157                 print("trace_endpos in solid, this can't be!\n");
 158                 // FAIL TODO why does this happen? (reported by MrBougo)
 159                 return 0;
 160         }
 161         to = trace_endpos + normalize(safe - trace_endpos) * 0;
 162         //print(vtos(to), "\n");
 163
 164         // ang_x stuff works around weird quake angles
 165         if(IS_PLAYER(player))
 166                 ang = Portal_ApplyTransformToPlayerAngle(transform, player.v_angle);
 167         else
 168                 ang = AnglesTransform_ApplyToAngles(transform, player.angles);
 169
 170         // factor -1 allows chaining portals, but may be weird
 171         player.right_vector = -1 * AnglesTransform_Apply(transform, player.right_vector);
 172
 173         entity oldself = self;
 174         self = player;
 175         MUTATOR_CALLHOOK(PortalTeleport);
 176         player = self;
 177         self = oldself;
 178
 179         if (!teleporter.enemy)
 180         {
 181                 backtrace("Portal_TeleportPlayer ended up without other portal being set BEFORE TeleportPlayer. Stop.");
 182                 return 0;
 183         }
 184
 185         tdeath_hit = 0;
 186         TeleportPlayer(teleporter, player, to, ang, newvel, teleporter.enemy.absmin, teleporter.enemy.absmax, TELEPORT_FLAGS_PORTAL);
 187         if(tdeath_hit)
 188         {
 189                 // telefrag within 1 second of portal creation = amazing
 190                 if(time < teleporter.teleport_time + 1)
 191                         Send_Notification(NOTIF_ONE, player, MSG_ANNCE, ANNCE_ACHIEVEMENT_AMAZING);
 192         }
 193
 194         if (!teleporter.enemy)
 195         {
 196                 backtrace("Portal_TeleportPlayer ended up without other portal being set AFTER TeleportPlayer. Stop.");
 197                 return 0;
 198         }
 199
 200         // reset fade counter
 201         teleporter.portal_wants_to_vanish = 0;
 202         teleporter.fade_time = time + autocvar_g_balance_portal_lifetime;
 203         teleporter.health = autocvar_g_balance_portal_health;
 204         teleporter.enemy.health = autocvar_g_balance_portal_health;
 205
 206         return 1;
 207 }
 208
 209 float Portal_FindSafeOrigin(entity portal)
 210 {
 211         vector o;
 212         o = portal.origin;
 213         portal.mins = PL_MIN - SAFERNUDGE;
 214         portal.maxs = PL_MAX + SAFERNUDGE;
 215         fixedmakevectors(portal.mangle);
 216         portal.origin += 16 * v_forward;
 217         if(!move_out_of_solid(portal))
 218         {
 219 #ifdef DEBUG
 220                 print("NO SAFE ORIGIN\n");
 221 #endif
 222                 return 0;
 223         }
 224         portal.portal_safe_origin = portal.origin;
 225         setorigin(portal, o);
 226         return 1;
 227 }
 228
 229 float Portal_WillHitPlane(vector eorg, vector emins, vector emaxs, vector evel, vector porg, vector pnorm, float psize)
 230 {
 231         float dist, distpersec, delta;
 232         vector v;
 233
 234         dist = (eorg - porg) * pnorm;
 235         dist += min(emins.x * pnorm.x, emaxs.x * pnorm.x);
 236         dist += min(emins.y * pnorm.y, emaxs.y * pnorm.y);
 237         dist += min(emins.z * pnorm.z, emaxs.z * pnorm.z);
 238         if(dist < -1) // other side?
 239                 return 0;
 240 #ifdef PORTALS_ARE_NOT_SOLID
 241         distpersec = evel * pnorm;
 242         if(distpersec >= 0) // going away from the portal?
 243                 return 0;
 244         // we don't need this check with solid portals, them being SOLID_BSP should suffice
 245         delta = dist / distpersec;
 246         v = eorg - evel * delta - porg;
 247         v = v - pnorm * (pnorm * v);
 248         return vlen(v) < psize;
 249 #else
 250         return 1;
 251 #endif
 252 }
 253
 254 void Portal_Touch()
 255 {
 256         vector g;
 257
 258 #ifdef PORTALS_ARE_NOT_SOLID
 259         // portal is being removed?
 260         if(self.solid != SOLID_TRIGGER)
 261                 return; // possibly engine bug
 262
 263         if(IS_PLAYER(other))
 264                 return; // handled by think
 265 #endif
 266
 267         if(other.classname == "item_flag_team")
 268                 return; // never portal these
 269
 270         if(other.classname == "grapplinghook")
 271                 return; // handled by think
 272
 273         if(!self.enemy)
 274                 error("Portal_Touch called for a broken portal\n");
 275
 276 #ifdef PORTALS_ARE_NOT_SOLID
 277         if(trace_fraction < 1)
 278                 return; // only handle TouchAreaGrid ones (only these can teleport)
 279 #else
 280         if(trace_fraction >= 1)
 281                 return; // only handle impacts
 282 #endif
 283
 284         if(other.classname == "porto")
 285         {
 286                 if(other.portal_id == self.portal_id)
 287                         return;
 288         }
 289         if(time < self.portal_activatetime)
 290                 if(other == self.aiment)
 291                 {
 292                         self.portal_activatetime = time + 0.1;
 293                         return;
 294                 }
 295         if(other != self.aiment)
 296                 if(IS_PLAYER(other))
 297                         if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.aiment))
 298                                 return; // cannot go through someone else's portal
 299         if(other.aiment != self.aiment)
 300                 if(IS_PLAYER(other.aiment))
 301                         if(IS_INDEPENDENT_PLAYER(other.aiment) || IS_INDEPENDENT_PLAYER(self.aiment))
 302                                 return; // cannot go through someone else's portal
 303         fixedmakevectors(self.mangle);
 304         g = frametime * '0 0 -1' * autocvar_sv_gravity;
 305         if(!Portal_WillHitPlane(other.origin, other.mins, other.maxs, other.velocity + g, self.origin, v_forward, self.maxs.x))
 306                 return;
 307
 308         /*
 309         if(other.mins_x < PL_MIN_x || other.mins_y < PL_MIN_y || other.mins_z < PL_MIN_z
 310         || other.maxs_x > PL_MAX_x || other.maxs_y > PL_MAX_y || other.maxs_z > PL_MAX_z)
 311         {
 312                 // can't teleport this
 313                 return;
 314         }
 315         */
 316
 317         if(Portal_TeleportPlayer(self, other))
 318                 if(other.classname == "porto")
 319                         if(other.effects & EF_RED)
 320                                 other.effects += EF_BLUE - EF_RED;
 321 }
 322
 323 void Portal_Think();
 324 void Portal_MakeBrokenPortal(entity portal)
 325 {
 326         portal.skin = 2;
 327         portal.solid = SOLID_NOT;
 328         portal.touch = func_null;
 329         portal.think = func_null;
 330         portal.effects = 0;
 331         portal.nextthink = 0;
 332         portal.takedamage = DAMAGE_NO;
 333 }
 334
 335 void Portal_MakeWaitingPortal(entity portal)
 336 {
 337         portal.skin = 2;
 338         portal.solid = SOLID_NOT;
 339         portal.touch = func_null;
 340         portal.think = func_null;
 341         portal.effects = EF_ADDITIVE;
 342         portal.nextthink = 0;
 343         portal.takedamage = DAMAGE_YES;
 344 }
 345
 346 void Portal_MakeInPortal(entity portal)
 347 {
 348         portal.skin = 0;
 349         portal.solid = SOLID_NOT; // this is done when connecting them!
 350         portal.touch = Portal_Touch;
 351         portal.think = Portal_Think;
 352         portal.effects = EF_RED;
 353         portal.nextthink = time;
 354         portal.takedamage = DAMAGE_NO;
 355 }
 356
 357 void Portal_MakeOutPortal(entity portal)
 358 {
 359         portal.skin = 1;
 360         portal.solid = SOLID_NOT;
 361         portal.touch = func_null;
 362         portal.think = func_null;
 363         portal.effects = EF_STARDUST | EF_BLUE;
 364         portal.nextthink = 0;
 365         portal.takedamage = DAMAGE_YES;
 366 }
 367
 368 void Portal_Disconnect(entity teleporter, entity destination)
 369 {
 370         teleporter.enemy = world;
 371         destination.enemy = world;
 372         Portal_MakeBrokenPortal(teleporter);
 373         Portal_MakeBrokenPortal(destination);
 374 }
 375
 376 void Portal_Connect(entity teleporter, entity destination)
 377 {
 378         teleporter.portal_transform = AnglesTransform_RightDivide(AnglesTransform_TurnDirectionFR(destination.mangle), teleporter.mangle);
 379
 380         teleporter.enemy = destination;
 381         destination.enemy = teleporter;
 382         Portal_MakeInPortal(teleporter);
 383         Portal_MakeOutPortal(destination);
 384         teleporter.fade_time = time + autocvar_g_balance_portal_lifetime;
 385         destination.fade_time = teleporter.fade_time;
 386         teleporter.portal_wants_to_vanish = 0;
 387         destination.portal_wants_to_vanish = 0;
 388         teleporter.teleport_time = time;
 389 #ifdef PORTALS_ARE_NOT_SOLID
 390         teleporter.solid = SOLID_TRIGGER;
 391 #else
 392         teleporter.solid = SOLID_BSP;
 393 #endif
 394 }
 395
 396 void Portal_Remove(entity portal, float killed)
 397 {
 398         entity e;
 399         e = portal.enemy;
 400
 401         if(e)
 402         {
 403                 Portal_Disconnect(portal, e);
 404                 Portal_Remove(e, killed);
 405         }
 406
 407         if(portal == portal.aiment.portal_in)
 408                 portal.aiment.portal_in = world;
 409         if(portal == portal.aiment.portal_out)
 410                 portal.aiment.portal_out = world;
 411         //portal.aiment = world;
 412
 413         // makes the portal vanish
 414         if(killed)
 415         {
 416                 fixedmakevectors(portal.mangle);
 417                 sound(portal, CH_SHOTS, "porto/explode.wav", VOL_BASE, ATTEN_NORM);
 418                 pointparticles(particleeffectnum("rocket_explode"), portal.origin + v_forward * 16, v_forward * 1024, 4);
 419                 remove(portal);
 420         }
 421         else
 422         {
 423                 Portal_MakeBrokenPortal(portal);
 424                 sound(portal, CH_SHOTS, "porto/expire.wav", VOL_BASE, ATTEN_NORM);
 425                 SUB_SetFade(portal, time, 0.5);
 426         }
 427 }
 428
 429 void Portal_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 430 {
 431         if(deathtype == DEATH_TELEFRAG)
 432                 return;
 433         if(attacker != self.aiment)
 434                 if(IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(self.aiment))
 435                         return;
 436         self.health -= damage;
 437         if(self.health < 0)
 438                 Portal_Remove(self, 1);
 439 }
 440
 441 void Portal_Think_TryTeleportPlayer(entity e, vector g)
 442 {
 443         if(!Portal_WillHitPlane(e.origin, e.mins, e.maxs, e.velocity + g, self.origin, v_forward, self.maxs.x))
 444                 return;
 445
 446         // if e would hit the portal in a frame...
 447         // already teleport him
 448         tracebox(e.origin, e.mins, e.maxs, e.origin + e.velocity * 2 * frametime, MOVE_NORMAL, e);
 449         if(trace_ent == self)
 450                 Portal_TeleportPlayer(self, e);
 451 }
 452
 453 void Portal_Think()
 454 {
 455         entity e, o;
 456         vector g;
 457
 458 #ifdef PORTALS_ARE_NOT_SOLID
 459         // portal is being removed?
 460         if(self.solid != SOLID_TRIGGER)
 461                 return; // possibly engine bug
 462
 463         if(!self.enemy)
 464                 error("Portal_Think called for a broken portal\n");
 465
 466         o = self.aiment;
 467         self.solid = SOLID_BBOX;
 468         self.aiment = world;
 469
 470         g = frametime * '0 0 -1' * autocvar_sv_gravity;
 471
 472         fixedmakevectors(self.mangle);
 473
 474         FOR_EACH_PLAYER(e)
 475         {
 476                 if(e != o)
 477                         if(IS_INDEPENDENT_PLAYER(e) || IS_INDEPENDENT_PLAYER(o))
 478                                 continue; // cannot go through someone else's portal
 479
 480                 if(e != o || time >= self.portal_activatetime)
 481                         Portal_Think_TryTeleportPlayer(e, g);
 482
 483                 if(e.hook)
 484                         Portal_Think_TryTeleportPlayer(e.hook, g);
 485         }
 486         self.solid = SOLID_TRIGGER;
 487         self.aiment = o;
 488 #endif
 489
 490         self.nextthink = time;
 491
 492         if(time > self.fade_time)
 493                 Portal_Remove(self, 0);
 494 }
 495
 496 float Portal_Customize()
 497 {
 498         if(IS_SPEC(other))
 499                 other = other.enemy;
 500         if(other == self.aiment)
 501         {
 502                 self.modelindex = self.savemodelindex;
 503         }
 504         else if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.aiment))
 505         {
 506                 self.modelindex = 0;
 507         }
 508         else
 509         {
 510                 self.modelindex = self.savemodelindex;
 511         }
 512         return true;
 513 }
 514
 515 // cleanup:
 516 //   when creating in-portal:
 517 //     disconnect
 518 //     clear existing in-portal
 519 //     set as in-portal
 520 //     connect
 521 //   when creating out-portal:
 522 //     disconnect
 523 //     clear existing out-portal
 524 //     set as out-portal
 525 //   when player dies:
 526 //     disconnect portals
 527 //     clear both portals
 528 //   after timeout of in-portal:
 529 //     disconnect portals
 530 //     clear both portals
 531 //   TODO: ensure only one portal shot at once
 532 float Portal_SetInPortal(entity own, entity portal)
 533 {
 534         if(own.portal_in)
 535         {
 536                 if(own.portal_out)
 537                         Portal_Disconnect(own.portal_in, own.portal_out);
 538                 Portal_Remove(own.portal_in, 0);
 539         }
 540         own.portal_in = portal;
 541         if(own.portal_out)
 542         {
 543                 own.portal_out.portal_id = portal.portal_id;
 544                 Portal_Connect(own.portal_in, own.portal_out);
 545         }
 546         return 2;
 547 }
 548 float Portal_SetOutPortal(entity own, entity portal)
 549 {
 550         if(own.portal_out)
 551         {
 552                 if(own.portal_in)
 553                         Portal_Disconnect(own.portal_in, own.portal_out);
 554                 Portal_Remove(own.portal_out, 0);
 555         }
 556         own.portal_out = portal;
 557         if(own.portal_in)
 558         {
 559                 own.portal_in.portal_id = portal.portal_id;
 560                 Portal_Connect(own.portal_in, own.portal_out);
 561         }
 562         return 1;
 563 }
 564 void Portal_ClearAll_PortalsOnly(entity own)
 565 {
 566         if(own.portal_in)
 567                 Portal_Remove(own.portal_in, 0);
 568         if(own.portal_out)
 569                 Portal_Remove(own.portal_out, 0);
 570 }
 571 void Portal_ClearAll(entity own)
 572 {
 573         Portal_ClearAll_PortalsOnly(own);
 574         W_Porto_Remove(own);
 575 }
 576 void Portal_RemoveLater_Think()
 577 {
 578         Portal_Remove(self, self.cnt);
 579 }
 580 void Portal_RemoveLater(entity portal, float kill)
 581 {
 582         Portal_MakeBrokenPortal(portal);
 583         portal.cnt = kill;
 584         portal.think = Portal_RemoveLater_Think;
 585         portal.nextthink = time;
 586 }
 587 void Portal_ClearAllLater_PortalsOnly(entity own)
 588 {
 589         if(own.portal_in)
 590                 Portal_RemoveLater(own.portal_in, 0);
 591         if(own.portal_out)
 592                 Portal_RemoveLater(own.portal_out, 0);
 593 }
 594 void Portal_ClearAllLater(entity own)
 595 {
 596         Portal_ClearAllLater_PortalsOnly(own);
 597         W_Porto_Remove(own);
 598 }
 599 void Portal_ClearWithID(entity own, float id)
 600 {
 601         if(own.portal_in)
 602                 if(own.portal_in.portal_id == id)
 603                 {
 604                         if(own.portal_out)
 605                                 Portal_Disconnect(own.portal_in, own.portal_out);
 606                         Portal_Remove(own.portal_in, 0);
 607                 }
 608         if(own.portal_out)
 609                 if(own.portal_out.portal_id == id)
 610                 {
 611                         if(own.portal_in)
 612                                 Portal_Disconnect(own.portal_in, own.portal_out);
 613                         Portal_Remove(own.portal_out, 0);
 614                 }
 615 }
 616
 617 entity Portal_Spawn(entity own, vector org, vector ang)
 618 {
 619         entity portal;
 620
 621         fixedmakevectors(ang);
 622         if(!CheckWireframeBox(own, org - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 623                 return world;
 624
 625         portal = spawn();
 626         portal.classname = "portal";
 627         portal.aiment = own;
 628         setorigin(portal, org);
 629         portal.mangle = ang;
 630         portal.angles = ang;
 631         portal.angles_x = -portal.angles.x; // is a bmodel
 632         portal.think = Portal_Think;
 633         portal.nextthink = 0;
 634         portal.portal_activatetime = time + 0.1;
 635         portal.takedamage = DAMAGE_AIM;
 636         portal.event_damage = Portal_Damage;
 637         portal.fade_time = time + autocvar_g_balance_portal_lifetime;
 638         portal.health = autocvar_g_balance_portal_health;
 639         setmodel(portal, "models/portal.md3");
 640         portal.savemodelindex = portal.modelindex;
 641         portal.customizeentityforclient = Portal_Customize;
 642
 643         if(!Portal_FindSafeOrigin(portal))
 644         {
 645                 remove(portal);
 646                 return world;
 647         }
 648
 649         setsize(portal, '-48 -48 -48', '48 48 48');
 650         Portal_MakeWaitingPortal(portal);
 651
 652         return portal;
 653 }
 654
 655 float Portal_SpawnInPortalAtTrace(entity own, vector dir, float portal_id_val)
 656 {
 657         entity portal;
 658         vector ang;
 659         vector org;
 660
 661         org = trace_endpos;
 662         ang = fixedvectoangles2(trace_plane_normal, dir);
 663         fixedmakevectors(ang);
 664
 665         portal = Portal_Spawn(own, org, ang);
 666         if(!portal)
 667                 return 0;
 668
 669         portal.portal_id = portal_id_val;
 670         Portal_SetInPortal(own, portal);
 671
 672         return 1;
 673 }
 674
 675 float Portal_SpawnOutPortalAtTrace(entity own, vector dir, float portal_id_val)
 676 {
 677         entity portal;
 678         vector ang;
 679         vector org;
 680
 681         org = trace_endpos;
 682         ang = fixedvectoangles2(trace_plane_normal, dir);
 683         fixedmakevectors(ang);
 684
 685         portal = Portal_Spawn(own, org, ang);
 686         if(!portal)
 687                 return 0;
 688
 689         portal.portal_id = portal_id_val;
 690         Portal_SetOutPortal(own, portal);
 691
 692         return 1;
 693 }