qcsrc/server/sv_main.qc

   1
   2 #include "anticheat.qh"
   3 #include "g_hook.qh"
   4 #include "g_world.qh"
   5
   6 #include "bot/bot.qh"
   7 #include "bot/waypoints.qh"
   8
   9 #include "command/common.qh"
  10
  11 #include "mutators/all.qh"
  12 #include "weapons/csqcprojectile.qh"
  13
  14 #include "../common/constants.qh"
  15 #include "../common/deathtypes/all.qh"
  16 #include "../common/debug.qh"
  17 #include "../common/mapinfo.qh"
  18 #include "../common/util.qh"
  19
  20 #include "../common/vehicles/all.qh"
  21 #include "../common/weapons/all.qh"
  22
  23 #include "../lib/csqcmodel/sv_model.qh"
  24
  25 #include "../lib/warpzone/common.qh"
  26 #include "../lib/warpzone/server.qh"
  27
  28 .float lastground;
  29 .int state;
  30
  31 void CreatureFrame_hotliquids(entity this)
  32 {
  33         if (this.dmgtime < time)
  34         {
  35                 this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  36
  37                 if (this.flags & FL_PROJECTILE)
  38                 {
  39                         if (this.watertype == CONTENT_LAVA)
  40                                 Damage (this, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  41                         else if (this.watertype == CONTENT_SLIME)
  42                                 Damage (this, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  43                 }
  44                 else
  45                 {
  46                         if (this.watertype == CONTENT_LAVA)
  47                         {
  48                                 if (this.watersound_finished < time)
  49                                 {
  50                                         this.watersound_finished = time + 0.5;
  51                                         sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  52                                 }
  53                                 Damage (this, world, world, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  54                                 if(autocvar_g_balance_contents_playerdamage_lava_burn)
  55                                         Fire_AddDamage(this, world, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  56                         }
  57                         else if (this.watertype == CONTENT_SLIME)
  58                         {
  59                                 if (this.watersound_finished < time)
  60                                 {
  61                                         this.watersound_finished = time + 0.5;
  62                                         sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  63                                 }
  64                                 Damage (this, world, world, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  65                         }
  66                 }
  67         }
  68 }
  69
  70 void CreatureFrame_Liquids(entity this)
  71 {
  72         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  73         {
  74                 if (!(this.flags & FL_INWATER))
  75                 {
  76                         this.flags |= FL_INWATER;
  77                         this.dmgtime = 0;
  78                 }
  79
  80                 CreatureFrame_hotliquids(this);
  81         }
  82         else
  83         {
  84                 if (this.flags & FL_INWATER)
  85                 {
  86                         // play leave water sound
  87                         this.flags &= ~FL_INWATER;
  88                         this.dmgtime = 0;
  89                 }
  90                 this.air_finished = time + 12;
  91                 this.dmg = 2;
  92         }
  93 }
  94
  95 void CreatureFrame_FallDamage(entity this)
  96 {
  97         if(!IS_VEHICLE(this) && !(this.flags & FL_PROJECTILE)) // vehicles don't get falling damage
  98         {
  99                 // check for falling damage
 100                 float velocity_len = vlen(this.velocity);
 101                 if(!this.hook.state)
 102                 {
 103                         float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 104                         if (this.deadflag)
 105                                 dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 106                         else
 107                                 dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 108                         if (dm > 0)
 109                                 Damage (this, world, world, dm, DEATH_FALL.m_id, this.origin, '0 0 0');
 110                 }
 111
 112                 if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 113                         Damage (this, world, world, 100000, DEATH_SHOOTING_STAR.m_id, this.origin, '0 0 0');
 114         }
 115 }
 116
 117 void CreatureFrame_All()
 118 {
 119         for(entity e = world; (e = findfloat(e, damagedbycontents, true)); )
 120         {
 121                 if (e.movetype == MOVETYPE_NOCLIP) { continue; }
 122
 123                 CreatureFrame_Liquids(e);
 124                 CreatureFrame_FallDamage(e);
 125
 126         e.oldvelocity = e.velocity;
 127         }
 128 }
 129
 130
 131 /*
 132 =============
 133 StartFrame
 134
 135 Called before each frame by the server
 136 =============
 137 */
 138
 139 float game_delay;
 140 float game_delay_last;
 141
 142 float RedirectionThink();
 143 void StartFrame()
 144 {
 145         SELFPARAM();
 146         execute_next_frame();
 147
 148         remove = remove_unsafely; // not during spawning!
 149         serverprevtime = servertime;
 150         servertime = time;
 151         serverframetime = frametime;
 152
 153 #ifdef PROFILING
 154         if(time > client_cefc_accumulatortime + 1)
 155         {
 156                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 157                 LOG_INFO("CEFC time: ", ftos(t * 1000), "ms; ");
 158                 int c_seeing = 0;
 159                 int c_seen = 0;
 160                 entity cl;
 161                 FOR_EACH_CLIENT(cl)
 162                 {
 163                         if(IS_REAL_CLIENT(cl))
 164                                 ++c_seeing;
 165                         if(IS_PLAYER(cl))
 166                                 ++c_seen;
 167                 }
 168                 LOG_INFO("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 169                 LOG_INFO("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 170
 171                 client_cefc_accumulatortime = time;
 172                 client_cefc_accumulator = 0;
 173         }
 174 #endif
 175
 176         for(entity e = world; (e = findfloat(e, csqcprojectile_clientanimate, 1)); )
 177                 CSQCProjectile_Check(e);
 178
 179         if(RedirectionThink())
 180                 return;
 181
 182         UncustomizeEntitiesRun();
 183         InitializeEntitiesRun();
 184
 185         WarpZone_StartFrame();
 186
 187         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 188         if(sys_frametime <= 0)
 189                 sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 190
 191         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 192                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 193
 194         skill = autocvar_skill;
 195
 196         // detect when the pre-game countdown (if any) has ended and the game has started
 197         game_delay = (time < game_starttime);
 198
 199         if(autocvar_sv_eventlog && game_delay_last && !game_delay)
 200                 GameLogEcho(":startdelay_ended");
 201
 202         game_delay_last = game_delay;
 203
 204         CreatureFrame_All();
 205         CheckRules_World();
 206
 207         // if in warmup stage and limit for warmup is hit start match
 208         if(warmup_stage)
 209         if(!gameover)
 210         if((g_warmup_limit > 0 && time >= g_warmup_limit)
 211          || (g_warmup_limit == 0 && autocvar_timelimit != 0 && time >= autocvar_timelimit * 60))
 212         {
 213                 ReadyRestart();
 214                 return;
 215         }
 216
 217         bot_serverframe();
 218         anticheat_startframe();
 219         MUTATOR_CALLHOOK(SV_StartFrame);
 220         {
 221         entity e;
 222         FOR_EACH_CLIENT(e)
 223         {
 224             GlobalStats_update(e);
 225         }
 226     }
 227 }
 228
 229 .vector originjitter;
 230 .vector anglesjitter;
 231 .float anglejitter;
 232 .string gametypefilter;
 233 .string cvarfilter;
 234 float DoesQ3ARemoveThisEntity();
 235 void SV_OnEntityPreSpawnFunction()
 236 {SELFPARAM();
 237         __spawnfunc_expect = this;
 238         if (self)
 239         if (self.gametypefilter != "")
 240         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, self.gametypefilter))
 241         {
 242                 remove(self);
 243                 return;
 244         }
 245         if(self.cvarfilter != "")
 246         {
 247                 float n, i, o, inv;
 248                 string s, k, v;
 249                 inv = 0;
 250
 251                 s = self.cvarfilter;
 252                 if(substring(s, 0, 1) == "+")
 253                 {
 254                         s = substring(s, 1, -1);
 255                 }
 256                 else if(substring(s, 0, 1) == "-")
 257                 {
 258                         inv = 1;
 259                         s = substring(s, 1, -1);
 260                 }
 261
 262                 n = tokenize_console(s);
 263                 for(i = 0; i < n; ++i)
 264                 {
 265                         s = argv(i);
 266                         // syntax:
 267                         // var>x
 268                         // var<x
 269                         // var>=x
 270                         // var<=x
 271                         // var==x
 272                         // var!=x
 273                         // var===x
 274                         // var!==x
 275                         if((o = strstrofs(s, ">=", 0)) >= 0)
 276                         {
 277                                 k = substring(s, 0, o);
 278                                 v = substring(s, o+2, -1);
 279                                 if(cvar(k) < stof(v))
 280                                         goto cvar_fail;
 281                         }
 282                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 283                         {
 284                                 k = substring(s, 0, o);
 285                                 v = substring(s, o+2, -1);
 286                                 if(cvar(k) > stof(v))
 287                                         goto cvar_fail;
 288                         }
 289                         else if((o = strstrofs(s, ">", 0)) >= 0)
 290                         {
 291                                 k = substring(s, 0, o);
 292                                 v = substring(s, o+1, -1);
 293                                 if(cvar(k) <= stof(v))
 294                                         goto cvar_fail;
 295                         }
 296                         else if((o = strstrofs(s, "<", 0)) >= 0)
 297                         {
 298                                 k = substring(s, 0, o);
 299                                 v = substring(s, o+1, -1);
 300                                 if(cvar(k) >= stof(v))
 301                                         goto cvar_fail;
 302                         }
 303                         else if((o = strstrofs(s, "==", 0)) >= 0)
 304                         {
 305                                 k = substring(s, 0, o);
 306                                 v = substring(s, o+2, -1);
 307                                 if(cvar(k) != stof(v))
 308                                         goto cvar_fail;
 309                         }
 310                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 311                         {
 312                                 k = substring(s, 0, o);
 313                                 v = substring(s, o+2, -1);
 314                                 if(cvar(k) == stof(v))
 315                                         goto cvar_fail;
 316                         }
 317                         else if((o = strstrofs(s, "===", 0)) >= 0)
 318                         {
 319                                 k = substring(s, 0, o);
 320                                 v = substring(s, o+2, -1);
 321                                 if(cvar_string(k) != v)
 322                                         goto cvar_fail;
 323                         }
 324                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 325                         {
 326                                 k = substring(s, 0, o);
 327                                 v = substring(s, o+2, -1);
 328                                 if(cvar_string(k) == v)
 329                                         goto cvar_fail;
 330                         }
 331                         else if(substring(s, 0, 1) == "!")
 332                         {
 333                                 k = substring(s, 1, -1);
 334                                 if(cvar(k))
 335                                         goto cvar_fail;
 336                         }
 337                         else
 338                         {
 339                                 k = s;
 340                                 if (!cvar(k))
 341                                         goto cvar_fail;
 342                         }
 343                 }
 344                 inv = !inv;
 345 :cvar_fail
 346                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 347                 if (!inv)
 348                 {
 349                         //print("cvarfilter fail\n");
 350                         remove(self);
 351                         return;
 352                 }
 353         }
 354
 355         if(DoesQ3ARemoveThisEntity())
 356         {
 357                 remove(self);
 358                 return;
 359         }
 360
 361         // support special -1 and -2 angle from radiant
 362         if (self.angles == '0 -1 0')
 363                 self.angles = '-90 0 0';
 364         else if (self.angles == '0 -2 0')
 365                 self.angles = '+90 0 0';
 366
 367         if(self.originjitter.x != 0)
 368                 self.origin_x = self.origin.x + (random() * 2 - 1) * self.originjitter.x;
 369         if(self.originjitter.y != 0)
 370                 self.origin_y = self.origin.y + (random() * 2 - 1) * self.originjitter.y;
 371         if(self.originjitter.z != 0)
 372                 self.origin_z = self.origin.z + (random() * 2 - 1) * self.originjitter.z;
 373         if(self.anglesjitter.x != 0)
 374                 self.angles_x = self.angles.x + (random() * 2 - 1) * self.anglesjitter.x;
 375         if(self.anglesjitter.y != 0)
 376                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglesjitter.y;
 377         if(self.anglesjitter.z != 0)
 378                 self.angles_z = self.angles.z + (random() * 2 - 1) * self.anglesjitter.z;
 379         if(self.anglejitter != 0)
 380                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglejitter;
 381
 382         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
 383         {
 384                 remove(self);
 385                 return;
 386         }
 387 }
 388
 389 void WarpZone_PostInitialize_Callback()
 390 {
 391         // create waypoint links for warpzones
 392         entity e;
 393         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 394         {
 395                 vector src, dst;
 396                 src = (e.absmin + e.absmax) * 0.5;
 397                 makevectors(e.warpzone_angles);
 398                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 399                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 400                 makevectors(e.enemy.warpzone_angles);
 401                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 402                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 403         }
 404 }