qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_world.qh"
   6
   7 #include "bot/api.qh"
   8
   9 #include "command/common.qh"
  10
  11 #include "mutators/_mod.qh"
  12 #include "weapons/csqcprojectile.qh"
  13
  14 #include "../common/constants.qh"
  15 #include "../common/deathtypes/all.qh"
  16 #include "../common/debug.qh"
  17 #include "../common/mapinfo.qh"
  18 #include "../common/util.qh"
  19
  20 #include "../common/vehicles/all.qh"
  21 #include <common/weapons/_all.qh>
  22
  23 #include "../lib/csqcmodel/sv_model.qh"
  24
  25 #include "../lib/warpzone/common.qh"
  26 #include "../lib/warpzone/server.qh"
  27
  28 .float lastground;
  29 .int state;
  30
  31 void CreatureFrame_hotliquids(entity this)
  32 {
  33         if (this.dmgtime < time)
  34         {
  35                 this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  36
  37                 if (this.flags & FL_PROJECTILE)
  38                 {
  39                         if (this.watertype == CONTENT_LAVA)
  40                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  41                         else if (this.watertype == CONTENT_SLIME)
  42                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  43                 }
  44                 else
  45                 {
  46                         if (this.watertype == CONTENT_LAVA)
  47                         {
  48                                 if (this.watersound_finished < time)
  49                                 {
  50                                         this.watersound_finished = time + 0.5;
  51                                         sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  52                                 }
  53                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  54                                 if(autocvar_g_balance_contents_playerdamage_lava_burn)
  55                                         Fire_AddDamage(this, NULL, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  56                         }
  57                         else if (this.watertype == CONTENT_SLIME)
  58                         {
  59                                 if (this.watersound_finished < time)
  60                                 {
  61                                         this.watersound_finished = time + 0.5;
  62                                         sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  63                                 }
  64                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  65                         }
  66                 }
  67         }
  68 }
  69
  70 void CreatureFrame_Liquids(entity this)
  71 {
  72         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  73         {
  74                 if (!(this.flags & FL_INWATER))
  75                 {
  76                         this.flags |= FL_INWATER;
  77                         this.dmgtime = 0;
  78                 }
  79
  80                 CreatureFrame_hotliquids(this);
  81         }
  82         else
  83         {
  84                 if (this.flags & FL_INWATER)
  85                 {
  86                         // play leave water sound
  87                         this.flags &= ~FL_INWATER;
  88                         this.dmgtime = 0;
  89                 }
  90                 this.air_finished = time + 12;
  91                 this.dmg = 2;
  92         }
  93 }
  94
  95 void CreatureFrame_FallDamage(entity this)
  96 {
  97         if(!IS_VEHICLE(this) && !(this.flags & FL_PROJECTILE)) // vehicles don't get falling damage
  98         if(this.velocity || this.oldvelocity) // moving or has moved
  99         {
 100                 // check for falling damage
 101                 float velocity_len = vlen(this.velocity);
 102                 bool have_hook = false;
 103                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 104             {
 105                 .entity weaponentity = weaponentities[slot];
 106                 if(this.(weaponentity).hook && this.(weaponentity).hook.state)
 107                 {
 108                         have_hook = true;
 109                         break;
 110                 }
 111             }
 112                 if(!have_hook)
 113                 {
 114                         float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 115                         if (IS_DEAD(this))
 116                                 dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 117                         else
 118                                 dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 119                         if (dm > 0)
 120                                 Damage (this, NULL, NULL, dm, DEATH_FALL.m_id, this.origin, '0 0 0');
 121                 }
 122
 123                 if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 124                         Damage (this, NULL, NULL, 100000, DEATH_SHOOTING_STAR.m_id, this.origin, '0 0 0');
 125         }
 126 }
 127
 128 void CreatureFrame_All()
 129 {
 130         IL_EACH(g_damagedbycontents, it.damagedbycontents,
 131         {
 132                 if (it.move_movetype == MOVETYPE_NOCLIP) continue;
 133                 CreatureFrame_Liquids(it);
 134                 CreatureFrame_FallDamage(it);
 135                 it.oldvelocity = it.velocity;
 136         });
 137 }
 138
 139 void Pause_TryPause(bool ispaused)
 140 {
 141         int n = 0;
 142         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 143                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 144                 ++n;
 145         });
 146         if (!n) return;
 147         setpause(ispaused);
 148 }
 149
 150 void SV_PausedTic(float elapsedtime)
 151 {
 152         if (!server_is_dedicated) Pause_TryPause(false);
 153 }
 154
 155 /*
 156 =============
 157 StartFrame
 158
 159 Called before each frame by the server
 160 =============
 161 */
 162
 163 bool game_delay_last;
 164
 165 bool autocvar_sv_autopause = false;
 166 float RedirectionThink();
 167 void systems_update();
 168 void sys_phys_update(entity this, float dt);
 169 void StartFrame()
 170 {
 171     // TODO: if move is more than 50ms, split it into two moves (this matches QWSV behavior and the client prediction)
 172     IL_EACH(g_players, IS_FAKE_CLIENT(it), sys_phys_update(it, frametime));
 173     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPreThink(it));
 174
 175         execute_next_frame();
 176         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 177
 178         delete_fn = remove_unsafely; // not during spawning!
 179         serverprevtime = servertime;
 180         servertime = time;
 181         serverframetime = frametime;
 182
 183 #ifdef PROFILING
 184         if(time > client_cefc_accumulatortime + 1)
 185         {
 186                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 187                 int c_seeing = 0;
 188                 int c_seen = 0;
 189                 FOREACH_CLIENT(true, {
 190                         if(IS_REAL_CLIENT(it))
 191                                 ++c_seeing;
 192                         if(IS_PLAYER(it))
 193                                 ++c_seen;
 194                 });
 195                 LOG_INFO(
 196                     "CEFC time: ", ftos(t * 1000), "ms; ",
 197             "CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ",
 198             "CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0')
 199         );
 200                 client_cefc_accumulatortime = time;
 201                 client_cefc_accumulator = 0;
 202         }
 203 #endif
 204
 205         IL_EACH(g_projectiles, it.csqcprojectile_clientanimate, CSQCProjectile_Check(it));
 206
 207         if (RedirectionThink()) return;
 208
 209         UncustomizeEntitiesRun();
 210         InitializeEntitiesRun();
 211
 212         WarpZone_StartFrame();
 213
 214         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 215         if (sys_frametime <= 0) sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 216
 217         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 218                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 219
 220         skill = autocvar_skill;
 221
 222         // detect when the pre-game countdown (if any) has ended and the game has started
 223         bool game_delay = (time < game_starttime);
 224         if (autocvar_sv_eventlog && game_delay_last && !game_delay)
 225                 GameLogEcho(":startdelay_ended");
 226         game_delay_last = game_delay;
 227
 228         CreatureFrame_All();
 229         CheckRules_World();
 230
 231         if (warmup_stage && !game_stopped && warmup_limit > 0 && time >= warmup_limit) {
 232                 ReadyRestart();
 233                 return;
 234         }
 235
 236         bot_serverframe();
 237         anticheat_startframe();
 238         MUTATOR_CALLHOOK(SV_StartFrame);
 239
 240     FOREACH_CLIENT(true, GlobalStats_update(it));
 241     IL_EACH(g_players, IS_FAKE_CLIENT(it), PlayerPostThink(it));
 242 }
 243
 244 .vector originjitter;
 245 .vector anglesjitter;
 246 .float anglejitter;
 247 .string gametypefilter;
 248 .string cvarfilter;
 249 bool DoesQ3ARemoveThisEntity(entity this);
 250 void SV_OnEntityPreSpawnFunction(entity this)
 251 {
 252         __spawnfunc_expecting = true;
 253         __spawnfunc_expect = this;
 254         if (this)
 255         if (this.gametypefilter != "")
 256         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, this.gametypefilter))
 257         {
 258                 delete(this);
 259                 __spawnfunc_expecting = false;
 260                 return;
 261         }
 262         if(this.cvarfilter != "")
 263         {
 264                 float n, i, o, inv;
 265                 string s, k, v;
 266                 inv = 0;
 267
 268                 s = this.cvarfilter;
 269                 if(substring(s, 0, 1) == "+")
 270                 {
 271                         s = substring(s, 1, -1);
 272                 }
 273                 else if(substring(s, 0, 1) == "-")
 274                 {
 275                         inv = 1;
 276                         s = substring(s, 1, -1);
 277                 }
 278
 279                 n = tokenize_console(s);
 280                 for(i = 0; i < n; ++i)
 281                 {
 282                         s = argv(i);
 283                         // syntax:
 284                         // var>x
 285                         // var<x
 286                         // var>=x
 287                         // var<=x
 288                         // var==x
 289                         // var!=x
 290                         // var===x
 291                         // var!==x
 292                         if((o = strstrofs(s, ">=", 0)) >= 0)
 293                         {
 294                                 k = substring(s, 0, o);
 295                                 v = substring(s, o+2, -1);
 296                                 if(cvar(k) < stof(v))
 297                                         goto cvar_fail;
 298                         }
 299                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 300                         {
 301                                 k = substring(s, 0, o);
 302                                 v = substring(s, o+2, -1);
 303                                 if(cvar(k) > stof(v))
 304                                         goto cvar_fail;
 305                         }
 306                         else if((o = strstrofs(s, ">", 0)) >= 0)
 307                         {
 308                                 k = substring(s, 0, o);
 309                                 v = substring(s, o+1, -1);
 310                                 if(cvar(k) <= stof(v))
 311                                         goto cvar_fail;
 312                         }
 313                         else if((o = strstrofs(s, "<", 0)) >= 0)
 314                         {
 315                                 k = substring(s, 0, o);
 316                                 v = substring(s, o+1, -1);
 317                                 if(cvar(k) >= stof(v))
 318                                         goto cvar_fail;
 319                         }
 320                         else if((o = strstrofs(s, "==", 0)) >= 0)
 321                         {
 322                                 k = substring(s, 0, o);
 323                                 v = substring(s, o+2, -1);
 324                                 if(cvar(k) != stof(v))
 325                                         goto cvar_fail;
 326                         }
 327                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 328                         {
 329                                 k = substring(s, 0, o);
 330                                 v = substring(s, o+2, -1);
 331                                 if(cvar(k) == stof(v))
 332                                         goto cvar_fail;
 333                         }
 334                         else if((o = strstrofs(s, "===", 0)) >= 0)
 335                         {
 336                                 k = substring(s, 0, o);
 337                                 v = substring(s, o+2, -1);
 338                                 if(cvar_string(k) != v)
 339                                         goto cvar_fail;
 340                         }
 341                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 342                         {
 343                                 k = substring(s, 0, o);
 344                                 v = substring(s, o+2, -1);
 345                                 if(cvar_string(k) == v)
 346                                         goto cvar_fail;
 347                         }
 348                         else if(substring(s, 0, 1) == "!")
 349                         {
 350                                 k = substring(s, 1, -1);
 351                                 if(cvar(k))
 352                                         goto cvar_fail;
 353                         }
 354                         else
 355                         {
 356                                 k = s;
 357                                 if (!cvar(k))
 358                                         goto cvar_fail;
 359                         }
 360                 }
 361                 inv = !inv;
 362 LABEL(cvar_fail)
 363                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 364                 if (!inv)
 365                 {
 366                         //print("cvarfilter fail\n");
 367                         delete(this);
 368                         __spawnfunc_expecting = false;
 369                         return;
 370                 }
 371         }
 372
 373         if(DoesQ3ARemoveThisEntity(this))
 374         {
 375                 delete(this);
 376                 __spawnfunc_expecting = false;
 377                 return;
 378         }
 379
 380         set_movetype(this, this.movetype);
 381
 382         if(this.monster_attack)
 383                 IL_PUSH(g_monster_targets, this);
 384
 385         // support special -1 and -2 angle from radiant
 386         if (this.angles == '0 -1 0')
 387                 this.angles = '-90 0 0';
 388         else if (this.angles == '0 -2 0')
 389                 this.angles = '+90 0 0';
 390
 391         if(this.originjitter.x != 0)
 392                 this.origin_x = this.origin.x + (random() * 2 - 1) * this.originjitter.x;
 393         if(this.originjitter.y != 0)
 394                 this.origin_y = this.origin.y + (random() * 2 - 1) * this.originjitter.y;
 395         if(this.originjitter.z != 0)
 396                 this.origin_z = this.origin.z + (random() * 2 - 1) * this.originjitter.z;
 397         if(this.anglesjitter.x != 0)
 398                 this.angles_x = this.angles.x + (random() * 2 - 1) * this.anglesjitter.x;
 399         if(this.anglesjitter.y != 0)
 400                 this.angles_y = this.angles.y + (random() * 2 - 1) * this.anglesjitter.y;
 401         if(this.anglesjitter.z != 0)
 402                 this.angles_z = this.angles.z + (random() * 2 - 1) * this.anglesjitter.z;
 403         if(this.anglejitter != 0)
 404                 this.angles_y = this.angles.y + (random() * 2 - 1) * this.anglejitter;
 405
 406         if(MUTATOR_CALLHOOK(OnEntityPreSpawn, this))
 407         {
 408                 delete(this);
 409                 __spawnfunc_expecting = false;
 410                 return;
 411         }
 412 }
 413
 414 void WarpZone_PostInitialize_Callback()
 415 {
 416         // create waypoint links for warpzones
 417         //for(entity e = warpzone_first; e; e = e.warpzone_next)
 418         for(entity e = NULL; (e = find(e, classname, "trigger_warpzone")); )
 419         {
 420                 vector src, dst;
 421                 src = (e.absmin + e.absmax) * 0.5;
 422                 makevectors(e.warpzone_angles);
 423                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 424                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 425                 makevectors(e.enemy.warpzone_angles);
 426                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 427                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 428         }
 429 }