qcsrc/server/spawnpoints.qc

   1 #include "spawnpoints.qh"
   2
   3 #include "mutators/_mod.qh"
   4 #include "g_world.qh"
   5 #include "race.qh"
   6 #include "../common/constants.qh"
   7 #include "../common/teams.qh"
   8 #include "../common/triggers/subs.qh"
   9 #include "../common/util.qh"
  10 #include "../lib/warpzone/common.qh"
  11 #include "../lib/warpzone/util_server.qh"
  12
  13 bool SpawnPoint_Send(entity this, entity to, int sf)
  14 {
  15         WriteHeader(MSG_ENTITY, ENT_CLIENT_SPAWNPOINT);
  16
  17         WriteByte(MSG_ENTITY, this.team);
  18         WriteCoord(MSG_ENTITY, this.origin.x);
  19         WriteCoord(MSG_ENTITY, this.origin.y);
  20         WriteCoord(MSG_ENTITY, this.origin.z);
  21
  22         return true;
  23 }
  24
  25 bool SpawnEvent_Send(entity this, entity to, int sf)
  26 {
  27         float send;
  28
  29         WriteHeader(MSG_ENTITY, ENT_CLIENT_SPAWNEVENT);
  30
  31         if(autocvar_g_spawn_alloweffects)
  32         {
  33                 WriteByte(MSG_ENTITY, etof(this.owner));
  34                 WriteCoord(MSG_ENTITY, this.owner.origin.x);
  35                 WriteCoord(MSG_ENTITY, this.owner.origin.y);
  36                 WriteCoord(MSG_ENTITY, this.owner.origin.z);
  37                 send = true;
  38         }
  39         else if((to == this.owner) || (IS_SPEC(to) && (to.enemy == this.owner)) )
  40         {
  41                 WriteByte(MSG_ENTITY, 0);
  42                 send = true;
  43         }
  44         else { send = false; }
  45
  46         return send;
  47 }
  48
  49 .vector spawnpoint_prevorigin;
  50 void spawnpoint_think(entity this)
  51 {
  52         this.nextthink = time + 0.1;
  53         if(this.origin != this.spawnpoint_prevorigin)
  54         {
  55                 this.spawnpoint_prevorigin = this.origin;
  56                 this.SendFlags |= 1;
  57         }
  58 }
  59
  60 void spawnpoint_use(entity this, entity actor, entity trigger)
  61 {
  62         if(teamplay)
  63         if(have_team_spawns > 0)
  64         {
  65                 this.team = actor.team;
  66                 some_spawn_has_been_used = 1;
  67         }
  68         //LOG_INFO("spawnpoint was used!\n");
  69 }
  70
  71 void relocate_spawnpoint(entity this)
  72 {
  73     // nudge off the floor
  74     setorigin(this, this.origin + '0 0 1');
  75
  76     tracebox(this.origin, PL_MIN_CONST, PL_MAX_CONST, this.origin, true, this);
  77     if (trace_startsolid)
  78     {
  79         vector o;
  80         o = this.origin;
  81         this.mins = PL_MIN_CONST;
  82         this.maxs = PL_MAX_CONST;
  83         if (!move_out_of_solid(this))
  84             objerror(this, "could not get out of solid at all!");
  85         LOG_INFO("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
  86         LOG_INFO(" needs to be moved out of solid, e.g. by '", ftos(this.origin.x - o.x));
  87         LOG_INFO(" ", ftos(this.origin.y - o.y));
  88         LOG_INFO(" ", ftos(this.origin.z - o.z), "'\n");
  89         if (autocvar_g_spawnpoints_auto_move_out_of_solid)
  90         {
  91             if (!spawnpoint_nag)
  92                 LOG_INFO("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
  93             spawnpoint_nag = 1;
  94         }
  95         else
  96         {
  97             setorigin(this, o);
  98             this.mins = this.maxs = '0 0 0';
  99             objerror(this, "player spawn point in solid, mapper sucks!\n");
 100             return;
 101         }
 102     }
 103
 104     this.use = spawnpoint_use;
 105     setthink(this, spawnpoint_think);
 106     this.nextthink = time + 0.5 + random() * 2; // shouldn't need it for a little second
 107     this.team_saved = this.team;
 108     if (!this.cnt)
 109         this.cnt = 1;
 110
 111     if (have_team_spawns != 0)
 112         if (this.team)
 113             have_team_spawns = 1;
 114     have_team_spawns_forteam[this.team] = 1;
 115
 116     if (autocvar_r_showbboxes)
 117     {
 118         // show where spawnpoints point at too
 119         makevectors(this.angles);
 120         entity e = new(info_player_foo);
 121         setorigin(e, this.origin + v_forward * 24);
 122         setsize(e, '-8 -8 -8', '8 8 8');
 123         e.solid = SOLID_TRIGGER;
 124     }
 125
 126         // Don't show team spawns in non-team matches,
 127         // and don't show non-team spawns in team matches.
 128         // (Unless useallspawns is activated)
 129         if(
 130                 !(
 131                         ( // if this passes, there is a DM spawn on a team match
 132                                 teamplay
 133                                 && (this.team != NUM_TEAM_1)
 134                                 && (this.team != NUM_TEAM_2)
 135                                 && (this.team != NUM_TEAM_3)
 136                                 && (this.team != NUM_TEAM_4)
 137                         )
 138                         ||
 139                         ( // if this passes, there is a team spawn on a DM match
 140                                 !teamplay
 141                                 &&
 142                                 (
 143                                         (this.team == NUM_TEAM_1)
 144                                         || (this.team == NUM_TEAM_2)
 145                                         || (this.team == NUM_TEAM_3)
 146                                         || (this.team == NUM_TEAM_4)
 147                                 )
 148                         )
 149                 )
 150                 ||
 151                 autocvar_g_spawn_useallspawns
 152         )
 153         { Net_LinkEntity(this, false, 0, SpawnPoint_Send); }
 154 }
 155
 156 spawnfunc(info_player_survivor)
 157 {
 158         spawnfunc_info_player_deathmatch(this);
 159 }
 160
 161 spawnfunc(info_player_start)
 162 {
 163         spawnfunc_info_player_deathmatch(this);
 164 }
 165
 166 spawnfunc(info_player_deathmatch)
 167 {
 168         this.classname = "info_player_deathmatch";
 169         IL_PUSH(g_spawnpoints, this);
 170         relocate_spawnpoint(this);
 171 }
 172
 173 /*QUAKED spawnfunc_info_player_team1 (1 0 0) (-16 -16 -24) (16 16 24)
 174 Starting point for a player in team one (Red).
 175 Keys: "angle" viewing angle when spawning. */
 176 spawnfunc(info_player_team1)
 177 {
 178         this.team = NUM_TEAM_1; // red
 179         spawnfunc_info_player_deathmatch(this);
 180 }
 181
 182
 183 /*QUAKED spawnfunc_info_player_team2 (1 0 0) (-16 -16 -24) (16 16 24)
 184 Starting point for a player in team two (Blue).
 185 Keys: "angle" viewing angle when spawning. */
 186 spawnfunc(info_player_team2)
 187 {
 188         this.team = NUM_TEAM_2; // blue
 189         spawnfunc_info_player_deathmatch(this);
 190 }
 191
 192 /*QUAKED spawnfunc_info_player_team3 (1 0 0) (-16 -16 -24) (16 16 24)
 193 Starting point for a player in team three (Yellow).
 194 Keys: "angle" viewing angle when spawning. */
 195 spawnfunc(info_player_team3)
 196 {
 197         this.team = NUM_TEAM_3; // yellow
 198         spawnfunc_info_player_deathmatch(this);
 199 }
 200
 201
 202 /*QUAKED spawnfunc_info_player_team4 (1 0 0) (-16 -16 -24) (16 16 24)
 203 Starting point for a player in team four (Purple).
 204 Keys: "angle" viewing angle when spawning. */
 205 spawnfunc(info_player_team4)
 206 {
 207         this.team = NUM_TEAM_4; // purple
 208         spawnfunc_info_player_deathmatch(this);
 209 }
 210
 211 // Returns:
 212 //   _x: prio (-1 if unusable)
 213 //   _y: weight
 214 vector Spawn_Score(entity this, entity spot, float mindist, float teamcheck)
 215 {
 216         float shortest, thisdist;
 217         float prio;
 218
 219         prio = 0;
 220
 221         // filter out spots for the wrong team
 222         if(teamcheck >= 0)
 223                 if(spot.team != teamcheck)
 224                         return '-1 0 0';
 225
 226         if(race_spawns)
 227                 if(spot.target == "")
 228                         return '-1 0 0';
 229
 230         if(IS_REAL_CLIENT(this))
 231         {
 232                 if(spot.restriction == 1)
 233                         return '-1 0 0';
 234         }
 235         else
 236         {
 237                 if(spot.restriction == 2)
 238                         return '-1 0 0';
 239         }
 240
 241         shortest = vlen(world.maxs - world.mins);
 242         FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
 243                 thisdist = vlen(it.origin - spot.origin);
 244                 if (thisdist < shortest)
 245                         shortest = thisdist;
 246         ));
 247         if(shortest > mindist)
 248                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 249
 250         vector spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 251
 252         // filter out spots for assault
 253         if(spot.target != "")
 254         {
 255                 int found = 0;
 256                 for(entity targ = findchain(targetname, spot.target); targ; targ = targ.chain)
 257                 {
 258                         ++found;
 259                         if(targ.spawn_evalfunc)
 260                         {
 261                                 spawn_score = targ.spawn_evalfunc(targ, this, spot, spawn_score);
 262                                 if(spawn_score.x < 0)
 263                                         return spawn_score;
 264                         }
 265                 }
 266
 267                 if(!found)
 268                 {
 269                         LOG_TRACE("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target);
 270                         return '-1 0 0';
 271                 }
 272         }
 273
 274         MUTATOR_CALLHOOK(Spawn_Score, this, spot, spawn_score);
 275         spawn_score = M_ARGV(2, vector);
 276         return spawn_score;
 277 }
 278
 279 void Spawn_ScoreAll(entity this, entity firstspot, float mindist, float teamcheck)
 280 {
 281         entity spot;
 282         for(spot = firstspot; spot; spot = spot.chain)
 283                 spot.spawnpoint_score = Spawn_Score(this, spot, mindist, teamcheck);
 284 }
 285
 286 entity Spawn_FilterOutBadSpots(entity this, entity firstspot, float mindist, float teamcheck)
 287 {
 288         entity spot, spotlist, spotlistend;
 289
 290         spotlist = NULL;
 291         spotlistend = NULL;
 292
 293         Spawn_ScoreAll(this, firstspot, mindist, teamcheck);
 294
 295         for(spot = firstspot; spot; spot = spot.chain)
 296         {
 297                 if(spot.spawnpoint_score.x >= 0) // spawning allowed here
 298                 {
 299                         if(spotlistend)
 300                                 spotlistend.chain = spot;
 301                         spotlistend = spot;
 302                         if(!spotlist)
 303                                 spotlist = spot;
 304                 }
 305         }
 306         if(spotlistend)
 307                 spotlistend.chain = NULL;
 308
 309         return spotlist;
 310 }
 311
 312 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 313 {
 314         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 315         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 316         entity spot;
 317
 318         RandomSelection_Init();
 319         for(spot = firstspot; spot; spot = spot.chain)
 320                 RandomSelection_AddEnt(spot, pow(bound(lower, spot.spawnpoint_score.y, upper), exponent) * spot.cnt, (spot.spawnpoint_score.y >= lower) * 0.5 + spot.spawnpoint_score.x);
 321
 322         return RandomSelection_chosen_ent;
 323 }
 324
 325 /*
 326 =============
 327 SelectSpawnPoint
 328
 329 Finds a point to respawn
 330 =============
 331 */
 332 entity SelectSpawnPoint(entity this, bool anypoint)
 333 {
 334         float teamcheck;
 335         entity spot, firstspot;
 336
 337         spot = find(NULL, classname, "testplayerstart");
 338         if (spot)
 339                 return spot;
 340
 341         if(anypoint || autocvar_g_spawn_useallspawns)
 342                 teamcheck = -1;
 343         else if(have_team_spawns > 0)
 344         {
 345                 if(have_team_spawns_forteam[this.team] == 0)
 346                 {
 347                         // we request a spawn for a team, and we have team
 348                         // spawns, but that team has no spawns?
 349                         if(have_team_spawns_forteam[0])
 350                                 // try noteam spawns
 351                                 teamcheck = 0;
 352                         else
 353                                 // if not, any spawn has to do
 354                                 teamcheck = -1;
 355                 }
 356                 else
 357                         teamcheck = this.team; // MUST be team
 358         }
 359         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 360                 teamcheck = 0; // MUST be noteam
 361         else
 362                 teamcheck = -1;
 363                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 364
 365
 366         // get the entire list of spots
 367         firstspot = findchain(classname, "info_player_deathmatch");
 368         // filter out the bad ones
 369         // (note this returns the original list if none survived)
 370         if(anypoint)
 371         {
 372                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 373         }
 374         else
 375         {
 376                 firstspot = Spawn_FilterOutBadSpots(this, firstspot, 100, teamcheck);
 377
 378                 // there is 50/50 chance of choosing a random spot or the furthest spot
 379                 // (this means that roughly every other spawn will be furthest, so you
 380                 // usually won't get fragged at spawn twice in a row)
 381                 if (random() > autocvar_g_spawn_furthest)
 382                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 383                 else
 384                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 385         }
 386
 387         if (!spot)
 388         {
 389                 if(autocvar_spawn_debug)
 390                         GotoNextMap(0);
 391                 else
 392                 {
 393                         if(some_spawn_has_been_used)
 394                                 return NULL; // team can't spawn any more, because of actions of other team
 395                         else
 396                                 error("Cannot find a spawn point - please fix the map!");
 397                 }
 398         }
 399
 400         return spot;
 401 }