qcsrc/server/scores.qc

   1 #include "scores.qh"
   2
   3 #include "command/common.qh"
   4 #include "mutators/all.qh"
   5 #include "../common/playerstats.qh"
   6 #include "../common/teams.qh"
   7
   8 .entity scorekeeper;
   9 entity teamscorekeepers[16];
  10 string scores_label[MAX_SCORE];
  11 float scores_flags[MAX_SCORE];
  12 string teamscores_label[MAX_TEAMSCORE];
  13 float teamscores_flags[MAX_TEAMSCORE];
  14 float teamscores_entities_count;
  15 var .float scores_primary;
  16 var .float teamscores_primary;
  17 float scores_flags_primary;
  18 float teamscores_flags_primary;
  19
  20 vector ScoreField_Compare(entity t1, entity t2, .float field, float fieldflags, vector previous, float strict) // returns: cmp value, best prio
  21 {
  22         if(!strict && !(fieldflags & SFL_SORT_PRIO_MASK)) // column does not sort
  23                 return previous;
  24         if((fieldflags & SFL_SORT_PRIO_MASK) < previous.y)
  25                 return previous;
  26         if (t1.(field) == t2.(field))
  27                 return previous;
  28
  29         previous.y = fieldflags & SFL_SORT_PRIO_MASK;
  30
  31         if(fieldflags & SFL_ZERO_IS_WORST)
  32         {
  33                 if (t1.(field) == 0)
  34                 {
  35                         previous.x = -1;
  36                         return previous;
  37                 }
  38                 else if (t2.(field) == 0)
  39                 {
  40                         previous.x = +1;
  41                         return previous;
  42                 }
  43         }
  44
  45         if (fieldflags & SFL_LOWER_IS_BETTER)
  46                 previous.x = (t2.(field) - t1.(field));
  47         else
  48                 previous.x = (t1.(field) - t2.(field));
  49
  50         return previous;
  51 }
  52
  53 /*
  54  * teamscore entities
  55  */
  56
  57 bool TeamScore_SendEntity(entity this, entity to, float sendflags)
  58 {
  59         float i, p, longflags;
  60
  61         WriteHeader(MSG_ENTITY, ENT_CLIENT_TEAMSCORES);
  62         int t = this.team - 1;
  63         assert(t, eprint(this));
  64         WriteByte(MSG_ENTITY, t);
  65
  66         longflags = 0;
  67         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
  68                 if(this.(teamscores[i]) > 127 || this.(teamscores[i]) <= -128)
  69                         longflags |= p;
  70
  71 #if MAX_TEAMSCORE <= 8
  72         WriteByte(MSG_ENTITY, sendflags);
  73         WriteByte(MSG_ENTITY, longflags);
  74 #else
  75         WriteShort(MSG_ENTITY, sendflags);
  76         WriteShort(MSG_ENTITY, longflags);
  77 #endif
  78         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
  79                 if(sendflags & p)
  80                 {
  81                         if(longflags & p)
  82                                 WriteInt24_t(MSG_ENTITY, this.(teamscores[i]));
  83                         else
  84                                 WriteChar(MSG_ENTITY, this.(teamscores[i]));
  85                 }
  86
  87         return true;
  88 }
  89
  90 void TeamScore_Spawn(float t, string name)
  91 {
  92         entity ts = new_pure(csqc_score_team);
  93         ts.netname = name; // not used yet, FIXME
  94         ts.team = t;
  95         Net_LinkEntity(ts, false, 0, TeamScore_SendEntity);
  96         teamscorekeepers[t - 1] = ts;
  97         ++teamscores_entities_count;
  98         PlayerStats_GameReport_AddTeam(t);
  99 }
 100
 101 float TeamScore_AddToTeam(float t, float scorefield, float score)
 102 {
 103         entity s;
 104
 105         if(gameover)
 106                 score = 0;
 107
 108         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 109         if(t <= 0 || t >= 16)
 110         {
 111                 if(gameover)
 112                         return 0;
 113                 error("Adding score to invalid team!");
 114         }
 115         s = teamscorekeepers[t - 1];
 116         if(!s)
 117         {
 118                 if(gameover)
 119                         return 0;
 120                 error("Adding score to unknown team!");
 121         }
 122         if(score)
 123                 if(teamscores_label[scorefield] != "")
 124                         s.SendFlags |= pow(2, scorefield);
 125         return (s.(teamscores[scorefield]) += score);
 126 }
 127
 128 float TeamScore_Add(entity player, float scorefield, float score)
 129 {
 130         return TeamScore_AddToTeam(player.team, scorefield, score);
 131 }
 132
 133 float TeamScore_Compare(entity t1, entity t2, float strict)
 134 {
 135         if(!t1 || !t2) return (!t2) - !t1;
 136
 137         vector result = '0 0 0';
 138         float i;
 139         for(i = 0; i < MAX_TEAMSCORE; ++i)
 140         {
 141                 var .float f;
 142                 f = teamscores[i];
 143                 result = ScoreField_Compare(t1, t2, f, teamscores_flags[i], result, strict);
 144         }
 145
 146         if (result.x == 0 && strict)
 147                 result.x = t1.team - t2.team;
 148
 149         return result.x;
 150 }
 151
 152 /*
 153  * the scoreinfo entity
 154  */
 155
 156 void ScoreInfo_SetLabel_PlayerScore(float i, string label, float scoreflags)
 157 {
 158         scores_label[i] = label;
 159         scores_flags[i] = scoreflags;
 160         if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 161         {
 162                 scores_primary = scores[i];
 163                 scores_flags_primary = scoreflags;
 164         }
 165         if(label != "")
 166         {
 167                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
 168                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
 169         }
 170 }
 171
 172 void ScoreInfo_SetLabel_TeamScore(float i, string label, float scoreflags)
 173 {
 174         teamscores_label[i] = label;
 175         teamscores_flags[i] = scoreflags;
 176         if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 177         {
 178                 teamscores_primary = teamscores[i];
 179                 teamscores_flags_primary = scoreflags;
 180         }
 181         if(label != "")
 182         {
 183                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
 184                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
 185         }
 186 }
 187
 188 bool ScoreInfo_SendEntity(entity this, entity to, int sf)
 189 {
 190         float i;
 191         WriteHeader(MSG_ENTITY, ENT_CLIENT_SCORES_INFO);
 192         WriteInt24_t(MSG_ENTITY, MapInfo_LoadedGametype);
 193         for(i = 0; i < MAX_SCORE; ++i)
 194         {
 195                 WriteString(MSG_ENTITY, scores_label[i]);
 196                 WriteByte(MSG_ENTITY, scores_flags[i]);
 197         }
 198         for(i = 0; i < MAX_TEAMSCORE; ++i)
 199         {
 200                 WriteString(MSG_ENTITY, teamscores_label[i]);
 201                 WriteByte(MSG_ENTITY, teamscores_flags[i]);
 202         }
 203         return true;
 204 }
 205
 206 void ScoreInfo_Init(int teams)
 207 {
 208         if(scores_initialized)
 209         {
 210                 scores_initialized.SendFlags |= 1; // force a resend
 211         }
 212         else
 213         {
 214                 scores_initialized = new_pure(ent_client_scoreinfo);
 215                 Net_LinkEntity(scores_initialized, false, 0, ScoreInfo_SendEntity);
 216         }
 217         if(teams & BIT(0))
 218                 TeamScore_Spawn(NUM_TEAM_1, "Red");
 219         if(teams & BIT(1))
 220                 TeamScore_Spawn(NUM_TEAM_2, "Blue");
 221         if(teams & BIT(2))
 222                 TeamScore_Spawn(NUM_TEAM_3, "Yellow");
 223         if(teams & BIT(3))
 224                 TeamScore_Spawn(NUM_TEAM_4, "Pink");
 225 }
 226
 227 /*
 228  * per-player score entities
 229  */
 230
 231 bool PlayerScore_SendEntity(entity this, entity to, float sendflags)
 232 {
 233         float i, p, longflags;
 234
 235         WriteHeader(MSG_ENTITY, ENT_CLIENT_SCORES);
 236         WriteByte(MSG_ENTITY, etof(this.owner));
 237
 238         longflags = 0;
 239         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 240                 if(this.(scores[i]) > 127 || this.(scores[i]) <= -128)
 241                         longflags |= p;
 242
 243 #if MAX_SCORE <= 8
 244         WriteByte(MSG_ENTITY, sendflags);
 245         WriteByte(MSG_ENTITY, longflags);
 246 #else
 247         WriteShort(MSG_ENTITY, sendflags);
 248         WriteShort(MSG_ENTITY, longflags);
 249 #endif
 250         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 251                 if(sendflags & p)
 252                 {
 253                         if(longflags & p)
 254                                 WriteInt24_t(MSG_ENTITY, this.(scores[i]));
 255                         else
 256                                 WriteChar(MSG_ENTITY, this.(scores[i]));
 257                 }
 258
 259         return true;
 260 }
 261
 262 float PlayerScore_Clear(entity player)
 263 {
 264         entity sk;
 265         float i;
 266
 267         if(teamscores_entities_count)
 268                 return 0;
 269
 270         if(MUTATOR_CALLHOOK(ForbidPlayerScore_Clear)) return 0;
 271
 272         sk = player.scorekeeper;
 273         for(i = 0; i < MAX_SCORE; ++i)
 274         {
 275                 if(sk.(scores[i]) != 0)
 276                         if(scores_label[i] != "")
 277                                 sk.SendFlags |= pow(2, i);
 278                 sk.(scores[i]) = 0;
 279         }
 280
 281         return 1;
 282 }
 283
 284 void Score_ClearAll()
 285 {
 286         entity sk;
 287         float t;
 288         FOREACH_CLIENTSLOT(true,
 289         {
 290                 sk = it.scorekeeper;
 291                 if(!sk)
 292                         continue;
 293                 for(int j = 0; j < MAX_SCORE; ++j)
 294                 {
 295                         if(sk.(scores[j]) != 0)
 296                                 if(scores_label[j] != "")
 297                                         sk.SendFlags |= pow(2, j);
 298                         sk.(scores[j]) = 0;
 299                 }
 300         });
 301         for(t = 0; t < 16; ++t)
 302         {
 303                 sk = teamscorekeepers[t];
 304                 if(!sk)
 305                         continue;
 306                 for(int j = 0; j < MAX_TEAMSCORE; ++j)
 307                 {
 308                         if(sk.(teamscores[j]) != 0)
 309                                 if(teamscores_label[j] != "")
 310                                         sk.SendFlags |= pow(2, j);
 311                         sk.(teamscores[j]) = 0;
 312                 }
 313         }
 314 }
 315
 316 void PlayerScore_Attach(entity player)
 317 {
 318         if(player.scorekeeper)
 319                 error("player already has a scorekeeper");
 320         entity sk = new_pure(scorekeeper);
 321         sk.owner = player;
 322         Net_LinkEntity(sk, false, 0, PlayerScore_SendEntity);
 323         player.scorekeeper = sk;
 324 }
 325
 326 void PlayerScore_Detach(entity player)
 327 {
 328         if(!player.scorekeeper)
 329                 error("player has no scorekeeper");
 330         remove(player.scorekeeper);
 331         player.scorekeeper = NULL;
 332 }
 333
 334 float PlayerScore_Add(entity player, float scorefield, float score)
 335 {
 336         bool mutator_returnvalue = MUTATOR_CALLHOOK(AddPlayerScore, scorefield, score, player);
 337         score = M_ARGV(1, float);
 338
 339         if(gameover)
 340         if(!mutator_returnvalue)
 341                 score = 0;
 342
 343         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 344         entity s = player.scorekeeper;
 345         if(!s)
 346         {
 347                 if(gameover)
 348                         return 0;
 349                 LOG_WARNING("Adding score to unknown player!");
 350                 return 0;
 351         }
 352         if(score)
 353                 if(scores_label[scorefield] != "")
 354                         s.SendFlags |= pow(2, scorefield);
 355         if(!warmup_stage)
 356                 PS_GR_P_ADDVAL(s.owner, strcat(PLAYERSTATS_TOTAL, scores_label[scorefield]), score);
 357         return (s.(scores[scorefield]) += score);
 358 }
 359
 360 float PlayerTeamScore_Add(entity player, float pscorefield, float tscorefield, float score)
 361 {
 362         float r;
 363         r = PlayerScore_Add(player, pscorefield, score);
 364         if(teamscores_entities_count) // only for teamplay
 365                 r = TeamScore_Add(player, tscorefield, score);
 366         return r;
 367 }
 368
 369 float PlayerScore_Compare(entity t1, entity t2, float strict)
 370 {
 371         if(!t1 || !t2) return (!t2) - !t1;
 372
 373         vector result = '0 0 0';
 374         float i;
 375         for(i = 0; i < MAX_SCORE; ++i)
 376         {
 377                 var .float f;
 378                 f = scores[i];
 379                 result = ScoreField_Compare(t1, t2, f, scores_flags[i], result, strict);
 380         }
 381
 382         if (result.x == 0 && strict)
 383                 result.x = etof(t1.owner) - etof(t2.owner);
 384
 385         return result.x;
 386 }
 387
 388 void WinningConditionHelper(entity this)
 389 {
 390         float c;
 391         string s;
 392         float fullstatus;
 393         entity winnerscorekeeper;
 394         entity secondscorekeeper;
 395         entity sk;
 396
 397         // format:
 398         // gametype:P<pure>:S<slots>::plabel,plabel:tlabel,tlabel:teamid:tscore,tscore:teamid:tscore,tscore
 399         // score labels always start with a symbol or with lower case
 400         // so to match pure, match for :P0:
 401         // to match full, match for :S0:
 402
 403         fullstatus = autocvar_g_full_getstatus_responses;
 404
 405         s = GetGametype();
 406         s = strcat(s, ":", autocvar_g_xonoticversion);
 407         s = strcat(s, ":P", ftos(cvar_purechanges_count));
 408         s = strcat(s, ":S", ftos(nJoinAllowed(this, NULL)));
 409         s = strcat(s, ":F", ftos(serverflags));
 410         s = strcat(s, ":M", modname);
 411         s = strcat(s, "::", GetPlayerScoreString(NULL, (fullstatus ? 1 : 2)));
 412
 413         if(teamscores_entities_count)
 414         {
 415                 float t;
 416
 417                 s = strcat(s, ":", GetTeamScoreString(0, 1));
 418                 for(t = 0; t < 16; ++t)
 419                         if(teamscorekeepers[t])
 420                                 s = strcat(s, ":", ftos(t+1), ":", GetTeamScoreString(t+1, 1));
 421
 422                 WinningConditionHelper_winnerteam = -1;
 423                 WinningConditionHelper_secondteam = -1;
 424                 winnerscorekeeper = NULL;
 425                 secondscorekeeper = NULL;
 426                 for(t = 0; t < 16; ++t)
 427                 {
 428                         sk = teamscorekeepers[t];
 429                         c = TeamScore_Compare(winnerscorekeeper, sk, 1);
 430                         if(c < 0)
 431                         {
 432                                 WinningConditionHelper_secondteam = WinningConditionHelper_winnerteam;
 433                                 WinningConditionHelper_winnerteam = t + 1;
 434                                 secondscorekeeper = winnerscorekeeper;
 435                                 winnerscorekeeper = sk;
 436                         }
 437                         else
 438                         {
 439                                 c = TeamScore_Compare(secondscorekeeper, sk, 1);
 440                                 if(c < 0)
 441                                 {
 442                                         WinningConditionHelper_secondteam = t + 1;
 443                                         secondscorekeeper = sk;
 444                                 }
 445                         }
 446                 }
 447
 448                 WinningConditionHelper_equality = (TeamScore_Compare(winnerscorekeeper, secondscorekeeper, 0) == 0);
 449                 if(WinningConditionHelper_equality)
 450                         WinningConditionHelper_winnerteam = WinningConditionHelper_secondteam = -1;
 451
 452                 WinningConditionHelper_topscore = winnerscorekeeper.teamscores_primary;
 453                 WinningConditionHelper_secondscore = secondscorekeeper.teamscores_primary;
 454                 WinningConditionHelper_lowerisbetter = (teamscores_flags_primary & SFL_LOWER_IS_BETTER);
 455                 WinningConditionHelper_zeroisworst = (teamscores_flags_primary & SFL_ZERO_IS_WORST);
 456
 457                 WinningConditionHelper_winner = NULL; // not supported in teamplay
 458                 WinningConditionHelper_second = NULL; // not supported in teamplay
 459         }
 460         else
 461         {
 462                 WinningConditionHelper_winner = NULL;
 463                 WinningConditionHelper_second = NULL;
 464                 winnerscorekeeper = NULL;
 465                 secondscorekeeper = NULL;
 466                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 467                         sk = it.scorekeeper;
 468                         c = PlayerScore_Compare(winnerscorekeeper, sk, 1);
 469                         if(c < 0)
 470                         {
 471                                 WinningConditionHelper_second = WinningConditionHelper_winner;
 472                                 WinningConditionHelper_winner = it;
 473                                 secondscorekeeper = winnerscorekeeper;
 474                                 winnerscorekeeper = sk;
 475                         }
 476                         else
 477                         {
 478                                 c = PlayerScore_Compare(secondscorekeeper, sk, 1);
 479                                 if(c < 0)
 480                                 {
 481                                         WinningConditionHelper_second = it;
 482                                         secondscorekeeper = sk;
 483                                 }
 484                         }
 485                 ));
 486
 487                 WinningConditionHelper_equality = (PlayerScore_Compare(winnerscorekeeper, secondscorekeeper, 0) == 0);
 488                 if(WinningConditionHelper_equality)
 489                         WinningConditionHelper_winner = WinningConditionHelper_second = NULL;
 490
 491                 WinningConditionHelper_topscore = winnerscorekeeper.scores_primary;
 492                 WinningConditionHelper_secondscore = secondscorekeeper.scores_primary;
 493                 WinningConditionHelper_lowerisbetter = (scores_flags_primary & SFL_LOWER_IS_BETTER);
 494                 WinningConditionHelper_zeroisworst = (scores_flags_primary & SFL_ZERO_IS_WORST);
 495
 496                 WinningConditionHelper_winnerteam = -1; // no teamplay
 497                 WinningConditionHelper_secondteam = -1; // no teamplay
 498         }
 499
 500         if(WinningConditionHelper_topscore == 0)
 501         {
 502                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 503                 {
 504                         if(WinningConditionHelper_lowerisbetter)
 505                                 WinningConditionHelper_topscore = 999999999;
 506                         else
 507                                 WinningConditionHelper_topscore = -999999999;
 508                 }
 509                 WinningConditionHelper_equality = 0;
 510         }
 511
 512         if(WinningConditionHelper_secondscore == 0)
 513         {
 514                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 515                 {
 516                         if(WinningConditionHelper_lowerisbetter)
 517                                 WinningConditionHelper_secondscore = 999999999;
 518                         else
 519                                 WinningConditionHelper_secondscore = -999999999;
 520                 }
 521         }
 522
 523         if(worldstatus)
 524                 strunzone(worldstatus);
 525         worldstatus = strzone(s);
 526
 527         FOREACH_CLIENT(true, LAMBDA(
 528                 string s = "";
 529                 if(fullstatus)
 530                 {
 531                         s = GetPlayerScoreString(it, 1);
 532                         s = strcat(s, IS_REAL_CLIENT(it) ? ":human" : ":bot");
 533                         if(!IS_PLAYER(it) && !MUTATOR_CALLHOOK(GetPlayerStatus, it))
 534                                 s = strcat(s, ":spectator");
 535                 }
 536                 else
 537                 {
 538                         if (IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
 539                                 s = GetPlayerScoreString(it, 2);
 540                         else
 541                                 s = "-666";
 542                 }
 543
 544                 if(it.clientstatus)
 545                         strunzone(it.clientstatus);
 546                 it.clientstatus = strzone(s);
 547         ));
 548 }
 549
 550 string GetScoreLogLabel(string label, float fl)
 551 {
 552         if(fl & SFL_LOWER_IS_BETTER)
 553                 label = strcat(label, "<");
 554         if((fl & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 555                 label = strcat(label, "!!");
 556         else if((fl & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 557                 label = strcat(label, "!");
 558         return label;
 559 }
 560
 561 string GetPlayerScoreString(entity pl, float shortString)
 562 {
 563         string out;
 564         entity sk;
 565         float i, f;
 566         string l;
 567
 568         out = "";
 569         if(!pl)
 570         {
 571                 // label
 572                 for(i = 0; i < MAX_SCORE; ++i)
 573                         if((scores_flags[i] & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 574                         {
 575                                 f = scores_flags[i];
 576                                 l = scores_label[i];
 577                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 578                         }
 579                 if(shortString < 2)
 580                 for(i = 0; i < MAX_SCORE; ++i)
 581                         if((scores_flags[i] & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 582                         {
 583                                 f = scores_flags[i];
 584                                 l = scores_label[i];
 585                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 586                         }
 587                 if(shortString < 1)
 588                 for(i = 0; i < MAX_SCORE; ++i)
 589                         if((scores_flags[i] & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 590                         if((scores_flags[i] & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 591                         {
 592                                 f = scores_flags[i];
 593                                 l = scores_label[i];
 594                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 595                         }
 596                 out = substring(out, 0, strlen(out) - 1);
 597         }
 598         else if((sk = pl.scorekeeper))
 599         {
 600                 for(i = 0; i < MAX_SCORE; ++i)
 601                         if((scores_flags[i] & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 602                                 out = strcat(out, ftos(sk.(scores[i])), ",");
 603                 if(shortString < 2)
 604                 for(i = 0; i < MAX_SCORE; ++i)
 605                         if((scores_flags[i] & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 606                                 out = strcat(out, ftos(sk.(scores[i])), ",");
 607                 if(shortString < 1)
 608                 for(i = 0; i < MAX_SCORE; ++i)
 609                         if((scores_flags[i] & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 610                         if((scores_flags[i] & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 611                                 out = strcat(out, ftos(sk.(scores[i])), ",");
 612                 out = substring(out, 0, strlen(out) - 1);
 613         }
 614         return out;
 615 }
 616
 617 string GetTeamScoreString(float tm, float shortString)
 618 {
 619         string out;
 620         entity sk;
 621         float i, f;
 622         string l;
 623
 624         out = "";
 625         if(tm == 0)
 626         {
 627                 // label
 628                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 629                         if((teamscores_flags[i] & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 630                         {
 631                                 f = teamscores_flags[i];
 632                                 l = teamscores_label[i];
 633                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 634                         }
 635                 if(shortString < 2)
 636                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 637                         if((teamscores_flags[i] & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 638                         {
 639                                 f = teamscores_flags[i];
 640                                 l = teamscores_label[i];
 641                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 642                         }
 643                 if(shortString < 1)
 644                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 645                         if((teamscores_flags[i] & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 646                         if((teamscores_flags[i] & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 647                         {
 648                                 f = teamscores_flags[i];
 649                                 l = teamscores_label[i];
 650                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 651                         }
 652                 out = substring(out, 0, strlen(out) - 1);
 653         }
 654         else if((sk = teamscorekeepers[tm - 1]))
 655         {
 656                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 657                         if((teamscores_flags[i] & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 658                                 out = strcat(out, ftos(sk.(teamscores[i])), ",");
 659                 if(shortString < 2)
 660                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 661                         if((teamscores_flags[i] & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 662                                 out = strcat(out, ftos(sk.(teamscores[i])), ",");
 663                 if(shortString < 1)
 664                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 665                         if((teamscores_flags[i] & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 666                         if((teamscores_flags[i] & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 667                                 out = strcat(out, ftos(sk.(teamscores[i])), ",");
 668                 out = substring(out, 0, strlen(out) - 1);
 669         }
 670         return out;
 671 }
 672
 673 float PlayerTeamScore_Compare(entity p1, entity p2, float teams, float strict)
 674 {
 675         if(teams && teamscores_entities_count)
 676         {
 677                 if(p1.team != p2.team)
 678                 {
 679                         entity t1, t2;
 680                         float r;
 681                         t1 = teamscorekeepers[p1.team - 1];
 682                         t2 = teamscorekeepers[p2.team - 1];
 683                         r = TeamScore_Compare(t1, t2, ((teams >= 0) ? 1 : strict));
 684                         return r;
 685                 }
 686                 if(teams < 0)
 687                         return 0;
 688         }
 689
 690         return PlayerScore_Compare(p1.scorekeeper, p2.scorekeeper, strict);
 691 }
 692
 693 entity PlayerScore_Sort(.float field, float teams, float strict, float nospectators)
 694 {
 695         entity p, plist, pprev, pbest, pbestprev, pfirst, plast;
 696         float i, j;
 697
 698         plist = NULL;
 699
 700         FOREACH_CLIENT(true, LAMBDA(it.(field) = 0));
 701
 702         FOREACH_CLIENT(it.scorekeeper,
 703         {
 704                 if(nospectators)
 705                         if(it.frags == FRAGS_SPECTATOR)
 706                                 continue;
 707
 708                 it.chain = plist;
 709                 plist = it;
 710         });
 711         // Now plist points to the whole list.
 712
 713         pfirst = plast = NULL;
 714
 715         i = j = 0;
 716         while(plist)
 717         {
 718                 pprev = pbestprev = NULL;
 719                 pbest = plist;
 720                 for(p = plist; (pprev = p), (p = p.chain); )
 721                 {
 722                         if(PlayerTeamScore_Compare(p, pbest, teams, strict) > 0)
 723                         {
 724                                 pbest = p;
 725                                 pbestprev = pprev;
 726                         }
 727                 }
 728
 729                 // remove pbest out of the chain
 730                 if(pbestprev == NULL)
 731                         plist = pbest.chain;
 732                 else
 733                         pbestprev.chain = pbest.chain;
 734                 pbest.chain = NULL;
 735
 736                 ++i;
 737                 if(!plast || PlayerTeamScore_Compare(plast, pbest, teams, 0))
 738                         j = i;
 739
 740                 pbest.(field) = j;
 741
 742                 if (!pfirst)
 743                         pfirst = pbest;
 744                 if(plast)
 745                         plast.chain = pbest;
 746                 plast = pbest;
 747         }
 748
 749         return pfirst;
 750 }
 751
 752 float TeamScore_GetCompareValue(float t)
 753 {
 754         float s;
 755         entity sk;
 756
 757         if(t <= 0 || t >= 16)
 758         {
 759                 if(gameover)
 760                         return 0;
 761                 error("Reading score of invalid team!");
 762         }
 763
 764         sk = teamscorekeepers[t - 1];
 765         if (!sk)
 766                 return -999999999;
 767         s = sk.teamscores_primary;
 768         if(teamscores_flags_primary & SFL_ZERO_IS_WORST)
 769                 if(!s)
 770                         return -999999999;
 771         if(teamscores_flags_primary & SFL_LOWER_IS_BETTER)
 772                 s = -s;
 773         return s;
 774 }
 775
 776 const float NAMEWIDTH = 22;
 777 const float SCORESWIDTH = 58;
 778 // TODO put this somewhere in common?
 779 string Score_NicePrint_ItemColor(float vflags)
 780 {
 781         if(vflags & SFL_SORT_PRIO_PRIMARY)
 782                 return "^3";
 783         else if(vflags & SFL_SORT_PRIO_SECONDARY)
 784                 return "^5";
 785         else
 786                 return "^7";
 787 }
 788
 789 void Score_NicePrint_Team(entity to, float t, float w)
 790 {
 791         string s, s2;
 792         float i;
 793         entity sk;
 794         float fl, sc;
 795         s = "";
 796
 797         sk = teamscorekeepers[t - 1];
 798         if(sk)
 799         {
 800                 s = strcat(s, Team_ColoredFullName(t));
 801                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 802                         if(teamscores_label[i] != "")
 803                         {
 804                                 fl = teamscores_flags[i];
 805                                 sc = sk.(teamscores[i]);
 806                                 s = strcat(s, " ", Score_NicePrint_ItemColor(fl), ScoreString(fl, sc));
 807                         }
 808         }
 809         else
 810                 s = "Scores:";
 811
 812         s = strcat(s, strpad(max(0, NAMEWIDTH - strlennocol(s)), ""));
 813
 814         for(i = 0; i < MAX_SCORE; ++i)
 815                 if(scores_label[i] != "")
 816                 {
 817                         fl = scores_flags[i];
 818                         s2 = scores_label[i];
 819                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, substring(s2, 0, w)));
 820                 }
 821
 822         print_to(to, s);
 823 }
 824
 825 void Score_NicePrint_Player(entity to, entity p, float w)
 826 {
 827         string s;
 828         float i;
 829         entity sk;
 830         float fl, sc;
 831         s = "  ";
 832
 833         sk = p.scorekeeper;
 834
 835         s = strcat(s, p.netname);
 836         for (;;)
 837         {
 838                 i = strlennocol(s) - NAMEWIDTH;
 839                 if(i > 0)
 840                         s = substring(s, 0, strlen(s) - i);
 841                 else
 842                 {
 843                         s = strcat(s, strpad(i, ""));
 844                         break;
 845                 }
 846         }
 847
 848         for(i = 0; i < MAX_SCORE; ++i)
 849                 if(scores_label[i] != "")
 850                 {
 851                         fl = scores_flags[i];
 852                         sc = sk.(scores[i]);
 853                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, ScoreString(fl, sc)));
 854                 }
 855
 856         print_to(to, s);
 857 }
 858
 859 void Score_NicePrint_Spectators(entity to)
 860 {
 861         print_to(to, "Spectators:");
 862 }
 863
 864 void Score_NicePrint_Spectator(entity to, entity p)
 865 {
 866         print_to(to, strcat("  ", p.netname));
 867 }
 868
 869 .float score_dummyfield;
 870 void Score_NicePrint(entity to)
 871 {
 872         entity p;
 873         float i;
 874         float w;
 875
 876         int t = 0;
 877         for(i = 0; i < MAX_SCORE; ++i)
 878                 if(scores_label[i] != "")
 879                         ++t;
 880         w = bound(6, floor(SCORESWIDTH / t - 1), 9);
 881
 882         p = PlayerScore_Sort(score_dummyfield, 1, 1, 0);
 883         t = -1;
 884
 885         if(!teamscores_entities_count)
 886                 Score_NicePrint_Team(to, t, w);
 887         while(p)
 888         {
 889                 if(teamscores_entities_count)
 890                         if(t != p.team)
 891                                 Score_NicePrint_Team(to, p.team, w);
 892                 Score_NicePrint_Player(to, p, w);
 893                 t = p.team;
 894                 p = p.chain;
 895         }
 896
 897         t = 0;
 898         FOREACH_CLIENT(!IS_PLAYER(it), LAMBDA(
 899                 if (!t)
 900                         Score_NicePrint_Spectators(to);
 901                 Score_NicePrint_Spectator(to, it);
 902                 t = 1;
 903         ));
 904 }
 905
 906 void PlayerScore_PlayerStats(entity p)
 907 {
 908         entity s;
 909         float i;
 910         s = p.scorekeeper;
 911
 912         for(i = 0; i < MAX_SCORE; ++i)
 913                 if(s.(scores[i]) != 0)
 914                         if(scores_label[i] != "")
 915                                 PS_GR_P_ADDVAL(s.owner, strcat(PLAYERSTATS_SCOREBOARD, scores_label[i]), s.(scores[i]));
 916 }
 917
 918 void PlayerScore_TeamStats()
 919 {
 920         entity sk;
 921         float t, i;
 922         for(t = 0; t < 16; ++t)
 923         {
 924                 sk = teamscorekeepers[t];
 925                 if(!sk)
 926                         continue;
 927                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 928                         if(sk.(teamscores[i]) != 0)
 929                                 if(teamscores_label[i] != "")
 930                                         // the +1 is important here!
 931                                         PS_GR_T_ADDVAL(t+1, strcat(PLAYERSTATS_SCOREBOARD, teamscores_label[i]), sk.(teamscores[i]));
 932         }
 933 }