67e9d73eecb6ba5e3e9b283634b4ee3ec75f31df
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / race.qc
1 #include "race.qh"
2
3 #include "cl_client.qh"
4 #include "portals.qh"
5 #include "scores.qh"
6 #include "spawnpoints.qh"
7 #include "bot/waypoints.qh"
8 #include "bot/navigation.qh"
9 #include "command/getreplies.qh"
10 #include "../common/deathtypes/all.qh"
11 #include "../common/notifications/all.qh"
12 #include "../common/mapinfo.qh"
13 #include "../common/triggers/subs.qh"
14 #include "../lib/warpzone/util_server.qh"
15 #include "../lib/warpzone/common.qh"
16 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
17
18 void race_InitSpectator()
19 {
20         if(g_race_qualifying)
21                 if(msg_entity.enemy.race_laptime)
22                         race_SendNextCheckpoint(msg_entity.enemy, 1);
23 }
24
25 void W_Porto_Fail(float failhard);
26
27 float race_readTime(string map, float pos)
28 {
29         string rr = (g_cts) ? CTS_RECORD : RACE_RECORD;
30
31         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
32 }
33
34 string race_readUID(string map, float pos)
35 {
36         string rr = (g_cts) ? CTS_RECORD : RACE_RECORD;
37
38         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
39 }
40
41 float race_readPos(string map, float t)
42 {
43         float i;
44         for (i = 1; i <= RANKINGS_CNT; ++i)
45         if (race_readTime(map, i) == 0 || race_readTime(map, i) > t)
46                 return i;
47
48         return 0; // pos is zero if unranked
49 }
50
51 void race_writeTime(string map, float t, string myuid)
52 {
53         string rr = (g_cts) ? CTS_RECORD : RACE_RECORD;
54
55         float newpos;
56         newpos = race_readPos(map, t);
57
58         float i, prevpos = 0;
59         for(i = 1; i <= RANKINGS_CNT; ++i)
60         {
61                 if(race_readUID(map, i) == myuid)
62                         prevpos = i;
63         }
64         if (prevpos)
65         {
66                 // player improved his existing record, only have to iterate on ranks between new and old recs
67                 for (i = prevpos; i > newpos; --i)
68                 {
69                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
70                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
71                 }
72         }
73         else
74         {
75                 // player has no ranked record yet
76                 for (i = RANKINGS_CNT; i > newpos; --i)
77                 {
78                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
79                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
80                 }
81         }
82
83         // store new time itself
84         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
85         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
86 }
87
88 string race_readName(string map, float pos)
89 {
90         string rr = (g_cts) ? CTS_RECORD : RACE_RECORD;
91
92         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
93 }
94
95
96 const float MAX_CHECKPOINTS = 255;
97
98 spawnfunc(target_checkpoint);
99
100 .float race_penalty;
101 .float race_penalty_accumulator;
102 .string race_penalty_reason;
103 .float race_checkpoint; // player: next checkpoint that has to be reached
104 .entity race_lastpenalty;
105
106 .entity sprite;
107
108 float race_checkpoint_records[MAX_CHECKPOINTS];
109 string race_checkpoint_recordholders[MAX_CHECKPOINTS];
110 float race_checkpoint_lasttimes[MAX_CHECKPOINTS];
111 float race_checkpoint_lastlaps[MAX_CHECKPOINTS];
112 entity race_checkpoint_lastplayers[MAX_CHECKPOINTS];
113
114 float race_highest_checkpoint;
115 float race_timed_checkpoint;
116
117 float defrag_ents;
118 float defragcpexists;
119
120 float race_NextCheckpoint(float f)
121 {
122         if(f >= race_highest_checkpoint)
123                 return 0;
124         else
125                 return f + 1;
126 }
127
128 float race_PreviousCheckpoint(float f)
129 {
130         if(f == -1)
131                 return 0;
132         else if(f == 0)
133                 return race_highest_checkpoint;
134         else
135                 return f - 1;
136 }
137
138 // encode as:
139 //   0 = common start/finish
140 // 254 = start
141 // 255 = finish
142 float race_CheckpointNetworkID(float f)
143 {
144         if(race_timed_checkpoint)
145         {
146                 if(f == 0)
147                         return 254; // start
148                 else if(f == race_timed_checkpoint)
149                         return 255; // finish
150         }
151         return f;
152 }
153
154 void race_SendNextCheckpoint(entity e, float spec) // qualifying only
155 {
156         float recordtime;
157         string recordholder;
158         float cp;
159
160         if(!e.race_laptime)
161                 return;
162
163         cp = e.race_checkpoint;
164         recordtime = race_checkpoint_records[cp];
165         recordholder = race_checkpoint_recordholders[cp];
166         if(recordholder == e.netname)
167                 recordholder = "";
168
169         if(!IS_REAL_CLIENT(e))
170                 return;
171
172         if(!spec)
173                 msg_entity = e;
174         WRITESPECTATABLE_MSG_ONE(msg_entity, {
175                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
176                 if(spec)
177                 {
178                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING);
179                         //WriteCoord(MSG_ONE, e.race_laptime - e.race_penalty_accumulator);
180                         WriteCoord(MSG_ONE, time - e.race_movetime - e.race_penalty_accumulator);
181                 }
182                 else
183                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_NEXT_QUALIFYING);
184                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player will be at next
185                 WriteInt24_t(MSG_ONE, recordtime);
186                 WriteString(MSG_ONE, recordholder);
187         });
188 }
189
190 void race_send_recordtime(float msg)
191 {
192         // send the server best time
193         WriteHeader(msg, TE_CSQC_RACE);
194         WriteByte(msg, RACE_NET_SERVER_RECORD);
195         WriteInt24_t(msg, race_readTime(GetMapname(), 1));
196 }
197
198
199 void race_send_speedaward(float msg)
200 {
201         // send the best speed of the round
202         WriteHeader(msg, TE_CSQC_RACE);
203         WriteByte(msg, RACE_NET_SPEED_AWARD);
204         WriteInt24_t(msg, floor(speedaward_speed+0.5));
205         WriteString(msg, speedaward_holder);
206 }
207
208 void race_send_speedaward_alltimebest(float msg)
209 {
210         // send the best speed
211         WriteHeader(msg, TE_CSQC_RACE);
212         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
213         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
214         WriteString(msg, speedaward_alltimebest_holder);
215 }
216
217 void race_SendRankings(float pos, float prevpos, float del, float msg)
218 {
219         WriteHeader(msg, TE_CSQC_RACE);
220         WriteByte(msg, RACE_NET_SERVER_RANKINGS);
221         WriteShort(msg, pos);
222         WriteShort(msg, prevpos);
223         WriteShort(msg, del);
224         WriteString(msg, race_readName(GetMapname(), pos));
225         WriteInt24_t(msg, race_readTime(GetMapname(), pos));
226 }
227
228 void race_SendStatus(float id, entity e)
229 {
230         if(!IS_REAL_CLIENT(e))
231                 return;
232
233         float msg;
234         if (id == 0)
235                 msg = MSG_ONE;
236         else
237                 msg = MSG_ALL;
238         msg_entity = e;
239         WRITESPECTATABLE_MSG_ONE(msg_entity, {
240                 WriteHeader(msg, TE_CSQC_RACE);
241                 WriteByte(msg, RACE_NET_SERVER_STATUS);
242                 WriteShort(msg, id);
243                 WriteString(msg, e.netname);
244         });
245 }
246
247 void race_setTime(string map, float t, string myuid, string mynetname, entity e)
248 {
249         // netname only used TEMPORARILY for printing
250         float newpos, player_prevpos;
251         newpos = race_readPos(map, t);
252
253         float i;
254         player_prevpos = 0;
255         for(i = 1; i <= RANKINGS_CNT; ++i)
256         {
257                 if(race_readUID(map, i) == myuid)
258                         player_prevpos = i;
259         }
260
261         float oldrec;
262         string oldrec_holder;
263         if (player_prevpos && (player_prevpos < newpos || !newpos))
264         {
265                 oldrec = race_readTime(GetMapname(), player_prevpos);
266                 race_SendStatus(0, e); // "fail"
267                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_RACE_FAIL_RANKED, mynetname, player_prevpos, t, oldrec);
268                 return;
269         }
270         else if (!newpos)
271         {
272                 // no ranking, time worse than the worst ranked
273                 oldrec = race_readTime(GetMapname(), RANKINGS_CNT);
274                 race_SendStatus(0, e); // "fail"
275                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_RACE_FAIL_UNRANKED, mynetname, RANKINGS_CNT, t, oldrec);
276                 return;
277         }
278
279         // if we didn't hit a return yet, we have a new record!
280
281         // if the player does not have a UID we can unfortunately not store the record, as the rankings system relies on UIDs
282         if(myuid == "")
283         {
284                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_RACE_NEW_MISSING_UID, mynetname, t);
285                 return;
286         }
287
288         oldrec = race_readTime(GetMapname(), newpos);
289         oldrec_holder = race_readName(GetMapname(), newpos);
290
291         // store new ranking
292         race_writeTime(GetMapname(), t, myuid);
293
294         if (newpos == 1)
295         {
296                 write_recordmarker(e, time - TIME_DECODE(t), TIME_DECODE(t));
297                 race_send_recordtime(MSG_ALL);
298         }
299
300         race_SendRankings(newpos, player_prevpos, 0, MSG_ALL);
301         if(rankings_reply)
302                 strunzone(rankings_reply);
303         rankings_reply = strzone(getrankings());
304
305         if(newpos == player_prevpos)
306         {
307                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_RACE_NEW_IMPROVED, mynetname, newpos, t, oldrec);
308                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
309                 else { race_SendStatus(1, e); } // "new time"
310         }
311         else if(oldrec == 0)
312         {
313                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_RACE_NEW_SET, mynetname, newpos, t);
314                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
315                 else { race_SendStatus(2, e); } // "new rank"
316         }
317         else
318         {
319                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_RACE_NEW_BROKEN, mynetname, oldrec_holder, newpos, t, oldrec);
320                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
321                 else { race_SendStatus(2, e); } // "new rank"
322         }
323 }
324
325 void race_deleteTime(string map, float pos)
326 {
327         string rr;
328         if(g_cts)
329                 rr = CTS_RECORD;
330         else
331                 rr = RACE_RECORD;
332
333         float i;
334         for (i = pos; i <= RANKINGS_CNT; ++i)
335         {
336                 if (i == RANKINGS_CNT)
337                 {
338                         db_remove(ServerProgsDB, strcat(map, rr, "time", ftos(i)));
339                         db_remove(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)));
340                 }
341                 else
342                 {
343                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(GetMapname(), i+1)));
344                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(GetMapname(), i+1));
345                 }
346         }
347
348         race_SendRankings(pos, 0, 1, MSG_ALL);
349         if(pos == 1)
350                 race_send_recordtime(MSG_ALL);
351
352         if(rankings_reply)
353                 strunzone(rankings_reply);
354         rankings_reply = strzone(getrankings());
355 }
356
357 void race_SendTime(entity e, float cp, float t, float tvalid)
358 {
359         float snew, l;
360
361         if(g_race_qualifying)
362                 t += e.race_penalty_accumulator;
363
364         t = TIME_ENCODE(t); // make integer
365         // adding just 0.4 so it rounds down in the .5 case (matching the timer display)
366
367         if(tvalid)
368         if(cp == race_timed_checkpoint) // finish line
369         if (!e.race_completed)
370         {
371                 float s;
372                 if(g_race_qualifying)
373                 {
374                         s = PlayerScore_Add(e, SP_RACE_FASTEST, 0);
375                         if(!s || t < s)
376                                 PlayerScore_Add(e, SP_RACE_FASTEST, t - s);
377                 }
378                 else
379                 {
380                         s = PlayerScore_Add(e, SP_RACE_FASTEST, 0);
381                         if(!s || t < s)
382                                 PlayerScore_Add(e, SP_RACE_FASTEST, t - s);
383
384                         s = PlayerScore_Add(e, SP_RACE_TIME, 0);
385                         snew = TIME_ENCODE(time - game_starttime);
386                         PlayerScore_Add(e, SP_RACE_TIME, snew - s);
387                         l = PlayerTeamScore_Add(e, SP_RACE_LAPS, ST_RACE_LAPS, 1);
388
389                         if(autocvar_fraglimit)
390                                 if(l >= autocvar_fraglimit)
391                                         race_StartCompleting();
392
393                         if(race_completing)
394                         {
395                                 e.race_completed = 1;
396                                 MAKE_INDEPENDENT_PLAYER(e);
397                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_RACE_FINISHED, e.netname);
398                                 ClientData_Touch(e);
399                         }
400                 }
401         }
402
403         float recordtime;
404         string recordholder;
405         if(g_race_qualifying)
406         {
407                 if(tvalid)
408                 {
409                         recordtime = race_checkpoint_records[cp];
410                         recordholder = strcat1(race_checkpoint_recordholders[cp]); // make a tempstring copy, as we'll possibly strunzone it!
411                         if(recordholder == e.netname)
412                                 recordholder = "";
413
414                         if(t != 0)
415                         {
416                                 if(cp == race_timed_checkpoint)
417                                 {
418                                         race_setTime(GetMapname(), t, e.crypto_idfp, e.netname, e);
419                                         MUTATOR_CALLHOOK(Race_FinalCheckpoint, e);
420                                 }
421                                 if(t < recordtime || recordtime == 0)
422                                 {
423                                         race_checkpoint_records[cp] = t;
424                                         if(race_checkpoint_recordholders[cp])
425                                                 strunzone(race_checkpoint_recordholders[cp]);
426                                         race_checkpoint_recordholders[cp] = strzone(e.netname);
427                                         if(g_race_qualifying)
428                                         {
429                                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it.race_checkpoint == cp, LAMBDA(race_SendNextCheckpoint(it, 0)));
430                                         }
431                                 }
432                         }
433                 }
434                 else
435                 {
436                         // dummies
437                         t = 0;
438                         recordtime = 0;
439                         recordholder = "";
440                 }
441
442                 if(IS_REAL_CLIENT(e))
443                 {
444                         msg_entity = e;
445                         if(g_race_qualifying)
446                         {
447                                 WRITESPECTATABLE_MSG_ONE(msg_entity, {
448                                         WriteHeader(MSG_ONE, TE_CSQC_RACE);
449                                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_QUALIFYING);
450                                         WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
451                                         WriteInt24_t(MSG_ONE, t); // time to that intermediate
452                                         WriteInt24_t(MSG_ONE, recordtime); // previously best time
453                                         WriteString(MSG_ONE, recordholder); // record holder
454                                 });
455                         }
456                 }
457         }
458         else // RACE! Not Qualifying
459         {
460                 float lself, lother, othtime;
461                 entity oth;
462                 oth = race_checkpoint_lastplayers[cp];
463                 if(oth)
464                 {
465                         lself = PlayerScore_Add(e, SP_RACE_LAPS, 0);
466                         lother = race_checkpoint_lastlaps[cp];
467                         othtime = race_checkpoint_lasttimes[cp];
468                 }
469                 else
470                         lself = lother = othtime = 0;
471
472                 if(IS_REAL_CLIENT(e))
473                 {
474                         msg_entity = e;
475                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
476                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
477                                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_RACE);
478                                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
479                                 if(e == oth)
480                                 {
481                                         WriteInt24_t(MSG_ONE, 0);
482                                         WriteByte(MSG_ONE, 0);
483                                         WriteString(MSG_ONE, "");
484                                 }
485                                 else
486                                 {
487                                         WriteInt24_t(MSG_ONE, TIME_ENCODE(time - race_checkpoint_lasttimes[cp]));
488                                         WriteByte(MSG_ONE, lself - lother);
489                                         WriteString(MSG_ONE, oth.netname); // record holder
490                                 }
491                         });
492                 }
493
494                 race_checkpoint_lastplayers[cp] = e;
495                 race_checkpoint_lasttimes[cp] = time;
496                 race_checkpoint_lastlaps[cp] = lself;
497
498                 if(IS_REAL_CLIENT(oth))
499                 {
500                         msg_entity = oth;
501                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
502                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
503                                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT);
504                                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
505                                 if(e == oth)
506                                 {
507                                         WriteInt24_t(MSG_ONE, 0);
508                                         WriteByte(MSG_ONE, 0);
509                                         WriteString(MSG_ONE, "");
510                                 }
511                                 else
512                                 {
513                                         WriteInt24_t(MSG_ONE, TIME_ENCODE(time - othtime));
514                                         WriteByte(MSG_ONE, lother - lself);
515                                         WriteString(MSG_ONE, e.netname); // record holder
516                                 }
517                         });
518                 }
519         }
520 }
521
522 void race_ClearTime(entity e)
523 {
524         e.race_checkpoint = 0;
525         e.race_laptime = 0;
526         e.race_movetime = e.race_movetime_frac = e.race_movetime_count = 0;
527         e.race_penalty_accumulator = 0;
528         e.race_lastpenalty = world;
529
530         if(!IS_REAL_CLIENT(e))
531                 return;
532
533         msg_entity = e;
534         WRITESPECTATABLE_MSG_ONE(msg_entity, {
535                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
536                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_CLEAR); // next
537         });
538 }
539
540 void dumpsurface(entity e)
541 {
542         float n, si, ni;
543         vector norm, vec;
544         LOG_INFO("Surfaces of ", etos(e), ":\n");
545
546         LOG_INFO("TEST = ", ftos(getsurfacenearpoint(e, '0 0 0')), "\n");
547
548         for(si = 0; ; ++si)
549         {
550                 n = getsurfacenumpoints(e, si);
551                 if(n <= 0)
552                         break;
553                 LOG_INFO("  Surface ", ftos(si), ":\n");
554                 norm = getsurfacenormal(e, si);
555                 LOG_INFO("    Normal = ", vtos(norm), "\n");
556                 for(ni = 0; ni < n; ++ni)
557                 {
558                         vec = getsurfacepoint(e, si, ni);
559                         LOG_INFO("    Point ", ftos(ni), " = ", vtos(vec), " (", ftos(norm * vec), ")\n");
560                 }
561         }
562 }
563
564 void checkpoint_passed(entity this, entity player)
565 {
566         string oldmsg;
567         entity cp;
568
569         if(player.classname == "porto")
570         {
571                 // do not allow portalling through checkpoints
572                 trace_plane_normal = normalize(-1 * player.velocity);
573                 WITHSELF(player, W_Porto_Fail(0));
574                 return;
575         }
576
577         /*
578          * Trigger targets
579          */
580         if (!((this.spawnflags & 2) && (IS_PLAYER(player))))
581         {
582                 oldmsg = this.message;
583                 this.message = "";
584                 SUB_UseTargets(this, player, player); // TODO: should we be using other for the trigger here?
585                 this.message = oldmsg;
586         }
587
588         if (!IS_PLAYER(player))
589                 return;
590
591         /*
592          * Remove unauthorized equipment
593          */
594         Portal_ClearAll(player);
595
596         player.porto_forbidden = 2; // decreased by 1 each StartFrame
597
598         if(defrag_ents)
599         {
600                 if(this.race_checkpoint == -2)
601                 {
602                         this.race_checkpoint = player.race_checkpoint;
603                 }
604
605                 float largest_cp_id = 0;
606                 float cp_amount = 0;
607                 for(cp = world; (cp = find(cp, classname, "target_checkpoint"));)
608                 {
609                         cp_amount += 1;
610                         if(cp.race_checkpoint > largest_cp_id) // update the finish id if someone hit a new checkpoint
611                         {
612                                 largest_cp_id = cp.race_checkpoint;
613                                 for(cp = world; (cp = find(cp, classname, "target_stopTimer"));)
614                                         cp.race_checkpoint = largest_cp_id + 1; // finish line
615                                 race_highest_checkpoint = largest_cp_id + 1;
616                                 race_timed_checkpoint = largest_cp_id + 1;
617
618                                 for(cp = world; (cp = find(cp, classname, "target_checkpoint"));)
619                                 {
620                                         if(cp.race_checkpoint == -2) // set defragcpexists to -1 so that the cp id file will be rewritten when someone finishes
621                                                 defragcpexists = -1;
622                                 }
623                         }
624                 }
625                 if(cp_amount == 0)
626                 {
627                         for(cp = world; (cp = find(cp, classname, "target_stopTimer"));)
628                                 cp.race_checkpoint = 1;
629                         race_highest_checkpoint = 1;
630                         race_timed_checkpoint = 1;
631                 }
632         }
633
634         if((player.race_checkpoint == -1 && this.race_checkpoint == 0) || (player.race_checkpoint == this.race_checkpoint))
635         {
636                 if(this.race_penalty)
637                 {
638                         if(player.race_lastpenalty != this)
639                         {
640                                 player.race_lastpenalty = this;
641                                 race_ImposePenaltyTime(player, this.race_penalty, this.race_penalty_reason);
642                         }
643                 }
644
645                 if(player.race_penalty)
646                         return;
647
648                 /*
649                  * Trigger targets
650                  */
651                 if(this.spawnflags & 2)
652                 {
653                         oldmsg = this.message;
654                         this.message = "";
655                         SUB_UseTargets(this, player, player); // TODO: should we be using other for the trigger here?
656                         this.message = oldmsg;
657                 }
658
659                 if(player.race_respawn_checkpoint != this.race_checkpoint || !player.race_started)
660                         player.race_respawn_spotref = this; // this is not a spot but a CP, but spawnpoint selection will deal with that
661                 player.race_respawn_checkpoint = this.race_checkpoint;
662                 player.race_checkpoint = race_NextCheckpoint(this.race_checkpoint);
663                 player.race_started = 1;
664
665                 race_SendTime(player, this.race_checkpoint, player.race_movetime, boolean(player.race_laptime));
666
667                 if(!this.race_checkpoint) // start line
668                 {
669                         player.race_laptime = time;
670                         player.race_movetime = player.race_movetime_frac = player.race_movetime_count = 0;
671                         player.race_penalty_accumulator = 0;
672                         player.race_lastpenalty = world;
673                 }
674
675                 if(g_race_qualifying)
676                         race_SendNextCheckpoint(player, 0);
677
678                 if(defrag_ents && defragcpexists < 0 && this.classname == "target_stopTimer")
679                 {
680                         float fh;
681                         defragcpexists = fh = fopen(strcat("maps/", GetMapname(), ".defragcp"), FILE_WRITE);
682                         if(fh >= 0)
683                         {
684                                 for(cp = world; (cp = find(cp, classname, "target_checkpoint"));)
685                                 fputs(fh, strcat(cp.targetname, " ", ftos(cp.race_checkpoint), "\n"));
686                         }
687                         fclose(fh);
688                 }
689         }
690         else if(player.race_checkpoint == race_NextCheckpoint(this.race_checkpoint))
691         {
692                 // ignored
693         }
694         else
695         {
696                 if(this.spawnflags & 4)
697                         Damage (player, this, this, 10000, DEATH_HURTTRIGGER.m_id, player.origin, '0 0 0');
698         }
699 }
700
701 void checkpoint_touch()
702 {SELFPARAM();
703         EXACTTRIGGER_TOUCH;
704         checkpoint_passed(this, other);
705 }
706
707 void checkpoint_use(entity this, entity actor, entity trigger)
708 {
709         if(trigger.classname == "info_player_deathmatch") // a spawn, a spawn
710                 return;
711
712         other = actor;
713         checkpoint_passed(this, other);
714 }
715
716 bool race_waypointsprite_visible_for_player(entity this, entity player, entity view)
717 {
718         if(view.race_checkpoint == -1 || this.owner.race_checkpoint == -2)
719                 return true;
720         else if(view.race_checkpoint == this.owner.race_checkpoint)
721                 return true;
722         else
723                 return false;
724 }
725
726 void trigger_race_checkpoint_verify(entity this)
727 {
728     static bool have_verified;
729         if (have_verified) return;
730         have_verified = true;
731
732         bool qual = g_race_qualifying;
733
734         int pl_race_checkpoint = 0;
735         int pl_race_place = 0;
736
737         if (g_race) {
738                 for (int i = 0; i <= race_highest_checkpoint; ++i) {
739                         pl_race_checkpoint = race_NextCheckpoint(i);
740
741                         // race only (middle of the race)
742                         g_race_qualifying = false;
743                         pl_race_place = 0;
744                         if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
745                                 error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for respawning in race) - bailing out"));
746             }
747
748                         if (i == 0) {
749                                 // qualifying only
750                                 g_race_qualifying = 1;
751                                 pl_race_place = race_lowest_place_spawn;
752                                 if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
753                                         error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for qualifying) - bailing out"));
754                 }
755
756                                 // race only (initial spawn)
757                                 g_race_qualifying = 0;
758                                 for (int p = 1; p <= race_highest_place_spawn; ++p) {
759                                         pl_race_place = p;
760                                         if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
761                                                 error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for initially spawning in race) - bailing out"));
762                     }
763                                 }
764                         }
765                 }
766         } else if (!defrag_ents) {
767                 // qualifying only
768                 pl_race_checkpoint = race_NextCheckpoint(0);
769                 g_race_qualifying = 1;
770                 pl_race_place = race_lowest_place_spawn;
771                 if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
772                         error(strcat("Checkpoint 0 misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for qualifying) - bailing out"));
773         }
774         } else {
775                 pl_race_checkpoint = race_NextCheckpoint(0);
776                 g_race_qualifying = 1;
777                 pl_race_place = 0; // there's only one spawn on defrag maps
778
779                 // check if a defragcp file already exists, then read it and apply the checkpoint order
780                 float fh;
781                 float len;
782                 string l;
783
784                 defragcpexists = fh = fopen(strcat("maps/", GetMapname(), ".defragcp"), FILE_READ);
785                 if (fh >= 0) {
786                         while ((l = fgets(fh))) {
787                                 len = tokenize_console(l);
788                                 if (len != 2) {
789                                         defragcpexists = -1; // something's wrong in the defrag cp file, set defragcpexists to -1 so that it will be rewritten when someone finishes
790                                         continue;
791                                 }
792                                 for (entity cp = world; (cp = find(cp, classname, "target_checkpoint"));) {
793                                         if (argv(0) == cp.targetname) {
794                                                 cp.race_checkpoint = stof(argv(1));
795                     }
796                 }
797                         }
798                         fclose(fh);
799                 }
800         }
801
802         g_race_qualifying = qual;
803
804         if (race_timed_checkpoint) {
805                 if (defrag_ents) {
806                         for (entity cp = world; (cp = find(cp, classname, "target_startTimer"));) {
807                                 WaypointSprite_UpdateSprites(cp.sprite, WP_RaceStart, WP_Null, WP_Null);
808             }
809                         for (entity cp = world; (cp = find(cp, classname, "target_stopTimer"));) {
810                                 WaypointSprite_UpdateSprites(cp.sprite, WP_RaceFinish, WP_Null, WP_Null);
811             }
812                         for (entity cp = world; (cp = find(cp, classname, "target_checkpoint"));) {
813                                 if (cp.race_checkpoint == -2) { // something's wrong with the defrag cp file or it has not been written yet, set defragcpexists to -1 so that it will be rewritten when someone finishes
814                                         defragcpexists = -1;
815                 }
816                         }
817                         if (defragcpexists != -1) {
818                                 float largest_cp_id = 0;
819                                 for (entity cp = world; (cp = find(cp, classname, "target_checkpoint"));) {
820                                         if (cp.race_checkpoint > largest_cp_id) {
821                                                 largest_cp_id = cp.race_checkpoint;
822                     }
823                 }
824                                 for (entity cp = world; (cp = find(cp, classname, "target_stopTimer"));) {
825                                         cp.race_checkpoint = largest_cp_id + 1; // finish line
826                 }
827                                 race_highest_checkpoint = largest_cp_id + 1;
828                                 race_timed_checkpoint = largest_cp_id + 1;
829                         } else {
830                                 for (entity cp = world; (cp = find(cp, classname, "target_stopTimer"));) {
831                                         cp.race_checkpoint = 255; // finish line
832                 }
833                                 race_highest_checkpoint = 255;
834                                 race_timed_checkpoint = 255;
835                         }
836                 } else {
837                         for (entity cp = world; (cp = find(cp, classname, "trigger_race_checkpoint")); ) {
838                                 if (cp.sprite) {
839                                         if (cp.race_checkpoint == 0) {
840                                                 WaypointSprite_UpdateSprites(cp.sprite, WP_RaceStart, WP_Null, WP_Null);
841                     } else if (cp.race_checkpoint == race_timed_checkpoint) {
842                                                 WaypointSprite_UpdateSprites(cp.sprite, WP_RaceFinish, WP_Null, WP_Null);
843                     }
844                                 }
845             }
846                 }
847         }
848
849         if (defrag_ents) {
850                 for (entity trigger = world; (trigger = find(trigger, classname, "trigger_multiple")); ) {
851                         for (entity targ = world; (targ = find(targ, targetname, trigger.target)); ) {
852                                 if (targ.classname == "target_checkpoint" || targ.classname == "target_startTimer" || targ.classname == "target_stopTimer") {
853                                         trigger.wait = 0;
854                                         trigger.delay = 0;
855                                         targ.wait = 0;
856                                         targ.delay = 0;
857
858                     // These just make the game crash on some maps with oddly shaped triggers.
859                     // (on the other hand they used to fix the case when two players ran through a checkpoint at once,
860                     // and often one of them just passed through without being registered. Hope it's fixed  in a better way now.
861                     // (happened on item triggers too)
862                     //
863                                         //targ.wait = -2;
864                                         //targ.delay = 0;
865
866                                         //setsize(targ, trigger.mins, trigger.maxs);
867                                         //setorigin(targ, trigger.origin);
868                                         //remove(trigger);
869                                 }
870             }
871         }
872         }
873 }
874
875 vector trigger_race_checkpoint_spawn_evalfunc(entity this, entity player, entity spot, vector current)
876 {
877         if(g_race_qualifying)
878         {
879                 // spawn at first
880                 if(this.race_checkpoint != 0)
881                         return '-1 0 0';
882                 if(spot.race_place != race_lowest_place_spawn)
883                         return '-1 0 0';
884         }
885         else
886         {
887                 if(this.race_checkpoint != player.race_respawn_checkpoint)
888                         return '-1 0 0';
889                 // try reusing the previous spawn
890                 if(this == player.race_respawn_spotref || spot == player.race_respawn_spotref)
891                         current.x += SPAWN_PRIO_RACE_PREVIOUS_SPAWN;
892                 if(this.race_checkpoint == 0)
893                 {
894                         int pl = player.race_place;
895                         if(pl > race_highest_place_spawn)
896                                 pl = 0;
897                         if(pl == 0 && !player.race_started)
898                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
899                         if(spot.race_place != pl)
900                                 return '-1 0 0';
901                 }
902         }
903         return current;
904 }
905
906 spawnfunc(trigger_race_checkpoint)
907 {
908         vector o;
909         if(!g_race && !g_cts) { remove(this); return; }
910
911         EXACTTRIGGER_INIT;
912
913         this.use = checkpoint_use;
914         if (!(this.spawnflags & 1))
915                 settouch(this, checkpoint_touch);
916
917         o = (this.absmin + this.absmax) * 0.5;
918         tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 1' * (o.z - this.absmin.z), MOVE_NORMAL, this);
919         waypoint_spawnforitem_force(this, trace_endpos);
920         this.nearestwaypointtimeout = time + 1000000000;
921
922         if(this.message == "")
923                 this.message = "went backwards";
924         if (this.message2 == "")
925                 this.message2 = "was pushed backwards by";
926         if (this.race_penalty_reason == "")
927                 this.race_penalty_reason = "missing a checkpoint";
928
929         this.race_checkpoint = this.cnt;
930
931         if(this.race_checkpoint > race_highest_checkpoint)
932         {
933                 race_highest_checkpoint = this.race_checkpoint;
934                 if(this.spawnflags & 8)
935                         race_timed_checkpoint = this.race_checkpoint;
936                 else
937                         race_timed_checkpoint = 0;
938         }
939
940         if(!this.race_penalty)
941         {
942                 if(this.race_checkpoint)
943                         WaypointSprite_SpawnFixed(WP_RaceCheckpoint, o, this, sprite, RADARICON_NONE);
944                 else
945                         WaypointSprite_SpawnFixed(WP_RaceStartFinish, o, this, sprite, RADARICON_NONE);
946         }
947
948         this.sprite.waypointsprite_visible_for_player = race_waypointsprite_visible_for_player;
949         this.spawn_evalfunc = trigger_race_checkpoint_spawn_evalfunc;
950
951         InitializeEntity(this, trigger_race_checkpoint_verify, INITPRIO_FINDTARGET);
952 }
953
954 spawnfunc(target_checkpoint) // defrag entity
955 {
956         vector o;
957         if(!g_race && !g_cts) { remove(this); return; }
958         defrag_ents = 1;
959
960         EXACTTRIGGER_INIT;
961
962         this.use = checkpoint_use;
963         if (!(this.spawnflags & 1))
964                 settouch(this, checkpoint_touch);
965
966         o = (this.absmin + this.absmax) * 0.5;
967         tracebox(o, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), o - '0 0 1' * (o.z - this.absmin.z), MOVE_NORMAL, this);
968         waypoint_spawnforitem_force(this, trace_endpos);
969         this.nearestwaypointtimeout = time + 1000000000;
970
971         if(this.message == "")
972                 this.message = "went backwards";
973         if (this.message2 == "")
974                 this.message2 = "was pushed backwards by";
975         if (this.race_penalty_reason == "")
976                 this.race_penalty_reason = "missing a checkpoint";
977
978         if(this.classname == "target_startTimer")
979                 this.race_checkpoint = 0;
980         else
981                 this.race_checkpoint = -2;
982
983         race_timed_checkpoint = 1;
984
985         if(this.race_checkpoint == 0)
986                 WaypointSprite_SpawnFixed(WP_RaceStart, o, this, sprite, RADARICON_NONE);
987         else
988                 WaypointSprite_SpawnFixed(WP_RaceCheckpoint, o, this, sprite, RADARICON_NONE);
989
990         this.sprite.waypointsprite_visible_for_player = race_waypointsprite_visible_for_player;
991
992         InitializeEntity(this, trigger_race_checkpoint_verify, INITPRIO_FINDTARGET);
993 }
994
995 spawnfunc(target_startTimer) { spawnfunc_target_checkpoint(this); }
996 spawnfunc(target_stopTimer) { spawnfunc_target_checkpoint(this); }
997
998 void race_AbandonRaceCheck(entity p)
999 {
1000         if(race_completing && !p.race_completed)
1001         {
1002                 p.race_completed = 1;
1003                 MAKE_INDEPENDENT_PLAYER(p);
1004                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_RACE_ABANDONED, p.netname);
1005                 ClientData_Touch(p);
1006         }
1007 }
1008
1009 void race_StartCompleting()
1010 {
1011         race_completing = 1;
1012         FOREACH_CLIENT(IS_PLAYER(it) && IS_DEAD(it), LAMBDA(race_AbandonRaceCheck(it)));
1013 }
1014
1015 void race_PreparePlayer(entity this)
1016 {
1017         race_ClearTime(this);
1018         this.race_place = 0;
1019         this.race_started = 0;
1020         this.race_respawn_checkpoint = 0;
1021         this.race_respawn_spotref = world;
1022 }
1023
1024 void race_RetractPlayer(entity this)
1025 {
1026         if(!g_race && !g_cts)
1027                 return;
1028         if(this.race_respawn_checkpoint == 0 || this.race_respawn_checkpoint == race_timed_checkpoint)
1029                 race_ClearTime(this);
1030         this.race_checkpoint = this.race_respawn_checkpoint;
1031 }
1032
1033 spawnfunc(info_player_race)
1034 {
1035         if(!g_race && !g_cts) { remove(this); return; }
1036         ++race_spawns;
1037         spawnfunc_info_player_deathmatch(this);
1038
1039         if(this.race_place > race_highest_place_spawn)
1040                 race_highest_place_spawn = this.race_place;
1041         if(this.race_place < race_lowest_place_spawn)
1042                 race_lowest_place_spawn = this.race_place;
1043 }
1044
1045 void race_ClearRecords()
1046 {
1047         float i;
1048
1049         for(i = 0; i < MAX_CHECKPOINTS; ++i)
1050         {
1051                 race_checkpoint_records[i] = 0;
1052                 if(race_checkpoint_recordholders[i])
1053                         strunzone(race_checkpoint_recordholders[i]);
1054                 race_checkpoint_recordholders[i] = string_null;
1055         }
1056
1057         FOREACH_CLIENT(true, LAMBDA(
1058                 float p = it.race_place;
1059                 race_PreparePlayer(it);
1060                 it.race_place = p;
1061         ));
1062 }
1063
1064 void race_ImposePenaltyTime(entity pl, float penalty, string reason)
1065 {
1066         if(g_race_qualifying)
1067         {
1068                 pl.race_penalty_accumulator += penalty;
1069                 if(IS_REAL_CLIENT(pl))
1070                 {
1071                         msg_entity = pl;
1072                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
1073                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
1074                                 WriteByte(MSG_ONE, RACE_NET_PENALTY_QUALIFYING);
1075                                 WriteShort(MSG_ONE, TIME_ENCODE(penalty));
1076                                 WriteString(MSG_ONE, reason);
1077                         });
1078                 }
1079         }
1080         else
1081         {
1082                 pl.race_penalty = time + penalty;
1083                 if(IS_REAL_CLIENT(pl))
1084                 {
1085                         msg_entity = pl;
1086                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
1087                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
1088                                 WriteByte(MSG_ONE, RACE_NET_PENALTY_RACE);
1089                                 WriteShort(MSG_ONE, TIME_ENCODE(penalty));
1090                                 WriteString(MSG_ONE, reason);
1091                         });
1092                 }
1093         }
1094 }
1095
1096 void penalty_touch()
1097 {SELFPARAM();
1098         EXACTTRIGGER_TOUCH;
1099         if(other.race_lastpenalty != this)
1100         {
1101                 other.race_lastpenalty = this;
1102                 race_ImposePenaltyTime(other, this.race_penalty, this.race_penalty_reason);
1103         }
1104 }
1105
1106 void penalty_use(entity this, entity actor, entity trigger)
1107 {
1108         race_ImposePenaltyTime(actor, this.race_penalty, this.race_penalty_reason);
1109 }
1110
1111 spawnfunc(trigger_race_penalty)
1112 {
1113         // TODO: find out why this wasnt done:
1114         //if(!g_cts && !g_race) { remove(this); return; }
1115
1116         EXACTTRIGGER_INIT;
1117
1118         this.use = penalty_use;
1119         if (!(this.spawnflags & 1))
1120                 settouch(this, penalty_touch);
1121
1122         if (this.race_penalty_reason == "")
1123                 this.race_penalty_reason = "missing a checkpoint";
1124         if (!this.race_penalty)
1125                 this.race_penalty = 5;
1126 }
1127
1128 float race_GetFractionalLapCount(entity e)
1129 {
1130         // interesting metrics (idea by KrimZon) to maybe sort players in the
1131         // scoreboard, immediately updates when overtaking
1132         //
1133         // requires the track to be built so you never get farther away from the
1134         // next checkpoint, though, and current Xonotic race maps are not built that
1135         // way
1136         //
1137         // also, this code is slow and would need optimization (i.e. "next CP"
1138         // links on CP entities)
1139
1140         float l;
1141         l = PlayerScore_Add(e, SP_RACE_LAPS, 0);
1142         if(e.race_completed)
1143                 return l; // not fractional
1144
1145         vector o0, o1;
1146         float bestfraction, fraction;
1147         entity lastcp, cp0, cp1;
1148         float nextcpindex, lastcpindex;
1149
1150         nextcpindex = max(e.race_checkpoint, 0);
1151         lastcpindex = e.race_respawn_checkpoint;
1152         lastcp = e.race_respawn_spotref;
1153
1154         if(nextcpindex == lastcpindex)
1155                 return l; // finish
1156
1157         bestfraction = 1;
1158         for(cp0 = world; (cp0 = find(cp0, classname, "trigger_race_checkpoint")); )
1159         {
1160                 if(cp0.race_checkpoint != lastcpindex)
1161                         continue;
1162                 if(lastcp)
1163                         if(cp0 != lastcp)
1164                                 continue;
1165                 o0 = (cp0.absmin + cp0.absmax) * 0.5;
1166                 for(cp1 = world; (cp1 = find(cp1, classname, "trigger_race_checkpoint")); )
1167                 {
1168                         if(cp1.race_checkpoint != nextcpindex)
1169                                 continue;
1170                         o1 = (cp1.absmin + cp1.absmax) * 0.5;
1171                         if(o0 == o1)
1172                                 continue;
1173                         fraction = bound(0.0001, vlen(e.origin - o1) / vlen(o0 - o1), 1);
1174                         if(fraction < bestfraction)
1175                                 bestfraction = fraction;
1176                 }
1177         }
1178
1179         // we are at CP "nextcpindex - bestfraction"
1180         // race_timed_checkpoint == 4: then nextcp==4 means 0.9999x, nextcp==0 means 0.0000x
1181         // race_timed_checkpoint == 0: then nextcp==0 means 0.9999x
1182         float c, nc;
1183         nc = race_highest_checkpoint + 1;
1184         c = ((nextcpindex - race_timed_checkpoint + nc + nc - 1) % nc) + 1 - bestfraction;
1185
1186         return l + c / nc;
1187 }