qcsrc/server/round_handler.qc

   1 void round_handler_Think()
   2 {
   3         float f;
   4
   5         if(time < game_starttime)
   6         {
   7                 round_handler_Reset(game_starttime);
   8                 return;
   9         }
  10
  11         if(gameover)
  12         {
  13                 round_handler_Reset(0);
  14                 round_handler_Remove();
  15                 return;
  16         }
  17
  18         if(self.wait)
  19         {
  20                 self.wait = FALSE;
  21                 self.cnt = self.count + 1; // init countdown
  22                 round_starttime = time + self.count;
  23                 reset_map(TRUE);
  24         }
  25
  26         if(self.cnt > 0) // countdown running
  27         {
  28                 if(self.canRoundStart())
  29                 {
  30                         if(self.cnt == self.count + 1)
  31                                 round_starttime = time + self.count;
  32                         f = self.cnt - 1;
  33                         if(f == 0)
  34                         {
  35                                 self.cnt = 0;
  36                                 self.round_endtime = (self.round_timelimit) ? time + self.round_timelimit : 0;
  37                                 self.nextthink = time;
  38                                 if(self.roundStart)
  39                                         self.roundStart();
  40                                 return;
  41                         }
  42                         self.cnt = self.cnt - 1;
  43                 }
  44                 else
  45                 {
  46                         round_handler_Reset(0);
  47                 }
  48                 self.nextthink = time + 1; // canRoundStart every second
  49         }
  50         else
  51         {
  52                 if(self.canRoundEnd())
  53                 {
  54                         // schedule a new round
  55                         self.wait = TRUE;
  56                         self.nextthink = time + self.delay;
  57                 }
  58                 else
  59                 {
  60                         self.nextthink = time; // canRoundEnd every frame
  61                 }
  62         }
  63 }
  64
  65 void round_handler_Init(float the_delay, float the_count, float the_round_timelimit)
  66 {
  67         round_handler.delay = (the_delay > 0) ? the_delay : 0;
  68         round_handler.count = fabs(floor(the_count));
  69         round_handler.cnt = round_handler.count + 1;
  70         round_handler.round_timelimit = (the_round_timelimit > 0) ? the_round_timelimit : 0;
  71 }
  72
  73 // NOTE: this is only needed because if round_handler spawns at time 1
  74 // gamestarttime isn't initialized yet
  75 void round_handler_FirstThink()
  76 {
  77         round_starttime = max(time, game_starttime) + round_handler.count;
  78         round_handler.think = round_handler_Think;
  79         round_handler.nextthink = max(time, game_starttime);
  80 }
  81
  82 void round_handler_Spawn(float() canRoundStart_func, float() canRoundEnd_func, void() roundStart_func)
  83 {
  84         if(round_handler)
  85         {
  86                 backtrace("Can't spawn round_handler again!");
  87                 return;
  88         }
  89         round_handler = spawn();
  90         round_handler.classname = "round_handler";
  91
  92         round_handler.think = round_handler_FirstThink;
  93         round_handler.canRoundStart = canRoundStart_func;
  94         round_handler.canRoundEnd = canRoundEnd_func;
  95         round_handler.roundStart = roundStart_func;
  96         round_handler.wait = FALSE;
  97         round_handler_Init(5, 5, 180);
  98         round_handler.nextthink = time;
  99 }
 100
 101 void round_handler_Reset(float next_think)
 102 {
 103         round_handler.wait = FALSE;
 104         if(round_handler.count)
 105         if(round_handler.cnt < round_handler.count + 1)
 106                 round_handler.cnt = round_handler.count + 1;
 107         round_handler.nextthink = next_think;
 108         round_starttime = (next_think) ? (next_think + round_handler.count) : -1;
 109 }
 110
 111 void round_handler_Remove()
 112 {
 113         remove(round_handler);
 114         round_handler = world;
 115 }
 116