qcsrc/server/spawnpoints.qc

   1 #include "spawnpoints.qh"
   2
   3 #include "mutators/all.qh"
   4 #include "g_world.qh"
   5 #include "race.qh"
   6 #include "../common/constants.qh"
   7 #include "../common/teams.qh"
   8 #include "../common/triggers/subs.qh"
   9 #include "../common/util.qh"
  10 #include "../lib/warpzone/common.qh"
  11 #include "../lib/warpzone/util_server.qh"
  12
  13 bool SpawnPoint_Send(entity this, entity to, int sf)
  14 {
  15         WriteHeader(MSG_ENTITY, ENT_CLIENT_SPAWNPOINT);
  16
  17         WriteByte(MSG_ENTITY, self.team);
  18         WriteShort(MSG_ENTITY, self.origin.x);
  19         WriteShort(MSG_ENTITY, self.origin.y);
  20         WriteShort(MSG_ENTITY, self.origin.z);
  21
  22         return true;
  23 }
  24
  25 bool SpawnEvent_Send(entity this, entity to, int sf)
  26 {
  27         float send;
  28
  29         WriteHeader(MSG_ENTITY, ENT_CLIENT_SPAWNEVENT);
  30
  31         if(autocvar_g_spawn_alloweffects)
  32         {
  33                 WriteByte(MSG_ENTITY, num_for_edict(self.owner));
  34                 WriteShort(MSG_ENTITY, self.owner.origin.x);
  35                 WriteShort(MSG_ENTITY, self.owner.origin.y);
  36                 WriteShort(MSG_ENTITY, self.owner.origin.z);
  37                 send = true;
  38         }
  39         else if((to == self.owner) || (IS_SPEC(to) && (to.enemy == self.owner)) )
  40         {
  41                 WriteByte(MSG_ENTITY, 0);
  42                 send = true;
  43         }
  44         else { send = false; }
  45
  46         return send;
  47 }
  48
  49 .vector spawnpoint_prevorigin;
  50 void spawnpoint_think()
  51 {
  52         self.nextthink = time + 0.1;
  53         if(self.origin != self.spawnpoint_prevorigin)
  54         {
  55                 self.spawnpoint_prevorigin = self.origin;
  56                 self.SendFlags |= 1;
  57         }
  58 }
  59
  60 void spawnpoint_use()
  61 {SELFPARAM();
  62         if(teamplay)
  63         if(have_team_spawns > 0)
  64         {
  65                 self.team = activator.team;
  66                 some_spawn_has_been_used = 1;
  67         }
  68         //LOG_INFO("spawnpoint was used!\n");
  69 }
  70
  71 void relocate_spawnpoint()
  72 {SELFPARAM();
  73     // nudge off the floor
  74     setorigin(self, self.origin + '0 0 1');
  75
  76     tracebox(self.origin, PL_MIN_CONST, PL_MAX_CONST, self.origin, true, self);
  77     if (trace_startsolid)
  78     {
  79         vector o;
  80         o = self.origin;
  81         self.mins = PL_MIN_CONST;
  82         self.maxs = PL_MAX_CONST;
  83         if (!move_out_of_solid(self))
  84             objerror("could not get out of solid at all!");
  85         LOG_INFO("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
  86         LOG_INFO(" needs to be moved out of solid, e.g. by '", ftos(self.origin.x - o.x));
  87         LOG_INFO(" ", ftos(self.origin.y - o.y));
  88         LOG_INFO(" ", ftos(self.origin.z - o.z), "'\n");
  89         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
  90         {
  91             if (!spawnpoint_nag)
  92                 LOG_INFO("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
  93             spawnpoint_nag = 1;
  94         }
  95         else
  96         {
  97             setorigin(self, o);
  98             self.mins = self.maxs = '0 0 0';
  99             objerror("player spawn point in solid, mapper sucks!\n");
 100             return;
 101         }
 102     }
 103
 104     self.use = spawnpoint_use;
 105     self.think = spawnpoint_think;
 106     self.nextthink = time + 0.5 + random() * 2; // shouldn't need it for a little second
 107     self.team_saved = self.team;
 108     if (!self.cnt)
 109         self.cnt = 1;
 110
 111     if (have_team_spawns != 0)
 112         if (self.team)
 113             have_team_spawns = 1;
 114     have_team_spawns_forteam[self.team] = 1;
 115
 116     if (autocvar_r_showbboxes)
 117     {
 118         // show where spawnpoints point at too
 119         makevectors(self.angles);
 120         entity e = new(info_player_foo);
 121         setorigin(e, self.origin + v_forward * 24);
 122         setsize(e, '-8 -8 -8', '8 8 8');
 123         e.solid = SOLID_TRIGGER;
 124     }
 125
 126         // Don't show team spawns in non-team matches,
 127         // and don't show non-team spawns in team matches.
 128         // (Unless useallspawns is activated)
 129         if(
 130                 !(
 131                         ( // if this passes, there is a DM spawn on a team match
 132                                 teamplay
 133                                 && (self.team != NUM_TEAM_1)
 134                                 && (self.team != NUM_TEAM_2)
 135                                 && (self.team != NUM_TEAM_3)
 136                                 && (self.team != NUM_TEAM_4)
 137                         )
 138                         ||
 139                         ( // if this passes, there is a team spawn on a DM match
 140                                 !teamplay
 141                                 &&
 142                                 (
 143                                         (self.team == NUM_TEAM_1)
 144                                         || (self.team == NUM_TEAM_2)
 145                                         || (self.team == NUM_TEAM_3)
 146                                         || (self.team == NUM_TEAM_4)
 147                                 )
 148                         )
 149                 )
 150                 ||
 151                 autocvar_g_spawn_useallspawns
 152         )
 153         { Net_LinkEntity(self, false, 0, SpawnPoint_Send); }
 154 }
 155
 156 spawnfunc(info_player_survivor)
 157 {
 158         spawnfunc_info_player_deathmatch(this);
 159 }
 160
 161 spawnfunc(info_player_start)
 162 {
 163         spawnfunc_info_player_deathmatch(this);
 164 }
 165
 166 spawnfunc(info_player_deathmatch)
 167 {
 168         self.classname = "info_player_deathmatch";
 169         relocate_spawnpoint();
 170 }
 171
 172 /*QUAKED spawnfunc_info_player_team1 (1 0 0) (-16 -16 -24) (16 16 24)
 173 Starting point for a player in team one (Red).
 174 Keys: "angle" viewing angle when spawning. */
 175 spawnfunc(info_player_team1)
 176 {
 177         this.team = NUM_TEAM_1; // red
 178         spawnfunc_info_player_deathmatch(this);
 179 }
 180
 181
 182 /*QUAKED spawnfunc_info_player_team2 (1 0 0) (-16 -16 -24) (16 16 24)
 183 Starting point for a player in team two (Blue).
 184 Keys: "angle" viewing angle when spawning. */
 185 spawnfunc(info_player_team2)
 186 {
 187         this.team = NUM_TEAM_2; // blue
 188         spawnfunc_info_player_deathmatch(this);
 189 }
 190
 191 /*QUAKED spawnfunc_info_player_team3 (1 0 0) (-16 -16 -24) (16 16 24)
 192 Starting point for a player in team three (Yellow).
 193 Keys: "angle" viewing angle when spawning. */
 194 spawnfunc(info_player_team3)
 195 {
 196         this.team = NUM_TEAM_3; // yellow
 197         spawnfunc_info_player_deathmatch(this);
 198 }
 199
 200
 201 /*QUAKED spawnfunc_info_player_team4 (1 0 0) (-16 -16 -24) (16 16 24)
 202 Starting point for a player in team four (Purple).
 203 Keys: "angle" viewing angle when spawning. */
 204 spawnfunc(info_player_team4)
 205 {
 206         this.team = NUM_TEAM_4; // purple
 207         spawnfunc_info_player_deathmatch(this);
 208 }
 209
 210 // Returns:
 211 //   _x: prio (-1 if unusable)
 212 //   _y: weight
 213 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 214 {SELFPARAM();
 215         float shortest, thisdist;
 216         float prio;
 217         entity player;
 218
 219         prio = 0;
 220
 221         // filter out spots for the wrong team
 222         if(teamcheck >= 0)
 223                 if(spot.team != teamcheck)
 224                         return '-1 0 0';
 225
 226         if(race_spawns)
 227                 if(spot.target == "")
 228                         return '-1 0 0';
 229
 230         if(IS_REAL_CLIENT(self))
 231         {
 232                 if(spot.restriction == 1)
 233                         return '-1 0 0';
 234         }
 235         else
 236         {
 237                 if(spot.restriction == 2)
 238                         return '-1 0 0';
 239         }
 240
 241         shortest = vlen(world.maxs - world.mins);
 242         FOR_EACH_PLAYER(player) if (player != self)
 243         {
 244                 thisdist = vlen(player.origin - spot.origin);
 245                 if (thisdist < shortest)
 246                         shortest = thisdist;
 247         }
 248         if(shortest > mindist)
 249                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 250
 251         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 252         spawn_spot = spot;
 253
 254         // filter out spots for assault
 255         if(spot.target != "") {
 256                 entity ent;
 257                 float found;
 258
 259                 found = 0;
 260                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 261                 {
 262                         ++found;
 263                         if(ent.spawn_evalfunc)
 264                         {
 265                                 WITH(entity, self, ent, {
 266                                         spawn_score = ent.spawn_evalfunc(this, spot, spawn_score);
 267                                 });
 268                                 if(spawn_score.x < 0)
 269                                         return spawn_score;
 270                         }
 271                 }
 272
 273                 if(!found)
 274                 {
 275                         LOG_TRACE("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 276                         return '-1 0 0';
 277                 }
 278         }
 279
 280         MUTATOR_CALLHOOK(Spawn_Score, self, spawn_spot, spawn_score);
 281         return spawn_score;
 282 }
 283
 284 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 285 {
 286         entity spot;
 287         for(spot = firstspot; spot; spot = spot.chain)
 288                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 289 }
 290
 291 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 292 {
 293         entity spot, spotlist, spotlistend;
 294
 295         spotlist = world;
 296         spotlistend = world;
 297
 298         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 299
 300         for(spot = firstspot; spot; spot = spot.chain)
 301         {
 302                 if(spot.spawnpoint_score.x >= 0) // spawning allowed here
 303                 {
 304                         if(spotlistend)
 305                                 spotlistend.chain = spot;
 306                         spotlistend = spot;
 307                         if(!spotlist)
 308                                 spotlist = spot;
 309                 }
 310         }
 311         if(spotlistend)
 312                 spotlistend.chain = world;
 313
 314         return spotlist;
 315 }
 316
 317 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 318 {
 319         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 320         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 321         entity spot;
 322
 323         RandomSelection_Init();
 324         for(spot = firstspot; spot; spot = spot.chain)
 325                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score.y, upper), exponent) * spot.cnt, (spot.spawnpoint_score.y >= lower) * 0.5 + spot.spawnpoint_score.x);
 326
 327         return RandomSelection_chosen_ent;
 328 }
 329
 330 /*
 331 =============
 332 SelectSpawnPoint
 333
 334 Finds a point to respawn
 335 =============
 336 */
 337 entity SelectSpawnPoint (float anypoint)
 338 {SELFPARAM();
 339         float teamcheck;
 340         entity spot, firstspot;
 341
 342         spot = find (world, classname, "testplayerstart");
 343         if (spot)
 344                 return spot;
 345
 346         if(anypoint || autocvar_g_spawn_useallspawns)
 347                 teamcheck = -1;
 348         else if(have_team_spawns > 0)
 349         {
 350                 if(have_team_spawns_forteam[self.team] == 0)
 351                 {
 352                         // we request a spawn for a team, and we have team
 353                         // spawns, but that team has no spawns?
 354                         if(have_team_spawns_forteam[0])
 355                                 // try noteam spawns
 356                                 teamcheck = 0;
 357                         else
 358                                 // if not, any spawn has to do
 359                                 teamcheck = -1;
 360                 }
 361                 else
 362                         teamcheck = self.team; // MUST be team
 363         }
 364         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 365                 teamcheck = 0; // MUST be noteam
 366         else
 367                 teamcheck = -1;
 368                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 369
 370
 371         // get the entire list of spots
 372         firstspot = findchain(classname, "info_player_deathmatch");
 373         // filter out the bad ones
 374         // (note this returns the original list if none survived)
 375         if(anypoint)
 376         {
 377                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 378         }
 379         else
 380         {
 381                 firstspot = Spawn_FilterOutBadSpots(firstspot, 100, teamcheck);
 382
 383                 // there is 50/50 chance of choosing a random spot or the furthest spot
 384                 // (this means that roughly every other spawn will be furthest, so you
 385                 // usually won't get fragged at spawn twice in a row)
 386                 if (random() > autocvar_g_spawn_furthest)
 387                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 388                 else
 389                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 390         }
 391
 392         if (!spot)
 393         {
 394                 if(autocvar_spawn_debug)
 395                         GotoNextMap(0);
 396                 else
 397                 {
 398                         if(some_spawn_has_been_used)
 399                                 return world; // team can't spawn any more, because of actions of other team
 400                         else
 401                                 error("Cannot find a spawn point - please fix the map!");
 402                 }
 403         }
 404
 405         return spot;
 406 }