qcsrc/server/scores.qc

   1 .entity scorekeeper;
   2 entity teamscorekeepers[16];
   3 string scores_label[MAX_SCORE];
   4 float scores_flags[MAX_SCORE];
   5 string teamscores_label[MAX_TEAMSCORE];
   6 float teamscores_flags[MAX_TEAMSCORE];
   7 float teamscores_entities_count;
   8 var .float scores_primary;
   9 var .float teamscores_primary;
  10 float scores_flags_primary;
  11 float teamscores_flags_primary;
  12
  13 vector ScoreField_Compare(entity t1, entity t2, .float field, float fieldflags, vector previous) // returns: cmp value, best prio
  14 {
  15         if(!(fieldflags & SFL_SORT_PRIO_MASK)) // column does not sort
  16                 return previous;
  17         if(fieldflags & SFL_SORT_PRIO_MASK < previous_y)
  18                 return previous;
  19         if(t1.field == t2.field)
  20                 return previous;
  21
  22         previous_y = fieldflags & SFL_SORT_PRIO_MASK;
  23
  24         if(fieldflags & SFL_ZERO_IS_WORST)
  25         {
  26                 if(t1.field == 0)
  27                 {
  28                         previous_x = -1;
  29                         return previous;
  30                 }
  31                 else if(t2.field == 0)
  32                 {
  33                         previous_x = +1;
  34                         return previous;
  35                 }
  36         }
  37
  38         if(fieldflags & SFL_LOWER_IS_BETTER)
  39                 previous_x = (t2.field - t1.field);
  40         else
  41                 previous_x = (t1.field - t2.field);
  42
  43         return previous;
  44 }
  45
  46 /*
  47  * teamscore entities
  48  */
  49
  50 float TeamScore_SendEntity(entity to, float sendflags)
  51 {
  52         float i, p, longflags;
  53
  54         WriteByte(MSG_ENTITY, ENT_CLIENT_TEAMSCORES);
  55         WriteByte(MSG_ENTITY, self.team - 1);
  56
  57         longflags = 0;
  58         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
  59                 if(self.teamscores[i] > 127 || self.teamscores[i] <= -128)
  60                         longflags |= p;
  61
  62 #if MAX_TEAMSCORE <= 8
  63         WriteByte(MSG_ENTITY, sendflags);
  64         WriteByte(MSG_ENTITY, longflags);
  65 #else
  66         WriteShort(MSG_ENTITY, sendflags);
  67         WriteShort(MSG_ENTITY, longflags);
  68 #endif
  69         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
  70                 if(sendflags & p)
  71                 {
  72                         if(longflags & p)
  73                                 WriteInt24_t(MSG_ENTITY, self.teamscores[i]);
  74                         else
  75                                 WriteChar(MSG_ENTITY, self.teamscores[i]);
  76                 }
  77
  78         return TRUE;
  79 }
  80
  81 void TeamScore_Spawn(float t, string name)
  82 {
  83         entity ts;
  84         ts = spawn();
  85         ts.classname = "csqc_score_team";
  86         ts.netname = name; // not used yet, FIXME
  87         ts.team = t;
  88         Net_LinkEntity(ts, FALSE, 0, TeamScore_SendEntity);
  89         teamscorekeepers[t - 1] = ts;
  90         ++teamscores_entities_count;
  91 }
  92
  93 float TeamScore_AddToTeam(float t, float scorefield, float score)
  94 {
  95         entity s;
  96
  97         if(gameover)
  98                 score = 0;
  99
 100         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 101         if(t <= 0 || t >= 16)
 102         {
 103                 if(gameover)
 104                         return 0;
 105                 error("Adding score to invalid team!");
 106         }
 107         s = teamscorekeepers[t - 1];
 108         if(!s)
 109         {
 110                 if(gameover)
 111                         return 0;
 112                 error("Adding score to unknown team!");
 113         }
 114         if(score)
 115                 if(teamscores_label[scorefield] != "")
 116                         s.SendFlags |= pow(2, scorefield);
 117         return (s.(teamscores[scorefield]) += score);
 118 }
 119
 120 float TeamScore_Add(entity player, float scorefield, float score)
 121 {
 122         return TeamScore_AddToTeam(player.team, scorefield, score);
 123 }
 124
 125 float TeamScore_Compare(entity t1, entity t2)
 126 {
 127         if(!t1 || !t2) return (!t2) - !t1;
 128
 129         vector result;
 130         float i;
 131         for(i = 0; i < MAX_TEAMSCORE; ++i)
 132         {
 133                 var .float f;
 134                 f = teamscores[i];
 135                 result = ScoreField_Compare(t1, t2, f, teamscores_flags[i], result);
 136         }
 137         return result_x;
 138 }
 139
 140 /*
 141  * the scoreinfo entity
 142  */
 143
 144 void ScoreInfo_SetLabel_PlayerScore(float i, string label, float scoreflags)
 145 {
 146         scores_label[i] = label;
 147         scores_flags[i] = scoreflags;
 148         if(scoreflags & SFL_SORT_PRIO_MASK == SFL_SORT_PRIO_PRIMARY)
 149         {
 150                 scores_primary = scores[i];
 151                 scores_flags_primary = scoreflags;
 152         }
 153 }
 154
 155 void ScoreInfo_SetLabel_TeamScore(float i, string label, float scoreflags)
 156 {
 157         teamscores_label[i] = label;
 158         teamscores_flags[i] = scoreflags;
 159         if(scoreflags & SFL_SORT_PRIO_MASK == SFL_SORT_PRIO_PRIMARY)
 160         {
 161                 teamscores_primary = teamscores[i];
 162                 teamscores_flags_primary = scoreflags;
 163         }
 164 }
 165
 166 float ScoreInfo_SendEntity(entity to, float sf)
 167 {
 168         float i;
 169         WriteByte(MSG_ENTITY, ENT_CLIENT_SCORES_INFO);
 170         WriteByte(MSG_ENTITY, game);
 171         for(i = 0; i < MAX_SCORE; ++i)
 172         {
 173                 WriteString(MSG_ENTITY, scores_label[i]);
 174                 WriteByte(MSG_ENTITY, scores_flags[i]);
 175         }
 176         for(i = 0; i < MAX_TEAMSCORE; ++i)
 177         {
 178                 WriteString(MSG_ENTITY, teamscores_label[i]);
 179                 WriteByte(MSG_ENTITY, teamscores_flags[i]);
 180         }
 181         return TRUE;
 182 }
 183
 184 void ScoreInfo_Init(float teams)
 185 {
 186         if(scores_initialized)
 187         {
 188                 scores_initialized.SendFlags |= 1; // force a resend
 189         }
 190         else
 191         {
 192                 scores_initialized = spawn();
 193                 scores_initialized.classname = "ent_client_scoreinfo";
 194                 Net_LinkEntity(scores_initialized, FALSE, 0, ScoreInfo_SendEntity);
 195         }
 196         if(teams >= 1)
 197                 TeamScore_Spawn(COLOR_TEAM1, "Red");
 198         if(teams >= 2)
 199                 TeamScore_Spawn(COLOR_TEAM2, "Blue");
 200         if(teams >= 3)
 201                 TeamScore_Spawn(COLOR_TEAM3, "Yellow");
 202         if(teams >= 4)
 203                 TeamScore_Spawn(COLOR_TEAM4, "Pink");
 204 }
 205
 206 /*
 207  * per-player score entities
 208  */
 209
 210 float PlayerScore_SendEntity(entity to, float sendflags)
 211 {
 212         float i, p, longflags;
 213
 214         WriteByte(MSG_ENTITY, ENT_CLIENT_SCORES);
 215         WriteByte(MSG_ENTITY, num_for_edict(self.owner));
 216
 217         longflags = 0;
 218         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 219                 if(self.scores[i] > 127 || self.scores[i] <= -128)
 220                         longflags |= p;
 221
 222 #if MAX_SCORE <= 8
 223         WriteByte(MSG_ENTITY, sendflags);
 224         WriteByte(MSG_ENTITY, longflags);
 225 #else
 226         WriteShort(MSG_ENTITY, sendflags);
 227         WriteShort(MSG_ENTITY, longflags);
 228 #endif
 229         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 230                 if(sendflags & p)
 231                 {
 232                         if(longflags & p)
 233                                 WriteInt24_t(MSG_ENTITY, self.scores[i]);
 234                         else
 235                                 WriteChar(MSG_ENTITY, self.scores[i]);
 236                 }
 237
 238         return TRUE;
 239 }
 240
 241 void PlayerScore_Clear(entity player)
 242 {
 243         entity sk;
 244         float i;
 245
 246         if(teamscores_entities_count)
 247                 return;
 248         if(g_lms) return;
 249         if(g_arena || g_ca) return;
 250         if(g_race && !g_race_qualifying) return;
 251
 252         sk = player.scorekeeper;
 253         for(i = 0; i < MAX_SCORE; ++i)
 254         {
 255                 if(sk.(scores[i]) != 0)
 256                         if(scores_label[i] != "")
 257                                 sk.SendFlags |= pow(2, i);
 258                 sk.(scores[i]) = 0;
 259         }
 260 }
 261
 262 void Score_ClearAll()
 263 {
 264         entity p, sk;
 265         float i, t;
 266         FOR_EACH_CLIENTSLOT(p)
 267         {
 268                 sk = p.scorekeeper;
 269                 if(!sk)
 270                         continue;
 271                 for(i = 0; i < MAX_SCORE; ++i)
 272                 {
 273                         if(sk.(scores[i]) != 0)
 274                                 if(scores_label[i] != "")
 275                                         sk.SendFlags |= pow(2, i);
 276                         sk.(scores[i]) = 0;
 277                 }
 278         }
 279         for(t = 0; t < 16; ++t)
 280         {
 281                 sk = teamscorekeepers[t];
 282                 if(!sk)
 283                         continue;
 284                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 285                 {
 286                         if(sk.(teamscores[i]) != 0)
 287                                 if(teamscores_label[i] != "")
 288                                         sk.SendFlags |= pow(2, i);
 289                         sk.(teamscores[i]) = 0;
 290                 }
 291         }
 292 }
 293
 294 void PlayerScore_Attach(entity player)
 295 {
 296         entity sk;
 297         if(player.scorekeeper)
 298                 error("player already has a scorekeeper");
 299         sk = spawn();
 300         sk.owner = player;
 301         Net_LinkEntity(sk, FALSE, 0, PlayerScore_SendEntity);
 302         player.scorekeeper = sk;
 303 }
 304
 305 void PlayerScore_Detach(entity player)
 306 {
 307         if(!player.scorekeeper)
 308                 error("player has no scorekeeper");
 309         remove(player.scorekeeper);
 310         player.scorekeeper = world;
 311 }
 312
 313 float PlayerScore_Add(entity player, float scorefield, float score)
 314 {
 315         entity s;
 316
 317         if(gameover)
 318         if not(g_lms && scorefield == SP_LMS_RANK) // allow writing to this field in intermission as it is needed for newly joining players
 319                 score = 0;
 320
 321         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 322         s = player.scorekeeper;
 323         if(!s)
 324         {
 325                 if(gameover)
 326                         return 0;
 327                 error("Adding score to unknown player!");
 328         }
 329         if(score)
 330                 if(scores_label[scorefield] != "")
 331                         s.SendFlags |= pow(2, scorefield);
 332         return (s.(scores[scorefield]) += score);
 333 }
 334
 335 float PlayerTeamScore_Add(entity player, float pscorefield, float tscorefield, float score)
 336 {
 337         float r;
 338         r = PlayerScore_Add(player, pscorefield, score);
 339         if(teamscores_entities_count) // only for teamplay
 340                 r = TeamScore_Add(player, tscorefield, score);
 341         return r;
 342 }
 343
 344 float PlayerScore_Compare(entity t1, entity t2)
 345 {
 346         if(!t1 || !t2) return (!t2) - !t1;
 347
 348         vector result;
 349         float i;
 350         for(i = 0; i < MAX_SCORE; ++i)
 351         {
 352                 var .float f;
 353                 f = scores[i];
 354                 result = ScoreField_Compare(t1, t2, f, scores_flags[i], result);
 355         }
 356         return result_x;
 357 }
 358
 359 void WinningConditionHelper()
 360 {
 361         float c;
 362         string s;
 363         entity p;
 364         float fullstatus;
 365         entity winnerscorekeeper;
 366         entity secondscorekeeper;
 367         entity sk;
 368
 369         s = GetGametype();
 370         s = strcat(s, ":", cvar_string("g_xonoticversion"));
 371         s = strcat(s, "::", GetPlayerScoreString(world, 2)); // make this 1 once we can
 372
 373         fullstatus = cvar("g_full_getstatus_responses");
 374
 375         if(teamscores_entities_count)
 376         {
 377                 float t;
 378
 379                 s = strcat(s, ":", GetTeamScoreString(0, 1));
 380                 for(t = 0; t < 16; ++t)
 381                         if(teamscorekeepers[t])
 382                                 s = strcat(s, ":", ftos(t+1), ":", GetTeamScoreString(t+1, 1));
 383
 384                 WinningConditionHelper_winnerteam = -1;
 385                 WinningConditionHelper_secondteam = -1;
 386                 winnerscorekeeper = world;
 387                 secondscorekeeper = world;
 388                 for(t = 0; t < 16; ++t)
 389                 {
 390                         sk = teamscorekeepers[t];
 391                         c = TeamScore_Compare(winnerscorekeeper, sk);
 392                         if(c < 0)
 393                         {
 394                                 WinningConditionHelper_secondteam = WinningConditionHelper_winnerteam;
 395                                 WinningConditionHelper_winnerteam = t + 1;
 396                                 secondscorekeeper = winnerscorekeeper;
 397                                 winnerscorekeeper = sk;
 398                         }
 399                         else
 400                         {
 401                                 c = TeamScore_Compare(secondscorekeeper, sk);
 402                                 if(c < 0)
 403                                 {
 404                                         WinningConditionHelper_secondteam = t + 1;
 405                                         secondscorekeeper = sk;
 406                                 }
 407                         }
 408                 }
 409
 410                 WinningConditionHelper_equality = (TeamScore_Compare(winnerscorekeeper, secondscorekeeper) == 0);
 411                 if(WinningConditionHelper_equality)
 412                         WinningConditionHelper_winnerteam = WinningConditionHelper_secondteam = -1;
 413
 414                 WinningConditionHelper_topscore = winnerscorekeeper.teamscores_primary;
 415                 WinningConditionHelper_secondscore = secondscorekeeper.teamscores_primary;
 416                 WinningConditionHelper_lowerisbetter = (teamscores_flags_primary & SFL_LOWER_IS_BETTER);
 417                 WinningConditionHelper_zeroisworst = (teamscores_flags_primary & SFL_ZERO_IS_WORST);
 418
 419                 WinningConditionHelper_winner = world; // not supported in teamplay
 420                 WinningConditionHelper_second = world; // not supported in teamplay
 421         }
 422         else
 423         {
 424                 WinningConditionHelper_winner = world;
 425                 WinningConditionHelper_second = world;
 426                 winnerscorekeeper = world;
 427                 secondscorekeeper = world;
 428                 FOR_EACH_PLAYER(p)
 429                 {
 430                         sk = p.scorekeeper;
 431                         c = PlayerScore_Compare(winnerscorekeeper, sk);
 432                         if(c < 0)
 433                         {
 434                                 WinningConditionHelper_second = WinningConditionHelper_winner;
 435                                 WinningConditionHelper_winner = p;
 436                                 secondscorekeeper = winnerscorekeeper;
 437                                 winnerscorekeeper = sk;
 438                         }
 439                         else
 440                         {
 441                                 c = PlayerScore_Compare(secondscorekeeper, sk);
 442                                 if(c < 0)
 443                                 {
 444                                         WinningConditionHelper_second = p;
 445                                         secondscorekeeper = sk;
 446                                 }
 447                         }
 448                 }
 449
 450                 WinningConditionHelper_equality = (PlayerScore_Compare(winnerscorekeeper, secondscorekeeper) == 0);
 451                 if(WinningConditionHelper_equality)
 452                         WinningConditionHelper_winner = WinningConditionHelper_second = world;
 453
 454                 WinningConditionHelper_topscore = winnerscorekeeper.scores_primary;
 455                 WinningConditionHelper_secondscore = secondscorekeeper.scores_primary;
 456                 WinningConditionHelper_lowerisbetter = (scores_flags_primary & SFL_LOWER_IS_BETTER);
 457                 WinningConditionHelper_zeroisworst = (scores_flags_primary & SFL_ZERO_IS_WORST);
 458
 459                 WinningConditionHelper_winnerteam = -1; // no teamplay
 460                 WinningConditionHelper_secondteam = -1; // no teamplay
 461         }
 462
 463         if(WinningConditionHelper_topscore == 0)
 464         {
 465                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 466                 {
 467                         if(WinningConditionHelper_lowerisbetter)
 468                                 WinningConditionHelper_topscore = 999999999;
 469                         else
 470                                 WinningConditionHelper_topscore = -999999999;
 471                 }
 472                 WinningConditionHelper_equality = 0;
 473         }
 474
 475         if(WinningConditionHelper_secondscore == 0)
 476         {
 477                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 478                 {
 479                         if(WinningConditionHelper_lowerisbetter)
 480                                 WinningConditionHelper_secondscore = 999999999;
 481                         else
 482                                 WinningConditionHelper_secondscore = -999999999;
 483                 }
 484         }
 485
 486         if(worldstatus)
 487                 strunzone(worldstatus);
 488         worldstatus = strzone(s);
 489
 490         FOR_EACH_CLIENT(p)
 491         {
 492                 if(fullstatus)
 493                 {
 494                         s = GetPlayerScoreString(p, 1);
 495                         if(clienttype(p) == CLIENTTYPE_REAL)
 496                                 s = strcat(s, ":human");
 497                         else
 498                                 s = strcat(s, ":bot");
 499                         if(p.classname != "player" && !g_arena && !g_ca && !g_lms)
 500                                 s = strcat(s, ":spectator");
 501                 }
 502                 else
 503                 {
 504                         if(p.classname == "player" || g_arena || g_ca || g_lms)
 505                                 s = GetPlayerScoreString(p, 2);
 506                         else
 507                                 s = "-666";
 508                 }
 509
 510                 if(p.clientstatus)
 511                         strunzone(p.clientstatus);
 512                 p.clientstatus = strzone(s);
 513         }
 514 }
 515
 516 string GetScoreLogLabel(string label, float fl)
 517 {
 518         if(fl & SFL_LOWER_IS_BETTER)
 519                 label = strcat(label, "<");
 520         if(fl & SFL_SORT_PRIO_MASK == SFL_SORT_PRIO_PRIMARY)
 521                 label = strcat(label, "!!");
 522         else if(fl & SFL_SORT_PRIO_MASK == SFL_SORT_PRIO_SECONDARY)
 523                 label = strcat(label, "!");
 524         return label;
 525 }
 526
 527 string GetPlayerScoreString(entity pl, float shortString)
 528 {
 529         string out;
 530         entity sk;
 531         float i, f;
 532         string l;
 533
 534         out = "";
 535         if(!pl)
 536         {
 537                 // label
 538                 for(i = 0; i < MAX_SCORE; ++i)
 539                         if(scores_flags[i] & SFL_SORT_PRIO_MASK == SFL_SORT_PRIO_PRIMARY)
 540                         {
 541                                 f = scores_flags[i];
 542                                 l = scores_label[i];
 543                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 544                         }
 545                 if(shortString < 2)
 546                 for(i = 0; i < MAX_SCORE; ++i)
 547                         if(scores_flags[i] & SFL_SORT_PRIO_MASK == SFL_SORT_PRIO_SECONDARY)
 548                         {
 549                                 f = scores_flags[i];
 550                                 l = scores_label[i];
 551                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 552                         }
 553                 if(shortString < 1)
 554                 for(i = 0; i < MAX_SCORE; ++i)
 555                         if(scores_flags[i] & SFL_SORT_PRIO_MASK != SFL_SORT_PRIO_PRIMARY)
 556                         if(scores_flags[i] & SFL_SORT_PRIO_MASK != SFL_SORT_PRIO_SECONDARY)
 557                         {
 558                                 f = scores_flags[i];
 559                                 l = scores_label[i];
 560                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 561                         }
 562                 out = substring(out, 0, strlen(out) - 1);
 563         }
 564         else if((sk = pl.scorekeeper))
 565         {
 566                 for(i = 0; i < MAX_SCORE; ++i)
 567                         if(scores_flags[i] & SFL_SORT_PRIO_MASK == SFL_SORT_PRIO_PRIMARY)
 568                                 out = strcat(out, ftos(sk.(scores[i])), ",");
 569                 if(shortString < 2)
 570                 for(i = 0; i < MAX_SCORE; ++i)
 571                         if(scores_flags[i] & SFL_SORT_PRIO_MASK == SFL_SORT_PRIO_SECONDARY)
 572                                 out = strcat(out, ftos(sk.(scores[i])), ",");
 573                 if(shortString < 1)
 574                 for(i = 0; i < MAX_SCORE; ++i)
 575                         if(scores_flags[i] & SFL_SORT_PRIO_MASK != SFL_SORT_PRIO_PRIMARY)
 576                         if(scores_flags[i] & SFL_SORT_PRIO_MASK != SFL_SORT_PRIO_SECONDARY)
 577                                 out = strcat(out, ftos(sk.(scores[i])), ",");
 578                 out = substring(out, 0, strlen(out) - 1);
 579         }
 580         return out;
 581 }
 582
 583 string GetTeamScoreString(float tm, float shortString)
 584 {
 585         string out;
 586         entity sk;
 587         float i, f;
 588         string l;
 589
 590         out = "";
 591         if(tm == 0)
 592         {
 593                 // label
 594                 for(i = 0; i < MAX_SCORE; ++i)
 595                         if(teamscores_flags[i] & SFL_SORT_PRIO_MASK == SFL_SORT_PRIO_PRIMARY)
 596                         {
 597                                 f = teamscores_flags[i];
 598                                 l = teamscores_label[i];
 599                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 600                         }
 601                 if(shortString < 2)
 602                 for(i = 0; i < MAX_SCORE; ++i)
 603                         if(teamscores_flags[i] & SFL_SORT_PRIO_MASK == SFL_SORT_PRIO_SECONDARY)
 604                         {
 605                                 f = teamscores_flags[i];
 606                                 l = teamscores_label[i];
 607                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 608                         }
 609                 if(shortString < 1)
 610                 for(i = 0; i < MAX_SCORE; ++i)
 611                         if(teamscores_flags[i] & SFL_SORT_PRIO_MASK != SFL_SORT_PRIO_PRIMARY)
 612                         if(teamscores_flags[i] & SFL_SORT_PRIO_MASK != SFL_SORT_PRIO_SECONDARY)
 613                         {
 614                                 f = teamscores_flags[i];
 615                                 l = teamscores_label[i];
 616                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 617                         }
 618                 out = substring(out, 0, strlen(out) - 1);
 619         }
 620         else if((sk = teamscorekeepers[tm - 1]))
 621         {
 622                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 623                         if(teamscores_flags[i] & SFL_SORT_PRIO_MASK == SFL_SORT_PRIO_PRIMARY)
 624                                 out = strcat(out, ftos(sk.(teamscores[i])), ",");
 625                 if(shortString < 2)
 626                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 627                         if(teamscores_flags[i] & SFL_SORT_PRIO_MASK == SFL_SORT_PRIO_SECONDARY)
 628                                 out = strcat(out, ftos(sk.(teamscores[i])), ",");
 629                 if(shortString < 1)
 630                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 631                         if(teamscores_flags[i] & SFL_SORT_PRIO_MASK != SFL_SORT_PRIO_PRIMARY)
 632                         if(teamscores_flags[i] & SFL_SORT_PRIO_MASK != SFL_SORT_PRIO_SECONDARY)
 633                                 out = strcat(out, ftos(sk.(teamscores[i])), ",");
 634                 out = substring(out, 0, strlen(out) - 1);
 635         }
 636         return out;
 637 }
 638
 639 float PlayerTeamScore_Compare(entity p1, entity p2)
 640 {
 641         if(teamscores_entities_count)
 642                 if(p1.team != p2.team)
 643                 {
 644                         entity t1, t2;
 645                         float r;
 646                         t1 = teamscorekeepers[p1.team - 1];
 647                         t2 = teamscorekeepers[p2.team - 1];
 648                         r = TeamScore_Compare(t1, t2);
 649                         if(r == 0) // ensure a deterministic order
 650                                 r = p1.team - p2.team;
 651                         return r;
 652                 }
 653
 654         return PlayerScore_Compare(p1.scorekeeper, p2.scorekeeper);
 655 }
 656
 657 entity PlayerScore_Sort(.float field)
 658 {
 659         entity p, plist, pprev, pbest, pbestprev, pfirst, plast;
 660         float i;
 661
 662         plist = world;
 663
 664         FOR_EACH_CLIENT(p)
 665                 p.field = 0;
 666
 667         FOR_EACH_PLAYER(p) if(p.scorekeeper)
 668         {
 669                 p.chain = plist;
 670                 plist = p;
 671         }
 672         // Now plist points to the whole list.
 673
 674         pfirst = plast = world;
 675
 676         i = 0;
 677         while(plist)
 678         {
 679                 pprev = pbestprev = world;
 680                 pbest = plist;
 681                 for(p = plist; (pprev = p), (p = p.chain); )
 682                 {
 683                         if(PlayerTeamScore_Compare(p, pbest) > 0)
 684                         {
 685                                 pbest = p;
 686                                 pbestprev = pprev;
 687                         }
 688                 }
 689
 690                 // remove pbest out of the chain
 691                 if(pbestprev == world)
 692                         plist = pbest.chain;
 693                 else
 694                         pbestprev.chain = pbest.chain;
 695                 pbest.chain = world;
 696
 697                 pbest.field = ++i;
 698
 699                 if not(pfirst)
 700                         pfirst = pbest;
 701                 if(plast)
 702                         plast.chain = pbest;
 703                 plast = pbest;
 704         }
 705
 706         return pfirst;
 707 }
 708
 709 float TeamScore_GetCompareValue(float t)
 710 {
 711         float s;
 712         entity sk;
 713
 714         if(t <= 0 || t >= 16)
 715         {
 716                 if(gameover)
 717                         return 0;
 718                 error("Reading score of invalid team!");
 719         }
 720
 721         sk = teamscorekeepers[t - 1];
 722         if not(sk)
 723                 return -999999999;
 724         s = sk.teamscores_primary;
 725         if(teamscores_flags_primary & SFL_ZERO_IS_WORST)
 726                 if(!s)
 727                         return -999999999;
 728         if(teamscores_flags_primary & SFL_LOWER_IS_BETTER)
 729                 s = -s;
 730         return s;
 731 }
 732
 733 #define NAMEWIDTH 22
 734 #define SCORESWIDTH 58
 735 // TODO put this somewhere in common?
 736 string Score_NicePrint_ItemColor(float vflags)
 737 {
 738         if(vflags & SFL_SORT_PRIO_PRIMARY)
 739                 return "^3";
 740         else if(vflags & SFL_SORT_PRIO_SECONDARY)
 741                 return "^5";
 742         else
 743                 return "^7";
 744 }
 745
 746 void Score_NicePrint_Team(entity to, float t, float w)
 747 {
 748         string s, s2;
 749         float i;
 750         entity sk;
 751         float fl, sc;
 752         s = "";
 753
 754         sk = teamscorekeepers[t - 1];
 755         if(sk)
 756         {
 757                 s = strcat(s, ColoredTeamName(t));
 758                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 759                         if(teamscores_label[i] != "")
 760                         {
 761                                 fl = teamscores_flags[i];
 762                                 sc = sk.(teamscores[i]);
 763                                 s = strcat(s, " ", Score_NicePrint_ItemColor(fl), ScoreString(fl, sc));
 764                         }
 765         }
 766         else
 767                 s = "Scores:";
 768
 769         s = strcat(s, strpad(max(0, NAMEWIDTH - strlennocol(s)), ""));
 770
 771         for(i = 0; i < MAX_SCORE; ++i)
 772                 if(scores_label[i] != "")
 773                 {
 774                         fl = scores_flags[i];
 775                         s2 = scores_label[i];
 776                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, substring(s2, 0, w)));
 777                 }
 778
 779         print_to(to, s);
 780 }
 781
 782 void Score_NicePrint_Player(entity to, entity p, float w)
 783 {
 784         string s;
 785         float i;
 786         entity sk;
 787         float fl, sc;
 788         s = "  ";
 789
 790         sk = p.scorekeeper;
 791
 792         s = strcat(s, p.netname);
 793         for(;;)
 794         {
 795                 i = strlennocol(s) - NAMEWIDTH;
 796                 if(i > 0)
 797                         s = substring(s, 0, strlen(s) - i);
 798                 else
 799                 {
 800                         s = strcat(s, strpad(i, ""));
 801                         break;
 802                 }
 803         }
 804
 805         for(i = 0; i < MAX_SCORE; ++i)
 806                 if(scores_label[i] != "")
 807                 {
 808                         fl = scores_flags[i];
 809                         sc = sk.(scores[i]);
 810                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, ScoreString(fl, sc)));
 811                 }
 812
 813         print_to(to, s);
 814 }
 815
 816 void Score_NicePrint_Spectators(entity to)
 817 {
 818         print_to(to, "Spectators:");
 819 }
 820
 821 void Score_NicePrint_Spectator(entity to, entity p)
 822 {
 823         print_to(to, strcat("  ", p.netname));
 824 }
 825
 826 .float score_dummyfield;
 827 void Score_NicePrint(entity to)
 828 {
 829         entity p;
 830         float t, i;
 831         float w;
 832
 833         t = 0;
 834         for(i = 0; i < MAX_SCORE; ++i)
 835                 if(scores_label[i] != "")
 836                         ++t;
 837         w = bound(6, floor(SCORESWIDTH / t - 1), 9);
 838
 839         p = PlayerScore_Sort(score_dummyfield);
 840         t = -1;
 841
 842         if(!teamscores_entities_count)
 843                 Score_NicePrint_Team(to, t, w);
 844         while(p)
 845         {
 846                 if(teamscores_entities_count)
 847                         if(t != p.team)
 848                                 Score_NicePrint_Team(to, p.team, w);
 849                 Score_NicePrint_Player(to, p, w);
 850                 t = p.team;
 851                 p = p.chain;
 852         }
 853
 854         t = 0;
 855         FOR_EACH_CLIENT(p)
 856         if(p.classname != "player")
 857         {
 858                 if not(t)
 859                         Score_NicePrint_Spectators(to);
 860                 Score_NicePrint_Spectator(to, p);
 861                 t = 1;
 862         }
 863 }
 864