qcsrc/server/race.qc

   1 #include "race.qh"
   2
   3 #include "client.qh"
   4 #include "portals.qh"
   5 #include "scores.qh"
   6 #include "spawnpoints.qh"
   7 #include "bot/api.qh"
   8 #include "command/getreplies.qh"
   9 #include "../common/deathtypes/all.qh"
  10 #include "../common/notifications/all.qh"
  11 #include "../common/mapinfo.qh"
  12 #include <common/net_linked.qh>
  13 #include "../common/triggers/subs.qh"
  14 #include "../lib/warpzone/util_server.qh"
  15 #include "../lib/warpzone/common.qh"
  16 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  17
  18 IntrusiveList g_race_targets;
  19 STATIC_INIT(g_race_targets) { g_race_targets = IL_NEW(); }
  20
  21 void race_InitSpectator()
  22 {
  23         if(g_race_qualifying)
  24                 if(msg_entity.enemy.race_laptime)
  25                         race_SendNextCheckpoint(msg_entity.enemy, 1);
  26 }
  27
  28 void W_Porto_Fail(entity this, float failhard);
  29
  30 float race_readTime(string map, float pos)
  31 {
  32         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  33
  34         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
  35 }
  36
  37 string race_readUID(string map, float pos)
  38 {
  39         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  40
  41         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
  42 }
  43
  44 float race_readPos(string map, float t)
  45 {
  46         for(int i = 1; i <= RANKINGS_CNT; ++i)
  47         {
  48                 int mytime = race_readTime(map, i);
  49                 if(!mytime || mytime > t)
  50                         return i;
  51         }
  52
  53         return 0; // pos is zero if unranked
  54 }
  55
  56 void race_writeTime(string map, float t, string myuid)
  57 {
  58         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  59
  60         float newpos;
  61         newpos = race_readPos(map, t);
  62
  63         float i, prevpos = 0;
  64         for(i = 1; i <= RANKINGS_CNT; ++i)
  65         {
  66                 if(race_readUID(map, i) == myuid)
  67                         prevpos = i;
  68         }
  69         if (prevpos)
  70         {
  71                 // player improved his existing record, only have to iterate on ranks between new and old recs
  72                 for (i = prevpos; i > newpos; --i)
  73                 {
  74                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
  75                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
  76                 }
  77         }
  78         else
  79         {
  80                 // player has no ranked record yet
  81                 for (i = RANKINGS_CNT; i > newpos; --i)
  82                 {
  83                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
  84                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
  85                 }
  86         }
  87
  88         // store new time itself
  89         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
  90         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
  91 }
  92
  93 string race_readName(string map, float pos)
  94 {
  95         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  96
  97         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
  98 }
  99
 100
 101 const float MAX_CHECKPOINTS = 255;
 102
 103 spawnfunc(target_checkpoint);
 104
 105 .float race_penalty;
 106 .float race_penalty_accumulator;
 107 .string race_penalty_reason;
 108 .float race_checkpoint; // player: next checkpoint that has to be reached
 109 .entity race_lastpenalty;
 110
 111 .entity sprite;
 112
 113 float race_checkpoint_records[MAX_CHECKPOINTS];
 114 string race_checkpoint_recordholders[MAX_CHECKPOINTS];
 115 float race_checkpoint_lasttimes[MAX_CHECKPOINTS];
 116 float race_checkpoint_lastlaps[MAX_CHECKPOINTS];
 117 entity race_checkpoint_lastplayers[MAX_CHECKPOINTS];
 118
 119 float race_highest_checkpoint;
 120 float race_timed_checkpoint;
 121
 122 float defrag_ents;
 123 float defragcpexists;
 124
 125 float race_NextCheckpoint(float f)
 126 {
 127         if(f >= race_highest_checkpoint)
 128                 return 0;
 129         else
 130                 return f + 1;
 131 }
 132
 133 float race_PreviousCheckpoint(float f)
 134 {
 135         if(f == -1)
 136                 return 0;
 137         else if(f == 0)
 138                 return race_highest_checkpoint;
 139         else
 140                 return f - 1;
 141 }
 142
 143 // encode as:
 144 //   0 = common start/finish
 145 // 254 = start
 146 // 255 = finish
 147 float race_CheckpointNetworkID(float f)
 148 {
 149         if(race_timed_checkpoint)
 150         {
 151                 if(f == 0)
 152                         return 254; // start
 153                 else if(f == race_timed_checkpoint)
 154                         return 255; // finish
 155         }
 156         return f;
 157 }
 158
 159 void race_SendNextCheckpoint(entity e, float spec) // qualifying only
 160 {
 161         float recordtime;
 162         string recordholder;
 163         float cp;
 164
 165         if(!e.race_laptime)
 166                 return;
 167
 168         cp = e.race_checkpoint;
 169         recordtime = race_checkpoint_records[cp];
 170         recordholder = race_checkpoint_recordholders[cp];
 171         if(recordholder == e.netname)
 172                 recordholder = "";
 173
 174         if(!IS_REAL_CLIENT(e))
 175                 return;
 176
 177         if(!spec)
 178                 msg_entity = e;
 179         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 180                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 181                 if(spec)
 182                 {
 183                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING);
 184                         //WriteCoord(MSG_ONE, e.race_laptime - e.race_penalty_accumulator);
 185                         WriteCoord(MSG_ONE, time - e.race_movetime - e.race_penalty_accumulator);
 186                 }
 187                 else
 188                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_NEXT_QUALIFYING);
 189                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player will be at next
 190                 WriteInt24_t(MSG_ONE, recordtime);
 191                 WriteString(MSG_ONE, recordholder);
 192         });
 193 }
 194
 195 void race_send_recordtime(float msg)
 196 {
 197         // send the server best time
 198         WriteHeader(msg, TE_CSQC_RACE);
 199         WriteByte(msg, RACE_NET_SERVER_RECORD);
 200         WriteInt24_t(msg, race_readTime(GetMapname(), 1));
 201 }
 202
 203
 204 void race_send_speedaward(float msg)
 205 {
 206         // send the best speed of the round
 207         WriteHeader(msg, TE_CSQC_RACE);
 208         WriteByte(msg, RACE_NET_SPEED_AWARD);
 209         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 210         WriteString(msg, speedaward_holder);
 211 }
 212
 213 void race_send_speedaward_alltimebest(float msg)
 214 {
 215         // send the best speed
 216         WriteHeader(msg, TE_CSQC_RACE);
 217         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 218         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
 219         WriteString(msg, speedaward_alltimebest_holder);
 220 }
 221
 222 void race_SendRankings(float pos, float prevpos, float del, float msg)
 223 {
 224         WriteHeader(msg, TE_CSQC_RACE);
 225         WriteByte(msg, RACE_NET_SERVER_RANKINGS);
 226         WriteShort(msg, pos);
 227         WriteShort(msg, prevpos);
 228         WriteShort(msg, del);
 229         WriteString(msg, race_readName(GetMapname(), pos));
 230         WriteInt24_t(msg, race_readTime(GetMapname(), pos));
 231 }
 232
 233 void race_SendStatus(float id, entity e)
 234 {
 235         if(!IS_REAL_CLIENT(e))
 236                 return;
 237
 238         float msg;
 239         if (id == 0)
 240                 msg = MSG_ONE;
 241         else
 242                 msg = MSG_ALL;
 243         msg_entity = e;
 244         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 245                 WriteHeader(msg, TE_CSQC_RACE);
 246                 WriteByte(msg, RACE_NET_SERVER_STATUS);
 247                 WriteShort(msg, id);
 248                 WriteString(msg, e.netname);
 249         });
 250 }
 251
 252 void race_setTime(string map, float t, string myuid, string mynetname, entity e, bool showmessage)
 253 {
 254         // netname only used TEMPORARILY for printing
 255         int newpos = race_readPos(map, t);
 256
 257         int player_prevpos = 0;
 258         for(int i = 1; i <= RANKINGS_CNT; ++i)
 259         {
 260                 if(race_readUID(map, i) == myuid)
 261                         player_prevpos = i;
 262         }
 263
 264         float oldrec;
 265         string oldrec_holder;
 266         if (player_prevpos && (player_prevpos < newpos || !newpos))
 267         {
 268                 oldrec = race_readTime(GetMapname(), player_prevpos);
 269                 race_SendStatus(0, e); // "fail"
 270                 if(showmessage)
 271                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FAIL_RANKED, mynetname, player_prevpos, t, oldrec);
 272                 return;
 273         }
 274         else if (!newpos)
 275         {
 276                 // no ranking, time worse than the worst ranked
 277                 oldrec = race_readTime(GetMapname(), RANKINGS_CNT);
 278                 race_SendStatus(0, e); // "fail"
 279                 if(showmessage)
 280                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FAIL_UNRANKED, mynetname, RANKINGS_CNT, t, oldrec);
 281                 return;
 282         }
 283
 284         // if we didn't hit a return yet, we have a new record!
 285
 286         // if the player does not have a UID we can unfortunately not store the record, as the rankings system relies on UIDs
 287         if(myuid == "")
 288         {
 289                 if(showmessage)
 290                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_MISSING_UID, mynetname, t);
 291                 return;
 292         }
 293
 294         if(uid2name(myuid) == "^1Unregistered Player")
 295         {
 296                 if(showmessage)
 297                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_MISSING_NAME, mynetname, t);
 298                 return;
 299         }
 300
 301         oldrec = race_readTime(GetMapname(), newpos);
 302         oldrec_holder = race_readName(GetMapname(), newpos);
 303
 304         // store new ranking
 305         race_writeTime(GetMapname(), t, myuid);
 306
 307         if (newpos == 1 && showmessage)
 308         {
 309                 write_recordmarker(e, time - TIME_DECODE(t), TIME_DECODE(t));
 310                 race_send_recordtime(MSG_ALL);
 311         }
 312
 313         race_SendRankings(newpos, player_prevpos, 0, MSG_ALL);
 314         if(rankings_reply)
 315                 strunzone(rankings_reply);
 316         rankings_reply = strzone(getrankings());
 317
 318         if(newpos == player_prevpos)
 319         {
 320                 if(showmessage)
 321                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_IMPROVED, mynetname, newpos, t, oldrec);
 322                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 323                 else { race_SendStatus(1, e); } // "new time"
 324         }
 325         else if(oldrec == 0)
 326         {
 327                 if(showmessage)
 328                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_SET, mynetname, newpos, t);
 329                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 330                 else { race_SendStatus(2, e); } // "new rank"
 331         }
 332         else
 333         {
 334                 if(showmessage)
 335                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_BROKEN, mynetname, oldrec_holder, newpos, t, oldrec);
 336                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 337                 else { race_SendStatus(2, e); } // "new rank"
 338         }
 339 }
 340
 341 void race_deleteTime(string map, float pos)
 342 {
 343         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
 344
 345         for(int i = pos; i <= RANKINGS_CNT; ++i)
 346         {
 347                 string therank = ftos(i);
 348                 if (i == RANKINGS_CNT)
 349                 {
 350                         db_remove(ServerProgsDB, strcat(map, rr, "time", therank));
 351                         db_remove(ServerProgsDB, strcat(map, rr, "crypto_idfp", therank));
 352                 }
 353                 else
 354                 {
 355                         db_put(ServerProgsDB, strcat(map, rr, "time", therank), ftos(race_readTime(GetMapname(), i+1)));
 356                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", therank), race_readUID(GetMapname(), i+1));
 357                 }
 358         }
 359
 360         race_SendRankings(pos, 0, 1, MSG_ALL);
 361         if(pos == 1)
 362                 race_send_recordtime(MSG_ALL);
 363
 364         if(rankings_reply)
 365                 strunzone(rankings_reply);
 366         rankings_reply = strzone(getrankings());
 367 }
 368
 369 void race_SendTime(entity e, float cp, float t, float tvalid)
 370 {
 371         float snew, l;
 372
 373         if(g_race_qualifying)
 374                 t += e.race_penalty_accumulator;
 375
 376         t = TIME_ENCODE(t); // make integer
 377
 378         if(tvalid)
 379         if(cp == race_timed_checkpoint) // finish line
 380         if (!e.race_completed)
 381         {
 382                 float s;
 383                 if(g_race_qualifying)
 384                 {
 385                         s = PlayerScore_Add(e, SP_RACE_FASTEST, 0);
 386                         if(!s || t < s)
 387                                 PlayerScore_Add(e, SP_RACE_FASTEST, t - s);
 388                 }
 389                 else
 390                 {
 391                         s = PlayerScore_Add(e, SP_RACE_FASTEST, 0);
 392                         if(!s || t < s)
 393                                 PlayerScore_Add(e, SP_RACE_FASTEST, t - s);
 394
 395                         s = PlayerScore_Add(e, SP_RACE_TIME, 0);
 396                         snew = TIME_ENCODE(time - game_starttime);
 397                         PlayerScore_Add(e, SP_RACE_TIME, snew - s);
 398                         l = PlayerTeamScore_Add(e, SP_RACE_LAPS, ST_RACE_LAPS, 1);
 399
 400                         if(autocvar_fraglimit)
 401                                 if(l >= autocvar_fraglimit)
 402                                         race_StartCompleting();
 403
 404                         if(race_completing)
 405                         {
 406                                 e.race_completed = 1;
 407                                 MAKE_INDEPENDENT_PLAYER(e);
 408                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FINISHED, e.netname);
 409                                 ClientData_Touch(e);
 410                         }
 411                 }
 412         }
 413
 414         float recordtime;
 415         string recordholder;
 416         if(g_race_qualifying)
 417         {
 418                 if(tvalid)
 419                 {
 420                         recordtime = race_checkpoint_records[cp];
 421                         recordholder = strcat1(race_checkpoint_recordholders[cp]); // make a tempstring copy, as we'll possibly strunzone it!
 422                         if(recordholder == e.netname)
 423                                 recordholder = "";
 424
 425                         if(t != 0)
 426                         {
 427                                 if(cp == race_timed_checkpoint)
 428                                 {
 429                                         race_setTime(GetMapname(), t, e.crypto_idfp, e.netname, e, true);
 430                                         MUTATOR_CALLHOOK(Race_FinalCheckpoint, e);
 431                                 }
 432                                 if(t < recordtime || recordtime == 0)
 433                                 {
 434                                         race_checkpoint_records[cp] = t;
 435                                         if(race_checkpoint_recordholders[cp])
 436                                                 strunzone(race_checkpoint_recordholders[cp]);
 437                                         race_checkpoint_recordholders[cp] = strzone(e.netname);
 438                                         if(g_race_qualifying)
 439                                         {
 440                                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it.race_checkpoint == cp, LAMBDA(race_SendNextCheckpoint(it, 0)));
 441                                         }
 442                                 }
 443                         }
 444                 }
 445                 else
 446                 {
 447                         // dummies
 448                         t = 0;
 449                         recordtime = 0;
 450                         recordholder = "";
 451                 }
 452
 453                 if(IS_REAL_CLIENT(e))
 454                 {
 455                         msg_entity = e;
 456                         if(g_race_qualifying)
 457                         {
 458                                 WRITESPECTATABLE_MSG_ONE(msg_entity, {
 459                                         WriteHeader(MSG_ONE, TE_CSQC_RACE);
 460                                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_QUALIFYING);
 461                                         WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 462                                         WriteInt24_t(MSG_ONE, t); // time to that intermediate
 463                                         WriteInt24_t(MSG_ONE, recordtime); // previously best time
 464                                         WriteString(MSG_ONE, recordholder); // record holder
 465                                 });
 466                         }
 467                 }
 468         }
 469         else // RACE! Not Qualifying
 470         {
 471                 float mylaps, lother, othtime;
 472                 entity oth;
 473                 oth = race_checkpoint_lastplayers[cp];
 474                 if(oth)
 475                 {
 476                         mylaps = PlayerScore_Add(e, SP_RACE_LAPS, 0);
 477                         lother = race_checkpoint_lastlaps[cp];
 478                         othtime = race_checkpoint_lasttimes[cp];
 479                 }
 480                 else
 481                         mylaps = lother = othtime = 0;
 482
 483                 if(IS_REAL_CLIENT(e))
 484                 {
 485                         msg_entity = e;
 486                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 487                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 488                                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_RACE);
 489                                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 490                                 if(e == oth)
 491                                 {
 492                                         WriteInt24_t(MSG_ONE, 0);
 493                                         WriteByte(MSG_ONE, 0);
 494                                         WriteString(MSG_ONE, "");
 495                                 }
 496                                 else
 497                                 {
 498                                         WriteInt24_t(MSG_ONE, TIME_ENCODE(time - race_checkpoint_lasttimes[cp]));
 499                                         WriteByte(MSG_ONE, mylaps - lother);
 500                                         WriteString(MSG_ONE, oth.netname); // record holder
 501                                 }
 502                         });
 503                 }
 504
 505                 race_checkpoint_lastplayers[cp] = e;
 506                 race_checkpoint_lasttimes[cp] = time;
 507                 race_checkpoint_lastlaps[cp] = mylaps;
 508
 509                 if(IS_REAL_CLIENT(oth))
 510                 {
 511                         msg_entity = oth;
 512                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 513                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 514                                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT);
 515                                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 516                                 if(e == oth)
 517                                 {
 518                                         WriteInt24_t(MSG_ONE, 0);
 519                                         WriteByte(MSG_ONE, 0);
 520                                         WriteString(MSG_ONE, "");
 521                                 }
 522                                 else
 523                                 {
 524                                         WriteInt24_t(MSG_ONE, TIME_ENCODE(time - othtime));
 525                                         WriteByte(MSG_ONE, lother - mylaps);
 526                                         WriteString(MSG_ONE, e.netname); // record holder
 527                                 }
 528                         });
 529                 }
 530         }
 531 }
 532
 533 void race_ClearTime(entity e)
 534 {
 535         e.race_checkpoint = 0;
 536         e.race_laptime = 0;
 537         e.race_movetime = e.race_movetime_frac = e.race_movetime_count = 0;
 538         e.race_penalty_accumulator = 0;
 539         e.race_lastpenalty = NULL;
 540
 541         if(!IS_REAL_CLIENT(e))
 542                 return;
 543
 544         msg_entity = e;
 545         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 546                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 547                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_CLEAR); // next
 548         });
 549 }
 550
 551 void dumpsurface(entity e)
 552 {
 553         float n, si, ni;
 554         vector norm, vec;
 555         LOG_INFO("Surfaces of ", etos(e), ":\n");
 556
 557         LOG_INFO("TEST = ", ftos(getsurfacenearpoint(e, '0 0 0')), "\n");
 558
 559         for(si = 0; ; ++si)
 560         {
 561                 n = getsurfacenumpoints(e, si);
 562                 if(n <= 0)
 563                         break;
 564                 LOG_INFO("  Surface ", ftos(si), ":\n");
 565                 norm = getsurfacenormal(e, si);
 566                 LOG_INFO("    Normal = ", vtos(norm), "\n");
 567                 for(ni = 0; ni < n; ++ni)
 568                 {
 569                         vec = getsurfacepoint(e, si, ni);
 570                         LOG_INFO("    Point ", ftos(ni), " = ", vtos(vec), " (", ftos(norm * vec), ")\n");
 571                 }
 572         }
 573 }
 574
 575 void checkpoint_passed(entity this, entity player)
 576 {
 577         if(player.personal && autocvar_g_allow_checkpoints)
 578                 return; // practice mode!
 579
 580         string oldmsg;
 581         entity cp;
 582
 583         if(player.classname == "porto")
 584         {
 585                 // do not allow portalling through checkpoints
 586                 trace_plane_normal = normalize(-1 * player.velocity);
 587                 W_Porto_Fail(player, 0);
 588                 return;
 589         }
 590
 591         /*
 592          * Trigger targets
 593          */
 594         if (!((this.spawnflags & 2) && (IS_PLAYER(player))))
 595         {
 596                 oldmsg = this.message;
 597                 this.message = "";
 598                 SUB_UseTargets(this, player, player);
 599                 this.message = oldmsg;
 600         }
 601
 602         if (!IS_PLAYER(player))
 603                 return;
 604
 605         /*
 606          * Remove unauthorized equipment
 607          */
 608         Portal_ClearAll(player);
 609
 610         player.porto_forbidden = 2; // decreased by 1 each StartFrame
 611
 612         if(defrag_ents)
 613         {
 614                 if(this.race_checkpoint == -2)
 615                 {
 616                         this.race_checkpoint = player.race_checkpoint;
 617                 }
 618
 619                 float largest_cp_id = 0;
 620                 float cp_amount = 0;
 621                 for(cp = NULL; (cp = find(cp, classname, "target_checkpoint"));)
 622                 {
 623                         cp_amount += 1;
 624                         if(cp.race_checkpoint > largest_cp_id) // update the finish id if someone hit a new checkpoint
 625                         {
 626                                 largest_cp_id = cp.race_checkpoint;
 627                                 for(cp = NULL; (cp = find(cp, classname, "target_stopTimer"));)
 628                                         cp.race_checkpoint = largest_cp_id + 1; // finish line
 629                                 race_highest_checkpoint = largest_cp_id + 1;
 630                                 race_timed_checkpoint = largest_cp_id + 1;
 631
 632                                 for(cp = NULL; (cp = find(cp, classname, "target_checkpoint"));)
 633                                 {
 634                                         if(cp.race_checkpoint == -2) // set defragcpexists to -1 so that the cp id file will be rewritten when someone finishes
 635                                                 defragcpexists = -1;
 636                                 }
 637                         }
 638                 }
 639                 if(cp_amount == 0)
 640                 {
 641                         for(cp = NULL; (cp = find(cp, classname, "target_stopTimer"));)
 642                                 cp.race_checkpoint = 1;
 643                         race_highest_checkpoint = 1;
 644                         race_timed_checkpoint = 1;
 645                 }
 646         }
 647
 648         if((player.race_checkpoint == -1 && this.race_checkpoint == 0) || (player.race_checkpoint == this.race_checkpoint))
 649         {
 650                 if(this.race_penalty)
 651                 {
 652                         if(player.race_lastpenalty != this)
 653                         {
 654                                 player.race_lastpenalty = this;
 655                                 race_ImposePenaltyTime(player, this.race_penalty, this.race_penalty_reason);
 656                         }
 657                 }
 658
 659                 if(player.race_penalty)
 660                         return;
 661
 662                 /*
 663                  * Trigger targets
 664                  */
 665                 if(this.spawnflags & 2)
 666                 {
 667                         oldmsg = this.message;
 668                         this.message = "";
 669                         SUB_UseTargets(this, player, player); // TODO: should we be using other for the trigger here?
 670                         this.message = oldmsg;
 671                 }
 672
 673                 if(player.race_respawn_checkpoint != this.race_checkpoint || !player.race_started)
 674                         player.race_respawn_spotref = this; // this is not a spot but a CP, but spawnpoint selection will deal with that
 675                 player.race_respawn_checkpoint = this.race_checkpoint;
 676                 player.race_checkpoint = race_NextCheckpoint(this.race_checkpoint);
 677                 player.race_started = 1;
 678
 679                 race_SendTime(player, this.race_checkpoint, player.race_movetime, boolean(player.race_laptime));
 680
 681                 if(!this.race_checkpoint) // start line
 682                 {
 683                         player.race_laptime = time;
 684                         player.race_movetime = player.race_movetime_frac = player.race_movetime_count = 0;
 685                         player.race_penalty_accumulator = 0;
 686                         player.race_lastpenalty = NULL;
 687                 }
 688
 689                 if(g_race_qualifying)
 690                         race_SendNextCheckpoint(player, 0);
 691
 692                 if(defrag_ents && defragcpexists < 0 && this.classname == "target_stopTimer")
 693                 {
 694                         float fh;
 695                         defragcpexists = fh = fopen(strcat("maps/", GetMapname(), ".defragcp"), FILE_WRITE);
 696                         if(fh >= 0)
 697                         {
 698                                 for(cp = NULL; (cp = find(cp, classname, "target_checkpoint"));)
 699                                 fputs(fh, strcat(cp.targetname, " ", ftos(cp.race_checkpoint), "\n"));
 700                         }
 701                         fclose(fh);
 702                 }
 703         }
 704         else if(player.race_checkpoint == race_NextCheckpoint(this.race_checkpoint))
 705         {
 706                 // ignored
 707         }
 708         else
 709         {
 710                 if(this.spawnflags & 4)
 711                         Damage (player, this, this, 10000, DEATH_HURTTRIGGER.m_id, player.origin, '0 0 0');
 712         }
 713 }
 714
 715 void checkpoint_touch(entity this, entity toucher)
 716 {
 717         EXACTTRIGGER_TOUCH(this, toucher);
 718         checkpoint_passed(this, toucher);
 719 }
 720
 721 void checkpoint_use(entity this, entity actor, entity trigger)
 722 {
 723         if(trigger.classname == "info_player_deathmatch") // a spawn, a spawn
 724                 return;
 725
 726         checkpoint_passed(this, actor);
 727 }
 728
 729 bool race_waypointsprite_visible_for_player(entity this, entity player, entity view)
 730 {
 731         if(view.race_checkpoint == -1 || this.owner.race_checkpoint == -2)
 732                 return true;
 733         else if(view.race_checkpoint == this.owner.race_checkpoint)
 734                 return true;
 735         else
 736                 return false;
 737 }
 738
 739 void trigger_race_checkpoint_verify(entity this)
 740 {
 741     static bool have_verified;
 742         if (have_verified) return;
 743         have_verified = true;
 744
 745         bool qual = g_race_qualifying;
 746
 747         int pl_race_checkpoint = 0;
 748         int pl_race_place = 0;
 749
 750         if (g_race) {
 751                 for (int i = 0; i <= race_highest_checkpoint; ++i) {
 752                         pl_race_checkpoint = race_NextCheckpoint(i);
 753
 754                         // race only (middle of the race)
 755                         g_race_qualifying = false;
 756                         pl_race_place = 0;
 757                         if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 758                                 error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for respawning in race) - bailing out"));
 759             }
 760
 761                         if (i == 0) {
 762                                 // qualifying only
 763                                 g_race_qualifying = 1;
 764                                 pl_race_place = race_lowest_place_spawn;
 765                                 if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 766                                         error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for qualifying) - bailing out"));
 767                 }
 768
 769                                 // race only (initial spawn)
 770                                 g_race_qualifying = 0;
 771                                 for (int p = 1; p <= race_highest_place_spawn; ++p) {
 772                                         pl_race_place = p;
 773                                         if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 774                                                 error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for initially spawning in race) - bailing out"));
 775                     }
 776                                 }
 777                         }
 778                 }
 779         } else if (!defrag_ents) {
 780                 // qualifying only
 781                 pl_race_checkpoint = race_NextCheckpoint(0);
 782                 g_race_qualifying = 1;
 783                 pl_race_place = race_lowest_place_spawn;
 784                 if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 785                         error(strcat("Checkpoint 0 misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for qualifying) - bailing out"));
 786         }
 787         } else {
 788                 pl_race_checkpoint = race_NextCheckpoint(0);
 789                 g_race_qualifying = 1;
 790                 pl_race_place = 0; // there's only one spawn on defrag maps
 791
 792                 // check if a defragcp file already exists, then read it and apply the checkpoint order
 793                 float fh;
 794                 float len;
 795                 string l;
 796
 797                 defragcpexists = fh = fopen(strcat("maps/", GetMapname(), ".defragcp"), FILE_READ);
 798                 if (fh >= 0) {
 799                         while ((l = fgets(fh))) {
 800                                 len = tokenize_console(l);
 801                                 if (len != 2) {
 802                                         defragcpexists = -1; // something's wrong in the defrag cp file, set defragcpexists to -1 so that it will be rewritten when someone finishes
 803                                         continue;
 804                                 }
 805                                 for (entity cp = NULL; (cp = find(cp, classname, "target_checkpoint"));) {
 806                                         if (argv(0) == cp.targetname) {
 807                                                 cp.race_checkpoint = stof(argv(1));
 808                     }
 809                 }
 810                         }
 811                         fclose(fh);
 812                 }
 813         }
 814
 815         g_race_qualifying = qual;
 816
 817         IL_EACH(g_race_targets, true,
 818         {
 819                 entity cpt = it;
 820                 FOREACH_ENTITY_STRING(target, cpt.targetname,
 821                 {
 822                         vector org = (this.absmin + this.absmax) * 0.5;
 823                         if(cpt.race_checkpoint == 0)
 824                                 WaypointSprite_SpawnFixed(WP_RaceStart, org, it, sprite, RADARICON_NONE);
 825                         else
 826                                 WaypointSprite_SpawnFixed(WP_RaceCheckpoint, org, it, sprite, RADARICON_NONE);
 827
 828                         it.sprite.waypointsprite_visible_for_player = race_waypointsprite_visible_for_player;
 829                 });
 830         });
 831
 832         if (race_timed_checkpoint) {
 833                 if (defrag_ents) {
 834                         IL_EACH(g_race_targets, true,
 835                         {
 836                                 entity cpt = it;
 837                                 if(it.classname == "target_startTimer" || it.classname == "target_stopTimer") {
 838                                         FOREACH_ENTITY_STRING(target, cpt.targetname, {
 839                                                 WaypointSprite_UpdateSprites(it.sprite, ((cpt.classname == "target_startTimer") ? WP_RaceStart : WP_RaceFinish), WP_Null, WP_Null);
 840                                         });
 841                                 }
 842                                 if(it.classname == "target_checkpoint") {
 843                                         if(it.race_checkpoint == -2)
 844                                                 defragcpexists = -1; // something's wrong with the defrag cp file or it has not been written yet, set defragcpexists to -1 so that it will be rewritten when someone finishes
 845                                 }
 846                         });
 847                         if (defragcpexists != -1) {
 848                                 float largest_cp_id = 0;
 849                                 for (entity cp = NULL; (cp = find(cp, classname, "target_checkpoint"));) {
 850                                         if (cp.race_checkpoint > largest_cp_id) {
 851                                                 largest_cp_id = cp.race_checkpoint;
 852                     }
 853                 }
 854                                 for (entity cp = NULL; (cp = find(cp, classname, "target_stopTimer"));) {
 855                                         cp.race_checkpoint = largest_cp_id + 1; // finish line
 856                 }
 857                                 race_highest_checkpoint = largest_cp_id + 1;
 858                                 race_timed_checkpoint = largest_cp_id + 1;
 859                         } else {
 860                                 for (entity cp = NULL; (cp = find(cp, classname, "target_stopTimer"));) {
 861                                         cp.race_checkpoint = 255; // finish line
 862                 }
 863                                 race_highest_checkpoint = 255;
 864                                 race_timed_checkpoint = 255;
 865                         }
 866                 } else {
 867                         IL_EACH(g_racecheckpoints, it.sprite,
 868                         {
 869                                 if (it.race_checkpoint == 0) {
 870                                         WaypointSprite_UpdateSprites(it.sprite, WP_RaceStart, WP_Null, WP_Null);
 871                 } else if (it.race_checkpoint == race_timed_checkpoint) {
 872                                         WaypointSprite_UpdateSprites(it.sprite, WP_RaceFinish, WP_Null, WP_Null);
 873                                 }
 874             });
 875                 }
 876         }
 877
 878         if (defrag_ents) {
 879                 for (entity trigger = NULL; (trigger = find(trigger, classname, "trigger_multiple")); ) {
 880                         for (entity targ = NULL; (targ = find(targ, targetname, trigger.target)); ) {
 881                                 if (targ.classname == "target_checkpoint" || targ.classname == "target_startTimer" || targ.classname == "target_stopTimer") {
 882                                         trigger.wait = 0;
 883                                         trigger.delay = 0;
 884                                         targ.wait = 0;
 885                                         targ.delay = 0;
 886
 887                     // These just make the game crash on some maps with oddly shaped triggers.
 888                     // (on the other hand they used to fix the case when two players ran through a checkpoint at once,
 889                     // and often one of them just passed through without being registered. Hope it's fixed  in a better way now.
 890                     // (happened on item triggers too)
 891                     //
 892                                         //targ.wait = -2;
 893                                         //targ.delay = 0;
 894
 895                                         //setsize(targ, trigger.mins, trigger.maxs);
 896                                         //setorigin(targ, trigger.origin);
 897                                         //remove(trigger);
 898                                 }
 899             }
 900         }
 901         }
 902 }
 903
 904 vector trigger_race_checkpoint_spawn_evalfunc(entity this, entity player, entity spot, vector current)
 905 {
 906         if(g_race_qualifying)
 907         {
 908                 // spawn at first
 909                 if(this.race_checkpoint != 0)
 910                         return '-1 0 0';
 911                 if(spot.race_place != race_lowest_place_spawn)
 912                         return '-1 0 0';
 913         }
 914         else
 915         {
 916                 if(this.race_checkpoint != player.race_respawn_checkpoint)
 917                         return '-1 0 0';
 918                 // try reusing the previous spawn
 919                 if(this == player.race_respawn_spotref || spot == player.race_respawn_spotref)
 920                         current.x += SPAWN_PRIO_RACE_PREVIOUS_SPAWN;
 921                 if(this.race_checkpoint == 0)
 922                 {
 923                         int pl = player.race_place;
 924                         if(pl > race_highest_place_spawn)
 925                                 pl = 0;
 926                         if(pl == 0 && !player.race_started)
 927                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 928                         if(spot.race_place != pl)
 929                                 return '-1 0 0';
 930                 }
 931         }
 932         return current;
 933 }
 934
 935 spawnfunc(trigger_race_checkpoint)
 936 {
 937         vector o;
 938         if(!g_race && !g_cts) { delete(this); return; }
 939
 940         EXACTTRIGGER_INIT;
 941
 942         this.use = checkpoint_use;
 943         if (!(this.spawnflags & 1))
 944                 settouch(this, checkpoint_touch);
 945
 946         o = (this.absmin + this.absmax) * 0.5;
 947         tracebox(o, PL_MIN_CONST, PL_MAX_CONST, o - '0 0 1' * (o.z - this.absmin.z), MOVE_NORMAL, this);
 948         waypoint_spawnforitem_force(this, trace_endpos);
 949         this.nearestwaypointtimeout = -1;
 950
 951         if(this.message == "")
 952                 this.message = "went backwards";
 953         if (this.message2 == "")
 954                 this.message2 = "was pushed backwards by";
 955         if (this.race_penalty_reason == "")
 956                 this.race_penalty_reason = "missing a checkpoint";
 957
 958         this.race_checkpoint = this.cnt;
 959
 960         if(this.race_checkpoint > race_highest_checkpoint)
 961         {
 962                 race_highest_checkpoint = this.race_checkpoint;
 963                 if(this.spawnflags & 8)
 964                         race_timed_checkpoint = this.race_checkpoint;
 965                 else
 966                         race_timed_checkpoint = 0;
 967         }
 968
 969         if(!this.race_penalty)
 970         {
 971                 if(this.race_checkpoint)
 972                         WaypointSprite_SpawnFixed(WP_RaceCheckpoint, o, this, sprite, RADARICON_NONE);
 973                 else
 974                         WaypointSprite_SpawnFixed(WP_RaceStartFinish, o, this, sprite, RADARICON_NONE);
 975         }
 976
 977         this.sprite.waypointsprite_visible_for_player = race_waypointsprite_visible_for_player;
 978         this.spawn_evalfunc = trigger_race_checkpoint_spawn_evalfunc;
 979
 980         IL_PUSH(g_racecheckpoints, this);
 981
 982         InitializeEntity(this, trigger_race_checkpoint_verify, INITPRIO_FINDTARGET);
 983 }
 984
 985 spawnfunc(target_checkpoint) // defrag entity
 986 {
 987         if(!g_race && !g_cts) { delete(this); return; }
 988         defrag_ents = 1;
 989
 990         // if this is targeted, then it probably isn't a trigger
 991         bool is_trigger = !boolean(!this.nottargeted && this.targetname != "");
 992
 993         if(is_trigger)
 994                 EXACTTRIGGER_INIT;
 995
 996         this.use = checkpoint_use;
 997         if (is_trigger && !(this.spawnflags & 1))
 998                 settouch(this, checkpoint_touch);
 999
1000         vector org = this.origin;
1001
1002         // bots should only pathfind to this if it is a valid touchable trigger
1003         if(is_trigger)
1004         {
1005                 org = (this.absmin + this.absmax) * 0.5;
1006                 tracebox(org, PL_MIN_CONST, PL_MAX_CONST, org - '0 0 1' * (org.z - this.absmin.z), MOVE_NORMAL, this);
1007                 waypoint_spawnforitem_force(this, trace_endpos);
1008                 this.nearestwaypointtimeout = -1;
1009         }
1010
1011         if(this.message == "")
1012                 this.message = "went backwards";
1013         if (this.message2 == "")
1014                 this.message2 = "was pushed backwards by";
1015         if (this.race_penalty_reason == "")
1016                 this.race_penalty_reason = "missing a checkpoint";
1017
1018         if(this.classname == "target_startTimer")
1019                 this.race_checkpoint = 0;
1020         else
1021                 this.race_checkpoint = -2;
1022
1023         race_timed_checkpoint = 1;
1024
1025         IL_PUSH(g_race_targets, this);
1026
1027         InitializeEntity(this, trigger_race_checkpoint_verify, INITPRIO_FINDTARGET);
1028 }
1029
1030 spawnfunc(target_startTimer) { spawnfunc_target_checkpoint(this); }
1031 spawnfunc(target_stopTimer) { spawnfunc_target_checkpoint(this); }
1032
1033 void race_AbandonRaceCheck(entity p)
1034 {
1035         if(race_completing && !p.race_completed)
1036         {
1037                 p.race_completed = 1;
1038                 MAKE_INDEPENDENT_PLAYER(p);
1039                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_ABANDONED, p.netname);
1040                 ClientData_Touch(p);
1041         }
1042 }
1043
1044 void race_StartCompleting()
1045 {
1046         race_completing = 1;
1047         FOREACH_CLIENT(IS_PLAYER(it) && IS_DEAD(it), LAMBDA(race_AbandonRaceCheck(it)));
1048 }
1049
1050 void race_PreparePlayer(entity this)
1051 {
1052         race_ClearTime(this);
1053         this.race_place = 0;
1054         this.race_started = 0;
1055         this.race_respawn_checkpoint = 0;
1056         this.race_respawn_spotref = NULL;
1057 }
1058
1059 void race_RetractPlayer(entity this)
1060 {
1061         if(!g_race && !g_cts)
1062                 return;
1063         if(this.race_respawn_checkpoint == 0 || this.race_respawn_checkpoint == race_timed_checkpoint)
1064                 race_ClearTime(this);
1065         this.race_checkpoint = this.race_respawn_checkpoint;
1066 }
1067
1068 spawnfunc(info_player_race)
1069 {
1070         if(!g_race && !g_cts) { delete(this); return; }
1071         ++race_spawns;
1072         spawnfunc_info_player_deathmatch(this);
1073
1074         if(this.race_place > race_highest_place_spawn)
1075                 race_highest_place_spawn = this.race_place;
1076         if(this.race_place < race_lowest_place_spawn)
1077                 race_lowest_place_spawn = this.race_place;
1078 }
1079
1080 void race_ClearRecords()
1081 {
1082         float i;
1083
1084         for(i = 0; i < MAX_CHECKPOINTS; ++i)
1085         {
1086                 race_checkpoint_records[i] = 0;
1087                 if(race_checkpoint_recordholders[i])
1088                         strunzone(race_checkpoint_recordholders[i]);
1089                 race_checkpoint_recordholders[i] = string_null;
1090         }
1091
1092         FOREACH_CLIENT(true, LAMBDA(
1093                 float p = it.race_place;
1094                 race_PreparePlayer(it);
1095                 it.race_place = p;
1096         ));
1097 }
1098
1099 void race_ImposePenaltyTime(entity pl, float penalty, string reason)
1100 {
1101         if(g_race_qualifying)
1102         {
1103                 pl.race_penalty_accumulator += penalty;
1104                 if(IS_REAL_CLIENT(pl))
1105                 {
1106                         msg_entity = pl;
1107                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
1108                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
1109                                 WriteByte(MSG_ONE, RACE_NET_PENALTY_QUALIFYING);
1110                                 WriteShort(MSG_ONE, TIME_ENCODE(penalty));
1111                                 WriteString(MSG_ONE, reason);
1112                         });
1113                 }
1114         }
1115         else
1116         {
1117                 pl.race_penalty = time + penalty;
1118                 if(IS_REAL_CLIENT(pl))
1119                 {
1120                         msg_entity = pl;
1121                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
1122                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
1123                                 WriteByte(MSG_ONE, RACE_NET_PENALTY_RACE);
1124                                 WriteShort(MSG_ONE, TIME_ENCODE(penalty));
1125                                 WriteString(MSG_ONE, reason);
1126                         });
1127                 }
1128         }
1129 }
1130
1131 void penalty_touch(entity this, entity toucher)
1132 {
1133         EXACTTRIGGER_TOUCH(this, toucher);
1134         if(toucher.race_lastpenalty != this)
1135         {
1136                 toucher.race_lastpenalty = this;
1137                 race_ImposePenaltyTime(toucher, this.race_penalty, this.race_penalty_reason);
1138         }
1139 }
1140
1141 void penalty_use(entity this, entity actor, entity trigger)
1142 {
1143         race_ImposePenaltyTime(actor, this.race_penalty, this.race_penalty_reason);
1144 }
1145
1146 spawnfunc(trigger_race_penalty)
1147 {
1148         // TODO: find out why this wasnt done:
1149         //if(!g_cts && !g_race) { remove(this); return; }
1150
1151         EXACTTRIGGER_INIT;
1152
1153         this.use = penalty_use;
1154         if (!(this.spawnflags & 1))
1155                 settouch(this, penalty_touch);
1156
1157         if (this.race_penalty_reason == "")
1158                 this.race_penalty_reason = "missing a checkpoint";
1159         if (!this.race_penalty)
1160                 this.race_penalty = 5;
1161 }
1162
1163 float race_GetFractionalLapCount(entity e)
1164 {
1165         // interesting metrics (idea by KrimZon) to maybe sort players in the
1166         // scoreboard, immediately updates when overtaking
1167         //
1168         // requires the track to be built so you never get farther away from the
1169         // next checkpoint, though, and current Xonotic race maps are not built that
1170         // way
1171         //
1172         // also, this code is slow and would need optimization (i.e. "next CP"
1173         // links on CP entities)
1174
1175         float l;
1176         l = PlayerScore_Add(e, SP_RACE_LAPS, 0);
1177         if(e.race_completed)
1178                 return l; // not fractional
1179
1180         vector o0, o1;
1181         float bestfraction, fraction;
1182         entity lastcp;
1183         float nextcpindex, lastcpindex;
1184
1185         nextcpindex = max(e.race_checkpoint, 0);
1186         lastcpindex = e.race_respawn_checkpoint;
1187         lastcp = e.race_respawn_spotref;
1188
1189         if(nextcpindex == lastcpindex)
1190                 return l; // finish
1191
1192         bestfraction = 1;
1193         IL_EACH(g_racecheckpoints, true,
1194         {
1195                 if(it.race_checkpoint != lastcpindex)
1196                         continue;
1197                 if(lastcp)
1198                         if(it != lastcp)
1199                                 continue;
1200                 o0 = (it.absmin + it.absmax) * 0.5;
1201                 IL_EACH(g_racecheckpoints, true,
1202                 {
1203                         if(it.race_checkpoint != nextcpindex)
1204                                 continue;
1205                         o1 = (it.absmin + it.absmax) * 0.5;
1206                         if(o0 == o1)
1207                                 continue;
1208                         fraction = bound(0.0001, vlen(e.origin - o1) / vlen(o0 - o1), 1);
1209                         if(fraction < bestfraction)
1210                                 bestfraction = fraction;
1211                 });
1212         });
1213
1214         // we are at CP "nextcpindex - bestfraction"
1215         // race_timed_checkpoint == 4: then nextcp==4 means 0.9999x, nextcp==0 means 0.0000x
1216         // race_timed_checkpoint == 0: then nextcp==0 means 0.9999x
1217         float c, nc;
1218         nc = race_highest_checkpoint + 1;
1219         c = ((nextcpindex - race_timed_checkpoint + nc + nc - 1) % nc) + 1 - bestfraction;
1220
1221         return l + c / nc;
1222 }