qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_damage.qh"
   6 #include "g_world.qh"
   7 #include <server/gamelog.qh>
   8
   9 #include "bot/api.qh"
  10
  11 #include "command/common.qh"
  12
  13 #include <server/mutators/_mod.qh>
  14 #include "weapons/csqcprojectile.qh"
  15 #include <server/compat/quake3.qh>
  16
  17 #include "../common/constants.qh"
  18 #include "../common/deathtypes/all.qh"
  19 #include "../common/debug.qh"
  20 #include "../common/mapinfo.qh"
  21 #include "../common/util.qh"
  22
  23 #include "../common/vehicles/all.qh"
  24 #include <common/monsters/sv_monsters.qh>
  25 #include <common/weapons/_all.qh>
  26
  27 #include "../lib/csqcmodel/sv_model.qh"
  28
  29 #include "../lib/warpzone/common.qh"
  30 #include "../lib/warpzone/server.qh"
  31
  32 void CreatureFrame_hotliquids(entity this)
  33 {
  34         if (this.dmgtime >= time)
  35         {
  36                 return;
  37         }
  38
  39         this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  40
  41         if (this.flags & FL_PROJECTILE)
  42         {
  43                 if (this.watertype == CONTENT_LAVA)
  44                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  45                 else if (this.watertype == CONTENT_SLIME)
  46                         Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  47         }
  48         else
  49         {
  50                 if (STAT(FROZEN, this))
  51                 {
  52                         if (this.watertype == CONTENT_LAVA)
  53                                 Damage(this, NULL, NULL, 10000, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  54                         else if (this.watertype == CONTENT_SLIME)
  55                                 Damage(this, NULL, NULL, 10000, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  56                 }
  57                 else if (this.watertype == CONTENT_LAVA)
  58                 {
  59                         if (this.watersound_finished < time)
  60                         {
  61                                 this.watersound_finished = time + 0.5;
  62                                 sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  63                         }
  64                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, DMG_NOWEP, this.origin, '0 0 0');
  65                         if(autocvar_g_balance_contents_playerdamage_lava_burn)
  66                                 Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  67                 }
  68                 else if (this.watertype == CONTENT_SLIME)
  69                 {
  70                         if (this.watersound_finished < time)
  71                         {
  72                                 this.watersound_finished = time + 0.5;
  73                                 sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  74                         }
  75                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, DMG_NOWEP, this.origin, '0 0 0');
  76                 }
  77         }
  78 }
  79
  80 void CreatureFrame_Liquids(entity this)
  81 {
  82         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  83         {
  84                 if (!(this.flags & FL_INWATER))
  85                 {
  86                         this.flags |= FL_INWATER;
  87                         this.dmgtime = 0;
  88                 }
  89
  90                 CreatureFrame_hotliquids(this);
  91         }
  92         else
  93         {
  94                 if (this.flags & FL_INWATER)
  95                 {
  96                         // play leave water sound
  97                         this.flags &= ~FL_INWATER;
  98                         this.dmgtime = 0;
  99                 }
 100         }
 101 }
 102
 103 void CreatureFrame_FallDamage(entity this)
 104 {
 105         if(IS_VEHICLE(this) || (this.flags & FL_PROJECTILE))
 106                 return; // vehicles and projectiles don't receive fall damage
 107         if(!(this.velocity || this.oldvelocity))
 108                 return; // if the entity hasn't moved and isn't moving, then don't do anything
 109
 110         // check for falling damage
 111         bool have_hook = false;
 112         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 113         {
 114             .entity weaponentity = weaponentities[slot];
 115             if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 116             {
 117                 have_hook = true;
 118                 break;
 119             }
 120         }
 121         if(!have_hook)
 122         {
 123                 float dm; // dm is the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 124                 if(autocvar_g_balance_falldamage_onlyvertical)
 125                         dm = fabs(this.oldvelocity.z) - vlen(this.velocity);
 126                 else
 127                         dm = vlen(this.oldvelocity) - vlen(this.velocity);
 128                 if (IS_DEAD(this))
 129                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 130                 else
 131                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 132                 if (dm > 0)
 133                 {
 134                         tracebox(this.origin, this.mins, this.maxs, this.origin - '0 0 1', MOVE_NOMONSTERS, this);
 135                         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODAMAGE))
 136                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 137                 }
 138         }
 139
 140         if(autocvar_g_maxspeed > 0 && vdist(this.velocity, >, autocvar_g_maxspeed))
 141                 Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, DMG_NOWEP, this.origin, '0 0 0');
 142 }
 143
 144 void CreatureFrame_All()
 145 {
 146         if(game_stopped || time < game_starttime)
 147                 return;
 148
 149         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 150         {
 151                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 152                 CreatureFrame_Liquids(it);
 153                 CreatureFrame_FallDamage(it);
 154                 it.oldvelocity = it.velocity;
 155         });
 156 }
 157
 158 void Pause_TryPause(bool ispaused)
 159 {
 160         int n = 0;
 161         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 162                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 163                 ++n;
 164         });
 165         if (!n) return;
 166         setpause(ispaused);
 167 }
 168
 169 void SV_PausedTic(float elapsedtime)
 170 {
 171         if (!server_is_dedicated) Pause_TryPause(false);
 172 }
 173
 174 /*
 175 =============
 176 StartFrame
 177
 178 Called before each frame by the server
 179 =============
 180 */
 181
 182 bool game_delay_last;
 183
 184 bool autocvar_sv_autopause = false;
 185 void systems_update();
 186 void sys_phys_update(entity this, float dt);
 187 void StartFrame()
 188 {
 189     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 190     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 191     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 192
 193         execute_next_frame();
 194         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 195
 196         delete_fn = remove_unsafely; // not during spawning!
 197         serverprevtime = servertime;
 198         servertime = time;
 199         serverframetime = frametime;
 200
 201 #ifdef PROFILING
 202         if(time > client_cefc_accumulatortime + 1)
 203         {
 204                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 205                 int c_seeing = 0;
 206                 int c_seen = 0;
 207                 FOREACH_CLIENT(true, {
 208                         if(IS_REAL_CLIENT(it))
 209                                 ++c_seeing;
 210                         if(IS_PLAYER(it))
 211                                 ++c_seen;
 212                 });
 213                 LOG_INFO(
 214                     "CEFC time: ", ftos(t * 1000), "ms; ",
 215             "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
 216             "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
 217         );
 218                 client_cefc_accumulatortime = time;
 219                 client_cefc_accumulator = 0;
 220         }
 221 #endif
 222
 223         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 224
 225         if (RedirectionThink()) return;
 226
 227         UncustomizeEntitiesRun();
 228         InitializeEntitiesRun();
 229
 230         WarpZone_StartFrame();
 231
 232         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 233         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 234
 235         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 236                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 237
 238         // detect when the pre-game countdown (if any) has ended and the game has started
 239         bool game_delay = (time < game_starttime);
 240         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 241                 GameLogEcho(":startdelay_ended");
 242         game_delay_last = game_delay;
 243
 244         CreatureFrame_All();
 245         CheckRules_World();
 246
 247         if (warmup_stage && !game_stopped && warmup_limit > 0 && time >= warmup_limit) {
 248                 ReadyRestart();
 249                 return;
 250         }
 251
 252         bot_serverframe();
 253         anticheat_startframe();
 254         MUTATOR_CALLHOOK(SV_StartFrame);
 255
 256         GlobalStats_updateglobal();
 257     FOREACH_CLIENT(true, GlobalStats_update(it));
 258     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 259 }
 260
 261 .vector originjitter;
 262 .vector anglesjitter;
 263 .float anglejitter;
 264 .string gametypefilter;
 265 .string cvarfilter;
 266
 267 /**
 268  * Evaluate an expression of the form: [+ | -]? [var[op]val | [op]var | val | var] ...
 269  * +: all must match. this is the default
 270  * -: one must NOT match
 271  *
 272  * var>x
 273  * var<x
 274  * var>=x
 275  * var<=x
 276  * var==x
 277  * var!=x
 278  * var===x
 279  * var!==x
 280  */
 281 bool expr_evaluate(string s)
 282 {
 283     bool ret = false;
 284     if (str2chr(s, 0) == '+') {
 285         s = substring(s, 1, -1);
 286     } else if (str2chr(s, 0) == '-') {
 287         ret = true;
 288         s = substring(s, 1, -1);
 289     }
 290     bool expr_fail = false;
 291     for (int i = 0, n = tokenize_console(s); i < n; ++i) {
 292         int o;
 293         string k, v;
 294         s = argv(i);
 295         #define X(expr) \
 296             if (expr) \
 297                 continue; \
 298             expr_fail = true; \
 299             break;
 300
 301         #define BINOP(op, len, expr) \
 302             if ((o = strstrofs(s, op, 0)) >= 0) { \
 303                 k = substring(s, 0, o); \
 304                 v = substring(s, o + len, -1); \
 305                 X(expr); \
 306             }
 307         BINOP(">=", 2, cvar(k) >= stof(v));
 308         BINOP("<=", 2, cvar(k) <= stof(v));
 309         BINOP(">",  1, cvar(k) >  stof(v));
 310         BINOP("<",  1, cvar(k) <  stof(v));
 311         BINOP("==", 2, cvar(k) == stof(v));
 312         BINOP("!=", 2, cvar(k) != stof(v));
 313         BINOP("===", 3, cvar_string(k) == v);
 314         BINOP("!==", 3, cvar_string(k) != v);
 315         {
 316             k = s;
 317             bool b = true;
 318             if (str2chr(k, 0) == '!') {
 319                 k = substring(s, 1, -1);
 320                 b = false;
 321             }
 322             float f = stof(k);
 323             bool isnum = ftos(f) == k;
 324             X(boolean(isnum ? f : cvar(k)) == b);
 325         }
 326         #undef BINOP
 327         #undef X
 328     }
 329     if (!expr_fail) {
 330         ret = !ret;
 331     }
 332     // now ret is true if we want to keep the item, and false if we want to get rid of it
 333     return ret;
 334 }
 335
 336 void SV_OnEntityPreSpawnFunction(entity this)
 337 {
 338         if (this)
 339         if (this.gametypefilter != "")
 340         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 341         {
 342                 delete(this);
 343                 return;
 344         }
 345         if (this.cvarfilter != "" && !expr_evaluate(this.cvarfilter)) {
 346                 delete(this);
 347                 return;
 348         }
 349
 350         if (DoesQ3ARemoveThisEntity(this)) {
 351                 delete(this);
 352                 return;
 353         }
 354
 355         set_movetype(this, this.movetype);
 356
 357         if (this.monster_attack) {
 358                 IL_PUSH(g_monster_targets, this);
 359     }
 360
 361         // support special -1 and -2 angle from radiant
 362         if (this.angles == '0 -1 0') {
 363                 this.angles = '-90 0 0';
 364         } else if (this.angles == '0 -2 0') {
 365                 this.angles = '+90 0 0';
 366     }
 367
 368     #define X(out, in) MACRO_BEGIN \
 369         if (in != 0) { out = out + (random() * 2 - 1) * in; } \
 370     MACRO_END
 371     X(this.origin.x, this.originjitter.x); X(this.origin.y, this.originjitter.y); X(this.origin.z, this.originjitter.z);
 372     X(this.angles.x, this.anglesjitter.x); X(this.angles.y, this.anglesjitter.y); X(this.angles.z, this.anglesjitter.z);
 373     X(this.angles.y, this.anglejitter);
 374     #undef X
 375
 376         if (MUTATOR_CALLHOOK(OnEntityPreSpawn, this)) {
 377                 delete(this);
 378                 return;
 379         }
 380 }
 381
 382 void WarpZone_PostInitialize_Callback()
 383 {
 384         // create waypoint links for warpzones
 385         entity tracetest_ent = spawn();
 386         setsize(tracetest_ent, PL_MIN_CONST, PL_MAX_CONST);
 387         tracetest_ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 388         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 389         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 390                 waypoint_spawnforteleporter_wz(e, tracetest_ent);
 391         delete(tracetest_ent);
 392 }
 393
 394 /*
 395 ==================
 396 main
 397
 398 unused but required by the engine
 399 ==================
 400 */
 401 void main ()
 402 {
 403
 404 }